| 1 | MODULE traqsr |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traqsr *** |
|---|
| 4 | !! Ocean physics: solar radiation penetration in the top ocean levels |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1990-10 (B. Blanke) Original code |
|---|
| 7 | !! 7.0 ! 1991-11 (G. Madec) |
|---|
| 8 | !! ! 1996-01 (G. Madec) s-coordinates |
|---|
| 9 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 10 | !! - ! 2005-11 (G. Madec) zco, zps, sco coordinate |
|---|
| 11 | !! 3.2 ! 2009-04 (G. Madec & NEMO team) |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! tra_qsr : trend due to the solar radiation penetration |
|---|
| 16 | !! tra_qsr_init : solar radiation penetration initialization |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | USE oce ! ocean dynamics and active tracers |
|---|
| 19 | USE dom_oce ! ocean space and time domain |
|---|
| 20 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 21 | USE trc_oce ! share SMS/Ocean variables |
|---|
| 22 | USE trdmod_oce ! ocean variables trends |
|---|
| 23 | USE trdtra ! ocean active tracers trends |
|---|
| 24 | USE in_out_manager ! I/O manager |
|---|
| 25 | USE phycst ! physical constants |
|---|
| 26 | USE prtctl ! Print control |
|---|
| 27 | USE iom ! I/O manager |
|---|
| 28 | USE fldread ! read input fields |
|---|
| 29 | USE restart ! ocean restart |
|---|
| 30 | |
|---|
| 31 | IMPLICIT NONE |
|---|
| 32 | PRIVATE |
|---|
| 33 | |
|---|
| 34 | PUBLIC tra_qsr ! routine called by step.F90 (ln_traqsr=T) |
|---|
| 35 | PUBLIC tra_qsr_init ! routine called by opa.F90 |
|---|
| 36 | |
|---|
| 37 | ! !!* Namelist namtra_qsr: penetrative solar radiation |
|---|
| 38 | LOGICAL , PUBLIC :: ln_traqsr = .TRUE. !: light absorption (qsr) flag |
|---|
| 39 | LOGICAL , PUBLIC :: ln_qsr_rgb = .FALSE. !: Red-Green-Blue light absorption flag |
|---|
| 40 | LOGICAL , PUBLIC :: ln_qsr_2bd = .TRUE. !: 2 band light absorption flag |
|---|
| 41 | LOGICAL , PUBLIC :: ln_qsr_bio = .FALSE. !: bio-model light absorption flag |
|---|
| 42 | INTEGER , PUBLIC :: nn_chldta = 0 !: use Chlorophyll data (=1) or not (=0) |
|---|
| 43 | REAL(wp), PUBLIC :: rn_abs = 0.58_wp !: fraction absorbed in the very near surface (RGB & 2 bands) |
|---|
| 44 | REAL(wp), PUBLIC :: rn_si0 = 0.35_wp !: very near surface depth of extinction (RGB & 2 bands) |
|---|
| 45 | REAL(wp), PUBLIC :: rn_si1 = 23.0_wp !: deepest depth of extinction (water type I) (2 bands) |
|---|
| 46 | |
|---|
| 47 | ! Module variables |
|---|
| 48 | REAL(wp) :: xsi0r !: inverse of rn_si0 |
|---|
| 49 | REAL(wp) :: xsi1r !: inverse of rn_si1 |
|---|
| 50 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_chl ! structure of input Chl (file informations, fields read) |
|---|
| 51 | INTEGER, PUBLIC :: nksr ! levels below which the light cannot penetrate ( depth larger than 391 m) |
|---|
| 52 | REAL(wp), DIMENSION(3,61) :: rkrgb !: tabulated attenuation coefficients for RGB absorption |
|---|
| 53 | |
|---|
| 54 | !! * Substitutions |
|---|
| 55 | # include "domzgr_substitute.h90" |
|---|
| 56 | # include "vectopt_loop_substitute.h90" |
|---|
| 57 | !!---------------------------------------------------------------------- |
|---|
| 58 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 59 | !! $Id$ |
|---|
| 60 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 61 | !!---------------------------------------------------------------------- |
|---|
| 62 | |
|---|
| 63 | CONTAINS |
|---|
| 64 | |
|---|
| 65 | SUBROUTINE tra_qsr( kt ) |
|---|
| 66 | !!---------------------------------------------------------------------- |
|---|
| 67 | !! *** ROUTINE tra_qsr *** |
|---|
| 68 | !! |
|---|
| 69 | !! ** Purpose : Compute the temperature trend due to the solar radiation |
|---|
| 70 | !! penetration and add it to the general temperature trend. |
|---|
| 71 | !! |
|---|
| 72 | !! ** Method : The profile of the solar radiation within the ocean is defined |
|---|
| 73 | !! through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs |
|---|
| 74 | !! Considering the 2 wavebands case: |
|---|
| 75 | !! I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) ) |
|---|
| 76 | !! The temperature trend associated with the solar radiation penetration |
|---|
| 77 | !! is given by : zta = 1/e3t dk[ I ] / (rau0*Cp) |
|---|
| 78 | !! At the bottom, boudary condition for the radiation is no flux : |
|---|
| 79 | !! all heat which has not been absorbed in the above levels is put |
|---|
| 80 | !! in the last ocean level. |
|---|
| 81 | !! In z-coordinate case, the computation is only done down to the |
|---|
| 82 | !! level where I(k) < 1.e-15 W/m2. In addition, the coefficients |
|---|
| 83 | !! used for the computation are calculated one for once as they |
|---|
| 84 | !! depends on k only. |
|---|
| 85 | !! |
|---|
| 86 | !! ** Action : - update ta with the penetrative solar radiation trend |
|---|
| 87 | !! - save the trend in ttrd ('key_trdtra') |
|---|
| 88 | !! |
|---|
| 89 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 90 | !! Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516. |
|---|
| 91 | !!---------------------------------------------------------------------- |
|---|
| 92 | !! |
|---|
| 93 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 94 | !! |
|---|
| 95 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 96 | INTEGER :: irgb ! temporary integers |
|---|
| 97 | REAL(wp) :: zchl, zcoef ! temporary scalars |
|---|
| 98 | REAL(wp) :: zc0, zc1, zc2, zc3 ! - - |
|---|
| 99 | REAL(wp) :: zz0, zz1 ! - - |
|---|
| 100 | REAL(wp) :: z1_e3t, zfact ! - - |
|---|
| 101 | REAL(wp), DIMENSION(jpi,jpj) :: zekb, zekg, zekr ! 2D workspace |
|---|
| 102 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: ze0, ze1 , ze2, ze3, zea ! 3D workspace |
|---|
| 103 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: ztrdt |
|---|
| 104 | !!---------------------------------------------------------------------- |
|---|
| 105 | |
|---|
| 106 | IF( kt == nit000 ) THEN |
|---|
| 107 | IF(lwp) WRITE(numout,*) |
|---|
| 108 | IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation' |
|---|
| 109 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
|---|
| 110 | IF( .NOT.ln_traqsr ) RETURN |
|---|
| 111 | ENDIF |
|---|
| 112 | |
|---|
| 113 | IF( l_trdtra ) THEN ! Save ta and sa trends |
|---|
| 114 | ALLOCATE( ztrdt(jpi,jpj,jpk) ) ; ztrdt(:,:,:) = tsa(:,:,:,jp_tem) |
|---|
| 115 | ENDIF |
|---|
| 116 | |
|---|
| 117 | ! Set before qsr tracer content field |
|---|
| 118 | ! *********************************** |
|---|
| 119 | IF( kt == nit000 ) THEN ! Set the forcing field at nit000 - 1 |
|---|
| 120 | ! ! ----------------------------------- |
|---|
| 121 | IF( ln_rstart .AND. & ! Restart: read in restart file |
|---|
| 122 | & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 123 | IF(lwp) WRITE(numout,*) ' nit000-1 qsr tracer content forcing field red in the restart file' |
|---|
| 124 | zfact = 0.5e0 |
|---|
| 125 | CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b ) ! before heat content trend due to Qsr flux |
|---|
| 126 | ELSE ! No restart or restart not found: Euler forward time stepping |
|---|
| 127 | zfact = 1.e0 |
|---|
| 128 | qsr_hc_b(:,:,:) = 0.e0 |
|---|
| 129 | ENDIF |
|---|
| 130 | ELSE ! Swap of forcing field |
|---|
| 131 | ! ! --------------------- |
|---|
| 132 | zfact = 0.5e0 |
|---|
| 133 | qsr_hc_b(:,:,:) = qsr_hc(:,:,:) |
|---|
| 134 | ENDIF |
|---|
| 135 | ! Compute now qsr tracer content field |
|---|
| 136 | ! ************************************ |
|---|
| 137 | |
|---|
| 138 | ! ! ============================================== ! |
|---|
| 139 | IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN ! bio-model fluxes : all vertical coordinates ! |
|---|
| 140 | ! ! ============================================== ! |
|---|
| 141 | DO jk = 1, jpkm1 |
|---|
| 142 | qsr_hc(:,:,jk) = ro0cpr * ( etot3(:,:,jk) - etot3(:,:,jk+1) ) |
|---|
| 143 | END DO |
|---|
| 144 | ! Add to the general trend |
|---|
| 145 | DO jk = 1, jpkm1 |
|---|
| 146 | DO jj = 2, jpjm1 |
|---|
| 147 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 148 | z1_e3t = zfact / fse3t(ji,jj,jk) |
|---|
| 149 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t |
|---|
| 150 | END DO |
|---|
| 151 | END DO |
|---|
| 152 | END DO |
|---|
| 153 | CALL iom_put( 'qsr3d', etot3 ) ! Shortwave Radiation 3D distribution |
|---|
| 154 | ! ! ============================================== ! |
|---|
| 155 | ELSE ! Ocean alone : |
|---|
| 156 | ! ! ============================================== ! |
|---|
| 157 | ! |
|---|
| 158 | ! ! ------------------------- ! |
|---|
| 159 | IF( ln_qsr_rgb) THEN ! R-G-B light penetration ! |
|---|
| 160 | ! ! ------------------------- ! |
|---|
| 161 | ! Set chlorophyl concentration |
|---|
| 162 | IF( nn_chldta == 1 .OR. lk_vvl ) THEN !* Variable Chlorophyll or ocean volume |
|---|
| 163 | ! |
|---|
| 164 | IF( nn_chldta == 1 ) THEN !* Variable Chlorophyll |
|---|
| 165 | ! |
|---|
| 166 | CALL fld_read( kt, 1, sf_chl ) ! Read Chl data and provides it at the current time step |
|---|
| 167 | ! |
|---|
| 168 | !CDIR COLLAPSE |
|---|
| 169 | !CDIR NOVERRCHK |
|---|
| 170 | DO jj = 1, jpj ! Separation in R-G-B depending of the surface Chl |
|---|
| 171 | !CDIR NOVERRCHK |
|---|
| 172 | DO ji = 1, jpi |
|---|
| 173 | zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) ) |
|---|
| 174 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 175 | zekb(ji,jj) = rkrgb(1,irgb) |
|---|
| 176 | zekg(ji,jj) = rkrgb(2,irgb) |
|---|
| 177 | zekr(ji,jj) = rkrgb(3,irgb) |
|---|
| 178 | END DO |
|---|
| 179 | END DO |
|---|
| 180 | ELSE ! Variable ocean volume but constant chrlorophyll |
|---|
| 181 | zchl = 0.05 ! constant chlorophyll |
|---|
| 182 | irgb = NINT( 41 + 20.*LOG10( zchl ) + 1.e-15 ) |
|---|
| 183 | zekb(:,:) = rkrgb(1,irgb) ! Separation in R-G-B depending of the chlorophyll |
|---|
| 184 | zekg(:,:) = rkrgb(2,irgb) |
|---|
| 185 | zekr(:,:) = rkrgb(3,irgb) |
|---|
| 186 | ENDIF |
|---|
| 187 | ! |
|---|
| 188 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 189 | ze0(:,:,1) = rn_abs * qsr(:,:) |
|---|
| 190 | ze1(:,:,1) = zcoef * qsr(:,:) |
|---|
| 191 | ze2(:,:,1) = zcoef * qsr(:,:) |
|---|
| 192 | ze3(:,:,1) = zcoef * qsr(:,:) |
|---|
| 193 | zea(:,:,1) = qsr(:,:) |
|---|
| 194 | ! |
|---|
| 195 | DO jk = 2, nksr+1 |
|---|
| 196 | !CDIR NOVERRCHK |
|---|
| 197 | DO jj = 1, jpj |
|---|
| 198 | !CDIR NOVERRCHK |
|---|
| 199 | DO ji = 1, jpi |
|---|
| 200 | zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r ) |
|---|
| 201 | zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 202 | zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 203 | zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 204 | ze0(ji,jj,jk) = zc0 |
|---|
| 205 | ze1(ji,jj,jk) = zc1 |
|---|
| 206 | ze2(ji,jj,jk) = zc2 |
|---|
| 207 | ze3(ji,jj,jk) = zc3 |
|---|
| 208 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 209 | END DO |
|---|
| 210 | END DO |
|---|
| 211 | END DO |
|---|
| 212 | ! |
|---|
| 213 | DO jk = 1, nksr ! compute and add qsr trend to ta |
|---|
| 214 | qsr_hc(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) |
|---|
| 215 | END DO |
|---|
| 216 | zea(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 217 | CALL iom_put( 'qsr3d', zea ) ! Shortwave Radiation 3D distribution |
|---|
| 218 | ! |
|---|
| 219 | ELSE !* Constant Chlorophyll |
|---|
| 220 | DO jk = 1, nksr |
|---|
| 221 | qsr_hc(:,:,jk) = etot3(:,:,jk) * qsr(:,:) |
|---|
| 222 | END DO |
|---|
| 223 | ENDIF |
|---|
| 224 | |
|---|
| 225 | ENDIF |
|---|
| 226 | ! ! ------------------------- ! |
|---|
| 227 | IF( ln_qsr_2bd ) THEN ! 2 band light penetration ! |
|---|
| 228 | ! ! ------------------------- ! |
|---|
| 229 | ! |
|---|
| 230 | IF( lk_vvl ) THEN !* variable volume |
|---|
| 231 | zz0 = rn_abs * ro0cpr |
|---|
| 232 | zz1 = ( 1. - rn_abs ) * ro0cpr |
|---|
| 233 | DO jk = 1, nksr ! solar heat absorbed at T-point in the top 400m |
|---|
| 234 | DO jj = 2, jpjm1 |
|---|
| 235 | DO ji = 2, jpim1 |
|---|
| 236 | zc0 = zz0 * EXP( -fsdepw(ji,jj,jk )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk )*xsi1r ) |
|---|
| 237 | zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r ) |
|---|
| 238 | qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) |
|---|
| 239 | END DO |
|---|
| 240 | END DO |
|---|
| 241 | END DO |
|---|
| 242 | ELSE !* constant volume: coef. computed one for all |
|---|
| 243 | DO jk = 1, nksr |
|---|
| 244 | DO jj = 2, jpjm1 |
|---|
| 245 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 246 | qsr_hc(ji,jj,jk) = etot3(ji,jj,jk) * qsr(ji,jj) |
|---|
| 247 | END DO |
|---|
| 248 | END DO |
|---|
| 249 | END DO |
|---|
| 250 | ! |
|---|
| 251 | ENDIF |
|---|
| 252 | ! |
|---|
| 253 | ENDIF |
|---|
| 254 | ! |
|---|
| 255 | ! Add to the general trend |
|---|
| 256 | DO jk = 1, nksr |
|---|
| 257 | DO jj = 2, jpjm1 |
|---|
| 258 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 259 | z1_e3t = zfact / fse3t(ji,jj,jk) |
|---|
| 260 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t |
|---|
| 261 | END DO |
|---|
| 262 | END DO |
|---|
| 263 | END DO |
|---|
| 264 | ! |
|---|
| 265 | ENDIF |
|---|
| 266 | ! |
|---|
| 267 | IF( lrst_oce ) THEN ! Write in the ocean restart file |
|---|
| 268 | ! ******************************* |
|---|
| 269 | IF(lwp) WRITE(numout,*) |
|---|
| 270 | IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ', & |
|---|
| 271 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 272 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 273 | CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b', qsr_hc ) |
|---|
| 274 | ! |
|---|
| 275 | ENDIF |
|---|
| 276 | |
|---|
| 277 | IF( l_trdtra ) THEN ! qsr tracers trends saved for diagnostics |
|---|
| 278 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:) |
|---|
| 279 | CALL trd_tra( kt, 'TRA', jp_tem, jptra_trd_qsr, ztrdt ) |
|---|
| 280 | DEALLOCATE( ztrdt ) |
|---|
| 281 | ENDIF |
|---|
| 282 | ! ! print mean trends (used for debugging) |
|---|
| 283 | IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr - Ta: ', mask1=tmask, clinfo3='tra-ta' ) |
|---|
| 284 | ! |
|---|
| 285 | END SUBROUTINE tra_qsr |
|---|
| 286 | |
|---|
| 287 | |
|---|
| 288 | SUBROUTINE tra_qsr_init |
|---|
| 289 | !!---------------------------------------------------------------------- |
|---|
| 290 | !! *** ROUTINE tra_qsr_init *** |
|---|
| 291 | !! |
|---|
| 292 | !! ** Purpose : Initialization for the penetrative solar radiation |
|---|
| 293 | !! |
|---|
| 294 | !! ** Method : The profile of solar radiation within the ocean is set |
|---|
| 295 | !! from two length scale of penetration (rn_si0,rn_si1) and a ratio |
|---|
| 296 | !! (rn_abs). These parameters are read in the namtra_qsr namelist. The |
|---|
| 297 | !! default values correspond to clear water (type I in Jerlov' |
|---|
| 298 | !! (1968) classification. |
|---|
| 299 | !! called by tra_qsr at the first timestep (nit000) |
|---|
| 300 | !! |
|---|
| 301 | !! ** Action : - initialize rn_si0, rn_si1 and rn_abs |
|---|
| 302 | !! |
|---|
| 303 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 304 | !!---------------------------------------------------------------------- |
|---|
| 305 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 306 | INTEGER :: irgb, ierror ! temporary integer |
|---|
| 307 | INTEGER :: ioptio, nqsr ! temporary integer |
|---|
| 308 | REAL(wp) :: zc0 , zc1, zcoef ! temporary scalars |
|---|
| 309 | REAL(wp) :: zc2 , zc3 , zchl ! - - |
|---|
| 310 | REAL(wp) :: zz0 , zz1 ! - - |
|---|
| 311 | REAL(wp), DIMENSION(jpi,jpj) :: zekb, zekg, zekr ! 2D workspace |
|---|
| 312 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: ze0 , ze1 , ze2 , ze3 , zea ! 3D workspace |
|---|
| 313 | !! |
|---|
| 314 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 315 | TYPE(FLD_N) :: sn_chl ! informations about the chlorofyl field to be read |
|---|
| 316 | NAMELIST/namtra_qsr/ sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, & |
|---|
| 317 | & nn_chldta, rn_abs, rn_si0, rn_si1 |
|---|
| 318 | !!---------------------------------------------------------------------- |
|---|
| 319 | |
|---|
| 320 | cn_dir = './' ! directory in which the model is executed |
|---|
| 321 | ! ... default values (NB: frequency positive => hours, negative => months) |
|---|
| 322 | ! ! file ! frequency ! variable ! time interp ! clim ! 'yearly' or ! weights ! rotation ! |
|---|
| 323 | ! ! name ! (hours) ! name ! (T/F) ! (T/F) ! 'monthly' ! filename ! pairs ! |
|---|
| 324 | sn_chl = FLD_N( 'chlorophyll' , -1 , 'CHLA' , .true. , .true. , 'yearly' , '' , '' ) |
|---|
| 325 | ! |
|---|
| 326 | REWIND( numnam ) ! Read Namelist namtra_qsr : ratio and length of penetration |
|---|
| 327 | READ ( numnam, namtra_qsr ) |
|---|
| 328 | ! |
|---|
| 329 | IF(lwp) THEN ! control print |
|---|
| 330 | WRITE(numout,*) |
|---|
| 331 | WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation' |
|---|
| 332 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 333 | WRITE(numout,*) ' Namelist namtra_qsr : set the parameter of penetration' |
|---|
| 334 | WRITE(numout,*) ' Light penetration (T) or not (F) ln_traqsr = ', ln_traqsr |
|---|
| 335 | WRITE(numout,*) ' RGB (Red-Green-Blue) light penetration ln_qsr_rgb = ', ln_qsr_rgb |
|---|
| 336 | WRITE(numout,*) ' 2 band light penetration ln_qsr_2bd = ', ln_qsr_2bd |
|---|
| 337 | WRITE(numout,*) ' bio-model light penetration ln_qsr_bio = ', ln_qsr_bio |
|---|
| 338 | WRITE(numout,*) ' RGB : Chl data (=1) or cst value (=0) nn_chldta = ', nn_chldta |
|---|
| 339 | WRITE(numout,*) ' RGB & 2 bands: fraction of light (rn_si1) rn_abs = ', rn_abs |
|---|
| 340 | WRITE(numout,*) ' RGB & 2 bands: shortess depth of extinction rn_si0 = ', rn_si0 |
|---|
| 341 | WRITE(numout,*) ' 2 bands: longest depth of extinction rn_si1 = ', rn_si1 |
|---|
| 342 | ENDIF |
|---|
| 343 | |
|---|
| 344 | IF( ln_traqsr ) THEN ! control consistency |
|---|
| 345 | ! |
|---|
| 346 | IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio ) THEN |
|---|
| 347 | CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' ) |
|---|
| 348 | ln_qsr_bio = .FALSE. |
|---|
| 349 | ENDIF |
|---|
| 350 | ! |
|---|
| 351 | ioptio = 0 ! Parameter control |
|---|
| 352 | IF( ln_qsr_rgb ) ioptio = ioptio + 1 |
|---|
| 353 | IF( ln_qsr_2bd ) ioptio = ioptio + 1 |
|---|
| 354 | IF( ln_qsr_bio ) ioptio = ioptio + 1 |
|---|
| 355 | ! |
|---|
| 356 | IF( ioptio /= 1 ) & |
|---|
| 357 | CALL ctl_stop( ' Choose ONE type of light penetration in namelist namtra_qsr', & |
|---|
| 358 | & ' 2 bands, 3 RGB bands or bio-model light penetration' ) |
|---|
| 359 | ! |
|---|
| 360 | IF( ln_qsr_rgb .AND. nn_chldta == 0 ) nqsr = 1 |
|---|
| 361 | IF( ln_qsr_rgb .AND. nn_chldta == 1 ) nqsr = 2 |
|---|
| 362 | IF( ln_qsr_2bd ) nqsr = 3 |
|---|
| 363 | IF( ln_qsr_bio ) nqsr = 4 |
|---|
| 364 | ! |
|---|
| 365 | IF(lwp) THEN ! Print the choice |
|---|
| 366 | WRITE(numout,*) |
|---|
| 367 | IF( nqsr == 1 ) WRITE(numout,*) ' R-G-B light penetration - Constant Chlorophyll' |
|---|
| 368 | IF( nqsr == 2 ) WRITE(numout,*) ' R-G-B light penetration - Chl data ' |
|---|
| 369 | IF( nqsr == 3 ) WRITE(numout,*) ' 2 bands light penetration' |
|---|
| 370 | IF( nqsr == 4 ) WRITE(numout,*) ' bio-model light penetration' |
|---|
| 371 | ENDIF |
|---|
| 372 | ! |
|---|
| 373 | ENDIF |
|---|
| 374 | ! ! ===================================== ! |
|---|
| 375 | IF( ln_traqsr ) THEN ! Initialisation of Light Penetration ! |
|---|
| 376 | ! ! ===================================== ! |
|---|
| 377 | ! |
|---|
| 378 | xsi0r = 1.e0 / rn_si0 |
|---|
| 379 | xsi1r = 1.e0 / rn_si1 |
|---|
| 380 | ! ! ---------------------------------- ! |
|---|
| 381 | IF( ln_qsr_rgb ) THEN ! Red-Green-Blue light penetration ! |
|---|
| 382 | ! ! ---------------------------------- ! |
|---|
| 383 | ! |
|---|
| 384 | CALL trc_oce_rgb( rkrgb ) !* tabulated attenuation coef. |
|---|
| 385 | ! |
|---|
| 386 | ! !* level of light extinction |
|---|
| 387 | IF( ln_sco ) THEN ; nksr = jpkm1 |
|---|
| 388 | ELSE ; nksr = trc_oce_ext_lev( r_si2, 0.33e2 ) |
|---|
| 389 | ENDIF |
|---|
| 390 | |
|---|
| 391 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m' |
|---|
| 392 | ! |
|---|
| 393 | IF( nn_chldta == 1 ) THEN !* Chl data : set sf_chl structure |
|---|
| 394 | IF(lwp) WRITE(numout,*) |
|---|
| 395 | IF(lwp) WRITE(numout,*) ' Chlorophyll read in a file' |
|---|
| 396 | ALLOCATE( sf_chl(1), STAT=ierror ) |
|---|
| 397 | IF( ierror > 0 ) THEN |
|---|
| 398 | CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' ) ; RETURN |
|---|
| 399 | ENDIF |
|---|
| 400 | ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1) ) |
|---|
| 401 | IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 402 | ! ! fill sf_chl with sn_chl and control print |
|---|
| 403 | CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init', & |
|---|
| 404 | & 'Solar penetration function of read chlorophyll', 'namtra_qsr' ) |
|---|
| 405 | ! |
|---|
| 406 | ELSE !* constant Chl : compute once for all the distribution of light (etot3) |
|---|
| 407 | IF(lwp) WRITE(numout,*) |
|---|
| 408 | IF(lwp) WRITE(numout,*) ' Constant Chlorophyll concentration = 0.05' |
|---|
| 409 | IF( lk_vvl ) THEN ! variable volume |
|---|
| 410 | IF(lwp) WRITE(numout,*) ' key_vvl: light distribution will be computed at each time step' |
|---|
| 411 | ELSE ! constant volume: computes one for all |
|---|
| 412 | IF(lwp) WRITE(numout,*) ' fixed volume: light distribution computed one for all' |
|---|
| 413 | ! |
|---|
| 414 | zchl = 0.05 ! constant chlorophyll |
|---|
| 415 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 416 | zekb(:,:) = rkrgb(1,irgb) ! Separation in R-G-B depending of the chlorophyll |
|---|
| 417 | zekg(:,:) = rkrgb(2,irgb) |
|---|
| 418 | zekr(:,:) = rkrgb(3,irgb) |
|---|
| 419 | ! |
|---|
| 420 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 421 | ze0(:,:,1) = rn_abs |
|---|
| 422 | ze1(:,:,1) = zcoef |
|---|
| 423 | ze2(:,:,1) = zcoef |
|---|
| 424 | ze3(:,:,1) = zcoef |
|---|
| 425 | zea(:,:,1) = tmask(:,:,1) ! = ( ze0+ze1+z2+ze3 ) * tmask |
|---|
| 426 | |
|---|
| 427 | DO jk = 2, nksr+1 |
|---|
| 428 | !CDIR NOVERRCHK |
|---|
| 429 | DO jj = 1, jpj |
|---|
| 430 | !CDIR NOVERRCHK |
|---|
| 431 | DO ji = 1, jpi |
|---|
| 432 | zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * xsi0r ) |
|---|
| 433 | zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 434 | zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 435 | zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 436 | ze0(ji,jj,jk) = zc0 |
|---|
| 437 | ze1(ji,jj,jk) = zc1 |
|---|
| 438 | ze2(ji,jj,jk) = zc2 |
|---|
| 439 | ze3(ji,jj,jk) = zc3 |
|---|
| 440 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 441 | END DO |
|---|
| 442 | END DO |
|---|
| 443 | END DO |
|---|
| 444 | ! |
|---|
| 445 | DO jk = 1, nksr |
|---|
| 446 | etot3(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) |
|---|
| 447 | END DO |
|---|
| 448 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 449 | ENDIF |
|---|
| 450 | ENDIF |
|---|
| 451 | ! |
|---|
| 452 | ENDIF |
|---|
| 453 | ! ! ---------------------------------- ! |
|---|
| 454 | IF( ln_qsr_2bd ) THEN ! 2 bands light penetration ! |
|---|
| 455 | ! ! ---------------------------------- ! |
|---|
| 456 | ! |
|---|
| 457 | ! ! level of light extinction |
|---|
| 458 | nksr = trc_oce_ext_lev( rn_si1, 1.e2 ) |
|---|
| 459 | IF(lwp) THEN |
|---|
| 460 | WRITE(numout,*) |
|---|
| 461 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m' |
|---|
| 462 | ENDIF |
|---|
| 463 | ! |
|---|
| 464 | IF( lk_vvl ) THEN ! variable volume |
|---|
| 465 | IF(lwp) WRITE(numout,*) ' key_vvl: light distribution will be computed at each time step' |
|---|
| 466 | ELSE ! constant volume: computes one for all |
|---|
| 467 | zz0 = rn_abs * ro0cpr |
|---|
| 468 | zz1 = ( 1. - rn_abs ) * ro0cpr |
|---|
| 469 | DO jk = 1, nksr !* solar heat absorbed at T-point computed once for all |
|---|
| 470 | DO jj = 1, jpj ! top 400 meters |
|---|
| 471 | DO ji = 1, jpi |
|---|
| 472 | zc0 = zz0 * EXP( -fsdepw(ji,jj,jk )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk )*xsi1r ) |
|---|
| 473 | zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r ) |
|---|
| 474 | etot3(ji,jj,jk) = ( zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1) ) |
|---|
| 475 | END DO |
|---|
| 476 | END DO |
|---|
| 477 | END DO |
|---|
| 478 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 479 | ! |
|---|
| 480 | ENDIF |
|---|
| 481 | ENDIF |
|---|
| 482 | ! ! ===================================== ! |
|---|
| 483 | ELSE ! No light penetration ! |
|---|
| 484 | ! ! ===================================== ! |
|---|
| 485 | IF(lwp) THEN |
|---|
| 486 | WRITE(numout,*) |
|---|
| 487 | WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration' |
|---|
| 488 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 489 | ENDIF |
|---|
| 490 | ENDIF |
|---|
| 491 | ! |
|---|
| 492 | END SUBROUTINE tra_qsr_init |
|---|
| 493 | |
|---|
| 494 | !!====================================================================== |
|---|
| 495 | END MODULE traqsr |
|---|
