New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso_grif.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso_grif.F90 @ 2528

Last change on this file since 2528 was 2528, checked in by rblod, 13 years ago

Update NEMOGCM from branch nemo_v3_3_beta
  • Property svn:keywords set to Id
File size: 17.7 KB
Line 
1MODULE traldf_iso_grif
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso_grif  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History : 3.3  ! 2010-10  (G. Nurser, C. Harris, G. Madec) 
7   !!                !          Griffies operator version adapted from traldf_iso.F90
8   !!----------------------------------------------------------------------
9#if   defined key_ldfslp   ||   defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_ldfslp'               slope of the lateral diffusive direction
12   !!----------------------------------------------------------------------
13   !!   tra_ldf_iso_grif  : update the tracer trend with the horizontal component 
14   !!                       of the Griffies iso-neutral laplacian operator
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and active tracers
17   USE dom_oce         ! ocean space and time domain
18   USE trc_oce         ! share passive tracers/Ocean variables
19   USE zdf_oce         ! ocean vertical physics
20   USE ldftra_oce      ! ocean active tracers: lateral physics
21   USE ldfslp          ! iso-neutral slopes
22   USE diaptr          ! poleward transport diagnostics
23   USE in_out_manager  ! I/O manager
24   USE iom             ! I/O library
25#if defined key_diaar5
26   USE phycst          ! physical constants
27   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
28#endif
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC tra_ldf_iso_grif   ! routine called by traldf.F90
34
35   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE ::   psix_eiv
36   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE ::   psiy_eiv
37   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE ::   ah_wslp2
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41#  include "ldftra_substitute.h90"
42#  include "vectopt_loop_substitute.h90"
43#  include "ldfeiv_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51  SUBROUTINE tra_ldf_iso_grif( kt, cdtype, pgu, pgv,              &
52       &                                   ptb, pta, kjpt, pahtb0 )
53      !!----------------------------------------------------------------------
54      !!                  ***  ROUTINE tra_ldf_iso_grif  ***
55      !!
56      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
57      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
58      !!      add it to the general trend of tracer equation.
59      !!
60      !! ** Method  :   The horizontal component of the lateral diffusive trends
61      !!      is provided by a 2nd order operator rotated along neural or geopo-
62      !!      tential surfaces to which an eddy induced advection can be added
63      !!      It is computed using before fields (forward in time) and isopyc-
64      !!      nal or geopotential slopes computed in routine ldfslp.
65      !!
66      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
67      !!      ========    with partial cell update if ln_zps=T.
68      !!
69      !!      2nd part :  horizontal fluxes of the lateral mixing operator
70      !!      ========   
71      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
72      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
73      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
74      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
75      !!      take the horizontal divergence of the fluxes:
76      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
77      !!      Add this trend to the general trend (ta,sa):
78      !!         ta = ta + difft
79      !!
80      !!      3rd part: vertical trends of the lateral mixing operator
81      !!      ========  (excluding the vertical flux proportional to dk[t] )
82      !!      vertical fluxes associated with the rotated lateral mixing:
83      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
84      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
85      !!      take the horizontal divergence of the fluxes:
86      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
87      !!      Add this trend to the general trend (ta,sa):
88      !!         pta = pta + difft
89      !!
90      !! ** Action :   Update pta arrays with the before rotated diffusion
91      !!----------------------------------------------------------------------
92      USE oce,   zftu => ua   ! use ua as workspace
93      USE oce,   zftv => va   ! use va as workspace
94      !!
95      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
96      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
97      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
98      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
99      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
100      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
101      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
102      !!
103      INTEGER  ::  ji, jj, jk,jn   ! dummy loop indices
104      INTEGER  ::  ip,jp,kp        ! dummy loop indices
105      INTEGER  ::  ierr            ! temporary integer
106      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
107      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
108      REAL(wp) ::  zcoef0, zbtr                  !   -      -
109      REAL(wp), DIMENSION(jpi,jpj,0:1) ::   zdkt               ! 2D+1 workspace
110      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdit, zdjt, ztfw   ! 3D workspace
111      !
112      REAL(wp) ::   zslope_skew, zslope_iso, zslope2, zbu, zbv
113      REAL(wp) ::   ze1ur, zdxt, ze2vr, ze3wr, zdyt, zdzt
114      REAL(wp) ::   zah, zah_slp, zaei_slp
115#if defined key_diaar5
116      REAL(wp), DIMENSION(jpi,jpj)     ::   z2d                ! 2D workspace
117      REAL(wp)                         ::   zztmp              ! local scalar
118#endif
119      !!----------------------------------------------------------------------
120
121      IF( kt == nit000 )  THEN
122         IF(lwp) WRITE(numout,*)
123         IF(lwp) WRITE(numout,*) 'tra_ldf_iso_grif : rotated laplacian diffusion operator on ', cdtype
124         IF(lwp) WRITE(numout,*) '                   WARNING: STILL UNDER TEST, NOT RECOMMENDED. USE AT YOUR OWN PERIL'
125         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
126         ALLOCATE( ah_wslp2(jpi,jpj,jpk) , STAT=ierr )
127         IF( ierr > 0 ) THEN
128            CALL ctl_stop( 'tra_ldf_iso_grif : unable to allocate Griffies operator ah_wslp2 ' )   ;   RETURN
129         ENDIF
130         IF( ln_traldf_gdia ) THEN
131            ALLOCATE( psix_eiv(jpi,jpj,jpk) , psiy_eiv(jpi,jpj,jpk) , STAT=ierr )
132            IF( ierr > 0 ) THEN
133               CALL ctl_stop( 'tra_ldf_iso_grif : unable to allocate Griffies operator diagnostics ' )   ;   RETURN
134            ENDIF
135         ENDIF
136      ENDIF
137
138      !!----------------------------------------------------------------------
139      !!   0 - calculate  ah_wslp2, psix_eiv, psiy_eiv
140      !!----------------------------------------------------------------------
141
142!!gm Future development: consider using Ah defined at T-points and attached to the 4 t-point triads
143
144      ah_wslp2(:,:,:) = 0._wp
145      IF( ln_traldf_gdia ) THEN
146         psix_eiv(:,:,:) = 0._wp
147         psiy_eiv(:,:,:) = 0._wp
148      ENDIF
149
150      DO ip = 0, 1
151         DO kp = 0, 1
152            DO jk = 1, jpkm1
153               DO jj = 1, jpjm1
154                  DO ji = 1, fs_jpim1
155                     ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
156                     zbu   = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
157                     zah   = fsahtu(ji,jj,jk)                                  !  fsaht(ji+ip,jj,jk)
158                     zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
159                     zslope2 = zslope_skew - ( fsdept(ji+1,jj,jk) - fsdept(ji ,jj ,jk) ) * ze1ur * umask(ji,jj,jk+kp)
160                     zslope2 = zslope2 *zslope2
161                     ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp)    &
162                        &                     + zah * ( zbu * ze3wr / ( e1t(ji+ip,jj) * e2t(ji+ip,jj) ) ) * zslope2
163                     IF( ln_traldf_gdia ) THEN
164                        zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew        !fsaeit(ji+ip,jj,jk)*zslope_skew
165                        psix_eiv(ji,jj,jk+kp) = psix_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp
166                     ENDIF
167                  END DO
168               END DO
169            END DO
170         END DO
171      END DO
172      !
173      DO jp = 0, 1
174         DO kp = 0, 1
175            DO jk = 1, jpkm1
176               DO jj = 1, jpjm1
177                  DO ji=1,fs_jpim1
178                     ze3wr = 1.0_wp / fse3w(ji,jj+jp,jk+kp)
179                     zbv   = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
180                     zah   = fsahtu(ji,jj,jk)                                       !fsaht(ji,jj+jp,jk)
181                     zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
182                     zslope2 = zslope_skew - ( fsdept(ji,jj+1,jk) - fsdept(ji,jj,jk) ) * ze2vr * vmask(ji,jj,jk+kp)
183                     zslope2 = zslope2 * zslope2
184                     ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp)   &
185                        &                     + zah * ( zbv * ze3wr / ( e1t(ji,jj+jp) * e2t(ji,jj+jp) ) ) * zslope2
186                     IF( ln_traldf_gdia ) THEN
187                        zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew     !fsaeit(ji,jj+jp,jk)*zslope_skew
188                        psiy_eiv(ji,jj,jk+kp) = psiy_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp
189                     ENDIF
190                  END DO
191               END DO
192            END DO
193         END DO
194      END DO
195      !
196      !                                                          ! ===========
197      DO jn = 1, kjpt                                            ! tracer loop
198         !                                                       ! ===========
199         ! Zero fluxes for each tracer
200         ztfw(:,:,:) = 0._wp
201         zftu(:,:,:) = 0._wp
202         zftv(:,:,:) = 0._wp
203         !                                               
204         DO jk = 1, jpkm1                          !==  before lateral T & S gradients at T-level jk  ==!
205            DO jj = 1, jpjm1
206               DO ji = 1, fs_jpim1   ! vector opt.
207                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
208                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
209               END DO
210            END DO
211         END DO
212         IF( ln_zps ) THEN                               ! partial steps: correction at the last level
213# if defined key_vectopt_loop
214            DO jj = 1, 1
215               DO ji = 1, jpij-jpi   ! vector opt. (forced unrolling)
216# else
217            DO jj = 1, jpjm1
218               DO ji = 1, jpim1
219# endif
220                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
221                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)     
222               END DO
223            END DO
224         ENDIF
225
226         !!----------------------------------------------------------------------
227         !!   II - horizontal trend  (full)
228         !!----------------------------------------------------------------------
229         !
230         DO jk = 1, jpkm1
231            !
232            !                    !==  Vertical tracer gradient at level jk and jk+1
233            zdkt(:,:,1) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
234            !
235            !                          ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
236            IF( jk == 1 ) THEN   ;   zdkt(:,:,0) = zdkt(:,:,1)
237            ELSE                 ;   zdkt(:,:,0) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk)
238            ENDIF
239
240            IF( .NOT. l_triad_iso ) THEN
241               triadi = triadi_g
242               triadj = triadj_g
243            ENDIF
244
245            DO ip = 0, 1              !==  Horizontal & vertical fluxes
246               DO kp = 0, 1
247                  DO jj = 1, jpjm1
248                     DO ji = 1, fs_jpim1
249                        ze1ur = 1._wp / e1u(ji,jj)
250                        zdxt = zdit(ji,jj,jk) * ze1ur
251                        ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
252                        zdzt  = zdkt(ji+ip,jj,kp) * ze3wr
253                        zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
254                        zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
255
256                        zbu = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
257                        zah = fsahtu(ji,jj,jk)   !*umask(ji,jj,jk+kp)         !fsaht(ji+ip,jj,jk)           ===>>  ????
258                        zah_slp  = zah * zslope_iso
259                        zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew    !fsaeit(ji+ip,jj,jk)*zslope_skew
260                        zftu(ji,jj,jk) = zftu(ji,jj,jk) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
261                        ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr
262                     END DO
263                  END DO
264               END DO
265            END DO
266
267            DO jp = 0, 1
268               DO kp = 0, 1
269                  DO jj = 1, jpjm1
270                     DO ji = 1, fs_jpim1
271                        ze2vr = 1._wp / e2v(ji,jj)
272                        zdyt = zdjt(ji,jj,jk) * ze2vr
273                        ze3wr = 1._wp / fse3w(ji,jj+jp,jk+kp)
274                        zdzt = zdkt(ji,jj+jp,kp) * ze3wr
275                        zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
276                        zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
277                        zbv = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
278                        zah = fsahtv(ji,jj,jk)        !*vmask(ji,jj,jk+kp)         !fsaht(ji,jj+jp,jk)
279                        zah_slp = zah * zslope_iso
280                        zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew    !fsaeit(ji,jj+jp,jk)*zslope_skew
281                        zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
282                        ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr
283                     END DO
284                  END DO
285               END DO
286            END DO
287
288            !                        !==  divergence and add to the general trend  ==!
289            DO jj = 2 , jpjm1
290               DO ji = fs_2, fs_jpim1   ! vector opt.
291                  zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
292                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * (   zftu(ji-1,jj,jk) - zftu(ji,jj,jk)   &
293                     &                                           + zftv(ji,jj-1,jk) - zftv(ji,jj,jk)   )
294               END DO
295            END DO
296            !
297         END DO
298         !
299         DO jk = 1, jpkm1            !== Divergence of vertical fluxes added to the general tracer trend
300            DO jj = 2, jpjm1
301               DO ji = fs_2, fs_jpim1   ! vector opt.
302                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (  ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk)  )   &
303                     &                                / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
304               END DO
305            END DO
306         END DO
307         !
308         !                            ! "Poleward" diffusive heat or salt transports (T-S case only)
309         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
310            IF( jn == jp_tem)   htr_ldf(:) = ptr_vj( zftv(:,:,:) )        ! 3.3  names
311            IF( jn == jp_sal)   str_ldf(:) = ptr_vj( zftv(:,:,:) )
312         ENDIF
313
314#if defined key_diaar5
315         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
316            z2d(:,:) = 0._wp 
317            zztmp = rau0 * rcp 
318            DO jk = 1, jpkm1
319               DO jj = 2, jpjm1
320                  DO ji = fs_2, fs_jpim1   ! vector opt.
321                     z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
322                  END DO
323               END DO
324            END DO
325            z2d(:,:) = zztmp * z2d(:,:)
326            CALL lbc_lnk( z2d, 'U', -1. )
327            CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
328            z2d(:,:) = 0._wp 
329            DO jk = 1, jpkm1
330               DO jj = 2, jpjm1
331                  DO ji = fs_2, fs_jpim1   ! vector opt.
332                     z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
333                  END DO
334               END DO
335            END DO
336            z2d(:,:) = zztmp * z2d(:,:)
337            CALL lbc_lnk( z2d, 'V', -1. )
338            CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
339         END IF
340#endif
341         !
342      END DO
343      !
344  END SUBROUTINE tra_ldf_iso_grif
345
346#else
347   !!----------------------------------------------------------------------
348   !!   default option :   Dummy code   NO rotation of the diffusive tensor
349   !!----------------------------------------------------------------------
350CONTAINS
351   SUBROUTINE tra_ldf_iso_grif( kt, cdtype, pgu, pgv, ptb, pta, kjpt, pahtb0 )      ! Empty routine
352      CHARACTER(len=3) ::   cdtype
353      REAL, DIMENSION(:,:,:) ::   pgu, pgv   ! tracer gradient at pstep levels
354      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
355      WRITE(*,*) 'tra_ldf_iso_grif: You should not have seen this print! error?', kt, cdtype,    &
356         &                  pgu(1,1,1), pgv(1,1,1), ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
357   END SUBROUTINE tra_ldf_iso_grif
358#endif
359
360   !!==============================================================================
361END MODULE traldf_iso_grif
Note: See TracBrowser for help on using the repository browser.