New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trasbc.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/trasbc.F90 @ 7788

Last change on this file since 7788 was 7788, checked in by cetlod, 7 years ago

trunk : representation of ice shelf melting in coupled mode

  • Property svn:keywords set to Id
File size: 12.0 KB
Line 
1MODULE trasbc
2   !!==============================================================================
3   !!                       ***  MODULE  trasbc  ***
4   !! Ocean active tracers:  surface boundary condition
5   !!==============================================================================
6   !! History :  OPA  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!  NEMO      1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
10   !!             -   !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.6  !  2014-11  (P. Mathiot) isf melting forcing
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_sbc       : update the tracer trend at ocean surface
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and active tracers
18   USE sbc_oce        ! surface boundary condition: ocean
19   USE dom_oce        ! ocean space domain variables
20   USE phycst         ! physical constant
21   USE eosbn2         ! Equation Of State
22   USE sbcmod         ! ln_rnf 
23   USE sbcrnf         ! River runoff 
24   USE sbcisf         ! Ice shelf   
25   USE iscplini       ! Ice sheet coupling
26   USE traqsr         ! solar radiation penetration
27   USE trd_oce        ! trends: ocean variables
28   USE trdtra         ! trends manager: tracers
29   !
30   USE in_out_manager ! I/O manager
31   USE prtctl         ! Print control
32   USE iom            ! xIOS server
33   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
34   USE wrk_nemo       ! Memory Allocation
35   USE timing         ! Timing
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   tra_sbc   ! routine called by step.F90
41
42   !! * Substitutions
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_sbc ( kt )
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE tra_sbc  ***
54      !!                   
55      !! ** Purpose :   Compute the tracer surface boundary condition trend of
56      !!      (flux through the interface, concentration/dilution effect)
57      !!      and add it to the general trend of tracer equations.
58      !!
59      !! ** Method :   The (air+ice)-sea flux has two components:
60      !!      (1) Fext, external forcing (i.e. flux through the (air+ice)-sea interface);
61      !!      (2) Fwe , tracer carried with the water that is exchanged with air+ice.
62      !!               The input forcing fields (emp, rnf, sfx, isf) contain Fext+Fwe,
63      !!             they are simply added to the tracer trend (tsa).
64      !!               In linear free surface case (ln_linssh=T), the volume of the
65      !!             ocean does not change with the water exchanges at the (air+ice)-sea
66      !!             interface. Therefore another term has to be added, to mimic the
67      !!             concentration/dilution effect associated with water exchanges.
68      !!
69      !! ** Action  : - Update tsa with the surface boundary condition trend
70      !!              - send trends to trdtra module for further diagnostics(l_trdtra=T)
71      !!----------------------------------------------------------------------
72      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
73      !
74      INTEGER  ::   ji, jj, jk, jn        ! dummy loop indices 
75      INTEGER  ::   ikt, ikb              ! local integers
76      REAL(wp) ::   zfact, z1_e3t, zdep   ! local scalar
77      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdt, ztrds
78      !!----------------------------------------------------------------------
79      !
80      IF( nn_timing == 1 )  CALL timing_start('tra_sbc')
81      !
82      IF( kt == nit000 ) THEN
83         IF(lwp) WRITE(numout,*)
84         IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition'
85         IF(lwp) WRITE(numout,*) '~~~~~~~ '
86      ENDIF
87      !
88      IF( l_trdtra ) THEN                    !* Save ta and sa trends
89         CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds ) 
90         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
91         ztrds(:,:,:) = tsa(:,:,:,jp_sal)
92      ENDIF
93      !
94!!gm  This should be moved into sbcmod.F90 module ? (especially now that ln_traqsr is read in namsbc namelist)
95      IF( .NOT.ln_traqsr ) THEN     ! no solar radiation penetration
96         qns(:,:) = qns(:,:) + qsr(:,:)      ! total heat flux in qns
97         qsr(:,:) = 0._wp                     ! qsr set to zero
98      ENDIF
99
100      !----------------------------------------
101      !        EMP, SFX and QNS effects
102      !----------------------------------------
103      !                             !==  Set before sbc tracer content fields  ==!
104      IF( kt == nit000 ) THEN             !* 1st time-step
105         IF( ln_rstart .AND.    &               ! Restart: read in restart file
106              & iom_varid( numror, 'sbc_hc_b', ldstop = .FALSE. ) > 0 ) THEN
107            IF(lwp) WRITE(numout,*) '          nit000-1 sbc tracer content field read in the restart file'
108            zfact = 0.5_wp
109            sbc_tsc(:,:,:) = 0._wp
110            CALL iom_get( numror, jpdom_autoglo, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem) )   ! before heat content sbc trend
111            CALL iom_get( numror, jpdom_autoglo, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal) )   ! before salt content sbc trend
112         ELSE                                   ! No restart or restart not found: Euler forward time stepping
113            zfact = 1._wp
114            sbc_tsc(:,:,:) = 0._wp
115            sbc_tsc_b(:,:,:) = 0._wp
116         ENDIF
117      ELSE                                !* other time-steps: swap of forcing fields
118         zfact = 0.5_wp
119         sbc_tsc_b(:,:,:) = sbc_tsc(:,:,:)
120      ENDIF
121      !                             !==  Now sbc tracer content fields  ==!
122      DO jj = 2, jpj
123         DO ji = fs_2, fs_jpim1   ! vector opt.
124            sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj)   ! non solar heat flux
125            sbc_tsc(ji,jj,jp_sal) = r1_rau0     * sfx(ji,jj)   ! salt flux due to freezing/melting
126         END DO
127      END DO
128      IF( ln_linssh ) THEN                !* linear free surface 
129         DO jj = 2, jpj                         !==>> add concentration/dilution effect due to constant volume cell
130            DO ji = fs_2, fs_jpim1   ! vector opt.
131               sbc_tsc(ji,jj,jp_tem) = sbc_tsc(ji,jj,jp_tem) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_tem)
132               sbc_tsc(ji,jj,jp_sal) = sbc_tsc(ji,jj,jp_sal) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_sal)
133            END DO
134         END DO                                 !==>> output c./d. term
135         IF( iom_use('emp_x_sst') )   CALL iom_put( "emp_x_sst", emp (:,:) * tsn(:,:,1,jp_tem) )
136         IF( iom_use('emp_x_sss') )   CALL iom_put( "emp_x_sss", emp (:,:) * tsn(:,:,1,jp_sal) )
137      ENDIF
138      !
139      DO jn = 1, jpts               !==  update tracer trend  ==!
140         DO jj = 2, jpj
141            DO ji = fs_2, fs_jpim1   ! vector opt. 
142               tsa(ji,jj,1,jn) = tsa(ji,jj,1,jn) + zfact * ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) ) / e3t_n(ji,jj,1)
143            END DO
144         END DO
145      END DO
146      !                 
147      IF( lrst_oce ) THEN           !==  write sbc_tsc in the ocean restart file  ==!
148         CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem) )
149         CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal) )
150      ENDIF
151      !
152      !----------------------------------------
153      !       Ice Shelf effects (ISF)
154      !     tbl treated as in Losh (2008) JGR
155      !----------------------------------------
156      !
157!!gm BUG ?   Why no differences between non-linear and linear free surface ?
158!!gm         probably taken into account in r1_hisf_tbl : to be verified
159      IF( ln_isf ) THEN
160         zfact = 0.5_wp
161         DO jj = 2, jpj
162            DO ji = fs_2, fs_jpim1
163               !
164               ikt = misfkt(ji,jj)
165               ikb = misfkb(ji,jj)
166               !
167               ! level fully include in the ice shelf boundary layer
168               ! sign - because fwf sign of evapo (rnf sign of precip)
169               DO jk = ikt, ikb - 1
170               ! compute trend
171                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)                                                &
172                     &           + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) )             &
173                     &           * r1_hisf_tbl(ji,jj)
174               END DO
175   
176               ! level partially include in ice shelf boundary layer
177               ! compute trend
178               tsa(ji,jj,ikb,jp_tem) = tsa(ji,jj,ikb,jp_tem)                                                 &
179                  &              + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) )             &
180                  &              * r1_hisf_tbl(ji,jj) * ralpha(ji,jj)
181
182            END DO
183         END DO
184      END IF
185      !
186      !----------------------------------------
187      !        River Runoff effects
188      !----------------------------------------
189      !
190      IF( ln_rnf ) THEN         ! input of heat and salt due to river runoff
191         zfact = 0.5_wp
192         DO jj = 2, jpj 
193            DO ji = fs_2, fs_jpim1
194               IF( rnf(ji,jj) /= 0._wp ) THEN
195                  zdep = zfact / h_rnf(ji,jj)
196                  DO jk = 1, nk_rnf(ji,jj)
197                                        tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)                                 &
198                                           &                 +  ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep
199                     IF( ln_rnf_sal )   tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal)                                 &
200                                           &                 +  ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep 
201                  END DO
202               ENDIF
203            END DO 
204         END DO 
205      ENDIF
206
207      IF( iom_use('rnf_x_sst') )   CALL iom_put( "rnf_x_sst", rnf*tsn(:,:,1,jp_tem) )   ! runoff term on sst
208      IF( iom_use('rnf_x_sss') )   CALL iom_put( "rnf_x_sss", rnf*tsn(:,:,1,jp_sal) )   ! runoff term on sss
209
210      !
211      !----------------------------------------
212      !        Ice Sheet coupling imbalance correction to have conservation
213      !----------------------------------------
214      !
215      IF( ln_iscpl .AND. ln_hsb) THEN         ! input of heat and salt due to river runoff
216         DO jk = 1,jpk
217            DO jj = 2, jpj 
218               DO ji = fs_2, fs_jpim1
219                  zdep = 1._wp / e3t_n(ji,jj,jk) 
220                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) - htsc_iscpl(ji,jj,jk,jp_tem)                       &
221                      &                                         * zdep
222                  tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) - htsc_iscpl(ji,jj,jk,jp_sal)                       &
223                      &                                         * zdep 
224               END DO 
225            END DO 
226         END DO
227      ENDIF
228
229      IF( l_trdtra )   THEN                      ! save the horizontal diffusive trends for further diagnostics
230         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
231         ztrds(:,:,:) = tsa(:,:,:,jp_sal) - ztrds(:,:,:)
232         CALL trd_tra( kt, 'TRA', jp_tem, jptra_nsr, ztrdt )
233         CALL trd_tra( kt, 'TRA', jp_sal, jptra_nsr, ztrds )
234         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds ) 
235      ENDIF
236      !
237      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' sbc  - Ta: ', mask1=tmask,   &
238         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
239      !
240      IF( nn_timing == 1 )  CALL timing_stop('tra_sbc')
241      !
242   END SUBROUTINE tra_sbc
243
244   !!======================================================================
245END MODULE trasbc
Note: See TracBrowser for help on using the repository browser.