New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_lap.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_lap.F90 @ 2528

Last change on this file since 2528 was 2528, checked in by rblod, 13 years ago

Update NEMOGCM from branch nemo_v3_3_beta

  • Property svn:keywords set to Id
File size: 7.6 KB
Line 
1MODULE traldf_lap
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6   !! History :  OPA  !  87-06  (P. Andrich, D. L Hostis)  Original code
7   !!                 !  91-11  (G. Madec)
8   !!                 !  95-11  (G. Madec)  suppress volumetric scale factors
9   !!                 !  96-01  (G. Madec)  statement function for e3
10   !!            NEMO !  02-06  (G. Madec)  F90: Free form and module
11   !!            1.0  !  04-08  (C. Talandier) New trends organization
12   !!                 !  05-11  (G. Madec)  add zps case
13   !!            3.0  !  10-06  (C. Ethe, G. Madec) Merge TRA-TRC
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   tra_ldf_lap  : update the tracer trend with the horizontal diffusion
18   !!                 using a iso-level harmonic (laplacien) operator.
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and active tracers
21   USE dom_oce         ! ocean space and time domain
22   USE ldftra_oce      ! ocean active tracers: lateral physics
23   USE in_out_manager  ! I/O manager
24   USE diaptr          ! poleward transport diagnostics
25   USE trc_oce         ! share passive tracers/Ocean variables
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   tra_ldf_lap   ! routine called by step.F90
31
32   REAL(wp), DIMENSION(jpi,jpj) ::   e1ur, e2vr   ! scale factor coefficients
33
34   !! * Substitutions
35#  include "domzgr_substitute.h90"
36#  include "ldftra_substitute.h90"
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
40   !! $Id$
41   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE tra_ldf_lap( kt, cdtype, pgu, pgv,      &
46      &                                ptb, pta, kjpt ) 
47      !!----------------------------------------------------------------------
48      !!                  ***  ROUTINE tra_ldf_lap  ***
49      !!                   
50      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
51      !!      trend and add it to the general trend of tracer equation.
52      !!
53      !! ** Method  :   Second order diffusive operator evaluated using before
54      !!      fields (forward time scheme). The horizontal diffusive trends of
55      !!      the tracer is given by:
56      !!          difft = 1/(e1t*e2t*e3t) {  di-1[ aht e2u*e3u/e1u di(tb) ]
57      !!                                   + dj-1[ aht e1v*e3v/e2v dj(tb) ] }
58      !!      Add this trend to the general tracer trend pta :
59      !!          pta = pta + difft
60      !!
61      !! ** Action  : - Update pta arrays with the before iso-level
62      !!                harmonic mixing trend.
63      !!----------------------------------------------------------------------
64      USE oce         , ztu => ua   ! use ua as workspace
65      USE oce         , ztv => va   ! use va as workspace
66      !!
67      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
68      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
69      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
70      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
71      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
72      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
73      !!
74      INTEGER  ::   ji, jj, jk, jn       ! dummy loop indices
75      INTEGER  ::   iku, ikv             ! local integers
76      REAL(wp) ::   zabe1, zabe2, zbtr   ! local scalars
77      !!----------------------------------------------------------------------
78     
79      IF( kt == nit000 )  THEN
80         IF(lwp) WRITE(numout,*)
81         IF(lwp) WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion on ', cdtype
82         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
83         e1ur(:,:) = e2u(:,:) / e1u(:,:)
84         e2vr(:,:) = e1v(:,:) / e2v(:,:)
85      ENDIF
86
87      !                                                          ! =========== !
88      DO jn = 1, kjpt                                            ! tracer loop !
89         !                                                       ! =========== !   
90         DO jk = 1, jpkm1                                            ! slab loop
91            !                                           
92            ! 1. First derivative (gradient)
93            ! -------------------
94            DO jj = 1, jpjm1
95               DO ji = 1, fs_jpim1   ! vector opt.
96                  zabe1 = fsahtu(ji,jj,jk) * umask(ji,jj,jk) * e1ur(ji,jj) * fse3u(ji,jj,jk)
97                  zabe2 = fsahtv(ji,jj,jk) * vmask(ji,jj,jk) * e2vr(ji,jj) * fse3v(ji,jj,jk)
98                  ztu(ji,jj,jk) = zabe1 * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
99                  ztv(ji,jj,jk) = zabe2 * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
100               END DO
101            END DO
102            IF( ln_zps ) THEN      ! set gradient at partial step level
103               DO jj = 1, jpjm1
104                  DO ji = 1, fs_jpim1   ! vector opt.
105                     ! last level
106                     iku = mbku(ji,jj)
107                     ikv = mbkv(ji,jj)
108                     IF( iku == jk ) THEN
109                        zabe1 = fsahtu(ji,jj,iku) * umask(ji,jj,iku) * e1ur(ji,jj) * fse3u(ji,jj,iku)
110                        ztu(ji,jj,jk) = zabe1 * pgu(ji,jj,jn)
111                     ENDIF
112                     IF( ikv == jk ) THEN
113                        zabe2 = fsahtv(ji,jj,ikv) * vmask(ji,jj,ikv) * e2vr(ji,jj) * fse3v(ji,jj,ikv)
114                        ztv(ji,jj,jk) = zabe2 * pgv(ji,jj,jn)
115                     ENDIF
116                  END DO
117               END DO
118            ENDIF
119         
120         
121            ! 2. Second derivative (divergence) added to the general tracer trends
122            ! ---------------------------------------------------------------------
123            DO jj = 2, jpjm1
124               DO ji = fs_2, fs_jpim1   ! vector opt.
125                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
126                  ! horizontal diffusive trends added to the general tracer trends
127                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)   &
128                     &                                          + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
129               END DO
130            END DO
131            !
132         END DO                                             !  End of slab 
133         !
134         ! "Poleward" diffusive heat or salt transports
135         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
136            IF( jn  == jp_tem)   htr_ldf(:) = ptr_vj( ztv(:,:,:) )
137            IF( jn  == jp_sal)   str_ldf(:) = ptr_vj( ztv(:,:,:) )
138         ENDIF
139         !                                                  ! ==================
140      END DO                                                ! end of tracer loop
141      !                                                     ! ==================
142   END SUBROUTINE tra_ldf_lap
143
144   !!==============================================================================
145END MODULE traldf_lap
Note: See TracBrowser for help on using the repository browser.