source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 6140

Last change on this file since 6140 was 6140, checked in by timgraham, 5 years ago

Merge of branches/2015/dev_merge_2015 back into trunk. Merge excludes NEMOGCM/TOOLS/OBSTOOLS/ for now due to issues with the change of file type. Will sort these manually with further commits.

Branch merged as follows:
In the working copy of branch ran:
svn merge svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk@HEAD
Small conflicts due to bug fixes applied to trunk since the dev_merge_2015 was copied. Bug fixes were applied to the branch as well so these were easy to resolve.
Branch committed at this stage

In working copy run:
svn switch svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk
to switch working copy

Run:
svn merge —reintegrate svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/2015/dev_merge_2015
to merge the branch into the trunk and then commit - no conflicts at this stage.

  • Property svn:keywords set to Id
File size: 22.9 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  ! 1994-08  (G. Madec, M. Imbard)
7   !!            8.0  ! 1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO ! 2002-08  (G. Madec)  Free form, F90
9   !!            1.0  ! 2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  ! 2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.7  ! 2014-01  (G. Madec, S. Masson)  restructuration/simplification of aht/aeiv specification
12   !!             -   ! 2014-02  (F. Lemarie, G. Madec)  triad operator (Griffies) + Method of Stabilizing Correction
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso   : update the tracer trend with the horizontal component of a iso-neutral laplacian operator
17   !!                   and with the vertical part of the isopycnal or geopotential s-coord. operator
18   !!----------------------------------------------------------------------
19   USE oce            ! ocean dynamics and active tracers
20   USE dom_oce        ! ocean space and time domain
21   USE trc_oce        ! share passive tracers/Ocean variables
22   USE zdf_oce        ! ocean vertical physics
23   USE ldftra         ! lateral diffusion: tracer eddy coefficients
24   USE ldfslp         ! iso-neutral slopes
25   USE diaptr         ! poleward transport diagnostics
26   !
27   USE in_out_manager ! I/O manager
28   USE iom            ! I/O library
29   USE phycst         ! physical constants
30   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
31   USE wrk_nemo       ! Memory Allocation
32   USE timing         ! Timing
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_ldf_iso   ! routine called by step.F90
38
39   !! * Substitutions
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48  SUBROUTINE tra_ldf_iso( kt, kit000, cdtype, pahu, pahv, pgu , pgv ,   &
49      &                                                   pgui, pgvi,   &
50      &                                       ptb , ptbb, pta , kjpt, kpass )
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE tra_ldf_iso  ***
53      !!
54      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
55      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
56      !!      add it to the general trend of tracer equation.
57      !!
58      !! ** Method  :   The horizontal component of the lateral diffusive trends
59      !!      is provided by a 2nd order operator rotated along neural or geopo-
60      !!      tential surfaces to which an eddy induced advection can be added
61      !!      It is computed using before fields (forward in time) and isopyc-
62      !!      nal or geopotential slopes computed in routine ldfslp.
63      !!
64      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
65      !!      ========    with partial cell update if ln_zps=T
66      !!                  with top     cell update if ln_isfcav
67      !!
68      !!      2nd part :  horizontal fluxes of the lateral mixing operator
69      !!      ========   
70      !!         zftu =  pahu e2u*e3u/e1u di[ tb ]
71      !!               - pahu e2u*uslp    dk[ mi(mk(tb)) ]
72      !!         zftv =  pahv e1v*e3v/e2v dj[ tb ]
73      !!               - pahv e2u*vslp    dk[ mj(mk(tb)) ]
74      !!      take the horizontal divergence of the fluxes:
75      !!         difft = 1/(e1e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
76      !!      Add this trend to the general trend (ta,sa):
77      !!         ta = ta + difft
78      !!
79      !!      3rd part: vertical trends of the lateral mixing operator
80      !!      ========  (excluding the vertical flux proportional to dk[t] )
81      !!      vertical fluxes associated with the rotated lateral mixing:
82      !!         zftw = - {  mi(mk(pahu)) * e2t*wslpi di[ mi(mk(tb)) ]
83      !!                   + mj(mk(pahv)) * e1t*wslpj dj[ mj(mk(tb)) ]  }
84      !!      take the horizontal divergence of the fluxes:
85      !!         difft = 1/(e1e2t*e3t) dk[ zftw ]
86      !!      Add this trend to the general trend (ta,sa):
87      !!         pta = pta + difft
88      !!
89      !! ** Action :   Update pta arrays with the before rotated diffusion
90      !!----------------------------------------------------------------------
91      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
92      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
93      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
94      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
95      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
96      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
97      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
98      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
99      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! tracer (kpass=1) or laplacian of tracer (kpass=2)
100      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptbb       ! tracer (only used in kpass=2)
101      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
102      !
103      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
104      INTEGER  ::  ikt
105      INTEGER  ::  ierr             ! local integer
106      REAL(wp) ::  zmsku, zahu_w, zabe1, zcof1, zcoef3   ! local scalars
107      REAL(wp) ::  zmskv, zahv_w, zabe2, zcof2, zcoef4   !   -      -
108      REAL(wp) ::  zcoef0, ze3w_2, zsign, z2dt, z1_2dt   !   -      -
109#if defined key_diaar5
110      REAL(wp) ::   zztmp   ! local scalar
111#endif
112      REAL(wp), POINTER, DIMENSION(:,:)   ::   zdkt, zdk1t, z2d
113      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdit, zdjt, zftu, zftv, ztfw 
114      !!----------------------------------------------------------------------
115      !
116      IF( nn_timing == 1 )  CALL timing_start('tra_ldf_iso')
117      !
118      CALL wrk_alloc( jpi,jpj,       zdkt, zdk1t, z2d ) 
119      CALL wrk_alloc( jpi,jpj,jpk,   zdit, zdjt , zftu, zftv, ztfw  ) 
120      !
121      IF( kt == kit000 )  THEN
122         IF(lwp) WRITE(numout,*)
123         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
124         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
125         !
126         akz     (:,:,:) = 0._wp     
127         ah_wslp2(:,:,:) = 0._wp
128      ENDIF
129      !                                               ! set time step size (Euler/Leapfrog)
130      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;   z2dt =     rdt      ! at nit000   (Euler)
131      ELSE                                        ;   z2dt = 2.* rdt      !             (Leapfrog)
132      ENDIF
133      z1_2dt = 1._wp / z2dt
134      !
135      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
136      ELSE                    ;   zsign = -1._wp
137      ENDIF
138         
139      !!----------------------------------------------------------------------
140      !!   0 - calculate  ah_wslp2 and akz
141      !!----------------------------------------------------------------------
142      !
143      IF( kpass == 1 ) THEN                  !==  first pass only  ==!
144         !
145         DO jk = 2, jpkm1
146            DO jj = 2, jpjm1
147               DO ji = fs_2, fs_jpim1   ! vector opt.
148                  !
149                  zmsku = wmask(ji,jj,jk) / MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)          &
150                     &                           + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk) , 1._wp  )
151                  zmskv = wmask(ji,jj,jk) / MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)          &
152                     &                           + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk) , 1._wp  )
153                     !
154                  zahu_w = (   pahu(ji  ,jj,jk-1) + pahu(ji-1,jj,jk)    &
155                     &       + pahu(ji-1,jj,jk-1) + pahu(ji  ,jj,jk)  ) * zmsku
156                  zahv_w = (   pahv(ji,jj  ,jk-1) + pahv(ji,jj-1,jk)    &
157                     &       + pahv(ji,jj-1,jk-1) + pahv(ji,jj  ,jk)  ) * zmskv
158                     !
159                  ah_wslp2(ji,jj,jk) = zahu_w * wslpi(ji,jj,jk) * wslpi(ji,jj,jk)   &
160                     &               + zahv_w * wslpj(ji,jj,jk) * wslpj(ji,jj,jk)
161               END DO
162            END DO
163         END DO
164         !
165         IF( ln_traldf_msc ) THEN                ! stabilizing vertical diffusivity coefficient
166            DO jk = 2, jpkm1
167               DO jj = 2, jpjm1
168                  DO ji = fs_2, fs_jpim1
169                     akz(ji,jj,jk) = 0.25_wp * (                                                                     &
170                        &              ( pahu(ji  ,jj,jk) + pahu(ji  ,jj,jk-1) ) / ( e1u(ji  ,jj) * e1u(ji  ,jj) )   &
171                        &            + ( pahu(ji-1,jj,jk) + pahu(ji-1,jj,jk-1) ) / ( e1u(ji-1,jj) * e1u(ji-1,jj) )   &
172                        &            + ( pahv(ji,jj  ,jk) + pahv(ji,jj  ,jk-1) ) / ( e2v(ji,jj  ) * e2v(ji,jj  ) )   &
173                        &            + ( pahv(ji,jj-1,jk) + pahv(ji,jj-1,jk-1) ) / ( e2v(ji,jj-1) * e2v(ji,jj-1) )   )
174                  END DO
175               END DO
176            END DO
177            !
178            IF( ln_traldf_blp ) THEN                ! bilaplacian operator
179               DO jk = 2, jpkm1
180                  DO jj = 1, jpjm1
181                     DO ji = 1, fs_jpim1
182                        akz(ji,jj,jk) = 16._wp * ah_wslp2(ji,jj,jk)   &
183                           &          * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ( e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk) )  )
184                     END DO
185                  END DO
186               END DO
187            ELSEIF( ln_traldf_lap ) THEN              ! laplacian operator
188               DO jk = 2, jpkm1
189                  DO jj = 1, jpjm1
190                     DO ji = 1, fs_jpim1
191                        ze3w_2 = e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk)
192                        zcoef0 = z2dt * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2  )
193                        akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * z1_2dt
194                     END DO
195                  END DO
196               END DO
197           ENDIF
198           !
199         ELSE                                    ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit
200            akz(:,:,:) = ah_wslp2(:,:,:)     
201         ENDIF
202      ENDIF
203      !
204      !                                                          ! ===========
205      DO jn = 1, kjpt                                            ! tracer loop
206         !                                                       ! ===========
207         !                                               
208         !!----------------------------------------------------------------------
209         !!   I - masked horizontal derivative
210         !!----------------------------------------------------------------------
211!!gm : bug.... why (x,:,:)?   (1,jpj,:) and (jpi,1,:) should be sufficient....
212         zdit (1,:,:) = 0._wp     ;     zdit (jpi,:,:) = 0._wp
213         zdjt (1,:,:) = 0._wp     ;     zdjt (jpi,:,:) = 0._wp
214         !!end
215
216         ! Horizontal tracer gradient
217         DO jk = 1, jpkm1
218            DO jj = 1, jpjm1
219               DO ji = 1, fs_jpim1   ! vector opt.
220                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
221                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
222               END DO
223            END DO
224         END DO
225         IF( ln_zps ) THEN      ! botton and surface ocean correction of the horizontal gradient
226            DO jj = 1, jpjm1              ! bottom correction (partial bottom cell)
227               DO ji = 1, fs_jpim1   ! vector opt.
228                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
229                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
230               END DO
231            END DO
232            IF( ln_isfcav ) THEN      ! first wet level beneath a cavity
233               DO jj = 1, jpjm1
234                  DO ji = 1, fs_jpim1   ! vector opt.
235                     IF( miku(ji,jj) > 1 )   zdit(ji,jj,miku(ji,jj)) = pgui(ji,jj,jn)         
236                     IF( mikv(ji,jj) > 1 )   zdjt(ji,jj,mikv(ji,jj)) = pgvi(ji,jj,jn)     
237                  END DO
238               END DO
239            ENDIF
240         ENDIF
241         !
242         !!----------------------------------------------------------------------
243         !!   II - horizontal trend  (full)
244         !!----------------------------------------------------------------------
245         !
246         DO jk = 1, jpkm1                                 ! Horizontal slab
247            !
248            !                             !== Vertical tracer gradient
249            zdk1t(:,:) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * wmask(:,:,jk+1)     ! level jk+1
250            !
251            IF( jk == 1 ) THEN   ;   zdkt(:,:) = zdk1t(:,:)                          ! surface: zdkt(jk=1)=zdkt(jk=2)
252            ELSE                 ;   zdkt(:,:) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * wmask(:,:,jk)
253            ENDIF
254            DO jj = 1 , jpjm1            !==  Horizontal fluxes
255               DO ji = 1, fs_jpim1   ! vector opt.
256                  zabe1 = pahu(ji,jj,jk) * e2_e1u(ji,jj) * e3u_n(ji,jj,jk)
257                  zabe2 = pahv(ji,jj,jk) * e1_e2v(ji,jj) * e3v_n(ji,jj,jk)
258                  !
259                  zmsku = 1. / MAX(  wmask(ji+1,jj,jk  ) + wmask(ji,jj,jk+1)   &
260                     &             + wmask(ji+1,jj,jk+1) + wmask(ji,jj,jk  ), 1. )
261                  !
262                  zmskv = 1. / MAX(  wmask(ji,jj+1,jk  ) + wmask(ji,jj,jk+1)   &
263                     &             + wmask(ji,jj+1,jk+1) + wmask(ji,jj,jk  ), 1. )
264                  !
265                  zcof1 = - pahu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
266                  zcof2 = - pahv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
267                  !
268                  zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
269                     &               + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
270                     &                          + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
271                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
272                     &               + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
273                     &                          + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)                 
274               END DO
275            END DO
276            !
277            DO jj = 2 , jpjm1          !== horizontal divergence and add to pta
278               DO ji = fs_2, fs_jpim1   ! vector opt.
279                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * (  zftu(ji,jj,jk) - zftu(ji-1,jj,jk)      &
280                     &                                           + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )   &
281                     &                                        * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
282               END DO
283            END DO
284         END DO                                        !   End of slab 
285
286         !!----------------------------------------------------------------------
287         !!   III - vertical trend (full)
288         !!----------------------------------------------------------------------
289         !
290         ztfw(1,:,:) = 0._wp     ;     ztfw(jpi,:,:) = 0._wp
291         !
292         ! Vertical fluxes
293         ! ---------------
294         !                          ! Surface and bottom vertical fluxes set to zero
295         ztfw(:,:, 1 ) = 0._wp      ;      ztfw(:,:,jpk) = 0._wp
296         
297         DO jk = 2, jpkm1           ! interior (2=<jk=<jpk-1)
298            DO jj = 2, jpjm1
299               DO ji = fs_2, fs_jpim1   ! vector opt.
300                  !
301                  zmsku = wmask(ji,jj,jk) / MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)          &
302                     &                           + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk) , 1._wp  )
303                  zmskv = wmask(ji,jj,jk) / MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)          &
304                     &                           + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk) , 1._wp  )
305                     !
306                  zahu_w = (   pahu(ji  ,jj,jk-1) + pahu(ji-1,jj,jk)    &
307                     &       + pahu(ji-1,jj,jk-1) + pahu(ji  ,jj,jk)  ) * zmsku
308                  zahv_w = (   pahv(ji,jj  ,jk-1) + pahv(ji,jj-1,jk)    &
309                     &       + pahv(ji,jj-1,jk-1) + pahv(ji,jj  ,jk)  ) * zmskv
310                     !
311                  zcoef3 = - zahu_w * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)   !wslpi & j are already w-masked
312                  zcoef4 = - zahv_w * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
313                  !
314                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
315                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
316                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
317                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
318               END DO
319            END DO
320         END DO
321         !                                !==  add the vertical 33 flux  ==!
322         IF( ln_traldf_lap ) THEN               ! laplacian case: eddy coef = ah_wslp2 - akz
323            DO jk = 2, jpkm1       
324               DO jj = 1, jpjm1
325                  DO ji = fs_2, fs_jpim1
326                     ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / e3w_n(ji,jj,jk) * wmask(ji,jj,jk)   &
327                        &                            * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) )             &
328                        &                            * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) )
329                  END DO
330               END DO
331            END DO
332            !
333         ELSE                                   ! bilaplacian
334            SELECT CASE( kpass )
335            CASE(  1  )                            ! 1st pass : eddy coef = ah_wslp2
336               DO jk = 2, jpkm1 
337                  DO jj = 1, jpjm1
338                     DO ji = fs_2, fs_jpim1
339                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk)    &
340                           &           + ah_wslp2(ji,jj,jk) * e1e2t(ji,jj)   &
341                           &           * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) ) / e3w_n(ji,jj,jk) * wmask(ji,jj,jk)
342                     END DO
343                  END DO
344               END DO
345            CASE(  2  )                         ! 2nd pass : eddy flux = ah_wslp2 and akz applied on ptb  and ptbb gradients, resp.
346               DO jk = 2, jpkm1 
347                  DO jj = 1, jpjm1
348                     DO ji = fs_2, fs_jpim1
349                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / e3w_n(ji,jj,jk) * wmask(ji,jj,jk)                      &
350                           &                            * (  ah_wslp2(ji,jj,jk) * ( ptb (ji,jj,jk-1,jn) - ptb (ji,jj,jk,jn) )   &
351                           &                               + akz     (ji,jj,jk) * ( ptbb(ji,jj,jk-1,jn) - ptbb(ji,jj,jk,jn) )   )
352                     END DO
353                  END DO
354               END DO
355            END SELECT
356         ENDIF
357         !         
358         DO jk = 1, jpkm1                 !==  Divergence of vertical fluxes added to pta  ==!
359            DO jj = 2, jpjm1
360               DO ji = fs_2, fs_jpim1   ! vector opt.
361                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * (  ztfw (ji,jj,jk) - ztfw(ji,jj,jk+1)  )   &
362                     &                                        * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
363               END DO
364            END DO
365         END DO
366         !
367         IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR.  &     !==  first pass only (  laplacian)  ==!
368             ( kpass == 2 .AND. ln_traldf_blp ) ) THEN      !==  2nd   pass      (bilaplacian)  ==!
369            !
370            !                             ! "Poleward" diffusive heat or salt transports (T-S case only)
371            IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN
372               ! note sign is reversed to give down-gradient diffusive transports (#1043)
373               IF( jn == jp_tem)   htr_ldf(:) = ptr_sj( -zftv(:,:,:) )
374               IF( jn == jp_sal)   str_ldf(:) = ptr_sj( -zftv(:,:,:) )
375            ENDIF
376            !
377            IF( iom_use("udiff_heattr") .OR. iom_use("vdiff_heattr") ) THEN
378              !
379              IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
380                  z2d(:,:) = zftu(ji,jj,1) 
381                  DO jk = 2, jpkm1
382                     DO jj = 2, jpjm1
383                        DO ji = fs_2, fs_jpim1   ! vector opt.
384                           z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
385                        END DO
386                     END DO
387                  END DO
388!!gm CAUTION I think there is an error of sign when using BLP operator....
389!!gm         a multiplication by zsign is required (to be checked twice !)
390                  z2d(:,:) = - rau0_rcp * z2d(:,:)     ! note sign is reversed to give down-gradient diffusive transports (#1043)
391                  CALL lbc_lnk( z2d, 'U', -1. )
392                  CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
393                  !
394                  z2d(:,:) = zftv(ji,jj,1) 
395                  DO jk = 2, jpkm1
396                     DO jj = 2, jpjm1
397                        DO ji = fs_2, fs_jpim1   ! vector opt.
398                           z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
399                        END DO
400                     END DO
401                  END DO
402                  z2d(:,:) = - rau0_rcp * z2d(:,:)     ! note sign is reversed to give down-gradient diffusive transports (#1043)
403                  CALL lbc_lnk( z2d, 'V', -1. )
404                  CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
405               END IF
406               !
407            ENDIF
408            !
409         ENDIF                                                    !== end pass selection  ==!
410         !
411         !                                                        ! ===============
412      END DO                                                      ! end tracer loop
413      !                                                           ! ===============
414      !
415      CALL wrk_dealloc( jpi, jpj,      zdkt, zdk1t, z2d ) 
416      CALL wrk_dealloc( jpi, jpj, jpk, zdit, zdjt , zftu, zftv, ztfw  ) 
417      !
418      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_iso')
419      !
420   END SUBROUTINE tra_ldf_iso
421
422   !!==============================================================================
423END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.