New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trdvor.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/TRD – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/TRD/trdvor.F90 @ 3294

Last change on this file since 3294 was 3294, checked in by rblod, 12 years ago

Merge of 3.4beta into the trunk

  • Property svn:keywords set to Id
File size: 26.3 KB
Line 
1MODULE trdvor
2   !!======================================================================
3   !!                       ***  MODULE  trdvor  ***
4   !! Ocean diagnostics:  momentum trends
5   !!=====================================================================
6   !! History :  1.0  !  04-2006  (L. Brunier, A-M. Treguier) Original code
7   !!            2.0  !  04-2008  (C. Talandier) New trends organization
8   !!----------------------------------------------------------------------
9#if defined key_trdvor   ||   defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_trdvor'   : momentum trend diagnostics
12   !!----------------------------------------------------------------------
13   !!   trd_vor      : momentum trends averaged over the depth
14   !!   trd_vor_zint : vorticity vertical integration
15   !!   trd_vor_init : initialization step
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers variables
18   USE dom_oce         ! ocean space and time domain variables
19   USE trdmod_oce      ! ocean variables trends
20   USE zdf_oce         ! ocean vertical physics
21   USE in_out_manager  ! I/O manager
22   USE phycst          ! Define parameters for the routines
23   USE ldfdyn_oce      ! ocean active tracers: lateral physics
24   USE dianam          ! build the name of file (routine)
25   USE zdfmxl          ! mixed layer depth
26   USE ioipsl          ! NetCDF library
27   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
28   USE lib_mpp         ! MPP library
29   USE wrk_nemo        ! Memory allocation
30
31
32   IMPLICIT NONE
33   PRIVATE
34
35   INTERFACE trd_vor_zint
36      MODULE PROCEDURE trd_vor_zint_2d, trd_vor_zint_3d
37   END INTERFACE
38
39   PUBLIC   trd_vor        ! routine called by step.F90
40   PUBLIC   trd_vor_zint   ! routine called by dynamics routines
41   PUBLIC   trd_vor_init   ! routine called by opa.F90
42   PUBLIC   trd_vor_alloc  ! routine called by nemogcm.F90
43
44   INTEGER ::   nh_t, nmoydpvor, nidvor, nhoridvor, ndimvor1, icount   ! needs for IOIPSL output
45   INTEGER, SAVE, ALLOCATABLE, DIMENSION(:) ::   ndexvor1   ! needed for IOIPSL output
46   INTEGER ::   ndebug     ! (0/1) set it to 1 in case of problem to have more print
47
48   REAL(wp), SAVE, ALLOCATABLE, DIMENSION(:,:)   ::   vor_avr      ! average
49   REAL(wp), SAVE, ALLOCATABLE, DIMENSION(:,:)   ::   vor_avrb     ! before vorticity (kt-1)
50   REAL(wp), SAVE, ALLOCATABLE, DIMENSION(:,:)   ::   vor_avrbb    ! vorticity at begining of the nwrite-1 timestep averaging period
51   REAL(wp), SAVE, ALLOCATABLE, DIMENSION(:,:)   ::   vor_avrbn    ! after vorticity at time step after the
52   REAL(wp), SAVE, ALLOCATABLE, DIMENSION(:,:)   ::   rotot        ! begining of the NWRITE-1 timesteps
53   REAL(wp), SAVE, ALLOCATABLE, DIMENSION(:,:)   ::   vor_avrtot   !
54   REAL(wp), SAVE, ALLOCATABLE, DIMENSION(:,:)   ::   vor_avrres   !
55   REAL(wp), SAVE, ALLOCATABLE, DIMENSION(:,:,:) ::   vortrd       ! curl of trends
56         
57   CHARACTER(len=12) ::   cvort
58
59   !! * Substitutions
60#  include "domzgr_substitute.h90"
61#  include "ldfdyn_substitute.h90"
62#  include "vectopt_loop_substitute.h90"
63   !!----------------------------------------------------------------------
64   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
65   !! $Id$
66   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
67   !!----------------------------------------------------------------------
68CONTAINS
69
70   INTEGER FUNCTION trd_vor_alloc()
71      !!----------------------------------------------------------------------------
72      !!                  ***  ROUTINE trd_vor_alloc  ***
73      !!----------------------------------------------------------------------------
74      ALLOCATE( vor_avr   (jpi,jpj) , vor_avrb(jpi,jpj) , vor_avrbb (jpi,jpj) ,   &
75         &      vor_avrbn (jpi,jpj) , rotot   (jpi,jpj) , vor_avrtot(jpi,jpj) ,   &
76         &      vor_avrres(jpi,jpj) , vortrd  (jpi,jpj,jpltot_vor) ,              &
77         &      ndexvor1  (jpi*jpj)                                ,   STAT= trd_vor_alloc )
78         !
79      IF( lk_mpp             )   CALL mpp_sum ( trd_vor_alloc )
80      IF( trd_vor_alloc /= 0 )   CALL ctl_warn('trd_vor_alloc: failed to allocate arrays')
81   END FUNCTION trd_vor_alloc
82
83
84   SUBROUTINE trd_vor_zint_2d( putrdvor, pvtrdvor, ktrd )
85      !!----------------------------------------------------------------------------
86      !!                  ***  ROUTINE trd_vor_zint  ***
87      !!
88      !! ** Purpose :   computation of vertically integrated vorticity budgets
89      !!              from ocean surface down to control surface (NetCDF output)
90      !!
91      !! ** Method/usage :   integration done over nwrite-1 time steps
92      !!
93      !! ** Action :   trends :
94      !!                  vortrd (,, 1) = Pressure Gradient Trend
95      !!                  vortrd (,, 2) = KE Gradient Trend
96      !!                  vortrd (,, 3) = Relative Vorticity Trend
97      !!                  vortrd (,, 4) = Coriolis Term Trend
98      !!                  vortrd (,, 5) = Horizontal Diffusion Trend
99      !!                  vortrd (,, 6) = Vertical Advection Trend
100      !!                  vortrd (,, 7) = Vertical Diffusion Trend
101      !!                  vortrd (,, 8) = Surface Pressure Grad. Trend
102      !!                  vortrd (,, 9) = Beta V
103      !!                  vortrd (,,10) = forcing term
104      !!                  vortrd (,,11) = bottom friction term
105      !!                  rotot(,) : total cumulative trends over nwrite-1 time steps
106      !!                  vor_avrtot(,) : first membre of vrticity equation
107      !!                  vor_avrres(,) : residual = dh/dt entrainment
108      !!
109      !!      trends output in netCDF format using ioipsl
110      !!----------------------------------------------------------------------
111      !
112      INTEGER                     , INTENT(in   ) ::   ktrd       ! ocean trend index
113      REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) ::   putrdvor   ! u vorticity trend
114      REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) ::   pvtrdvor   ! v vorticity trend
115      !
116      INTEGER ::   ji, jj       ! dummy loop indices
117      INTEGER ::   ikbu, ikbv   ! local integers
118      REAL(wp), POINTER, DIMENSION(:,:) :: zudpvor, zvdpvor  ! total cmulative trends
119      !!----------------------------------------------------------------------
120
121      !
122      CALL wrk_alloc( jpi, jpj, zudpvor, zvdpvor )                                     ! Memory allocation
123      !
124
125      zudpvor(:,:) = 0._wp                 ;   zvdpvor(:,:) = 0._wp                    ! Initialisation
126      CALL lbc_lnk( putrdvor, 'U', -1. )   ;   CALL lbc_lnk( pvtrdvor, 'V', -1. )      ! lateral boundary condition
127     
128
129      !  =====================================
130      !  I vertical integration of 2D trends
131      !  =====================================
132
133      SELECT CASE (ktrd) 
134      !
135      CASE (jpvor_bfr)        ! bottom friction
136         DO jj = 2, jpjm1
137            DO ji = fs_2, fs_jpim1 
138               ikbu = mbkv(ji,jj)
139               ikbv = mbkv(ji,jj)           
140               zudpvor(ji,jj) = putrdvor(ji,jj) * fse3u(ji,jj,ikbu) * e1u(ji,jj) * umask(ji,jj,ikbu)
141               zvdpvor(ji,jj) = pvtrdvor(ji,jj) * fse3v(ji,jj,ikbv) * e2v(ji,jj) * vmask(ji,jj,ikbv)
142            END DO
143         END DO
144         !
145      CASE (jpvor_swf)        ! wind stress
146         zudpvor(:,:) = putrdvor(:,:) * fse3u(:,:,1) * e1u(:,:) * umask(:,:,1)
147         zvdpvor(:,:) = pvtrdvor(:,:) * fse3v(:,:,1) * e2v(:,:) * vmask(:,:,1)
148         !
149      END SELECT
150
151      ! Average except for Beta.V
152      zudpvor(:,:) = zudpvor(:,:) * hur(:,:)
153      zvdpvor(:,:) = zvdpvor(:,:) * hvr(:,:)
154   
155      ! Curl
156      DO ji=1,jpim1
157         DO jj=1,jpjm1
158            vortrd(ji,jj,ktrd) = (    zvdpvor(ji+1,jj) - zvdpvor(ji,jj)       &
159                 &                - ( zudpvor(ji,jj+1) - zudpvor(ji,jj) )   ) / ( e1f(ji,jj) * e2f(ji,jj) )
160         END DO
161      END DO
162      vortrd(:,:,ktrd) = vortrd(:,:,ktrd) * fmask(:,:,1)      ! Surface mask
163
164      IF( ndebug /= 0 ) THEN
165         IF(lwp) WRITE(numout,*) ' debuging trd_vor_zint: I done'
166         CALL FLUSH(numout)
167      ENDIF
168      !
169      CALL wrk_dealloc( jpi, jpj, zudpvor, zvdpvor )                                   
170      !
171   END SUBROUTINE trd_vor_zint_2d
172
173
174   SUBROUTINE trd_vor_zint_3d( putrdvor, pvtrdvor, ktrd )
175      !!----------------------------------------------------------------------------
176      !!                  ***  ROUTINE trd_vor_zint  ***
177      !!
178      !! ** Purpose :   computation of vertically integrated vorticity budgets
179      !!              from ocean surface down to control surface (NetCDF output)
180      !!
181      !! ** Method/usage :   integration done over nwrite-1 time steps
182      !!
183      !! ** Action :     trends :
184      !!                  vortrd (,,1) = Pressure Gradient Trend
185      !!                  vortrd (,,2) = KE Gradient Trend
186      !!                  vortrd (,,3) = Relative Vorticity Trend
187      !!                  vortrd (,,4) = Coriolis Term Trend
188      !!                  vortrd (,,5) = Horizontal Diffusion Trend
189      !!                  vortrd (,,6) = Vertical Advection Trend
190      !!                  vortrd (,,7) = Vertical Diffusion Trend
191      !!                  vortrd (,,8) = Surface Pressure Grad. Trend
192      !!                  vortrd (,,9) = Beta V
193      !!                  vortrd (,,10) = forcing term
194      !!      vortrd (,,11) = bottom friction term
195      !!                  rotot(,) : total cumulative trends over nwrite-1 time steps
196      !!                  vor_avrtot(,) : first membre of vrticity equation
197      !!                  vor_avrres(,) : residual = dh/dt entrainment
198      !!
199      !!      trends output in netCDF format using ioipsl
200      !!----------------------------------------------------------------------
201      !
202      INTEGER                         , INTENT(in   ) ::   ktrd       ! ocean trend index
203      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   putrdvor   ! u vorticity trend
204      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pvtrdvor   ! v vorticity trend
205      !
206      INTEGER ::   ji, jj, jk   ! dummy loop indices
207      REAL(wp), POINTER, DIMENSION(:,:) :: zubet  , zvbet    ! Beta.V   
208      REAL(wp), POINTER, DIMENSION(:,:) :: zudpvor, zvdpvor  ! total cmulative trends
209      !!----------------------------------------------------------------------
210     
211      CALL wrk_alloc( jpi,jpj, zubet, zvbet, zudpvor, zvdpvor )                                   
212
213      ! Initialization
214      zubet  (:,:) = 0._wp
215      zvbet  (:,:) = 0._wp
216      zudpvor(:,:) = 0._wp
217      zvdpvor(:,:) = 0._wp
218      !
219      CALL lbc_lnk( putrdvor, 'U', -1. )         ! lateral boundary condition on input momentum trends
220      CALL lbc_lnk( pvtrdvor, 'V', -1. )
221
222      !  =====================================
223      !  I vertical integration of 3D trends
224      !  =====================================
225      ! putrdvor and pvtrdvor terms
226      DO jk = 1,jpk
227        zudpvor(:,:) = zudpvor(:,:) + putrdvor(:,:,jk) * fse3u(:,:,jk) * e1u(:,:) * umask(:,:,jk)
228        zvdpvor(:,:) = zvdpvor(:,:) + pvtrdvor(:,:,jk) * fse3v(:,:,jk) * e2v(:,:) * vmask(:,:,jk)
229      END DO
230
231      ! Save Beta.V term to avoid average before Curl
232      ! Beta.V : intergration, no average
233      IF( ktrd == jpvor_bev ) THEN
234         zubet(:,:) = zudpvor(:,:)
235         zvbet(:,:) = zvdpvor(:,:)
236      ENDIF
237
238      ! Average except for Beta.V
239      zudpvor(:,:) = zudpvor(:,:) * hur(:,:)
240      zvdpvor(:,:) = zvdpvor(:,:) * hvr(:,:)
241   
242      ! Curl
243      DO ji=1,jpim1
244         DO jj=1,jpjm1
245            vortrd(ji,jj,ktrd) = (    zvdpvor(ji+1,jj) - zvdpvor(ji,jj)     &
246               &                  - ( zudpvor(ji,jj+1) - zudpvor(ji,jj) ) ) / ( e1f(ji,jj) * e2f(ji,jj) )
247         END DO
248      END DO
249
250      ! Surface mask
251      vortrd(:,:,ktrd) = vortrd(:,:,ktrd) * fmask(:,:,1)
252
253      ! Special treatement for the Beta.V term
254      ! Compute the Curl of the Beta.V term which is not averaged
255      IF( ktrd == jpvor_bev ) THEN
256         DO ji=1,jpim1
257            DO jj=1,jpjm1
258               vortrd(ji,jj,jpvor_bev) = (    zvbet(ji+1,jj) - zvbet(ji,jj)     &
259                  &                       - ( zubet(ji,jj+1) - zubet(ji,jj) ) ) / ( e1f(ji,jj) * e2f(ji,jj) )
260            END DO
261         END DO
262
263         ! Average on the Curl
264         vortrd(:,:,jpvor_bev) = vortrd(:,:,jpvor_bev) * hur(:,:)
265
266         ! Surface mask
267         vortrd(:,:,jpvor_bev) = vortrd(:,:,jpvor_bev) * fmask(:,:,1)
268      ENDIF
269   
270      IF( ndebug /= 0 ) THEN
271         IF(lwp) WRITE(numout,*) ' debuging trd_vor_zint: I done'
272         CALL FLUSH(numout)
273      ENDIF
274      !
275      CALL wrk_dealloc( jpi,jpj, zubet, zvbet, zudpvor, zvdpvor )                                   
276      !
277   END SUBROUTINE trd_vor_zint_3d
278
279
280   SUBROUTINE trd_vor( kt )
281      !!----------------------------------------------------------------------
282      !!                  ***  ROUTINE trd_vor  ***
283      !!
284      !! ** Purpose :  computation of cumulated trends over analysis period
285      !!               and make outputs (NetCDF or DIMG format)
286      !!----------------------------------------------------------------------
287      !
288      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
289      !
290      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
291      INTEGER  ::   it, itmod        ! local integers
292      REAL(wp) ::   zmean            ! local scalars
293      REAL(wp), POINTER, DIMENSION(:,:) :: zun, zvn
294      !!----------------------------------------------------------------------
295
296      CALL wrk_alloc( jpi, jpj, zun, zvn )                                   
297
298      !  =================
299      !  I. Initialization
300      !  =================
301     
302     
303      ! I.1 set before values of vertically average u and v
304      ! ---------------------------------------------------
305
306      IF( kt > nit000 )   vor_avrb(:,:) = vor_avr(:,:)
307
308      IF( ndebug /= 0 ) THEN
309          WRITE(numout,*) ' debuging trd_vor: I.1 done '
310          CALL FLUSH(numout)
311      ENDIF
312
313      ! I.2 vertically integrated vorticity
314      !  ----------------------------------
315
316      vor_avr   (:,:) = 0._wp
317      zun       (:,:) = 0._wp
318      zvn       (:,:) = 0._wp
319      vor_avrtot(:,:) = 0._wp
320      vor_avrres(:,:) = 0._wp
321     
322      ! Vertically averaged velocity
323      DO jk = 1, jpk - 1
324         zun(:,:) = zun(:,:) + e1u(:,:) * un(:,:,jk) * fse3u(:,:,jk)
325         zvn(:,:) = zvn(:,:) + e2v(:,:) * vn(:,:,jk) * fse3v(:,:,jk)
326      END DO
327 
328      zun(:,:) = zun(:,:) * hur(:,:)
329      zvn(:,:) = zvn(:,:) * hvr(:,:)
330
331      ! Curl
332      DO ji=1,jpim1
333         DO jj=1,jpjm1
334            vor_avr(ji,jj) = (  ( zvn(ji+1,jj) - zvn(ji,jj) )    &
335               &              - ( zun(ji,jj+1) - zun(ji,jj) ) ) / ( e1f(ji,jj) * e2f(ji,jj) ) * fmask(ji,jj,1)
336         END DO
337      END DO
338     
339      IF( ndebug /= 0 ) THEN
340         WRITE(numout,*) ' debuging trd_vor: I.2 done'
341         CALL FLUSH(numout)
342      ENDIF
343
344      !  =================================
345      !   II. Cumulated trends
346      !  =================================
347
348      ! II.1 set `before' mixed layer values for kt = nit000+1
349      ! ------------------------------------------------------
350      IF( kt == nit000+1 ) THEN
351         vor_avrbb(:,:) = vor_avrb(:,:)
352         vor_avrbn(:,:) = vor_avr (:,:)
353      ENDIF
354
355      IF( ndebug /= 0 ) THEN
356         WRITE(numout,*) ' debuging trd_vor: I1.1 done'
357         CALL FLUSH(numout)
358      ENDIF
359
360      ! II.2 cumulated trends over analysis period (kt=2 to nwrite)
361      ! ----------------------
362      ! trends cumulated over nwrite-2 time steps
363
364      IF( kt >= nit000+2 ) THEN
365         nmoydpvor = nmoydpvor + 1
366         DO jl = 1, jpltot_vor
367            IF( jl /= 9 ) THEN
368               rotot(:,:) = rotot(:,:) + vortrd(:,:,jl)
369            ENDIF
370         END DO
371      ENDIF
372
373      IF( ndebug /= 0 ) THEN
374         WRITE(numout,*) ' debuging trd_vor: II.2 done'
375         CALL FLUSH(numout)
376      ENDIF
377
378      !  =============================================
379      !   III. Output in netCDF + residual computation
380      !  =============================================
381
382      ! define time axis
383      it    = kt
384      itmod = kt - nit000 + 1
385
386      IF( MOD( it, nn_trd ) == 0 ) THEN
387
388         ! III.1 compute total trend
389         ! ------------------------
390         zmean = 1._wp / (  REAL( nmoydpvor, wp ) * 2._wp * rdt  )
391         vor_avrtot(:,:) = (  vor_avr(:,:) - vor_avrbn(:,:) + vor_avrb(:,:) - vor_avrbb(:,:) ) * zmean
392
393         IF( ndebug /= 0 ) THEN
394             WRITE(numout,*) ' zmean = ',zmean
395             WRITE(numout,*) ' debuging trd_vor: III.1 done'
396             CALL FLUSH(numout)
397         ENDIF
398
399         ! III.2 compute residual
400         ! ---------------------
401         zmean = 1._wp / REAL( nmoydpvor, wp )
402         vor_avrres(:,:) = vor_avrtot(:,:) - rotot(:,:) / zmean
403
404         ! Boundary conditions
405         CALL lbc_lnk( vor_avrtot, 'F', 1. )
406         CALL lbc_lnk( vor_avrres, 'F', 1. )
407
408         IF( ndebug /= 0 ) THEN
409            WRITE(numout,*) ' debuging trd_vor: III.2 done'
410            CALL FLUSH(numout)
411         ENDIF
412
413         ! III.3 time evolution array swap
414         ! ------------------------------
415         vor_avrbb(:,:) = vor_avrb(:,:)
416         vor_avrbn(:,:) = vor_avr (:,:)
417
418         IF( ndebug /= 0 ) THEN
419            WRITE(numout,*) ' debuging trd_vor: III.3 done'
420            CALL FLUSH(numout)
421         ENDIF
422         !
423         nmoydpvor = 0
424         !
425      ENDIF
426
427      ! III.4 write trends to output
428      ! ---------------------------
429
430      IF( kt >=  nit000+1 ) THEN
431
432         IF( lwp .AND. MOD( itmod, nn_trd ) == 0 ) THEN
433            WRITE(numout,*) ''
434            WRITE(numout,*) 'trd_vor : write trends in the NetCDF file at kt = ', kt
435            WRITE(numout,*) '~~~~~~~  '
436         ENDIF
437 
438         CALL histwrite( nidvor,"sovortPh",it,vortrd(:,:,jpvor_prg),ndimvor1,ndexvor1)  ! grad Ph
439         CALL histwrite( nidvor,"sovortEk",it,vortrd(:,:,jpvor_keg),ndimvor1,ndexvor1)  ! Energy
440         CALL histwrite( nidvor,"sovozeta",it,vortrd(:,:,jpvor_rvo),ndimvor1,ndexvor1)  ! rel vorticity
441         CALL histwrite( nidvor,"sovortif",it,vortrd(:,:,jpvor_pvo),ndimvor1,ndexvor1)  ! coriolis
442         CALL histwrite( nidvor,"sovodifl",it,vortrd(:,:,jpvor_ldf),ndimvor1,ndexvor1)  ! lat diff
443         CALL histwrite( nidvor,"sovoadvv",it,vortrd(:,:,jpvor_zad),ndimvor1,ndexvor1)  ! vert adv
444         CALL histwrite( nidvor,"sovodifv",it,vortrd(:,:,jpvor_zdf),ndimvor1,ndexvor1)  ! vert diff
445         CALL histwrite( nidvor,"sovortPs",it,vortrd(:,:,jpvor_spg),ndimvor1,ndexvor1)  ! grad Ps
446         CALL histwrite( nidvor,"sovortbv",it,vortrd(:,:,jpvor_bev),ndimvor1,ndexvor1)  ! beta.V
447         CALL histwrite( nidvor,"sovowind",it,vortrd(:,:,jpvor_swf),ndimvor1,ndexvor1) ! wind stress
448         CALL histwrite( nidvor,"sovobfri",it,vortrd(:,:,jpvor_bfr),ndimvor1,ndexvor1) ! bottom friction
449         CALL histwrite( nidvor,"1st_mbre",it,vor_avrtot    ,ndimvor1,ndexvor1) ! First membre
450         CALL histwrite( nidvor,"sovorgap",it,vor_avrres    ,ndimvor1,ndexvor1) ! gap between 1st and 2 nd mbre
451         !
452         IF( ndebug /= 0 ) THEN
453            WRITE(numout,*) ' debuging trd_vor: III.4 done'
454            CALL FLUSH(numout)
455         ENDIF
456         !
457      ENDIF
458      !
459      IF( MOD( it, nn_trd ) == 0 ) rotot(:,:)=0
460      !
461      IF( kt == nitend )   CALL histclo( nidvor )
462      !
463      CALL wrk_dealloc( jpi, jpj, zun, zvn )                                   
464      !
465   END SUBROUTINE trd_vor
466
467
468   SUBROUTINE trd_vor_init
469      !!----------------------------------------------------------------------
470      !!                  ***  ROUTINE trd_vor_init  ***
471      !!
472      !! ** Purpose :   computation of vertically integrated T and S budgets
473      !!      from ocean surface down to control surface (NetCDF output)
474      !!----------------------------------------------------------------------
475      REAL(wp) ::   zjulian, zsto, zout
476      CHARACTER (len=40) ::   clhstnam
477      CHARACTER (len=40) ::   clop
478      !!----------------------------------------------------------------------
479
480      !  ===================
481      !   I. initialization
482      !  ===================
483
484      cvort='averaged-vor'
485
486      ! Open specifier
487      ndebug = 0      ! set it to 1 in case of problem to have more Print
488
489      IF(lwp) THEN
490         WRITE(numout,*) ' '
491         WRITE(numout,*) ' trd_vor_init: vorticity trends'
492         WRITE(numout,*) ' ~~~~~~~~~~~~'
493         WRITE(numout,*) ' '
494         WRITE(numout,*) '               ##########################################################################'
495         WRITE(numout,*) '                CAUTION: The interpretation of the vorticity trends is'
496         WRITE(numout,*) '                not obvious, please contact Anne-Marie TREGUIER at: treguier@ifremer.fr '
497         WRITE(numout,*) '               ##########################################################################'
498         WRITE(numout,*) ' '
499      ENDIF
500
501      IF( trd_vor_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'trd_vor_init : unable to allocate trdvor arrays' )
502
503
504      ! cumulated trends array init
505      nmoydpvor = 0
506      rotot(:,:)=0
507      vor_avrtot(:,:)=0
508      vor_avrres(:,:)=0
509
510      IF( ndebug /= 0 ) THEN
511         WRITE(numout,*) ' debuging trd_vor_init: I. done'
512         CALL FLUSH(numout)
513      ENDIF
514
515      !  =================================
516      !   II. netCDF output initialization
517      !  =================================
518
519      !-----------------------------------------
520      ! II.1 Define frequency of output and means
521      ! -----------------------------------------
522      IF( ln_mskland )   THEN   ;   clop = "only(x)"   ! put 1.e+20 on land (very expensive!!)
523      ELSE                      ;   clop = "x"         ! no use of the mask value (require less cpu time)
524      ENDIF
525#if defined key_diainstant
526      zsto = nwrite*rdt
527      clop = "inst("//TRIM(clop)//")"
528#else
529      zsto = rdt
530      clop = "ave("//TRIM(clop)//")"
531#endif
532      zout = nn_trd*rdt
533
534      IF(lwp) WRITE(numout,*) '               netCDF initialization'
535
536      ! II.2 Compute julian date from starting date of the run
537      ! ------------------------
538      CALL ymds2ju( nyear, nmonth, nday, rdt, zjulian )
539      zjulian = zjulian - adatrj   !   set calendar origin to the beginning of the experiment
540      IF(lwp) WRITE(numout,*)' ' 
541      IF(lwp) WRITE(numout,*)'               Date 0 used :',nit000,    &
542         &                   ' YEAR ', nyear,' MONTH '      , nmonth,   &
543         &                   ' DAY ' , nday, 'Julian day : ', zjulian
544
545      ! II.3 Define the T grid trend file (nidvor)
546      ! ---------------------------------
547      CALL dia_nam( clhstnam, nn_trd, 'vort' )                  ! filename
548      IF(lwp) WRITE(numout,*) ' Name of NETCDF file ', clhstnam
549      CALL histbeg( clhstnam, jpi, glamf, jpj, gphif,1, jpi,   &  ! Horizontal grid : glamt and gphit
550         &          1, jpj, nit000-1, zjulian, rdt, nh_t, nidvor, domain_id=nidom, snc4chunks=snc4set )
551      CALL wheneq( jpi*jpj, fmask, 1, 1., ndexvor1, ndimvor1 )    ! surface
552
553      ! Declare output fields as netCDF variables
554      CALL histdef( nidvor, "sovortPh", cvort//"grad Ph" , "s-2",        & ! grad Ph
555         &          jpi,jpj,nh_t,1,1,1,-99,32,clop,zsto,zout)
556      CALL histdef( nidvor, "sovortEk", cvort//"Energy", "s-2",          & ! Energy
557         &          jpi,jpj,nh_t,1,1,1,-99,32,clop,zsto,zout)
558      CALL histdef( nidvor, "sovozeta", cvort//"rel vorticity", "s-2",   & ! rel vorticity
559         &          jpi,jpj,nh_t,1,1,1,-99,32,clop,zsto,zout)
560      CALL histdef( nidvor, "sovortif", cvort//"coriolis", "s-2",        & ! coriolis
561         &          jpi,jpj,nh_t,1,1,1,-99,32,clop,zsto,zout)
562      CALL histdef( nidvor, "sovodifl", cvort//"lat diff ", "s-2",       & ! lat diff
563         &          jpi,jpj,nh_t,1,1,1,-99,32,clop,zsto,zout)
564      CALL histdef( nidvor, "sovoadvv", cvort//"vert adv", "s-2",        & ! vert adv
565         &          jpi,jpj,nh_t,1,1,1,-99,32,clop,zsto,zout)
566      CALL histdef( nidvor, "sovodifv", cvort//"vert diff" , "s-2",      & ! vert diff
567         &          jpi,jpj,nh_t,1,1,1,-99,32,clop,zsto,zout)
568      CALL histdef( nidvor, "sovortPs", cvort//"grad Ps", "s-2",         & ! grad Ps
569         &          jpi,jpj,nh_t,1,1,1,-99,32,clop,zsto,zout)
570      CALL histdef( nidvor, "sovortbv", cvort//"Beta V", "s-2",          & ! beta.V
571         &          jpi,jpj,nh_t,1,1,1,-99,32,clop,zsto,zout)
572      CALL histdef( nidvor, "sovowind", cvort//"wind stress", "s-2",     & ! wind stress
573         &          jpi,jpj,nh_t,1,1,1,-99,32,clop,zsto,zout)
574      CALL histdef( nidvor, "sovobfri", cvort//"bottom friction", "s-2", & ! bottom friction
575         &          jpi,jpj,nh_t,1,1,1,-99,32,clop,zsto,zout)
576      CALL histdef( nidvor, "1st_mbre", cvort//"1st mbre", "s-2",        & ! First membre
577         &          jpi,jpj,nh_t,1,1,1,-99,32,clop,zsto,zout)
578      CALL histdef( nidvor, "sovorgap", cvort//"gap", "s-2",             & ! gap between 1st and 2 nd mbre
579         &          jpi,jpj,nh_t,1,1,1,-99,32,clop,zsto,zout)
580      CALL histend( nidvor, snc4set )
581
582      IF( ndebug /= 0 ) THEN
583         WRITE(numout,*) ' debuging trd_vor_init: II. done'
584         CALL FLUSH(numout)
585      ENDIF
586      !
587   END SUBROUTINE trd_vor_init
588
589#else
590   !!----------------------------------------------------------------------
591   !!   Default option :                                       Empty module
592   !!----------------------------------------------------------------------
593   INTERFACE trd_vor_zint
594      MODULE PROCEDURE trd_vor_zint_2d, trd_vor_zint_3d
595   END INTERFACE
596CONTAINS
597   SUBROUTINE trd_vor( kt )        ! Empty routine
598      WRITE(*,*) 'trd_vor: You should not have seen this print! error?', kt
599   END SUBROUTINE trd_vor
600   SUBROUTINE trd_vor_zint_2d( putrdvor, pvtrdvor, ktrd )
601      REAL, DIMENSION(:,:), INTENT( inout ) ::   putrdvor, pvtrdvor
602      INTEGER, INTENT( in ) ::   ktrd         ! ocean trend index
603      WRITE(*,*) 'trd_vor_zint_2d: You should not have seen this print! error?', putrdvor(1,1), pvtrdvor(1,1), ktrd
604   END SUBROUTINE trd_vor_zint_2d
605   SUBROUTINE trd_vor_zint_3d( putrdvor, pvtrdvor, ktrd )
606      REAL, DIMENSION(:,:,:), INTENT( inout ) ::   putrdvor, pvtrdvor
607      INTEGER, INTENT( in ) ::   ktrd         ! ocean trend index
608      WRITE(*,*) 'trd_vor_zint_3d: You should not have seen this print! error?', putrdvor(1,1,1), pvtrdvor(1,1,1), ktrd
609   END SUBROUTINE trd_vor_zint_3d
610   SUBROUTINE trd_vor_init              ! Empty routine
611      WRITE(*,*) 'trd_vor_init: You should not have seen this print! error?'
612   END SUBROUTINE trd_vor_init
613#endif
614   !!======================================================================
615END MODULE trdvor
Note: See TracBrowser for help on using the repository browser.