New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfgls.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfgls.F90 @ 3294

Last change on this file since 3294 was 3294, checked in by rblod, 12 years ago

Merge of 3.4beta into the trunk

  • Property svn:keywords set to Id
File size: 59.8 KB
Line 
1MODULE zdfgls
2   !!======================================================================
3   !!                       ***  MODULE  zdfgls  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the gls
5   !!                 turbulent closure parameterization
6   !!======================================================================
7   !! History :   3.0  !  2009-09  (G. Reffray)  Original code
8   !!             3.3  !  2010-10  (C. Bricaud)  Add in the reference
9   !!----------------------------------------------------------------------
10#if defined key_zdfgls   ||   defined key_esopa
11   !!----------------------------------------------------------------------
12   !!   'key_zdfgls'                 Generic Length Scale vertical physics
13   !!----------------------------------------------------------------------
14   !!   zdf_gls      : update momentum and tracer Kz from a gls scheme
15   !!   zdf_gls_init : initialization, namelist read, and parameters control
16   !!   gls_rst      : read/write gls restart in ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! ocean space and time domain : variable volume layer
21   USE zdf_oce        ! ocean vertical physics
22   USE sbc_oce        ! surface boundary condition: ocean
23   USE phycst         ! physical constants
24   USE zdfmxl         ! mixed layer
25   USE restart        ! only for lrst_oce
26   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
27   USE lib_mpp        ! MPP manager
28   USE wrk_nemo       ! work arrays
29   USE prtctl         ! Print control
30   USE in_out_manager ! I/O manager
31   USE iom            ! I/O manager library
32   USE timing         ! Timing
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   zdf_gls        ! routine called in step module
38   PUBLIC   zdf_gls_init   ! routine called in opa module
39   PUBLIC   gls_rst        ! routine called in step module
40
41   LOGICAL , PUBLIC, PARAMETER ::   lk_zdfgls = .TRUE.   !: TKE vertical mixing flag
42   !
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   en      !: now turbulent kinetic energy
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   mxln    !: now mixing length
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zwall   !: wall function
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustars2 !: Squared surface velocity scale at T-points
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustarb2 !: Squared bottom  velocity scale at T-points
48
49   !                                         !!! ** Namelist  namzdf_gls  **
50   LOGICAL  ::   ln_crban      = .FALSE.      ! =T use Craig and Banner scheme
51   LOGICAL  ::   ln_length_lim = .FALSE.      ! use limit on the dissipation rate under stable stratification (Galperin et al. 1988)
52   LOGICAL  ::   ln_sigpsi     = .FALSE.      ! Activate Burchard (2003) modification for k-eps closure & wave breaking mixing
53   INTEGER  ::   nn_tkebc_surf = 0            ! TKE surface boundary condition (=0/1)
54   INTEGER  ::   nn_tkebc_bot  = 0            ! TKE bottom boundary condition (=0/1)
55   INTEGER  ::   nn_psibc_surf = 0            ! PSI surface boundary condition (=0/1)
56   INTEGER  ::   nn_psibc_bot  = 0            ! PSI bottom boundary condition (=0/1)
57   INTEGER  ::   nn_stab_func  = 0            ! stability functions G88, KC or Canuto (=0/1/2)
58   INTEGER  ::   nn_clos       = 0            ! closure 0/1/2/3 MY82/k-eps/k-w/gen
59   REAL(wp) ::   rn_clim_galp  = 0.53_wp      ! Holt 2008 value for k-eps: 0.267
60   REAL(wp) ::   rn_epsmin     = 1.e-12_wp    ! minimum value of dissipation (m2/s3)
61   REAL(wp) ::   rn_emin       = 1.e-6_wp     ! minimum value of TKE (m2/s2)
62   REAL(wp) ::   rn_charn      = 2.e+5_wp     ! Charnock constant for surface breaking waves mixing : 1400. (standard) or 2.e5 (Stacey value)
63   REAL(wp) ::   rn_crban      = 100._wp      ! Craig and Banner constant for surface breaking waves mixing
64
65   REAL(wp) ::   hsro          =  0.003_wp    ! Minimum surface roughness
66   REAL(wp) ::   hbro          =  0.003_wp    ! Bottom roughness (m)
67   REAL(wp) ::   rcm_sf        =  0.73_wp     ! Shear free turbulence parameters
68   REAL(wp) ::   ra_sf         = -2.0_wp      ! Must be negative -2 < ra_sf < -1
69   REAL(wp) ::   rl_sf         =  0.2_wp      ! 0 <rl_sf<vkarmn   
70   REAL(wp) ::   rghmin        = -0.28_wp
71   REAL(wp) ::   rgh0          =  0.0329_wp
72   REAL(wp) ::   rghcri        =  0.03_wp
73   REAL(wp) ::   ra1           =  0.92_wp
74   REAL(wp) ::   ra2           =  0.74_wp
75   REAL(wp) ::   rb1           = 16.60_wp
76   REAL(wp) ::   rb2           = 10.10_wp         
77   REAL(wp) ::   re2           =  1.33_wp         
78   REAL(wp) ::   rl1           =  0.107_wp
79   REAL(wp) ::   rl2           =  0.0032_wp
80   REAL(wp) ::   rl3           =  0.0864_wp
81   REAL(wp) ::   rl4           =  0.12_wp
82   REAL(wp) ::   rl5           = 11.9_wp
83   REAL(wp) ::   rl6           =  0.4_wp
84   REAL(wp) ::   rl7           =  0.0_wp
85   REAL(wp) ::   rl8           =  0.48_wp
86   REAL(wp) ::   rm1           =  0.127_wp
87   REAL(wp) ::   rm2           =  0.00336_wp
88   REAL(wp) ::   rm3           =  0.0906_wp
89   REAL(wp) ::   rm4           =  0.101_wp
90   REAL(wp) ::   rm5           = 11.2_wp
91   REAL(wp) ::   rm6           =  0.4_wp
92   REAL(wp) ::   rm7           =  0.0_wp
93   REAL(wp) ::   rm8           =  0.318_wp
94   
95   REAL(wp) ::   rc02, rc02r, rc03, rc04                          ! coefficients deduced from above parameters
96   REAL(wp) ::   rc03_sqrt2_galp                                  !     -           -           -        -
97   REAL(wp) ::   rsbc_tke1, rsbc_tke2, rsbc_tke3, rfact_tke       !     -           -           -        -
98   REAL(wp) ::   rsbc_psi1, rsbc_psi2, rsbc_psi3, rfact_psi       !     -           -           -        -
99   REAL(wp) ::   rsbc_mb  , rsbc_std , rsbc_zs                    !     -           -           -        -
100   REAL(wp) ::   rc0, rc2, rc3, rf6, rcff, rc_diff                !     -           -           -        -
101   REAL(wp) ::   rs0, rs1, rs2, rs4, rs5, rs6                     !     -           -           -        -
102   REAL(wp) ::   rd0, rd1, rd2, rd3, rd4, rd5                     !     -           -           -        -
103   REAL(wp) ::   rsc_tke, rsc_psi, rpsi1, rpsi2, rpsi3, rsc_psi0  !     -           -           -        -
104   REAL(wp) ::   rpsi3m, rpsi3p, rpp, rmm, rnn                    !     -           -           -        -
105
106   !! * Substitutions
107#  include "domzgr_substitute.h90"
108#  include "vectopt_loop_substitute.h90"
109   !!----------------------------------------------------------------------
110   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
111   !! $Id$
112   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
113   !!----------------------------------------------------------------------
114CONTAINS
115
116   INTEGER FUNCTION zdf_gls_alloc()
117      !!----------------------------------------------------------------------
118      !!                ***  FUNCTION zdf_gls_alloc  ***
119      !!----------------------------------------------------------------------
120      ALLOCATE( en(jpi,jpj,jpk),  mxln(jpi,jpj,jpk), zwall(jpi,jpj,jpk) ,     &
121         &      ustars2(jpi,jpj), ustarb2(jpi,jpj)                      , STAT= zdf_gls_alloc )
122         !
123      IF( lk_mpp             )   CALL mpp_sum ( zdf_gls_alloc )
124      IF( zdf_gls_alloc /= 0 )   CALL ctl_warn('zdf_gls_alloc: failed to allocate arrays')
125   END FUNCTION zdf_gls_alloc
126
127
128   SUBROUTINE zdf_gls( kt )
129      !!----------------------------------------------------------------------
130      !!                   ***  ROUTINE zdf_gls  ***
131      !!
132      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
133      !!              coefficients using the GLS turbulent closure scheme.
134      !!----------------------------------------------------------------------
135      INTEGER, INTENT(in) ::   kt ! ocean time step
136      INTEGER  ::   ji, jj, jk, ibot, ibotm1, dir  ! dummy loop arguments
137      REAL(wp) ::   zesh2, zsigpsi, zcoef, zex1, zex2   ! local scalars
138      REAL(wp) ::   ztx2, zty2, zup, zdown, zcof        !   -      -
139      REAL(wp) ::   zratio, zrn2, zflxb, sh             !   -      -
140      REAL(wp) ::   prod, buoy, diss, zdiss, sm         !   -      -
141      REAL(wp) ::   gh, gm, shr, dif, zsqen, zav        !   -      -
142      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zdep
143      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zflxs       ! Turbulence fluxed induced by internal waves
144      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zhsro       ! Surface roughness (surface waves)
145      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eb          ! tke at time before
146      REAL(wp), POINTER, DIMENSION(:,:,:) ::   mxlb        ! mixing length at time before
147      REAL(wp), POINTER, DIMENSION(:,:,:) ::   shear       ! vertical shear
148      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eps         ! dissipation rate
149      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwall_psi   ! Wall function use in the wb case (ln_sigpsi.AND.ln_crban=T)
150      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_a, z_elem_b, z_elem_c, psi
151      !!--------------------------------------------------------------------
152      !
153      IF( nn_timing == 1 )  CALL timing_start('zdf_gls')
154      !
155      CALL wrk_alloc( jpi,jpj, zdep, zflxs, zhsro )
156      CALL wrk_alloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi )
157
158      ! Preliminary computing
159
160      ustars2 = 0._wp   ;   ustarb2 = 0._wp   ;   psi  = 0._wp   ;   zwall_psi = 0._wp
161
162      ! Compute surface and bottom friction at T-points
163!CDIR NOVERRCHK
164      DO jj = 2, jpjm1
165!CDIR NOVERRCHK
166         DO ji = fs_2, fs_jpim1   ! vector opt.
167            !
168            ! surface friction
169            ustars2(ji,jj) = rau0r * taum(ji,jj) * tmask(ji,jj,1)
170            !
171            ! bottom friction (explicit before friction)
172            ! Note that we chose here not to bound the friction as in dynbfr)
173            ztx2 = (  bfrua(ji,jj)  * ub(ji,jj,mbku(ji,jj)) + bfrua(ji-1,jj) * ub(ji-1,jj,mbku(ji-1,jj))  )   &
174               & * ( 1._wp - 0.5_wp * umask(ji,jj,1) * umask(ji-1,jj,1)  )
175            zty2 = (  bfrva(ji,jj)  * vb(ji,jj,mbkv(ji,jj)) + bfrva(ji,jj-1) * vb(ji,jj-1,mbkv(ji,jj-1))  )   &
176               & * ( 1._wp - 0.5_wp * vmask(ji,jj,1) * vmask(ji,jj-1,1)  )
177            ustarb2(ji,jj) = SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)
178         END DO
179      END DO 
180
181      ! In case of breaking surface waves mixing,
182      ! Compute surface roughness length according to Charnock formula:
183      IF( ln_crban ) THEN   ;   zhsro(:,:) = MAX(rsbc_zs * ustars2(:,:), hsro)
184      ELSE                  ;   zhsro(:,:) = hsro
185      ENDIF
186
187      ! Compute shear and dissipation rate
188      DO jk = 2, jpkm1
189         DO jj = 2, jpjm1
190            DO ji = fs_2, fs_jpim1   ! vector opt.
191               avmu(ji,jj,jk) = avmu(ji,jj,jk) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )   &
192                  &                            * ( ub(ji,jj,jk-1) - ub(ji,jj,jk) )   &
193                  &                            / (  fse3uw_n(ji,jj,jk)               &
194                  &                            *    fse3uw_b(ji,jj,jk) )
195               avmv(ji,jj,jk) = avmv(ji,jj,jk) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )   &
196                  &                            * ( vb(ji,jj,jk-1) - vb(ji,jj,jk) )   &
197                  &                            / (  fse3vw_n(ji,jj,jk)               &
198                  &                            *    fse3vw_b(ji,jj,jk) )
199               eps(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT(en(ji,jj,jk)) / mxln(ji,jj,jk)
200            END DO
201         END DO
202      END DO
203      !
204      ! Lateral boundary conditions (avmu,avmv) (sign unchanged)
205      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
206
207      ! Save tke at before time step
208      eb  (:,:,:) = en  (:,:,:)
209      mxlb(:,:,:) = mxln(:,:,:)
210
211      IF( nn_clos == 0 ) THEN    ! Mellor-Yamada
212         DO jk = 2, jpkm1
213            DO jj = 2, jpjm1 
214               DO ji = fs_2, fs_jpim1   ! vector opt.
215                  zup   = mxln(ji,jj,jk) * fsdepw(ji,jj,mbkt(ji,jj)+1)
216                  zdown = vkarmn * fsdepw(ji,jj,jk) * ( -fsdepw(ji,jj,jk) + fsdepw(ji,jj,mbkt(ji,jj)+1) )
217                  zcoef = ( zup / MAX( zdown, rsmall ) )
218                  zwall (ji,jj,jk) = ( 1._wp + re2 * zcoef*zcoef ) * tmask(ji,jj,jk)
219               END DO
220            END DO
221         END DO
222      ENDIF
223
224      !!---------------------------------!!
225      !!   Equation to prognostic k      !!
226      !!---------------------------------!!
227      !
228      ! Now Turbulent kinetic energy (output in en)
229      ! -------------------------------
230      ! Resolution of a tridiagonal linear system by a "methode de chasse"
231      ! computation from level 2 to jpkm1  (e(1) computed after and e(jpk)=0 ).
232      ! The surface boundary condition are set after
233      ! The bottom boundary condition are also set after. In standard e(bottom)=0.
234      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
235      ! Warning : after this step, en : right hand side of the matrix
236
237      DO jk = 2, jpkm1
238         DO jj = 2, jpjm1
239            DO ji = fs_2, fs_jpim1   ! vector opt.
240               !
241               ! shear prod. at w-point weightened by mask
242               shear(ji,jj,jk) =  ( avmu(ji-1,jj,jk) + avmu(ji,jj,jk) ) / MAX( 1.e0 , umask(ji-1,jj,jk) + umask(ji,jj,jk) )   &
243                  &             + ( avmv(ji,jj-1,jk) + avmv(ji,jj,jk) ) / MAX( 1.e0 , vmask(ji,jj-1,jk) + vmask(ji,jj,jk) )
244               !
245               ! stratif. destruction
246               buoy = - avt(ji,jj,jk) * rn2(ji,jj,jk)
247               !
248               ! shear prod. - stratif. destruction
249               diss = eps(ji,jj,jk)
250               !
251               dir = 0.5_wp + SIGN( 0.5_wp, shear(ji,jj,jk) + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
252               !
253               zesh2 = dir*(shear(ji,jj,jk)+buoy)+(1._wp-dir)*shear(ji,jj,jk)          ! production term
254               zdiss = dir*(diss/en(ji,jj,jk))   +(1._wp-dir)*(diss-buoy)/en(ji,jj,jk) ! dissipation term
255               !
256               ! Compute a wall function from 1. to rsc_psi*zwall/rsc_psi0
257               ! Note that as long that Dirichlet boundary conditions are NOT set at the first and last levels (GOTM style)
258               ! there is no need to set a boundary condition for zwall_psi at the top and bottom boundaries.
259               ! Otherwise, this should be rsc_psi/rsc_psi0
260               IF( ln_sigpsi ) THEN
261                  zsigpsi = MIN( 1._wp, zesh2 / eps(ji,jj,jk) )     ! 0. <= zsigpsi <= 1.
262                  zwall_psi(ji,jj,jk) = rsc_psi /   & 
263                     &     (  zsigpsi * rsc_psi + (1._wp-zsigpsi) * rsc_psi0 / MAX( zwall(ji,jj,jk), 1._wp )  )
264               ELSE
265                  zwall_psi(ji,jj,jk) = 1._wp
266               ENDIF
267               !
268               ! building the matrix
269               zcof = rfact_tke * tmask(ji,jj,jk)
270               !
271               ! lower diagonal
272               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
273                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
274               !
275               ! upper diagonal
276               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
277                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
278               !
279               ! diagonal
280               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
281                  &                       + rdt * zdiss * tmask(ji,jj,jk) 
282               !
283               ! right hand side in en
284               en(ji,jj,jk) = en(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
285            END DO
286         END DO
287      END DO
288      !
289      z_elem_b(:,:,jpk) = 1._wp
290      !
291      ! Set surface condition on zwall_psi (1 at the bottom)
292      IF( ln_sigpsi ) THEN
293         zcoef = rsc_psi / rsc_psi0
294         DO jj = 2, jpjm1
295            DO ji = fs_2, fs_jpim1   ! vector opt.
296               zwall_psi(ji,jj,1) = zcoef
297            END DO
298         END DO
299      ENDIF
300
301      ! Surface boundary condition on tke
302      ! ---------------------------------
303      !
304      SELECT CASE ( nn_tkebc_surf )
305      !
306      CASE ( 0 )             ! Dirichlet case
307         !
308         IF (ln_crban) THEN     ! Wave induced mixing case
309            !                      ! en(1) = q2(1) = 0.5 * (15.8 * Ccb)^(2/3) * u*^2
310            !                      ! balance between the production and the dissipation terms including the wave effect
311            en(:,:,1) = MAX( rsbc_tke1 * ustars2(:,:), rn_emin )
312            z_elem_a(:,:,1) = en(:,:,1)
313            z_elem_c(:,:,1) = 0._wp
314            z_elem_b(:,:,1) = 1._wp
315            !
316            ! one level below
317            en(:,:,2) = MAX( rsbc_tke1 * ustars2(:,:) * ( (zhsro(:,:)+fsdepw(:,:,2))/zhsro(:,:) )**ra_sf, rn_emin )
318            z_elem_a(:,:,2) = 0._wp
319            z_elem_c(:,:,2) = 0._wp
320            z_elem_b(:,:,2) = 1._wp
321            !
322         ELSE                   ! No wave induced mixing case
323            !                      ! en(1) = u*^2/C0^2  &  l(1)  = K*zs
324            !                      ! balance between the production and the dissipation terms
325            en(:,:,1) = MAX( rc02r * ustars2(:,:), rn_emin )
326            z_elem_a(:,:,1) = en(:,:,1) 
327            z_elem_c(:,:,1) = 0._wp
328            z_elem_b(:,:,1) = 1._wp
329            !
330            ! one level below
331            en(:,:,2) = MAX( rc02r * ustars2(:,:), rn_emin )
332            z_elem_a(:,:,2) = 0._wp
333            z_elem_c(:,:,2) = 0._wp
334            z_elem_b(:,:,2) = 1._wp
335            !
336         ENDIF
337         !
338      CASE ( 1 )             ! Neumann boundary condition on d(e)/dz
339         !
340         IF (ln_crban) THEN ! Shear free case: d(e)/dz= Fw
341            !
342            ! Dirichlet conditions at k=1 (Cosmetic)
343            en(:,:,1) = MAX( rsbc_tke1 * ustars2(:,:), rn_emin )
344            z_elem_a(:,:,1) = en(:,:,1)
345            z_elem_c(:,:,1) = 0._wp
346            z_elem_b(:,:,1) = 1._wp
347            ! at k=2, set de/dz=Fw
348            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
349            z_elem_a(:,:,2) = 0._wp       
350            zflxs(:,:) = rsbc_tke3 * ustars2(:,:)**1.5_wp * ( (zhsro(:,:)+fsdept(:,:,1) ) / zhsro(:,:) )**(1.5*ra_sf)
351            en(:,:,2) = en(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
352            !
353         ELSE                   ! No wave induced mixing case: d(e)/dz=0.
354            !
355            ! Dirichlet conditions at k=1 (Cosmetic)
356            en(:,:,1) = MAX( rc02r * ustars2(:,:), rn_emin )
357            z_elem_a(:,:,1) = en(:,:,1)
358            z_elem_c(:,:,1) = 0._wp
359            z_elem_b(:,:,1) = 1._wp
360            ! at k=2 set de/dz=0.:
361            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2)  ! Remove z_elem_a from z_elem_b
362            z_elem_a(:,:,2) = 0._wp
363            !
364         ENDIF
365         !
366      END SELECT
367
368      ! Bottom boundary condition on tke
369      ! --------------------------------
370      !
371      SELECT CASE ( nn_tkebc_bot )
372      !
373      CASE ( 0 )             ! Dirichlet
374         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = rn_lmin
375         !                      ! Balance between the production and the dissipation terms
376!CDIR NOVERRCHK
377         DO jj = 2, jpjm1
378!CDIR NOVERRCHK
379            DO ji = fs_2, fs_jpim1   ! vector opt.
380               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
381               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
382               !
383               ! Bottom level Dirichlet condition:
384               z_elem_a(ji,jj,ibot  ) = 0._wp
385               z_elem_c(ji,jj,ibot  ) = 0._wp
386               z_elem_b(ji,jj,ibot  ) = 1._wp
387               en(ji,jj,ibot  ) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
388               !
389               ! Just above last level, Dirichlet condition again
390               z_elem_a(ji,jj,ibotm1) = 0._wp
391               z_elem_c(ji,jj,ibotm1) = 0._wp
392               z_elem_b(ji,jj,ibotm1) = 1._wp
393               en(ji,jj,ibotm1) = MAX( rc02r * ustarb2(ji,jj), rn_emin ) 
394            END DO
395         END DO
396         !
397      CASE ( 1 )             ! Neumman boundary condition
398         !                     
399!CDIR NOVERRCHK
400         DO jj = 2, jpjm1
401!CDIR NOVERRCHK
402            DO ji = fs_2, fs_jpim1   ! vector opt.
403               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
404               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
405               !
406               ! Bottom level Dirichlet condition:
407               z_elem_a(ji,jj,ibot) = 0._wp
408               z_elem_c(ji,jj,ibot) = 0._wp
409               z_elem_b(ji,jj,ibot) = 1._wp
410               en(ji,jj,ibot) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
411               !
412               ! Just above last level: Neumann condition
413               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1)   ! Remove z_elem_c from z_elem_b
414               z_elem_c(ji,jj,ibotm1) = 0._wp
415            END DO
416         END DO
417         !
418      END SELECT
419
420      ! Matrix inversion (en prescribed at surface and the bottom)
421      ! ----------------------------------------------------------
422      !
423      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
424         DO jj = 2, jpjm1
425            DO ji = fs_2, fs_jpim1    ! vector opt.
426               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
427            END DO
428         END DO
429      END DO
430      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
431         DO jj = 2, jpjm1
432            DO ji = fs_2, fs_jpim1    ! vector opt.
433               z_elem_a(ji,jj,jk) = en(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
434            END DO
435         END DO
436      END DO
437      DO jk = jpk-1, 2, -1                         ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
438         DO jj = 2, jpjm1
439            DO ji = fs_2, fs_jpim1    ! vector opt.
440               en(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * en(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
441            END DO
442         END DO
443      END DO
444      !                                            ! set the minimum value of tke
445      en(:,:,:) = MAX( en(:,:,:), rn_emin )
446     
447      !!----------------------------------------!!
448      !!   Solve prognostic equation for psi    !!
449      !!----------------------------------------!!
450
451      ! Set psi to previous time step value
452      !
453      SELECT CASE ( nn_clos )
454      !
455      CASE( 0 )               ! k-kl  (Mellor-Yamada)
456         DO jk = 2, jpkm1
457            DO jj = 2, jpjm1
458               DO ji = fs_2, fs_jpim1   ! vector opt.
459                  psi(ji,jj,jk)  = eb(ji,jj,jk) * mxlb(ji,jj,jk)
460               END DO
461            END DO
462         END DO
463         !
464      CASE( 1 )               ! k-eps
465         DO jk = 2, jpkm1
466            DO jj = 2, jpjm1
467               DO ji = fs_2, fs_jpim1   ! vector opt.
468                  psi(ji,jj,jk)  = eps(ji,jj,jk)
469               END DO
470            END DO
471         END DO
472         !
473      CASE( 2 )               ! k-w
474         DO jk = 2, jpkm1
475            DO jj = 2, jpjm1
476               DO ji = fs_2, fs_jpim1   ! vector opt.
477                  psi(ji,jj,jk)  = SQRT( eb(ji,jj,jk) ) / ( rc0 * mxlb(ji,jj,jk) )
478               END DO
479            END DO
480         END DO
481         !
482      CASE( 3 )               ! generic
483         DO jk = 2, jpkm1
484            DO jj = 2, jpjm1
485               DO ji = fs_2, fs_jpim1   ! vector opt.
486                  psi(ji,jj,jk)  = rc02 * eb(ji,jj,jk) * mxlb(ji,jj,jk)**rnn 
487               END DO
488            END DO
489         END DO
490         !
491      END SELECT
492      !
493      ! Now gls (output in psi)
494      ! -------------------------------
495      ! Resolution of a tridiagonal linear system by a "methode de chasse"
496      ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
497      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
498      ! Warning : after this step, en : right hand side of the matrix
499
500      DO jk = 2, jpkm1
501         DO jj = 2, jpjm1
502            DO ji = fs_2, fs_jpim1   ! vector opt.
503               !
504               ! psi / k
505               zratio = psi(ji,jj,jk) / eb(ji,jj,jk) 
506               !
507               ! psi3+ : stable : B=-KhN²<0 => N²>0 if rn2>0 dir = 1 (stable) otherwise dir = 0 (unstable)
508               dir = 0.5_wp + SIGN( 0.5_wp, rn2(ji,jj,jk) )
509               !
510               rpsi3 = dir * rpsi3m + ( 1._wp - dir ) * rpsi3p
511               !
512               ! shear prod. - stratif. destruction
513               prod = rpsi1 * zratio * shear(ji,jj,jk)
514               !
515               ! stratif. destruction
516               buoy = rpsi3 * zratio * (- avt(ji,jj,jk) * rn2(ji,jj,jk) )
517               !
518               ! shear prod. - stratif. destruction
519               diss = rpsi2 * zratio * zwall(ji,jj,jk) * eps(ji,jj,jk)
520               !
521               dir = 0.5_wp + SIGN( 0.5_wp, prod + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
522               !
523               zesh2 = dir * ( prod + buoy )          + (1._wp - dir ) * prod                        ! production term
524               zdiss = dir * ( diss / psi(ji,jj,jk) ) + (1._wp - dir ) * (diss-buoy) / psi(ji,jj,jk) ! dissipation term
525               !                                                       
526               ! building the matrix
527               zcof = rfact_psi * zwall_psi(ji,jj,jk) * tmask(ji,jj,jk)
528               ! lower diagonal
529               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
530                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
531               ! upper diagonal
532               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
533                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
534               ! diagonal
535               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
536                  &                       + rdt * zdiss * tmask(ji,jj,jk)
537               !
538               ! right hand side in psi
539               psi(ji,jj,jk) = psi(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
540            END DO
541         END DO
542      END DO
543      !
544      z_elem_b(:,:,jpk) = 1._wp
545
546      ! Surface boundary condition on psi
547      ! ---------------------------------
548      !
549      SELECT CASE ( nn_psibc_surf )
550      !
551      CASE ( 0 )             ! Dirichlet boundary conditions
552         !
553         IF( ln_crban ) THEN       ! Wave induced mixing case
554            !                      ! en(1) = q2(1) = 0.5 * (15.8 * Ccb)^(2/3) * u*^2
555            !                      ! balance between the production and the dissipation terms including the wave effect
556            zdep(:,:) = rl_sf * zhsro(:,:)
557            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
558            z_elem_a(:,:,1) = psi(:,:,1)
559            z_elem_c(:,:,1) = 0._wp
560            z_elem_b(:,:,1) = 1._wp
561            !
562            ! one level below
563            zex1 = (rmm*ra_sf+rnn)
564            zex2 = (rmm*ra_sf)
565            zdep(:,:) = ( (zhsro(:,:) + fsdepw(:,:,2))**zex1 ) / zhsro(:,:)**zex2
566            psi (:,:,2) = rsbc_psi1 * ustars2(:,:)**rmm * zdep(:,:) * tmask(:,:,1)
567            z_elem_a(:,:,2) = 0._wp
568            z_elem_c(:,:,2) = 0._wp
569            z_elem_b(:,:,2) = 1._wp
570            !
571         ELSE                   ! No wave induced mixing case
572            !                      ! en(1) = u*^2/C0^2  &  l(1)  = K*zs
573            !                      ! balance between the production and the dissipation terms
574            !
575            zdep(:,:) = vkarmn * zhsro(:,:)
576            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
577            z_elem_a(:,:,1) = psi(:,:,1)
578            z_elem_c(:,:,1) = 0._wp
579            z_elem_b(:,:,1) = 1._wp
580            !
581            ! one level below
582            zdep(:,:) = vkarmn * ( zhsro(:,:) + fsdepw(:,:,2) )
583            psi (:,:,2) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
584            z_elem_a(:,:,2) = 0._wp
585            z_elem_c(:,:,2) = 0._wp
586            z_elem_b(:,:,2) = 1.
587            !
588         ENDIF
589         !
590      CASE ( 1 )             ! Neumann boundary condition on d(psi)/dz
591         !
592         IF( ln_crban ) THEN     ! Wave induced mixing case
593            !
594            zdep(:,:) = rl_sf * zhsro(:,:)
595            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
596            z_elem_a(:,:,1) = psi(:,:,1)
597            z_elem_c(:,:,1) = 0._wp
598            z_elem_b(:,:,1) = 1._wp
599            !
600            ! Neumann condition at k=2
601            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
602            z_elem_a(:,:,2) = 0._wp
603            !
604            ! Set psi vertical flux at the surface:
605            zdep(:,:) = (zhsro(:,:) + fsdept(:,:,1))**(rmm*ra_sf+rnn-1._wp) / zhsro(:,:)**(rmm*ra_sf)
606            zflxs(:,:) = rsbc_psi3 * ( zwall_psi(:,:,1)*avm(:,:,1) + zwall_psi(:,:,2)*avm(:,:,2) ) & 
607               &                   * en(:,:,1)**rmm * zdep         
608            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
609            !
610      ELSE                   ! No wave induced mixing
611            !
612            zdep(:,:) = vkarmn * zhsro(:,:)
613            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
614            z_elem_a(:,:,1) = psi(:,:,1)
615            z_elem_c(:,:,1) = 0._wp
616            z_elem_b(:,:,1) = 1._wp
617            !
618            ! Neumann condition at k=2
619            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
620            z_elem_a(ji,jj,2) = 0._wp
621            !
622            ! Set psi vertical flux at the surface:
623            zdep(:,:)  = zhsro(:,:) + fsdept(:,:,1)
624            zflxs(:,:) = rsbc_psi2 * ( avm(:,:,1) + avm(:,:,2) ) * en(:,:,1)**rmm * zdep**(rnn-1._wp)
625            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
626            !     
627         ENDIF
628         !
629      END SELECT
630
631      ! Bottom boundary condition on psi
632      ! --------------------------------
633      !
634      SELECT CASE ( nn_psibc_bot )
635      !
636      CASE ( 0 )             ! Dirichlet
637         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = vkarmn * hbro
638         !                      ! Balance between the production and the dissipation terms
639!CDIR NOVERRCHK
640         DO jj = 2, jpjm1
641!CDIR NOVERRCHK
642            DO ji = fs_2, fs_jpim1   ! vector opt.
643               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
644               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
645               zdep(ji,jj) = vkarmn * hbro
646               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
647               z_elem_a(ji,jj,ibot) = 0._wp
648               z_elem_c(ji,jj,ibot) = 0._wp
649               z_elem_b(ji,jj,ibot) = 1._wp
650               !
651               ! Just above last level, Dirichlet condition again (GOTM like)
652               zdep(ji,jj) = vkarmn * ( hbro + fse3t(ji,jj,ibotm1) )
653               psi (ji,jj,ibotm1) = rc0**rpp * en(ji,jj,ibot  )**rmm * zdep(ji,jj)**rnn
654               z_elem_a(ji,jj,ibotm1) = 0._wp
655               z_elem_c(ji,jj,ibotm1) = 0._wp
656               z_elem_b(ji,jj,ibotm1) = 1._wp
657            END DO
658         END DO
659         !
660      CASE ( 1 )             ! Neumman boundary condition
661         !                     
662!CDIR NOVERRCHK
663         DO jj = 2, jpjm1
664!CDIR NOVERRCHK
665            DO ji = fs_2, fs_jpim1   ! vector opt.
666               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
667               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
668               !
669               ! Bottom level Dirichlet condition:
670               zdep(ji,jj) = vkarmn * hbro
671               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
672               !
673               z_elem_a(ji,jj,ibot) = 0._wp
674               z_elem_c(ji,jj,ibot) = 0._wp
675               z_elem_b(ji,jj,ibot) = 1._wp
676               !
677               ! Just above last level: Neumann condition with flux injection
678               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1) ! Remove z_elem_c from z_elem_b
679               z_elem_c(ji,jj,ibotm1) = 0.
680               !
681               ! Set psi vertical flux at the bottom:
682               zdep(ji,jj) = hbro + 0.5_wp*fse3t(ji,jj,ibotm1)
683               zflxb = rsbc_psi2 * ( avm(ji,jj,ibot) + avm(ji,jj,ibotm1) )   &
684                  &  * (0.5_wp*(en(ji,jj,ibot)+en(ji,jj,ibotm1)))**rmm * zdep(ji,jj)**(rnn-1._wp)
685               psi(ji,jj,ibotm1) = psi(ji,jj,ibotm1) + zflxb / fse3w(ji,jj,ibotm1)
686            END DO
687         END DO
688         !
689      END SELECT
690
691      ! Matrix inversion
692      ! ----------------
693      !
694      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
695         DO jj = 2, jpjm1
696            DO ji = fs_2, fs_jpim1    ! vector opt.
697               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
698            END DO
699         END DO
700      END DO
701      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
702         DO jj = 2, jpjm1
703            DO ji = fs_2, fs_jpim1    ! vector opt.
704               z_elem_a(ji,jj,jk) = psi(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
705            END DO
706         END DO
707      END DO
708      DO jk = jpk-1, 2, -1                         ! Third recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
709         DO jj = 2, jpjm1
710            DO ji = fs_2, fs_jpim1    ! vector opt.
711               psi(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * psi(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
712            END DO
713         END DO
714      END DO
715
716      ! Set dissipation
717      !----------------
718
719      SELECT CASE ( nn_clos )
720      !
721      CASE( 0 )               ! k-kl  (Mellor-Yamada)
722         DO jk = 1, jpkm1
723            DO jj = 2, jpjm1
724               DO ji = fs_2, fs_jpim1   ! vector opt.
725                  eps(ji,jj,jk) = rc03 * en(ji,jj,jk) * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / psi(ji,jj,jk)
726               END DO
727            END DO
728         END DO
729         !
730      CASE( 1 )               ! k-eps
731         DO jk = 1, jpkm1
732            DO jj = 2, jpjm1
733               DO ji = fs_2, fs_jpim1   ! vector opt.
734                  eps(ji,jj,jk) = psi(ji,jj,jk)
735               END DO
736            END DO
737         END DO
738         !
739      CASE( 2 )               ! k-w
740         DO jk = 1, jpkm1
741            DO jj = 2, jpjm1
742               DO ji = fs_2, fs_jpim1   ! vector opt.
743                  eps(ji,jj,jk) = rc04 * en(ji,jj,jk) * psi(ji,jj,jk) 
744               END DO
745            END DO
746         END DO
747         !
748      CASE( 3 )               ! generic
749         zcoef = rc0**( 3._wp  + rpp/rnn )
750         zex1  =      ( 1.5_wp + rmm/rnn )
751         zex2  = -1._wp / rnn
752         DO jk = 1, jpkm1
753            DO jj = 2, jpjm1
754               DO ji = fs_2, fs_jpim1   ! vector opt.
755                  eps(ji,jj,jk) = zcoef * en(ji,jj,jk)**zex1 * psi(ji,jj,jk)**zex2
756               END DO
757            END DO
758         END DO
759         !
760      END SELECT
761
762      ! Limit dissipation rate under stable stratification
763      ! --------------------------------------------------
764      DO jk = 1, jpkm1 ! Note that this set boundary conditions on mxln at the same time
765         DO jj = 2, jpjm1
766            DO ji = fs_2, fs_jpim1    ! vector opt.
767               ! limitation
768               eps(ji,jj,jk)  = MAX( eps(ji,jj,jk), rn_epsmin )
769               mxln(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / eps(ji,jj,jk)
770               ! Galperin criterium (NOTE : Not required if the proper value of C3 in stable cases is calculated)
771               zrn2 = MAX( rn2(ji,jj,jk), rsmall )
772               mxln(ji,jj,jk) = MIN(  rn_clim_galp * SQRT( 2._wp * en(ji,jj,jk) / zrn2 ), mxln(ji,jj,jk)  )
773            END DO
774         END DO
775      END DO 
776
777      !
778      ! Stability function and vertical viscosity and diffusivity
779      ! ---------------------------------------------------------
780      !
781      SELECT CASE ( nn_stab_func )
782      !
783      CASE ( 0 , 1 )             ! Galperin or Kantha-Clayson stability functions
784         DO jk = 2, jpkm1
785            DO jj = 2, jpjm1
786               DO ji = fs_2, fs_jpim1   ! vector opt.
787                  ! zcof =  l²/q²
788                  zcof = mxlb(ji,jj,jk) * mxlb(ji,jj,jk) / ( 2._wp*eb(ji,jj,jk) )
789                  ! Gh = -N²l²/q²
790                  gh = - rn2(ji,jj,jk) * zcof
791                  gh = MIN( gh, rgh0   )
792                  gh = MAX( gh, rghmin )
793                  ! Stability functions from Kantha and Clayson (if C2=C3=0 => Galperin)
794                  sh = ra2*( 1._wp-6._wp*ra1/rb1 ) / ( 1.-3.*ra2*gh*(6.*ra1+rb2*( 1._wp-rc3 ) ) )
795                  sm = ( rb1**(-1._wp/3._wp) + ( 18._wp*ra1*ra1 + 9._wp*ra1*ra2*(1._wp-rc2) )*sh*gh ) / (1._wp-9._wp*ra1*ra2*gh)
796                  !
797                  ! Store stability function in avmu and avmv
798                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
799                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
800               END DO
801            END DO
802         END DO
803         !
804      CASE ( 2, 3 )               ! Canuto stability functions
805         DO jk = 2, jpkm1
806            DO jj = 2, jpjm1
807               DO ji = fs_2, fs_jpim1   ! vector opt.
808                  ! zcof =  l²/q²
809                  zcof = mxlb(ji,jj,jk)*mxlb(ji,jj,jk) / ( 2._wp * eb(ji,jj,jk) )
810                  ! Gh = -N²l²/q²
811                  gh = - rn2(ji,jj,jk) * zcof
812                  gh = MIN( gh, rgh0   )
813                  gh = MAX( gh, rghmin )
814                  gh = gh * rf6
815                  ! Gm =  M²l²/q² Shear number
816                  shr = shear(ji,jj,jk) / MAX( avm(ji,jj,jk), rsmall )
817                  gm = MAX( shr * zcof , 1.e-10 )
818                  gm = gm * rf6
819                  gm = MIN ( (rd0 - rd1*gh + rd3*gh*gh) / (rd2-rd4*gh) , gm )
820                  ! Stability functions from Canuto
821                  rcff = rd0 - rd1*gh +rd2*gm + rd3*gh*gh - rd4*gh*gm + rd5*gm*gm
822                  sm = (rs0 - rs1*gh + rs2*gm) / rcff
823                  sh = (rs4 - rs5*gh + rs6*gm) / rcff
824                  !
825                  ! Store stability function in avmu and avmv
826                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
827                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
828               END DO
829            END DO
830         END DO
831         !
832      END SELECT
833
834      ! Boundary conditions on stability functions for momentum (Neumann):
835      ! Lines below are useless if GOTM style Dirichlet conditions are used
836      zcoef = rcm_sf / SQRT( 2._wp )
837      DO jj = 2, jpjm1
838         DO ji = fs_2, fs_jpim1   ! vector opt.
839            avmv(ji,jj,1) = zcoef
840         END DO
841      END DO
842      zcoef = rc0 / SQRT( 2._wp )
843      DO jj = 2, jpjm1
844         DO ji = fs_2, fs_jpim1   ! vector opt.
845            avmv(ji,jj,mbkt(ji,jj)+1) = zcoef
846         END DO
847      END DO
848
849      ! Compute diffusivities/viscosities
850      ! The computation below could be restrained to jk=2 to jpkm1 if GOTM style Dirichlet conditions are used
851      DO jk = 1, jpk
852         DO jj = 2, jpjm1
853            DO ji = fs_2, fs_jpim1   ! vector opt.
854               zsqen         = SQRT( 2._wp * en(ji,jj,jk) ) * mxln(ji,jj,jk)
855               zav           = zsqen * avmu(ji,jj,jk)
856               avt(ji,jj,jk) = MAX( zav, avtb(jk) )*tmask(ji,jj,jk) ! apply mask for zdfmxl routine
857               zav           = zsqen * avmv(ji,jj,jk)
858               avm(ji,jj,jk) = MAX( zav, avmb(jk) ) ! Note that avm is not masked at the surface and the bottom
859            END DO
860         END DO
861      END DO
862      !
863      ! Lateral boundary conditions (sign unchanged)
864      avt(:,:,1)  = 0._wp
865      CALL lbc_lnk( avm, 'W', 1. )   ;   CALL lbc_lnk( avt, 'W', 1. )
866
867      DO jk = 2, jpkm1            !* vertical eddy viscosity at u- and v-points
868         DO jj = 2, jpjm1
869            DO ji = fs_2, fs_jpim1   ! vector opt.
870               avmu(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji+1,jj  ,jk) ) * umask(ji,jj,jk)
871               avmv(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji  ,jj+1,jk) ) * vmask(ji,jj,jk)
872            END DO
873         END DO
874      END DO
875      avmu(:,:,1) = 0._wp             ;   avmv(:,:,1) = 0._wp                 ! set surface to zero
876      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )       ! Lateral boundary conditions
877
878      IF(ln_ctl) THEN
879         CALL prt_ctl( tab3d_1=en  , clinfo1=' gls  - e: ', tab3d_2=avt, clinfo2=' t: ', ovlap=1, kdim=jpk)
880         CALL prt_ctl( tab3d_1=avmu, clinfo1=' gls  - u: ', mask1=umask,                   &
881            &          tab3d_2=avmv, clinfo2=       ' v: ', mask2=vmask, ovlap=1, kdim=jpk )
882      ENDIF
883      !
884      CALL wrk_dealloc( jpi,jpj, zdep, zflxs, zhsro )
885      CALL wrk_dealloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi )
886      !
887      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls')
888      !
889      !
890   END SUBROUTINE zdf_gls
891
892
893   SUBROUTINE zdf_gls_init
894      !!----------------------------------------------------------------------
895      !!                  ***  ROUTINE zdf_gls_init  ***
896      !!                     
897      !! ** Purpose :   Initialization of the vertical eddy diffivity and
898      !!      viscosity when using a gls turbulent closure scheme
899      !!
900      !! ** Method  :   Read the namzdf_gls namelist and check the parameters
901      !!      called at the first timestep (nit000)
902      !!
903      !! ** input   :   Namlist namzdf_gls
904      !!
905      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
906      !!
907      !!----------------------------------------------------------------------
908      USE dynzdf_exp
909      USE trazdf_exp
910      !
911      INTEGER ::   jk    ! dummy loop indices
912      REAL(wp)::   zcr   ! local scalar
913      !!
914      NAMELIST/namzdf_gls/rn_emin, rn_epsmin, ln_length_lim, &
915         &            rn_clim_galp, ln_crban, ln_sigpsi,     &
916         &            rn_crban, rn_charn,                    &
917         &            nn_tkebc_surf, nn_tkebc_bot,           &
918         &            nn_psibc_surf, nn_psibc_bot,           &
919         &            nn_stab_func, nn_clos
920      !!----------------------------------------------------------
921      !
922      IF( nn_timing == 1 )  CALL timing_start('zdf_gls_init')
923      !
924      REWIND( numnam )                 !* Read Namelist namzdf_gls
925      READ  ( numnam, namzdf_gls )
926
927      IF(lwp) THEN                     !* Control print
928         WRITE(numout,*)
929         WRITE(numout,*) 'zdf_gls_init : gls turbulent closure scheme'
930         WRITE(numout,*) '~~~~~~~~~~~~'
931         WRITE(numout,*) '   Namelist namzdf_gls : set gls mixing parameters'
932         WRITE(numout,*) '      minimum value of en                           rn_emin       = ', rn_emin
933         WRITE(numout,*) '      minimum value of eps                          rn_epsmin     = ', rn_epsmin
934         WRITE(numout,*) '      Limit dissipation rate under stable stratif.  ln_length_lim = ', ln_length_lim
935         WRITE(numout,*) '      Galperin limit (Standard: 0.53, Holt: 0.26)   rn_clim_galp  = ', rn_clim_galp
936         WRITE(numout,*) '      TKE Surface boundary condition                nn_tkebc_surf = ', nn_tkebc_surf
937         WRITE(numout,*) '      TKE Bottom boundary condition                 nn_tkebc_bot  = ', nn_tkebc_bot
938         WRITE(numout,*) '      PSI Surface boundary condition                nn_psibc_surf = ', nn_psibc_surf
939         WRITE(numout,*) '      PSI Bottom boundary condition                 nn_psibc_bot  = ', nn_psibc_bot
940         WRITE(numout,*) '      Craig and Banner scheme                       ln_crban      = ', ln_crban
941         WRITE(numout,*) '      Modify psi Schmidt number (wb case)           ln_sigpsi     = ', ln_sigpsi
942         WRITE(numout,*) '      Craig and Banner coefficient                  rn_crban       = ', rn_crban
943         WRITE(numout,*) '      Charnock coefficient                          rn_charn       = ', rn_charn
944         WRITE(numout,*) '      Stability functions                           nn_stab_func   = ', nn_stab_func
945         WRITE(numout,*) '      Type of closure                               nn_clos        = ', nn_clos
946         WRITE(numout,*) '   Hard coded parameters'
947         WRITE(numout,*) '      Surface roughness (m)                         hsro          = ', hsro
948         WRITE(numout,*) '      Bottom roughness (m)                          hbro          = ', hbro
949      ENDIF
950
951      !                                !* allocate gls arrays
952      IF( zdf_gls_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_gls_init : unable to allocate arrays' )
953
954      !                                !* Check of some namelist values
955      IF( nn_tkebc_surf < 0 .OR. nn_tkebc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_tkebc_surf is 0 or 1' )
956      IF( nn_psibc_surf < 0 .OR. nn_psibc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_psibc_surf is 0 or 1' )
957      IF( nn_tkebc_bot  < 0 .OR. nn_tkebc_bot  > 1 ) CALL ctl_stop( 'bad flag: nn_tkebc_bot is 0 or 1' )
958      IF( nn_psibc_bot  < 0 .OR. nn_psibc_bot  > 1 ) CALL ctl_stop( 'bad flag: nn_psibc_bot is 0 or 1' )
959      IF( nn_stab_func  < 0 .OR. nn_stab_func  > 3 ) CALL ctl_stop( 'bad flag: nn_stab_func is 0, 1, 2 and 3' )
960      IF( nn_clos       < 0 .OR. nn_clos       > 3 ) CALL ctl_stop( 'bad flag: nn_clos is 0, 1, 2 or 3' )
961
962      SELECT CASE ( nn_clos )          !* set the parameters for the chosen closure
963      !
964      CASE( 0 )                              ! k-kl  (Mellor-Yamada)
965         !
966         IF(lwp) WRITE(numout,*) 'The choosen closure is k-kl closed to the classical Mellor-Yamada'
967         rpp     = 0._wp
968         rmm     = 1._wp
969         rnn     = 1._wp
970         rsc_tke = 1.96_wp
971         rsc_psi = 1.96_wp
972         rpsi1   = 0.9_wp
973         rpsi3p  = 1._wp
974         rpsi2   = 0.5_wp
975         !
976         SELECT CASE ( nn_stab_func )
977         CASE( 0, 1 )   ;   rpsi3m = 2.53_wp       ! G88 or KC stability functions
978         CASE( 2 )      ;   rpsi3m = 2.38_wp       ! Canuto A stability functions
979         CASE( 3 )      ;   rpsi3m = 2.38          ! Canuto B stability functions (caution : constant not identified)
980         END SELECT
981         !
982      CASE( 1 )                              ! k-eps
983         !
984         IF(lwp) WRITE(numout,*) 'The choosen closure is k-eps'
985         rpp     =  3._wp
986         rmm     =  1.5_wp
987         rnn     = -1._wp
988         rsc_tke =  1._wp
989         rsc_psi =  1.3_wp  ! Schmidt number for psi
990         rpsi1   =  1.44_wp
991         rpsi3p  =  1._wp
992         rpsi2   =  1.92_wp
993         !
994         SELECT CASE ( nn_stab_func )
995         CASE( 0, 1 )   ;   rpsi3m = -0.52_wp      ! G88 or KC stability functions
996         CASE( 2 )      ;   rpsi3m = -0.629_wp     ! Canuto A stability functions
997         CASE( 3 )      ;   rpsi3m = -0.566        ! Canuto B stability functions
998         END SELECT
999         !
1000      CASE( 2 )                              ! k-omega
1001         !
1002         IF(lwp) WRITE(numout,*) 'The choosen closure is k-omega'
1003         rpp     = -1._wp
1004         rmm     =  0.5_wp
1005         rnn     = -1._wp
1006         rsc_tke =  2._wp
1007         rsc_psi =  2._wp
1008         rpsi1   =  0.555_wp
1009         rpsi3p  =  1._wp
1010         rpsi2   =  0.833_wp
1011         !
1012         SELECT CASE ( nn_stab_func )
1013         CASE( 0, 1 )   ;   rpsi3m = -0.58_wp       ! G88 or KC stability functions
1014         CASE( 2 )      ;   rpsi3m = -0.64_wp       ! Canuto A stability functions
1015         CASE( 3 )      ;   rpsi3m = -0.64_wp       ! Canuto B stability functions caution : constant not identified)
1016         END SELECT
1017         !
1018      CASE( 3 )                              ! generic
1019         !
1020         IF(lwp) WRITE(numout,*) 'The choosen closure is generic'
1021         rpp     = 2._wp
1022         rmm     = 1._wp
1023         rnn     = -0.67_wp
1024         rsc_tke = 0.8_wp
1025         rsc_psi = 1.07_wp
1026         rpsi1   = 1._wp
1027         rpsi3p  = 1._wp
1028         rpsi2   = 1.22_wp
1029         !
1030         SELECT CASE ( nn_stab_func )
1031         CASE( 0, 1 )   ;   rpsi3m = 0.1_wp         ! G88 or KC stability functions
1032         CASE( 2 )      ;   rpsi3m = 0.05_wp        ! Canuto A stability functions
1033         CASE( 3 )      ;   rpsi3m = 0.05_wp        ! Canuto B stability functions caution : constant not identified)
1034         END SELECT
1035         !
1036      END SELECT
1037
1038      !
1039      SELECT CASE ( nn_stab_func )     !* set the parameters of the stability functions
1040      !
1041      CASE ( 0 )                             ! Galperin stability functions
1042         !
1043         IF(lwp) WRITE(numout,*) 'Stability functions from Galperin'
1044         rc2     =  0._wp
1045         rc3     =  0._wp
1046         rc_diff =  1._wp
1047         rc0     =  0.5544_wp
1048         rcm_sf  =  0.9884_wp
1049         rghmin  = -0.28_wp
1050         rgh0    =  0.0233_wp
1051         rghcri  =  0.02_wp
1052         !
1053      CASE ( 1 )                             ! Kantha-Clayson stability functions
1054         !
1055         IF(lwp) WRITE(numout,*) 'Stability functions from Kantha-Clayson'
1056         rc2     =  0.7_wp
1057         rc3     =  0.2_wp
1058         rc_diff =  1._wp
1059         rc0     =  0.5544_wp
1060         rcm_sf  =  0.9884_wp
1061         rghmin  = -0.28_wp
1062         rgh0    =  0.0233_wp
1063         rghcri  =  0.02_wp
1064         !
1065      CASE ( 2 )                             ! Canuto A stability functions
1066         !
1067         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto A'
1068         rs0 = 1.5_wp * rl1 * rl5*rl5
1069         rs1 = -rl4*(rl6+rl7) + 2._wp*rl4*rl5*(rl1-(1._wp/3._wp)*rl2-rl3) + 1.5_wp*rl1*rl5*rl8
1070         rs2 = -(3._wp/8._wp) * rl1*(rl6*rl6-rl7*rl7)
1071         rs4 = 2._wp * rl5
1072         rs5 = 2._wp * rl4
1073         rs6 = (2._wp/3._wp) * rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.5_wp * rl5*rl1 * (3._wp*rl3-rl2)   &
1074            &                                                    + 0.75_wp * rl1 * ( rl6 - rl7 )
1075         rd0 = 3._wp * rl5*rl5
1076         rd1 = rl5 * ( 7._wp*rl4 + 3._wp*rl8 )
1077         rd2 = rl5*rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.75_wp*(rl6*rl6 - rl7*rl7 )
1078         rd3 = rl4 * ( 4._wp*rl4 + 3._wp*rl8)
1079         rd4 = rl4 * ( rl2 * rl6 - 3._wp*rl3*rl7 - rl5*(rl2*rl2 - rl3*rl3 ) ) + rl5*rl8 * ( 3._wp*rl3*rl3 - rl2*rl2 )
1080         rd5 = 0.25_wp * ( rl2*rl2 - 3._wp *rl3*rl3 ) * ( rl6*rl6 - rl7*rl7 )
1081         rc0 = 0.5268_wp
1082         rf6 = 8._wp / (rc0**6._wp)
1083         rc_diff = SQRT(2._wp) / (rc0**3._wp)
1084         rcm_sf  =  0.7310_wp
1085         rghmin  = -0.28_wp
1086         rgh0    =  0.0329_wp
1087         rghcri  =  0.03_wp
1088         !
1089      CASE ( 3 )                             ! Canuto B stability functions
1090         !
1091         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto B'
1092         rs0 = 1.5_wp * rm1 * rm5*rm5
1093         rs1 = -rm4 * (rm6+rm7) + 2._wp * rm4*rm5*(rm1-(1._wp/3._wp)*rm2-rm3) + 1.5_wp * rm1*rm5*rm8
1094         rs2 = -(3._wp/8._wp) * rm1 * (rm6*rm6-rm7*rm7 )
1095         rs4 = 2._wp * rm5
1096         rs5 = 2._wp * rm4
1097         rs6 = (2._wp/3._wp) * rm5 * (3._wp*rm3*rm3-rm2*rm2) - 0.5_wp * rm5*rm1*(3._wp*rm3-rm2) + 0.75_wp * rm1*(rm6-rm7)
1098         rd0 = 3._wp * rm5*rm5
1099         rd1 = rm5 * (7._wp*rm4 + 3._wp*rm8)
1100         rd2 = rm5*rm5 * (3._wp*rm3*rm3 - rm2*rm2) - 0.75_wp * (rm6*rm6 - rm7*rm7)
1101         rd3 = rm4 * ( 4._wp*rm4 + 3._wp*rm8 )
1102         rd4 = rm4 * ( rm2*rm6 -3._wp*rm3*rm7 - rm5*(rm2*rm2 - rm3*rm3) ) + rm5 * rm8 * ( 3._wp*rm3*rm3 - rm2*rm2 )
1103         rd5 = 0.25_wp * ( rm2*rm2 - 3._wp*rm3*rm3 ) * ( rm6*rm6 - rm7*rm7 )
1104         rc0 = 0.5268_wp            !!       rc0 = 0.5540_wp (Warner ...) to verify !
1105         rf6 = 8._wp / ( rc0**6._wp )
1106         rc_diff = SQRT(2._wp)/(rc0**3.)
1107         rcm_sf  =  0.7470_wp
1108         rghmin  = -0.28_wp
1109         rgh0    =  0.0444_wp
1110         rghcri  =  0.0414_wp
1111         !
1112      END SELECT
1113   
1114      !                                !* Set Schmidt number for psi diffusion in the wave breaking case
1115      !                                     ! See Eq. (13) of Carniel et al, OM, 30, 225-239, 2009
1116      !                                     !  or Eq. (17) of Burchard, JPO, 31, 3133-3145, 2001
1117      IF( ln_sigpsi .AND. ln_crban ) THEN
1118         zcr = SQRT( 1.5_wp*rsc_tke ) * rcm_sf / vkarmn
1119         rsc_psi0 = vkarmn*vkarmn / ( rpsi2 * rcm_sf*rcm_sf )                       & 
1120        &         * ( rnn*rnn - 4._wp/3._wp * zcr*rnn*rmm - 1._wp/3._wp * zcr*rnn   &
1121        &           + 2._wp/9._wp * rmm * zcr*zcr + 4._wp/9._wp * zcr*zcr * rmm*rmm )                                 
1122      ELSE
1123         rsc_psi0 = rsc_psi
1124      ENDIF
1125 
1126      !                                !* Shear free turbulence parameters
1127      !
1128      ra_sf  = -4._wp * rnn * SQRT( rsc_tke ) / ( (1._wp+4._wp*rmm) * SQRT( rsc_tke )   &
1129         &                                      - SQRT(rsc_tke + 24._wp*rsc_psi0*rpsi2 ) )
1130      rl_sf  = rc0 * SQRT( rc0 / rcm_sf )                                                                   &
1131         &         * SQRT(  (  (1._wp + 4._wp*rmm + 8._wp*rmm*rmm) * rsc_tke                                &
1132         &                   + 12._wp * rsc_psi0 * rpsi2                                                    &
1133         &                   - (1._wp + 4._wp*rmm) * SQRT( rsc_tke*(rsc_tke+ 24._wp*rsc_psi0*rpsi2) )  )    &
1134         &                / ( 12._wp*rnn*rnn )                                                              )
1135
1136      !
1137      IF(lwp) THEN                     !* Control print
1138         WRITE(numout,*)
1139         WRITE(numout,*) 'Limit values'
1140         WRITE(numout,*) '~~~~~~~~~~~~'
1141         WRITE(numout,*) 'Parameter  m = ',rmm
1142         WRITE(numout,*) 'Parameter  n = ',rnn
1143         WRITE(numout,*) 'Parameter  p = ',rpp
1144         WRITE(numout,*) 'rpsi1   = ',rpsi1
1145         WRITE(numout,*) 'rpsi2   = ',rpsi2
1146         WRITE(numout,*) 'rpsi3m  = ',rpsi3m
1147         WRITE(numout,*) 'rpsi3p  = ',rpsi3p
1148         WRITE(numout,*) 'rsc_tke = ',rsc_tke
1149         WRITE(numout,*) 'rsc_psi = ',rsc_psi
1150         WRITE(numout,*) 'rsc_psi0 = ',rsc_psi0
1151         WRITE(numout,*) 'rc0     = ',rc0
1152         WRITE(numout,*)
1153         WRITE(numout,*) 'Shear free turbulence parameters:'
1154         WRITE(numout,*) 'rcm_sf  = ',rcm_sf
1155         WRITE(numout,*) 'ra_sf   = ',ra_sf
1156         WRITE(numout,*) 'rl_sf   = ',rl_sf
1157         WRITE(numout,*)
1158      ENDIF
1159
1160      !                                !* Constants initialization
1161      rc02  = rc0  * rc0   ;   rc02r = 1. / rc02
1162      rc03  = rc02 * rc0
1163      rc04  = rc03 * rc0
1164      rc03_sqrt2_galp = rc03 / SQRT(2._wp) / rn_clim_galp
1165      rsbc_mb   = 0.5_wp * (15.8_wp*rn_crban)**(2._wp/3._wp)               ! Surf. bound. cond. from Mellor and Blumberg
1166      rsbc_std  = 3.75_wp                                                  ! Surf. bound. cond. standard (prod=diss)
1167      rsbc_tke1 = (-rsc_tke*rn_crban/(rcm_sf*ra_sf*rl_sf))**(2._wp/3._wp)  ! k_eps = 53.  Dirichlet + Wave breaking
1168      rsbc_tke2 = 0.5_wp / rau0
1169      rsbc_tke3 = rdt * rn_crban                                                         ! Neumann + Wave breaking
1170      rsbc_zs   = rn_charn / grav                                                        ! Charnock formula
1171      rsbc_psi1 = rc0**rpp * rsbc_tke1**rmm * rl_sf**rnn                           ! Dirichlet + Wave breaking
1172      rsbc_psi2 = -0.5_wp * rdt * rc0**rpp * rnn * vkarmn**rnn / rsc_psi                   ! Neumann + NO Wave breaking
1173      rsbc_psi3 = -0.5_wp * rdt * rc0**rpp * rl_sf**rnn / rsc_psi  * (rnn + rmm*ra_sf) ! Neumann + Wave breaking
1174      rfact_tke = -0.5_wp / rsc_tke * rdt               ! Cst used for the Diffusion term of tke
1175      rfact_psi = -0.5_wp / rsc_psi * rdt               ! Cst used for the Diffusion term of tke
1176
1177      !                                !* Wall proximity function
1178      zwall (:,:,:) = 1._wp * tmask(:,:,:)
1179
1180      !                                !* set vertical eddy coef. to the background value
1181      DO jk = 1, jpk
1182         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
1183         avm (:,:,jk) = avmb(jk) * tmask(:,:,jk)
1184         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
1185         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
1186      END DO
1187      !                             
1188      CALL gls_rst( nit000, 'READ' )   !* read or initialize all required files
1189      !
1190      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls_init')
1191      !
1192   END SUBROUTINE zdf_gls_init
1193
1194
1195   SUBROUTINE gls_rst( kt, cdrw )
1196      !!---------------------------------------------------------------------
1197      !!                   ***  ROUTINE ts_rst  ***
1198      !!                     
1199      !! ** Purpose :   Read or write TKE file (en) in restart file
1200      !!
1201      !! ** Method  :   use of IOM library
1202      !!                if the restart does not contain TKE, en is either
1203      !!                set to rn_emin or recomputed (nn_igls/=0)
1204      !!----------------------------------------------------------------------
1205      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1206      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1207      !
1208      INTEGER ::   jit, jk   ! dummy loop indices
1209      INTEGER ::   id1, id2, id3, id4, id5, id6
1210      INTEGER ::   ji, jj, ikbu, ikbv
1211      REAL(wp)::   cbx, cby
1212      !!----------------------------------------------------------------------
1213      !
1214      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
1215         !                                   ! ---------------
1216         IF( ln_rstart ) THEN                   !* Read the restart file
1217            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
1218            id2 = iom_varid( numror, 'avt'  , ldstop = .FALSE. )
1219            id3 = iom_varid( numror, 'avm'  , ldstop = .FALSE. )
1220            id4 = iom_varid( numror, 'avmu' , ldstop = .FALSE. )
1221            id5 = iom_varid( numror, 'avmv' , ldstop = .FALSE. )
1222            id6 = iom_varid( numror, 'mxln' , ldstop = .FALSE. )
1223            !
1224            IF( MIN( id1, id2, id3, id4, id5, id6 ) > 0 ) THEN        ! all required arrays exist
1225               CALL iom_get( numror, jpdom_autoglo, 'en'    , en     )
1226               CALL iom_get( numror, jpdom_autoglo, 'avt'   , avt    )
1227               CALL iom_get( numror, jpdom_autoglo, 'avm'   , avm    )
1228               CALL iom_get( numror, jpdom_autoglo, 'avmu'  , avmu   )
1229               CALL iom_get( numror, jpdom_autoglo, 'avmv'  , avmv   )
1230               CALL iom_get( numror, jpdom_autoglo, 'mxln'  , mxln   )
1231            ELSE                       
1232               IF(lwp) WRITE(numout,*) ' ===>>>> : previous run without gls scheme, en and mxln computed by iterative loop'
1233               en  (:,:,:) = rn_emin
1234               mxln(:,:,:) = 0.001       
1235               DO jit = nit000 + 1, nit000 + 10   ;   CALL zdf_gls( jit )   ;   END DO
1236            ENDIF
1237         ELSE                                   !* Start from rest
1238            IF(lwp) WRITE(numout,*) ' ===>>>> : Initialisation of en and mxln by background values'
1239            en  (:,:,:) = rn_emin
1240            mxln(:,:,:) = 0.001       
1241         ENDIF
1242         !
1243      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
1244         !                                   ! -------------------
1245         IF(lwp) WRITE(numout,*) '---- gls-rst ----'
1246         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en    )
1247         CALL iom_rstput( kt, nitrst, numrow, 'avt'  , avt   )
1248         CALL iom_rstput( kt, nitrst, numrow, 'avm'  , avm   )
1249         CALL iom_rstput( kt, nitrst, numrow, 'avmu' , avmu  )
1250         CALL iom_rstput( kt, nitrst, numrow, 'avmv' , avmv  )
1251         CALL iom_rstput( kt, nitrst, numrow, 'mxln' , mxln  )
1252         !
1253      ENDIF
1254      !
1255   END SUBROUTINE gls_rst
1256
1257#else
1258   !!----------------------------------------------------------------------
1259   !!   Dummy module :                                        NO TKE scheme
1260   !!----------------------------------------------------------------------
1261   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfgls = .FALSE.   !: TKE flag
1262CONTAINS
1263   SUBROUTINE zdf_gls_init           ! Empty routine
1264      WRITE(*,*) 'zdf_gls_init: You should not have seen this print! error?'
1265   END SUBROUTINE zdf_gls_init
1266   SUBROUTINE zdf_gls( kt )          ! Empty routine
1267      WRITE(*,*) 'zdf_gls: You should not have seen this print! error?', kt
1268   END SUBROUTINE zdf_gls
1269   SUBROUTINE gls_rst( kt, cdrw )          ! Empty routine
1270      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1271      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1272      WRITE(*,*) 'gls_rst: You should not have seen this print! error?', kt, cdrw
1273   END SUBROUTINE gls_rst
1274#endif
1275
1276   !!======================================================================
1277END MODULE zdfgls
1278
Note: See TracBrowser for help on using the repository browser.