New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 3558

Last change on this file since 3558 was 3558, checked in by rblod, 11 years ago

Fix issues when using key_nosignedzeo, see ticket #996

  • Property svn:keywords set to Id
File size: 18.0 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd  : update the tracer trend with the horizontal
20   !!                  and vertical advection trends using a TVD scheme
21   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
22   !!                  algorithm
23   !!----------------------------------------------------------------------
24   USE oce             ! ocean dynamics and active tracers
25   USE dom_oce         ! ocean space and time domain
26   USE trdmod_oce      ! tracers trends
27   USE trdtra          ! tracers trends
28   USE in_out_manager  ! I/O manager
29   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
30   USE lib_mpp         ! MPP library
31   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
32   USE diaptr          ! poleward transport diagnostics
33   USE trc_oce         ! share passive tracers/Ocean variables
34   USE wrk_nemo        ! Memory Allocation
35   USE timing          ! Timing
36   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   tra_adv_tvd    ! routine called by step.F90
42
43   LOGICAL ::   l_trd   ! flag to compute trends
44
45   !! * Substitutions
46#  include "domzgr_substitute.h90"
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE tra_adv_tvd ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
56      &                                       ptb, ptn, pta, kjpt )
57      !!----------------------------------------------------------------------
58      !!                  ***  ROUTINE tra_adv_tvd  ***
59      !!
60      !! **  Purpose :   Compute the now trend due to total advection of
61      !!       tracers and add it to the general trend of tracer equations
62      !!
63      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
64      !!       corrected flux (monotonic correction)
65      !!       note: - this advection scheme needs a leap-frog time scheme
66      !!
67      !! ** Action : - update (pta) with the now advective tracer trends
68      !!             - save the trends
69      !!----------------------------------------------------------------------
70      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
71      !
72      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
73      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
74      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
75      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
76      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
77      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
79      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
80      !
81      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices 
82      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
83      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
84      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
85      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz
86      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd')
90      !
91      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz )
92      !
93      IF( kt == kit000 )  THEN
94         IF(lwp) WRITE(numout,*)
95         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
96         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
97         !
98         l_trd = .FALSE.
99         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
100      ENDIF
101      !
102      IF( l_trd )  THEN
103         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
104         ztrdx(:,:,:) = 0.e0   ;    ztrdy(:,:,:) = 0.e0   ;   ztrdz(:,:,:) = 0.e0
105      ENDIF
106      !
107      zwi(:,:,:) = 0.e0
108      !
109      !                                                          ! ===========
110      DO jn = 1, kjpt                                            ! tracer loop
111         !                                                       ! ===========
112         ! 1. Bottom value : flux set to zero
113         ! ----------------------------------
114         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
115         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
116
117         ! 2. upstream advection with initial mass fluxes & intermediate update
118         ! --------------------------------------------------------------------
119         ! upstream tracer flux in the i and j direction
120         DO jk = 1, jpkm1
121            DO jj = 1, jpjm1
122               DO ji = 1, fs_jpim1   ! vector opt.
123                  ! upstream scheme
124                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
125                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
126                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
127                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
128                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
129                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
130               END DO
131            END DO
132         END DO
133
134         ! upstream tracer flux in the k direction
135         ! Surface value
136         IF( lk_vvl ) THEN   ;   zwz(:,:, 1 ) = 0.e0                         ! volume variable
137         ELSE                ;   zwz(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
138         ENDIF
139         ! Interior value
140         DO jk = 2, jpkm1
141            DO jj = 1, jpj
142               DO ji = 1, jpi
143                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
144                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
145                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
146               END DO
147            END DO
148         END DO
149
150         ! total advective trend
151         DO jk = 1, jpkm1
152            z2dtt = p2dt(jk)
153            DO jj = 2, jpjm1
154               DO ji = fs_2, fs_jpim1   ! vector opt.
155                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
156                  ! total intermediate advective trends
157                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
158                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
159                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
160                  ! update and guess with monotonic sheme
161                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
162                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
163               END DO
164            END DO
165         END DO
166         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
167         CALL lbc_lnk( zwi, 'T', 1. ) 
168
169         !                                 ! trend diagnostics (contribution of upstream fluxes)
170         IF( l_trd )  THEN 
171            ! store intermediate advective trends
172            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
173         END IF
174         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
175         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
176           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
177           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
178         ENDIF
179
180         ! 3. antidiffusive flux : high order minus low order
181         ! --------------------------------------------------
182         ! antidiffusive flux on i and j
183         DO jk = 1, jpkm1
184            DO jj = 1, jpjm1
185               DO ji = 1, fs_jpim1   ! vector opt.
186                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
187                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
188               END DO
189            END DO
190         END DO
191     
192         ! antidiffusive flux on k
193         zwz(:,:,1) = 0.e0         ! Surface value
194         !
195         DO jk = 2, jpkm1          ! Interior value
196            DO jj = 1, jpj
197               DO ji = 1, jpi
198                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
199               END DO
200            END DO
201         END DO
202         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
203         CALL lbc_lnk( zwz, 'W',  1. )
204
205         ! 4. monotonicity algorithm
206         ! -------------------------
207         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
208
209
210         ! 5. final trend with corrected fluxes
211         ! ------------------------------------
212         DO jk = 1, jpkm1
213            DO jj = 2, jpjm1
214               DO ji = fs_2, fs_jpim1   ! vector opt. 
215                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
216                  ! total advective trends
217                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
218                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
219                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
220                  ! add them to the general tracer trends
221                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
222               END DO
223            END DO
224         END DO
225
226         !                                 ! trend diagnostics (contribution of upstream fluxes)
227         IF( l_trd )  THEN
228            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
229            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
230            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
231           
232            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, ztrdx, pun, ptn(:,:,:,jn) )   
233            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
234            CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
235         END IF
236         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
237         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
238           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) ) + htr_adv(:)
239           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) ) + str_adv(:)
240         ENDIF
241         !
242      END DO
243      !
244                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz )
245      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
246      !
247      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd')
248      !
249   END SUBROUTINE tra_adv_tvd
250
251
252   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
253      !!---------------------------------------------------------------------
254      !!                    ***  ROUTINE nonosc  ***
255      !!     
256      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
257      !!       scheme and the before field by a nonoscillatory algorithm
258      !!
259      !! **  Method  :   ... ???
260      !!       warning : pbef and paft must be masked, but the boundaries
261      !!       conditions on the fluxes are not necessary zalezak (1979)
262      !!       drange (1995) multi-dimensional forward-in-time and upstream-
263      !!       in-space based differencing for fluid
264      !!----------------------------------------------------------------------
265      !
266      !!----------------------------------------------------------------------
267      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
268      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
269      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
270      !
271      INTEGER ::   ji, jj, jk   ! dummy loop indices
272      INTEGER ::   ikm1         ! local integer
273      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
274      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
275      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
276      !!----------------------------------------------------------------------
277      !
278      IF( nn_timing == 1 )  CALL timing_start('nonosc')
279      !
280      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
281      !
282
283      zbig  = 1.e+40_wp
284      zrtrn = 1.e-15_wp
285      zbetup(:,:,jpk) = 0._wp   ;   zbetdo(:,:,jpk) = 0._wp
286
287
288      ! Search local extrema
289      ! --------------------
290      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
291      zbup = MAX( pbef * tmask - zbig * ( 1.e0 - tmask ),   &
292         &        paft * tmask - zbig * ( 1.e0 - tmask )  )
293      zbdo = MIN( pbef * tmask + zbig * ( 1.e0 - tmask ),   &
294         &        paft * tmask + zbig * ( 1.e0 - tmask )  )
295
296      DO jk = 1, jpkm1
297         ikm1 = MAX(jk-1,1)
298         z2dtt = p2dt(jk)
299         DO jj = 2, jpjm1
300            DO ji = fs_2, fs_jpim1   ! vector opt.
301
302               ! search maximum in neighbourhood
303               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
304                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
305                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
306                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
307
308               ! search minimum in neighbourhood
309               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
310                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
311                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
312                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
313
314               ! positive part of the flux
315               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
316                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
317                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
318
319               ! negative part of the flux
320               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
321                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
322                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
323
324               ! up & down beta terms
325               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
326               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
327               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
328            END DO
329         END DO
330      END DO
331      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
332
333      ! 3. monotonic flux in the i & j direction (paa & pbb)
334      ! ----------------------------------------
335      DO jk = 1, jpkm1
336         DO jj = 2, jpjm1
337            DO ji = fs_2, fs_jpim1   ! vector opt.
338               zau = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
339               zbu = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
340               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
341               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1.e0 - zcu) * zbu )
342
343               zav = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
344               zbv = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
345               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
346               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1.e0 - zcv) * zbv )
347
348      ! monotonic flux in the k direction, i.e. pcc
349      ! -------------------------------------------
350               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
351               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
352               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
353               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1.e0 - zc) * zb )
354            END DO
355         END DO
356      END DO
357      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
358      !
359      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
360      !
361      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
362      !
363   END SUBROUTINE nonosc
364
365   !!======================================================================
366END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.