New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trasbc.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/trasbc.F90 @ 7710

Last change on this file since 7710 was 7710, checked in by acc, 7 years ago

Trunk fix for ticket #1852. Add initialisation of sbc_tsc in trasbc.F90 to ensure consistency in unused haloes across restarts
  • Property svn:keywords set to Id
File size: 13.8 KB
Line 
1MODULE trasbc
2   !!==============================================================================
3   !!                       ***  MODULE  trasbc  ***
4   !! Ocean active tracers:  surface boundary condition
5   !!==============================================================================
6   !! History :  OPA  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!  NEMO      1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
10   !!             -   !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.6  !  2014-11  (P. Mathiot) isf melting forcing
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_sbc       : update the tracer trend at ocean surface
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and active tracers
18   USE sbc_oce        ! surface boundary condition: ocean
19   USE dom_oce        ! ocean space domain variables
20   USE phycst         ! physical constant
21   USE eosbn2         ! Equation Of State
22   USE sbcmod         ! ln_rnf 
23   USE sbcrnf         ! River runoff 
24   USE sbcisf         ! Ice shelf   
25   USE iscplini       ! Ice sheet coupling
26   USE traqsr         ! solar radiation penetration
27   USE trd_oce        ! trends: ocean variables
28   USE trdtra         ! trends manager: tracers
29   !
30   USE in_out_manager ! I/O manager
31   USE prtctl         ! Print control
32   USE iom            ! xIOS server
33   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
34   USE wrk_nemo       ! Memory Allocation
35   USE timing         ! Timing
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   tra_sbc   ! routine called by step.F90
41
42   !! * Substitutions
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_sbc ( kt )
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE tra_sbc  ***
54      !!                   
55      !! ** Purpose :   Compute the tracer surface boundary condition trend of
56      !!      (flux through the interface, concentration/dilution effect)
57      !!      and add it to the general trend of tracer equations.
58      !!
59      !! ** Method :   The (air+ice)-sea flux has two components:
60      !!      (1) Fext, external forcing (i.e. flux through the (air+ice)-sea interface);
61      !!      (2) Fwe , tracer carried with the water that is exchanged with air+ice.
62      !!               The input forcing fields (emp, rnf, sfx, isf) contain Fext+Fwe,
63      !!             they are simply added to the tracer trend (tsa).
64      !!               In linear free surface case (ln_linssh=T), the volume of the
65      !!             ocean does not change with the water exchanges at the (air+ice)-sea
66      !!             interface. Therefore another term has to be added, to mimic the
67      !!             concentration/dilution effect associated with water exchanges.
68      !!
69      !! ** Action  : - Update tsa with the surface boundary condition trend
70      !!              - send trends to trdtra module for further diagnostics(l_trdtra=T)
71      !!----------------------------------------------------------------------
72      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
73      !
74      INTEGER  ::   ji, jj, jk, jn        ! dummy loop indices 
75      INTEGER  ::   ikt, ikb              ! local integers
76      REAL(wp) ::   zfact, z1_e3t, zdep   ! local scalar
77      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdt, ztrds
78      !!----------------------------------------------------------------------
79      !
80      IF( nn_timing == 1 )  CALL timing_start('tra_sbc')
81      !
82      IF( kt == nit000 ) THEN
83         IF(lwp) WRITE(numout,*)
84         IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition'
85         IF(lwp) WRITE(numout,*) '~~~~~~~ '
86      ENDIF
87      !
88      IF( l_trdtra ) THEN                    !* Save ta and sa trends
89         CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds ) 
90!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
91         DO jk = 1, jpk
92            DO jj = 1, jpj
93               DO ji = 1, jpi
94                  ztrdt(ji,jj,jk) = tsa(ji,jj,jk,jp_tem)
95                  ztrds(ji,jj,jk) = tsa(ji,jj,jk,jp_sal)
96               END DO
97            END DO
98         END DO
99      ENDIF
100      !
101!!gm  This should be moved into sbcmod.F90 module ? (especially now that ln_traqsr is read in namsbc namelist)
102      IF( .NOT.ln_traqsr ) THEN     ! no solar radiation penetration
103!$OMP PARALLEL DO schedule(static) private(jj, ji)
104         DO jj = 1, jpj
105            DO ji = 1, jpi
106               qns(ji,jj) = qns(ji,jj) + qsr(ji,jj)      ! total heat flux in qns
107               qsr(ji,jj) = 0._wp                     ! qsr set to zero
108            END DO
109         END DO
110      ENDIF
111
112      !----------------------------------------
113      !        EMP, SFX and QNS effects
114      !----------------------------------------
115      !                             !==  Set before sbc tracer content fields  ==!
116      IF( kt == nit000 ) THEN             !* 1st time-step
117         IF( ln_rstart .AND.    &               ! Restart: read in restart file
118              & iom_varid( numror, 'sbc_hc_b', ldstop = .FALSE. ) > 0 ) THEN
119            IF(lwp) WRITE(numout,*) '          nit000-1 sbc tracer content field read in the restart file'
120            zfact = 0.5_wp
121            DO jn = 1, jpts
122!$OMP PARALLEL DO schedule(static) private(jj, ji)
123               DO jj = 1, jpj
124                  DO ji = 1, jpi
125                     sbc_tsc(ji,jj,jn) = 0._wp  ! needed just to ensure haloes are consistent across restarts
126                  END DO
127               END DO
128            END DO
129            CALL iom_get( numror, jpdom_autoglo, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem) )   ! before heat content sbc trend
130            CALL iom_get( numror, jpdom_autoglo, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal) )   ! before salt content sbc trend
131         ELSE                                   ! No restart or restart not found: Euler forward time stepping
132            zfact = 1._wp
133            DO jn = 1, jpts
134!$OMP PARALLEL DO schedule(static) private(jj, ji)
135               DO jj = 1, jpj
136                  DO ji = 1, jpi
137                     sbc_tsc(ji,jj,jn) = 0._wp
138                     sbc_tsc_b(ji,jj,jn) = 0._wp
139                  END DO
140               END DO
141            END DO
142         ENDIF
143      ELSE                                !* other time-steps: swap of forcing fields
144         zfact = 0.5_wp
145         DO jn = 1, jpts
146!$OMP PARALLEL DO schedule(static) private(jj, ji)
147            DO jj = 1, jpj
148               DO ji = 1, jpi
149                  sbc_tsc_b(ji,jj,jn) = sbc_tsc(ji,jj,jn)
150               END DO
151            END DO
152         END DO
153      ENDIF
154      !                             !==  Now sbc tracer content fields  ==!
155!$OMP PARALLEL DO schedule(static) private(jj, ji)
156      DO jj = 2, jpj
157         DO ji = fs_2, fs_jpim1   ! vector opt.
158            sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj)   ! non solar heat flux
159            sbc_tsc(ji,jj,jp_sal) = r1_rau0     * sfx(ji,jj)   ! salt flux due to freezing/melting
160         END DO
161      END DO
162      IF( ln_linssh ) THEN                !* linear free surface 
163!$OMP PARALLEL DO schedule(static) private(jj, ji)
164         DO jj = 2, jpj                         !==>> add concentration/dilution effect due to constant volume cell
165            DO ji = fs_2, fs_jpim1   ! vector opt.
166               sbc_tsc(ji,jj,jp_tem) = sbc_tsc(ji,jj,jp_tem) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_tem)
167               sbc_tsc(ji,jj,jp_sal) = sbc_tsc(ji,jj,jp_sal) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_sal)
168            END DO
169         END DO                                 !==>> output c./d. term
170         IF( iom_use('emp_x_sst') )   CALL iom_put( "emp_x_sst", emp (:,:) * tsn(:,:,1,jp_tem) )
171         IF( iom_use('emp_x_sss') )   CALL iom_put( "emp_x_sss", emp (:,:) * tsn(:,:,1,jp_sal) )
172      ENDIF
173      !
174      DO jn = 1, jpts               !==  update tracer trend  ==!
175!$OMP PARALLEL DO schedule(static) private(jj, ji)
176         DO jj = 2, jpj
177            DO ji = fs_2, fs_jpim1   ! vector opt. 
178               tsa(ji,jj,1,jn) = tsa(ji,jj,1,jn) + zfact * ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) ) / e3t_n(ji,jj,1)
179            END DO
180         END DO
181      END DO
182      !                 
183      IF( lrst_oce ) THEN           !==  write sbc_tsc in the ocean restart file  ==!
184         CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem) )
185         CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal) )
186      ENDIF
187      !
188      !----------------------------------------
189      !       Ice Shelf effects (ISF)
190      !     tbl treated as in Losh (2008) JGR
191      !----------------------------------------
192      !
193!!gm BUG ?   Why no differences between non-linear and linear free surface ?
194!!gm         probably taken into account in r1_hisf_tbl : to be verified
195      IF( ln_isf ) THEN
196         zfact = 0.5_wp
197         DO jj = 2, jpj
198            DO ji = fs_2, fs_jpim1
199               !
200               ikt = misfkt(ji,jj)
201               ikb = misfkb(ji,jj)
202               !
203               ! level fully include in the ice shelf boundary layer
204               ! sign - because fwf sign of evapo (rnf sign of precip)
205               DO jk = ikt, ikb - 1
206               ! compute trend
207                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)                                                &
208                     &           + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) )             &
209                     &           * r1_hisf_tbl(ji,jj)
210               END DO
211   
212               ! level partially include in ice shelf boundary layer
213               ! compute trend
214               tsa(ji,jj,ikb,jp_tem) = tsa(ji,jj,ikb,jp_tem)                                                 &
215                  &              + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) )             &
216                  &              * r1_hisf_tbl(ji,jj) * ralpha(ji,jj)
217
218            END DO
219         END DO
220         IF( lrst_oce ) THEN
221            CALL iom_rstput( kt, nitrst, numrow, 'fwf_isf_b', fwfisf  (:,:)        )
222            CALL iom_rstput( kt, nitrst, numrow, 'isf_hc_b' , risf_tsc(:,:,jp_tem) )
223            CALL iom_rstput( kt, nitrst, numrow, 'isf_sc_b' , risf_tsc(:,:,jp_sal) )
224         ENDIF
225      END IF
226      !
227      !----------------------------------------
228      !        River Runoff effects
229      !----------------------------------------
230      !
231      IF( ln_rnf ) THEN         ! input of heat and salt due to river runoff
232         zfact = 0.5_wp
233         DO jj = 2, jpj 
234            DO ji = fs_2, fs_jpim1
235               IF( rnf(ji,jj) /= 0._wp ) THEN
236                  zdep = zfact / h_rnf(ji,jj)
237                  DO jk = 1, nk_rnf(ji,jj)
238                                        tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)                                 &
239                                           &                 +  ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep
240                     IF( ln_rnf_sal )   tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal)                                 &
241                                           &                 +  ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep 
242                  END DO
243               ENDIF
244            END DO 
245         END DO 
246      ENDIF
247
248      IF( iom_use('rnf_x_sst') )   CALL iom_put( "rnf_x_sst", rnf*tsn(:,:,1,jp_tem) )   ! runoff term on sst
249      IF( iom_use('rnf_x_sss') )   CALL iom_put( "rnf_x_sss", rnf*tsn(:,:,1,jp_sal) )   ! runoff term on sss
250
251      !
252      !----------------------------------------
253      !        Ice Sheet coupling imbalance correction to have conservation
254      !----------------------------------------
255      !
256      IF( ln_iscpl .AND. ln_hsb) THEN         ! input of heat and salt due to river runoff
257!$OMP PARALLEL DO schedule(static) private(jk, jj, ji, zdep)
258         DO jk = 1,jpk
259            DO jj = 2, jpj 
260               DO ji = fs_2, fs_jpim1
261                  zdep = 1._wp / e3t_n(ji,jj,jk) 
262                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) - htsc_iscpl(ji,jj,jk,jp_tem)                       &
263                      &                                         * zdep
264                  tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) - htsc_iscpl(ji,jj,jk,jp_sal)                       &
265                      &                                         * zdep 
266               END DO 
267            END DO 
268         END DO
269      ENDIF
270
271      IF( l_trdtra )   THEN                      ! save the horizontal diffusive trends for further diagnostics
272!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
273         DO jk = 1, jpk
274            DO jj = 1, jpj
275               DO ji = 1, jpi
276                  ztrdt(ji,jj,jk) = tsa(ji,jj,jk,jp_tem) - ztrdt(ji,jj,jk)
277                  ztrds(ji,jj,jk) = tsa(ji,jj,jk,jp_sal) - ztrds(ji,jj,jk)
278               END DO 
279            END DO 
280         END DO
281         CALL trd_tra( kt, 'TRA', jp_tem, jptra_nsr, ztrdt )
282         CALL trd_tra( kt, 'TRA', jp_sal, jptra_nsr, ztrds )
283         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds ) 
284      ENDIF
285      !
286      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' sbc  - Ta: ', mask1=tmask,   &
287         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
288      !
289      IF( nn_timing == 1 )  CALL timing_stop('tra_sbc')
290      !
291   END SUBROUTINE tra_sbc
292
293   !!======================================================================
294END MODULE trasbc
Note: See TracBrowser for help on using the repository browser.