New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfgls.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfgls.F90 @ 7646

Last change on this file since 7646 was 7646, checked in by timgraham, 7 years ago

Merge of dev_merge_2016 into trunk. UPDATE TO ARCHFILES NEEDED for XIOS2.
LIM_SRC_s/limrhg.F90 to follow in next commit due to change of kind (I'm unable to do it in this commit).
Merged using the following steps:

1) svn merge --reintegrate svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk .
2) Resolve minor conflicts in sette.sh and namelist_cfg for ORCA2LIM3 (due to a change in trunk after branch was created)
3) svn commit
4) svn switch svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk
5) svn merge svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/2016/dev_merge_2016 .
6) At this stage I checked out a clean copy of the branch to compare against what is about to be committed to the trunk.
6) svn commit #Commit code to the trunk

In this commit I have also reverted a change to Fcheck_archfile.sh which was causing problems on the Paris machine.

  • Property svn:keywords set to Id
File size: 57.8 KB
Line 
1MODULE zdfgls
2   !!======================================================================
3   !!                       ***  MODULE  zdfgls  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the gls
5   !!                 turbulent closure parameterization
6   !!======================================================================
7   !! History :   3.0  !  2009-09  (G. Reffray)  Original code
8   !!             3.3  !  2010-10  (C. Bricaud)  Add in the reference
9   !!----------------------------------------------------------------------
10#if defined key_zdfgls
11   !!----------------------------------------------------------------------
12   !!   'key_zdfgls'                 Generic Length Scale vertical physics
13   !!----------------------------------------------------------------------
14   !!   zdf_gls       : update momentum and tracer Kz from a gls scheme
15   !!   zdf_gls_init  : initialization, namelist read, and parameters control
16   !!   gls_rst       : read/write gls restart in ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! ocean space and time domain : variable volume layer
21   USE zdf_oce        ! ocean vertical physics
22   USE zdfbfr         ! bottom friction (only for rn_bfrz0)
23   USE sbc_oce        ! surface boundary condition: ocean
24   USE phycst         ! physical constants
25   USE zdfmxl         ! mixed layer
26   USE sbcwave ,  ONLY: hsw   ! significant wave height
27   !
28   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
29   USE lib_mpp        ! MPP manager
30   USE wrk_nemo       ! work arrays
31   USE prtctl         ! Print control
32   USE in_out_manager ! I/O manager
33   USE iom            ! I/O manager library
34   USE timing         ! Timing
35   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   zdf_gls        ! routine called in step module
41   PUBLIC   zdf_gls_init   ! routine called in opa module
42   PUBLIC   gls_rst        ! routine called in step module
43
44   LOGICAL , PUBLIC, PARAMETER ::   lk_zdfgls = .TRUE.   !: TKE vertical mixing flag
45   !
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   mxln    !: now mixing length
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zwall   !: wall function
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustars2 !: Squared surface velocity scale at T-points
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustarb2 !: Squared bottom  velocity scale at T-points
50
51   !                              !! ** Namelist  namzdf_gls  **
52   LOGICAL  ::   ln_length_lim     ! use limit on the dissipation rate under stable stratification (Galperin et al. 1988)
53   LOGICAL  ::   ln_sigpsi         ! Activate Burchard (2003) modification for k-eps closure & wave breaking mixing
54   INTEGER  ::   nn_bc_surf        ! surface boundary condition (=0/1)
55   INTEGER  ::   nn_bc_bot         ! bottom boundary condition (=0/1)
56   INTEGER  ::   nn_z0_met         ! Method for surface roughness computation
57   INTEGER  ::   nn_stab_func      ! stability functions G88, KC or Canuto (=0/1/2)
58   INTEGER  ::   nn_clos           ! closure 0/1/2/3 MY82/k-eps/k-w/gen
59   REAL(wp) ::   rn_clim_galp      ! Holt 2008 value for k-eps: 0.267
60   REAL(wp) ::   rn_epsmin         ! minimum value of dissipation (m2/s3)
61   REAL(wp) ::   rn_emin           ! minimum value of TKE (m2/s2)
62   REAL(wp) ::   rn_charn          ! Charnock constant for surface breaking waves mixing : 1400. (standard) or 2.e5 (Stacey value)
63   REAL(wp) ::   rn_crban          ! Craig and Banner constant for surface breaking waves mixing
64   REAL(wp) ::   rn_hsro           ! Minimum surface roughness
65   REAL(wp) ::   rn_frac_hs        ! Fraction of wave height as surface roughness (if nn_z0_met > 1)
66
67   REAL(wp) ::   rcm_sf        =  0.73_wp     ! Shear free turbulence parameters
68   REAL(wp) ::   ra_sf         = -2.0_wp      ! Must be negative -2 < ra_sf < -1
69   REAL(wp) ::   rl_sf         =  0.2_wp      ! 0 <rl_sf<vkarmn   
70   REAL(wp) ::   rghmin        = -0.28_wp
71   REAL(wp) ::   rgh0          =  0.0329_wp
72   REAL(wp) ::   rghcri        =  0.03_wp
73   REAL(wp) ::   ra1           =  0.92_wp
74   REAL(wp) ::   ra2           =  0.74_wp
75   REAL(wp) ::   rb1           = 16.60_wp
76   REAL(wp) ::   rb2           = 10.10_wp         
77   REAL(wp) ::   re2           =  1.33_wp         
78   REAL(wp) ::   rl1           =  0.107_wp
79   REAL(wp) ::   rl2           =  0.0032_wp
80   REAL(wp) ::   rl3           =  0.0864_wp
81   REAL(wp) ::   rl4           =  0.12_wp
82   REAL(wp) ::   rl5           = 11.9_wp
83   REAL(wp) ::   rl6           =  0.4_wp
84   REAL(wp) ::   rl7           =  0.0_wp
85   REAL(wp) ::   rl8           =  0.48_wp
86   REAL(wp) ::   rm1           =  0.127_wp
87   REAL(wp) ::   rm2           =  0.00336_wp
88   REAL(wp) ::   rm3           =  0.0906_wp
89   REAL(wp) ::   rm4           =  0.101_wp
90   REAL(wp) ::   rm5           = 11.2_wp
91   REAL(wp) ::   rm6           =  0.4_wp
92   REAL(wp) ::   rm7           =  0.0_wp
93   REAL(wp) ::   rm8           =  0.318_wp
94   REAL(wp) ::   rtrans        =  0.1_wp
95   REAL(wp) ::   rc02, rc02r, rc03, rc04                          ! coefficients deduced from above parameters
96   REAL(wp) ::   rsbc_tke1, rsbc_tke2, rfact_tke                  !     -           -           -        -
97   REAL(wp) ::   rsbc_psi1, rsbc_psi2, rfact_psi                  !     -           -           -        -
98   REAL(wp) ::   rsbc_zs1, rsbc_zs2                               !     -           -           -        -
99   REAL(wp) ::   rc0, rc2, rc3, rf6, rcff, rc_diff                !     -           -           -        -
100   REAL(wp) ::   rs0, rs1, rs2, rs4, rs5, rs6                     !     -           -           -        -
101   REAL(wp) ::   rd0, rd1, rd2, rd3, rd4, rd5                     !     -           -           -        -
102   REAL(wp) ::   rsc_tke, rsc_psi, rpsi1, rpsi2, rpsi3, rsc_psi0  !     -           -           -        -
103   REAL(wp) ::   rpsi3m, rpsi3p, rpp, rmm, rnn                    !     -           -           -        -
104
105   !! * Substitutions
106#  include "vectopt_loop_substitute.h90"
107   !!----------------------------------------------------------------------
108   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
109   !! $Id$
110   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
111   !!----------------------------------------------------------------------
112CONTAINS
113
114   INTEGER FUNCTION zdf_gls_alloc()
115      !!----------------------------------------------------------------------
116      !!                ***  FUNCTION zdf_gls_alloc  ***
117      !!----------------------------------------------------------------------
118      ALLOCATE( mxln(jpi,jpj,jpk), zwall(jpi,jpj,jpk) ,     &
119         &      ustars2(jpi,jpj) , ustarb2(jpi,jpj)   , STAT= zdf_gls_alloc )
120         !
121      IF( lk_mpp             )   CALL mpp_sum ( zdf_gls_alloc )
122      IF( zdf_gls_alloc /= 0 )   CALL ctl_warn('zdf_gls_alloc: failed to allocate arrays')
123   END FUNCTION zdf_gls_alloc
124
125
126   SUBROUTINE zdf_gls( kt )
127      !!----------------------------------------------------------------------
128      !!                   ***  ROUTINE zdf_gls  ***
129      !!
130      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
131      !!              coefficients using the GLS turbulent closure scheme.
132      !!----------------------------------------------------------------------
133      INTEGER, INTENT(in) ::   kt ! ocean time step
134      INTEGER  ::   ji, jj, jk, ibot, ibotm1, dir  ! dummy loop arguments
135      REAL(wp) ::   zesh2, zsigpsi, zcoef, zex1, zex2   ! local scalars
136      REAL(wp) ::   ztx2, zty2, zup, zdown, zcof        !   -      -
137      REAL(wp) ::   zratio, zrn2, zflxb, sh             !   -      -
138      REAL(wp) ::   prod, buoy, diss, zdiss, sm         !   -      -
139      REAL(wp) ::   gh, gm, shr, dif, zsqen, zav        !   -      -
140      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zdep
141      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zkar
142      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zflxs       ! Turbulence fluxed induced by internal waves
143      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zhsro       ! Surface roughness (surface waves)
144      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eb          ! tke at time before
145      REAL(wp), POINTER, DIMENSION(:,:,:) ::   mxlb        ! mixing length at time before
146      REAL(wp), POINTER, DIMENSION(:,:,:) ::   shear       ! vertical shear
147      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eps         ! dissipation rate
148      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwall_psi   ! Wall function use in the wb case (ln_sigpsi)
149      REAL(wp), POINTER, DIMENSION(:,:,:) ::   psi         ! psi at time now
150      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_a    ! element of the first  matrix diagonal
151      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_b    ! element of the second matrix diagonal
152      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_c    ! element of the third  matrix diagonal
153      !!--------------------------------------------------------------------
154      !
155      IF( nn_timing == 1 )  CALL timing_start('zdf_gls')
156      !
157      CALL wrk_alloc( jpi,jpj,       zdep, zkar, zflxs, zhsro )
158      CALL wrk_alloc( jpi,jpj,jpk,   eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi  )
159     
160      ! Preliminary computing
161
162      ustars2 = 0._wp   ;   ustarb2 = 0._wp   ;   psi  = 0._wp   ;   zwall_psi = 0._wp
163
164      IF( kt /= nit000 ) THEN   ! restore before value to compute tke
165         avt (:,:,:) = avt_k (:,:,:)
166         avm (:,:,:) = avm_k (:,:,:)
167         avmu(:,:,:) = avmu_k(:,:,:)
168         avmv(:,:,:) = avmv_k(:,:,:) 
169      ENDIF
170
171      ! Compute surface and bottom friction at T-points
172      DO jj = 2, jpjm1         
173         DO ji = fs_2, fs_jpim1   ! vector opt.         
174            !
175            ! surface friction
176            ustars2(ji,jj) = r1_rau0 * taum(ji,jj) * tmask(ji,jj,1)
177            !   
178            ! bottom friction (explicit before friction)       
179            ! Note that we chose here not to bound the friction as in dynbfr)   
180            ztx2 = (  bfrua(ji,jj)  * ub(ji,jj,mbku(ji,jj)) + bfrua(ji-1,jj) * ub(ji-1,jj,mbku(ji-1,jj))  )   &         
181               & * ( 1._wp - 0.5_wp * umask(ji,jj,1) * umask(ji-1,jj,1)  )     
182            zty2 = (  bfrva(ji,jj)  * vb(ji,jj,mbkv(ji,jj)) + bfrva(ji,jj-1) * vb(ji,jj-1,mbkv(ji,jj-1))  )   &         
183               & * ( 1._wp - 0.5_wp * vmask(ji,jj,1) * vmask(ji,jj-1,1)  )     
184            ustarb2(ji,jj) = SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)         
185         END DO         
186      END DO   
187
188      ! Set surface roughness length
189      SELECT CASE ( nn_z0_met )
190      !
191      CASE ( 0 )             ! Constant roughness         
192         zhsro(:,:) = rn_hsro
193      CASE ( 1 )             ! Standard Charnock formula
194         zhsro(:,:) = MAX(rsbc_zs1 * ustars2(:,:), rn_hsro)
195      CASE ( 2 )             ! Roughness formulae according to Rascle et al., Ocean Modelling (2008)
196         zdep(:,:)  = 30.*TANH(2.*0.3/(28.*SQRT(MAX(ustars2(:,:),rsmall))))             ! Wave age (eq. 10)
197         zhsro(:,:) = MAX(rsbc_zs2 * ustars2(:,:) * zdep(:,:)**1.5, rn_hsro) ! zhsro = rn_frac_hs * Hsw (eq. 11)
198      CASE ( 3 )             ! Roughness given by the wave model (coupled or read in file)
199         zhsro(:,:) = hsw(:,:)
200      END SELECT
201
202      ! Compute shear and dissipation rate
203      DO jk = 2, jpkm1
204         DO jj = 2, jpjm1
205            DO ji = fs_2, fs_jpim1   ! vector opt.
206               avmu(ji,jj,jk) = avmu(ji,jj,jk) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )   &
207                  &                            * ( ub(ji,jj,jk-1) - ub(ji,jj,jk) )   &
208                  &                            / (  e3uw_n(ji,jj,jk) * e3uw_b(ji,jj,jk) )
209               avmv(ji,jj,jk) = avmv(ji,jj,jk) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )   &
210                  &                            * ( vb(ji,jj,jk-1) - vb(ji,jj,jk) )   &
211                  &                            / (  e3vw_n(ji,jj,jk) * e3vw_b(ji,jj,jk) )
212               eps(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT(en(ji,jj,jk)) / mxln(ji,jj,jk)
213            END DO
214         END DO
215      END DO
216      !
217      ! Lateral boundary conditions (avmu,avmv) (sign unchanged)
218      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
219
220      ! Save tke at before time step
221      eb  (:,:,:) = en  (:,:,:)
222      mxlb(:,:,:) = mxln(:,:,:)
223
224      IF( nn_clos == 0 ) THEN    ! Mellor-Yamada
225         DO jk = 2, jpkm1
226            DO jj = 2, jpjm1 
227               DO ji = fs_2, fs_jpim1   ! vector opt.
228                  zup   = mxln(ji,jj,jk) * gdepw_n(ji,jj,mbkt(ji,jj)+1)
229                  zdown = vkarmn * gdepw_n(ji,jj,jk) * ( -gdepw_n(ji,jj,jk) + gdepw_n(ji,jj,mbkt(ji,jj)+1) )
230                  zcoef = ( zup / MAX( zdown, rsmall ) )
231                  zwall (ji,jj,jk) = ( 1._wp + re2 * zcoef*zcoef ) * tmask(ji,jj,jk)
232               END DO
233            END DO
234         END DO
235      ENDIF
236
237      !!---------------------------------!!
238      !!   Equation to prognostic k      !!
239      !!---------------------------------!!
240      !
241      ! Now Turbulent kinetic energy (output in en)
242      ! -------------------------------
243      ! Resolution of a tridiagonal linear system by a "methode de chasse"
244      ! computation from level 2 to jpkm1  (e(1) computed after and e(jpk)=0 ).
245      ! The surface boundary condition are set after
246      ! The bottom boundary condition are also set after. In standard e(bottom)=0.
247      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
248      ! Warning : after this step, en : right hand side of the matrix
249
250      DO jk = 2, jpkm1
251         DO jj = 2, jpjm1
252            DO ji = fs_2, fs_jpim1   ! vector opt.
253               !
254               ! shear prod. at w-point weightened by mask
255               shear(ji,jj,jk) =  ( avmu(ji-1,jj,jk) + avmu(ji,jj,jk) ) / MAX( 1.e0 , umask(ji-1,jj,jk) + umask(ji,jj,jk) )   &
256                  &             + ( avmv(ji,jj-1,jk) + avmv(ji,jj,jk) ) / MAX( 1.e0 , vmask(ji,jj-1,jk) + vmask(ji,jj,jk) )
257               !
258               ! stratif. destruction
259               buoy = - avt(ji,jj,jk) * rn2(ji,jj,jk)
260               !
261               ! shear prod. - stratif. destruction
262               diss = eps(ji,jj,jk)
263               !
264               dir = 0.5_wp + SIGN( 0.5_wp, shear(ji,jj,jk) + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
265               !
266               zesh2 = dir*(shear(ji,jj,jk)+buoy)+(1._wp-dir)*shear(ji,jj,jk)          ! production term
267               zdiss = dir*(diss/en(ji,jj,jk))   +(1._wp-dir)*(diss-buoy)/en(ji,jj,jk) ! dissipation term
268               !
269               ! Compute a wall function from 1. to rsc_psi*zwall/rsc_psi0
270               ! Note that as long that Dirichlet boundary conditions are NOT set at the first and last levels (GOTM style)
271               ! there is no need to set a boundary condition for zwall_psi at the top and bottom boundaries.
272               ! Otherwise, this should be rsc_psi/rsc_psi0
273               IF( ln_sigpsi ) THEN
274                  zsigpsi = MIN( 1._wp, zesh2 / eps(ji,jj,jk) )     ! 0. <= zsigpsi <= 1.
275                  zwall_psi(ji,jj,jk) = rsc_psi /   & 
276                     &     (  zsigpsi * rsc_psi + (1._wp-zsigpsi) * rsc_psi0 / MAX( zwall(ji,jj,jk), 1._wp )  )
277               ELSE
278                  zwall_psi(ji,jj,jk) = 1._wp
279               ENDIF
280               !
281               ! building the matrix
282               zcof = rfact_tke * tmask(ji,jj,jk)
283               !
284               ! lower diagonal
285               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
286                  &                      / ( e3t_n(ji,jj,jk-1) * e3w_n(ji,jj,jk  ) )
287               !
288               ! upper diagonal
289               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
290                  &                      / ( e3t_n(ji,jj,jk  ) * e3w_n(ji,jj,jk) )
291               !
292               ! diagonal
293               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
294                  &                       + rdt * zdiss * tmask(ji,jj,jk) 
295               !
296               ! right hand side in en
297               en(ji,jj,jk) = en(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
298            END DO
299         END DO
300      END DO
301      !
302      z_elem_b(:,:,jpk) = 1._wp
303      !
304      ! Set surface condition on zwall_psi (1 at the bottom)
305      zwall_psi(:,:,1) = zwall_psi(:,:,2)
306      zwall_psi(:,:,jpk) = 1.
307      !
308      ! Surface boundary condition on tke
309      ! ---------------------------------
310      !
311      SELECT CASE ( nn_bc_surf )
312      !
313      CASE ( 0 )             ! Dirichlet case
314      ! First level
315      en(:,:,1) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1)**(2._wp/3._wp)
316      en(:,:,1) = MAX(en(:,:,1), rn_emin) 
317      z_elem_a(:,:,1) = en(:,:,1)
318      z_elem_c(:,:,1) = 0._wp
319      z_elem_b(:,:,1) = 1._wp
320      !
321      ! One level below
322      en(:,:,2) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1 * ((zhsro(:,:)+gdepw_n(:,:,2)) &
323         &               / zhsro(:,:) )**(1.5_wp*ra_sf))**(2._wp/3._wp)
324      en(:,:,2) = MAX(en(:,:,2), rn_emin )
325      z_elem_a(:,:,2) = 0._wp 
326      z_elem_c(:,:,2) = 0._wp
327      z_elem_b(:,:,2) = 1._wp
328      !
329      !
330      CASE ( 1 )             ! Neumann boundary condition on d(e)/dz
331      !
332      ! Dirichlet conditions at k=1
333      en(:,:,1)       = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1)**(2._wp/3._wp)
334      en(:,:,1)       = MAX(en(:,:,1), rn_emin)     
335      z_elem_a(:,:,1) = en(:,:,1)
336      z_elem_c(:,:,1) = 0._wp
337      z_elem_b(:,:,1) = 1._wp
338      !
339      ! at k=2, set de/dz=Fw
340      !cbr
341      z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
342      z_elem_a(:,:,2) = 0._wp
343      zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1.-exp(-rtrans*gdept_n(:,:,1)/zhsro(:,:)) ))
344      zflxs(:,:)      = rsbc_tke2 * ustars2(:,:)**1.5_wp * zkar(:,:) &
345          &                       * ((zhsro(:,:)+gdept_n(:,:,1)) / zhsro(:,:) )**(1.5_wp*ra_sf)
346
347      en(:,:,2) = en(:,:,2) + zflxs(:,:)/e3w_n(:,:,2)
348      !
349      !
350      END SELECT
351
352      ! Bottom boundary condition on tke
353      ! --------------------------------
354      !
355      SELECT CASE ( nn_bc_bot )
356      !
357      CASE ( 0 )             ! Dirichlet
358         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = rn_lmin
359         !                      ! Balance between the production and the dissipation terms
360         DO jj = 2, jpjm1
361            DO ji = fs_2, fs_jpim1   ! vector opt.
362               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
363               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
364               !
365               ! Bottom level Dirichlet condition:
366               z_elem_a(ji,jj,ibot  ) = 0._wp
367               z_elem_c(ji,jj,ibot  ) = 0._wp
368               z_elem_b(ji,jj,ibot  ) = 1._wp
369               en(ji,jj,ibot  ) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
370               !
371               ! Just above last level, Dirichlet condition again
372               z_elem_a(ji,jj,ibotm1) = 0._wp
373               z_elem_c(ji,jj,ibotm1) = 0._wp
374               z_elem_b(ji,jj,ibotm1) = 1._wp
375               en(ji,jj,ibotm1) = MAX( rc02r * ustarb2(ji,jj), rn_emin ) 
376            END DO
377         END DO
378         !
379      CASE ( 1 )             ! Neumman boundary condition
380         !                     
381         DO jj = 2, jpjm1
382            DO ji = fs_2, fs_jpim1   ! vector opt.
383               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
384               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
385               !
386               ! Bottom level Dirichlet condition:
387               z_elem_a(ji,jj,ibot) = 0._wp
388               z_elem_c(ji,jj,ibot) = 0._wp
389               z_elem_b(ji,jj,ibot) = 1._wp
390               en(ji,jj,ibot) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
391               !
392               ! Just above last level: Neumann condition
393               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1)   ! Remove z_elem_c from z_elem_b
394               z_elem_c(ji,jj,ibotm1) = 0._wp
395            END DO
396         END DO
397         !
398      END SELECT
399
400      ! Matrix inversion (en prescribed at surface and the bottom)
401      ! ----------------------------------------------------------
402      !
403      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
404         DO jj = 2, jpjm1
405            DO ji = fs_2, fs_jpim1    ! vector opt.
406               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
407            END DO
408         END DO
409      END DO
410      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
411         DO jj = 2, jpjm1
412            DO ji = fs_2, fs_jpim1    ! vector opt.
413               z_elem_a(ji,jj,jk) = en(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
414            END DO
415         END DO
416      END DO
417      DO jk = jpk-1, 2, -1                         ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
418         DO jj = 2, jpjm1
419            DO ji = fs_2, fs_jpim1    ! vector opt.
420               en(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * en(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
421            END DO
422         END DO
423      END DO
424      !                                            ! set the minimum value of tke
425      en(:,:,:) = MAX( en(:,:,:), rn_emin )
426
427      !!----------------------------------------!!
428      !!   Solve prognostic equation for psi    !!
429      !!----------------------------------------!!
430
431      ! Set psi to previous time step value
432      !
433      SELECT CASE ( nn_clos )
434      !
435      CASE( 0 )               ! k-kl  (Mellor-Yamada)
436         DO jk = 2, jpkm1
437            DO jj = 2, jpjm1
438               DO ji = fs_2, fs_jpim1   ! vector opt.
439                  psi(ji,jj,jk)  = eb(ji,jj,jk) * mxlb(ji,jj,jk)
440               END DO
441            END DO
442         END DO
443         !
444      CASE( 1 )               ! k-eps
445         DO jk = 2, jpkm1
446            DO jj = 2, jpjm1
447               DO ji = fs_2, fs_jpim1   ! vector opt.
448                  psi(ji,jj,jk)  = eps(ji,jj,jk)
449               END DO
450            END DO
451         END DO
452         !
453      CASE( 2 )               ! k-w
454         DO jk = 2, jpkm1
455            DO jj = 2, jpjm1
456               DO ji = fs_2, fs_jpim1   ! vector opt.
457                  psi(ji,jj,jk)  = SQRT( eb(ji,jj,jk) ) / ( rc0 * mxlb(ji,jj,jk) )
458               END DO
459            END DO
460         END DO
461         !
462      CASE( 3 )               ! generic
463         DO jk = 2, jpkm1
464            DO jj = 2, jpjm1
465               DO ji = fs_2, fs_jpim1   ! vector opt.
466                  psi(ji,jj,jk)  = rc02 * eb(ji,jj,jk) * mxlb(ji,jj,jk)**rnn 
467               END DO
468            END DO
469         END DO
470         !
471      END SELECT
472      !
473      ! Now gls (output in psi)
474      ! -------------------------------
475      ! Resolution of a tridiagonal linear system by a "methode de chasse"
476      ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
477      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
478      ! Warning : after this step, en : right hand side of the matrix
479
480      DO jk = 2, jpkm1
481         DO jj = 2, jpjm1
482            DO ji = fs_2, fs_jpim1   ! vector opt.
483               !
484               ! psi / k
485               zratio = psi(ji,jj,jk) / eb(ji,jj,jk) 
486               !
487               ! psi3+ : stable : B=-KhN²<0 => N²>0 if rn2>0 dir = 1 (stable) otherwise dir = 0 (unstable)
488               dir = 0.5_wp + SIGN( 0.5_wp, rn2(ji,jj,jk) )
489               !
490               rpsi3 = dir * rpsi3m + ( 1._wp - dir ) * rpsi3p
491               !
492               ! shear prod. - stratif. destruction
493               prod = rpsi1 * zratio * shear(ji,jj,jk)
494               !
495               ! stratif. destruction
496               buoy = rpsi3 * zratio * (- avt(ji,jj,jk) * rn2(ji,jj,jk) )
497               !
498               ! shear prod. - stratif. destruction
499               diss = rpsi2 * zratio * zwall(ji,jj,jk) * eps(ji,jj,jk)
500               !
501               dir = 0.5_wp + SIGN( 0.5_wp, prod + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
502               !
503               zesh2 = dir * ( prod + buoy )          + (1._wp - dir ) * prod                        ! production term
504               zdiss = dir * ( diss / psi(ji,jj,jk) ) + (1._wp - dir ) * (diss-buoy) / psi(ji,jj,jk) ! dissipation term
505               !                                                       
506               ! building the matrix
507               zcof = rfact_psi * zwall_psi(ji,jj,jk) * tmask(ji,jj,jk)
508               ! lower diagonal
509               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
510                  &                      / ( e3t_n(ji,jj,jk-1) * e3w_n(ji,jj,jk  ) )
511               ! upper diagonal
512               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
513                  &                      / ( e3t_n(ji,jj,jk  ) * e3w_n(ji,jj,jk) )
514               ! diagonal
515               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
516                  &                       + rdt * zdiss * tmask(ji,jj,jk)
517               !
518               ! right hand side in psi
519               psi(ji,jj,jk) = psi(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
520            END DO
521         END DO
522      END DO
523      !
524      z_elem_b(:,:,jpk) = 1._wp
525
526      ! Surface boundary condition on psi
527      ! ---------------------------------
528      !
529      SELECT CASE ( nn_bc_surf )
530      !
531      CASE ( 0 )             ! Dirichlet boundary conditions
532      !
533      ! Surface value
534      zdep(:,:)       = zhsro(:,:) * rl_sf ! Cosmetic
535      psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
536      z_elem_a(:,:,1) = psi(:,:,1)
537      z_elem_c(:,:,1) = 0._wp
538      z_elem_b(:,:,1) = 1._wp
539      !
540      ! One level below
541      zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans*gdepw_n(:,:,2)/zhsro(:,:) )))
542      zdep(:,:)       = (zhsro(:,:) + gdepw_n(:,:,2)) * zkar(:,:)
543      psi (:,:,2)     = rc0**rpp * en(:,:,2)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
544      z_elem_a(:,:,2) = 0._wp
545      z_elem_c(:,:,2) = 0._wp
546      z_elem_b(:,:,2) = 1._wp
547      !
548      !
549      CASE ( 1 )             ! Neumann boundary condition on d(psi)/dz
550      !
551      ! Surface value: Dirichlet
552      zdep(:,:)       = zhsro(:,:) * rl_sf
553      psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
554      z_elem_a(:,:,1) = psi(:,:,1)
555      z_elem_c(:,:,1) = 0._wp
556      z_elem_b(:,:,1) = 1._wp
557      !
558      ! Neumann condition at k=2
559      z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
560      z_elem_a(:,:,2) = 0._wp
561      !
562      ! Set psi vertical flux at the surface:
563      zkar(:,:) = rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans*gdept_n(:,:,1)/zhsro(:,:) )) ! Lengh scale slope
564      zdep(:,:) = ((zhsro(:,:) + gdept_n(:,:,1)) / zhsro(:,:))**(rmm*ra_sf)
565      zflxs(:,:) = (rnn + rsbc_tke1 * (rnn + rmm*ra_sf) * zdep(:,:))*(1._wp + rsbc_tke1*zdep(:,:))**(2._wp*rmm/3._wp-1_wp)
566      zdep(:,:) =  rsbc_psi1 * (zwall_psi(:,:,1)*avm(:,:,1)+zwall_psi(:,:,2)*avm(:,:,2)) * &
567             & ustars2(:,:)**rmm * zkar(:,:)**rnn * (zhsro(:,:) + gdept_n(:,:,1))**(rnn-1.)
568      zflxs(:,:) = zdep(:,:) * zflxs(:,:)
569      psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / e3w_n(:,:,2)
570
571      !   
572      !
573      END SELECT
574
575      ! Bottom boundary condition on psi
576      ! --------------------------------
577      !
578      SELECT CASE ( nn_bc_bot )
579      !
580      !
581      CASE ( 0 )             ! Dirichlet
582         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = vkarmn * rn_bfrz0
583         !                      ! Balance between the production and the dissipation terms
584         DO jj = 2, jpjm1
585            DO ji = fs_2, fs_jpim1   ! vector opt.
586               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
587               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
588               zdep(ji,jj) = vkarmn * rn_bfrz0
589               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
590               z_elem_a(ji,jj,ibot) = 0._wp
591               z_elem_c(ji,jj,ibot) = 0._wp
592               z_elem_b(ji,jj,ibot) = 1._wp
593               !
594               ! Just above last level, Dirichlet condition again (GOTM like)
595               zdep(ji,jj) = vkarmn * ( rn_bfrz0 + e3t_n(ji,jj,ibotm1) )
596               psi (ji,jj,ibotm1) = rc0**rpp * en(ji,jj,ibot  )**rmm * zdep(ji,jj)**rnn
597               z_elem_a(ji,jj,ibotm1) = 0._wp
598               z_elem_c(ji,jj,ibotm1) = 0._wp
599               z_elem_b(ji,jj,ibotm1) = 1._wp
600            END DO
601         END DO
602         !
603      CASE ( 1 )             ! Neumman boundary condition
604         !                     
605         DO jj = 2, jpjm1
606            DO ji = fs_2, fs_jpim1   ! vector opt.
607               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
608               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
609               !
610               ! Bottom level Dirichlet condition:
611               zdep(ji,jj) = vkarmn * rn_bfrz0
612               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
613               !
614               z_elem_a(ji,jj,ibot) = 0._wp
615               z_elem_c(ji,jj,ibot) = 0._wp
616               z_elem_b(ji,jj,ibot) = 1._wp
617               !
618               ! Just above last level: Neumann condition with flux injection
619               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1) ! Remove z_elem_c from z_elem_b
620               z_elem_c(ji,jj,ibotm1) = 0.
621               !
622               ! Set psi vertical flux at the bottom:
623               zdep(ji,jj) = rn_bfrz0 + 0.5_wp*e3t_n(ji,jj,ibotm1)
624               zflxb = rsbc_psi2 * ( avm(ji,jj,ibot) + avm(ji,jj,ibotm1) )   &
625                  &  * (0.5_wp*(en(ji,jj,ibot)+en(ji,jj,ibotm1)))**rmm * zdep(ji,jj)**(rnn-1._wp)
626               psi(ji,jj,ibotm1) = psi(ji,jj,ibotm1) + zflxb / e3w_n(ji,jj,ibotm1)
627            END DO
628         END DO
629         !
630      END SELECT
631
632      ! Matrix inversion
633      ! ----------------
634      !
635      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
636         DO jj = 2, jpjm1
637            DO ji = fs_2, fs_jpim1    ! vector opt.
638               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
639            END DO
640         END DO
641      END DO
642      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
643         DO jj = 2, jpjm1
644            DO ji = fs_2, fs_jpim1    ! vector opt.
645               z_elem_a(ji,jj,jk) = psi(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
646            END DO
647         END DO
648      END DO
649      DO jk = jpk-1, 2, -1                         ! Third recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
650         DO jj = 2, jpjm1
651            DO ji = fs_2, fs_jpim1    ! vector opt.
652               psi(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * psi(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
653            END DO
654         END DO
655      END DO
656
657      ! Set dissipation
658      !----------------
659
660      SELECT CASE ( nn_clos )
661      !
662      CASE( 0 )               ! k-kl  (Mellor-Yamada)
663         DO jk = 1, jpkm1
664            DO jj = 2, jpjm1
665               DO ji = fs_2, fs_jpim1   ! vector opt.
666                  eps(ji,jj,jk) = rc03 * en(ji,jj,jk) * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / MAX( psi(ji,jj,jk), rn_epsmin)
667               END DO
668            END DO
669         END DO
670         !
671      CASE( 1 )               ! k-eps
672         DO jk = 1, jpkm1
673            DO jj = 2, jpjm1
674               DO ji = fs_2, fs_jpim1   ! vector opt.
675                  eps(ji,jj,jk) = psi(ji,jj,jk)
676               END DO
677            END DO
678         END DO
679         !
680      CASE( 2 )               ! k-w
681         DO jk = 1, jpkm1
682            DO jj = 2, jpjm1
683               DO ji = fs_2, fs_jpim1   ! vector opt.
684                  eps(ji,jj,jk) = rc04 * en(ji,jj,jk) * psi(ji,jj,jk) 
685               END DO
686            END DO
687         END DO
688         !
689      CASE( 3 )               ! generic
690         zcoef = rc0**( 3._wp  + rpp/rnn )
691         zex1  =      ( 1.5_wp + rmm/rnn )
692         zex2  = -1._wp / rnn
693         DO jk = 1, jpkm1
694            DO jj = 2, jpjm1
695               DO ji = fs_2, fs_jpim1   ! vector opt.
696                  eps(ji,jj,jk) = zcoef * en(ji,jj,jk)**zex1 * psi(ji,jj,jk)**zex2
697               END DO
698            END DO
699         END DO
700         !
701      END SELECT
702
703      ! Limit dissipation rate under stable stratification
704      ! --------------------------------------------------
705      DO jk = 1, jpkm1 ! Note that this set boundary conditions on mxln at the same time
706         DO jj = 2, jpjm1
707            DO ji = fs_2, fs_jpim1    ! vector opt.
708               ! limitation
709               eps(ji,jj,jk)  = MAX( eps(ji,jj,jk), rn_epsmin )
710               mxln(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / eps(ji,jj,jk)
711               ! Galperin criterium (NOTE : Not required if the proper value of C3 in stable cases is calculated)
712               zrn2 = MAX( rn2(ji,jj,jk), rsmall )
713               IF (ln_length_lim) mxln(ji,jj,jk) = MIN(  rn_clim_galp * SQRT( 2._wp * en(ji,jj,jk) / zrn2 ), mxln(ji,jj,jk) )
714            END DO
715         END DO
716      END DO 
717
718      !
719      ! Stability function and vertical viscosity and diffusivity
720      ! ---------------------------------------------------------
721      !
722      SELECT CASE ( nn_stab_func )
723      !
724      CASE ( 0 , 1 )             ! Galperin or Kantha-Clayson stability functions
725         DO jk = 2, jpkm1
726            DO jj = 2, jpjm1
727               DO ji = fs_2, fs_jpim1   ! vector opt.
728                  ! zcof =  l²/q²
729                  zcof = mxlb(ji,jj,jk) * mxlb(ji,jj,jk) / ( 2._wp*eb(ji,jj,jk) )
730                  ! Gh = -N²l²/q²
731                  gh = - rn2(ji,jj,jk) * zcof
732                  gh = MIN( gh, rgh0   )
733                  gh = MAX( gh, rghmin )
734                  ! Stability functions from Kantha and Clayson (if C2=C3=0 => Galperin)
735                  sh = ra2*( 1._wp-6._wp*ra1/rb1 ) / ( 1.-3.*ra2*gh*(6.*ra1+rb2*( 1._wp-rc3 ) ) )
736                  sm = ( rb1**(-1._wp/3._wp) + ( 18._wp*ra1*ra1 + 9._wp*ra1*ra2*(1._wp-rc2) )*sh*gh ) / (1._wp-9._wp*ra1*ra2*gh)
737                  !
738                  ! Store stability function in avmu and avmv
739                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
740                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
741               END DO
742            END DO
743         END DO
744         !
745      CASE ( 2, 3 )               ! Canuto stability functions
746         DO jk = 2, jpkm1
747            DO jj = 2, jpjm1
748               DO ji = fs_2, fs_jpim1   ! vector opt.
749                  ! zcof =  l²/q²
750                  zcof = mxlb(ji,jj,jk)*mxlb(ji,jj,jk) / ( 2._wp * eb(ji,jj,jk) )
751                  ! Gh = -N²l²/q²
752                  gh = - rn2(ji,jj,jk) * zcof
753                  gh = MIN( gh, rgh0   )
754                  gh = MAX( gh, rghmin )
755                  gh = gh * rf6
756                  ! Gm =  M²l²/q² Shear number
757                  shr = shear(ji,jj,jk) / MAX( avm(ji,jj,jk), rsmall )
758                  gm = MAX( shr * zcof , 1.e-10 )
759                  gm = gm * rf6
760                  gm = MIN ( (rd0 - rd1*gh + rd3*gh*gh) / (rd2-rd4*gh) , gm )
761                  ! Stability functions from Canuto
762                  rcff = rd0 - rd1*gh +rd2*gm + rd3*gh*gh - rd4*gh*gm + rd5*gm*gm
763                  sm = (rs0 - rs1*gh + rs2*gm) / rcff
764                  sh = (rs4 - rs5*gh + rs6*gm) / rcff
765                  !
766                  ! Store stability function in avmu and avmv
767                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
768                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
769               END DO
770            END DO
771         END DO
772         !
773      END SELECT
774
775      ! Boundary conditions on stability functions for momentum (Neumann):
776      ! Lines below are useless if GOTM style Dirichlet conditions are used
777
778      avmv(:,:,1) = avmv(:,:,2)
779
780      DO jj = 2, jpjm1
781         DO ji = fs_2, fs_jpim1   ! vector opt.
782            avmv(ji,jj,mbkt(ji,jj)+1) = avmv(ji,jj,mbkt(ji,jj))
783         END DO
784      END DO
785
786      ! Compute diffusivities/viscosities
787      ! The computation below could be restrained to jk=2 to jpkm1 if GOTM style Dirichlet conditions are used
788      DO jk = 1, jpk
789         DO jj = 2, jpjm1
790            DO ji = fs_2, fs_jpim1   ! vector opt.
791               zsqen         = SQRT( 2._wp * en(ji,jj,jk) ) * mxln(ji,jj,jk)
792               zav           = zsqen * avmu(ji,jj,jk)
793               avt(ji,jj,jk) = MAX( zav, avtb(jk) )*tmask(ji,jj,jk) ! apply mask for zdfmxl routine
794               zav           = zsqen * avmv(ji,jj,jk)
795               avm(ji,jj,jk) = MAX( zav, avmb(jk) ) ! Note that avm is not masked at the surface and the bottom
796            END DO
797         END DO
798      END DO
799      !
800      ! Lateral boundary conditions (sign unchanged)
801      avt(:,:,1)  = 0._wp
802      CALL lbc_lnk( avm, 'W', 1. )   ;   CALL lbc_lnk( avt, 'W', 1. )
803
804      DO jk = 2, jpkm1            !* vertical eddy viscosity at u- and v-points
805         DO jj = 2, jpjm1
806            DO ji = fs_2, fs_jpim1   ! vector opt.
807               avmu(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji+1,jj  ,jk) ) * umask(ji,jj,jk)
808               avmv(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji  ,jj+1,jk) ) * vmask(ji,jj,jk)
809            END DO
810         END DO
811      END DO
812      avmu(:,:,1) = 0._wp             ;   avmv(:,:,1) = 0._wp                 ! set surface to zero
813      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )       ! Lateral boundary conditions
814
815      IF(ln_ctl) THEN
816         CALL prt_ctl( tab3d_1=en  , clinfo1=' gls  - e: ', tab3d_2=avt, clinfo2=' t: ', ovlap=1, kdim=jpk)
817         CALL prt_ctl( tab3d_1=avmu, clinfo1=' gls  - u: ', mask1=umask,                   &
818            &          tab3d_2=avmv, clinfo2=       ' v: ', mask2=vmask, ovlap=1, kdim=jpk )
819      ENDIF
820      !
821      avt_k (:,:,:) = avt (:,:,:)
822      avm_k (:,:,:) = avm (:,:,:)
823      avmu_k(:,:,:) = avmu(:,:,:)
824      avmv_k(:,:,:) = avmv(:,:,:)
825      !
826      CALL wrk_dealloc( jpi,jpj,       zdep, zkar, zflxs, zhsro )
827      CALL wrk_dealloc( jpi,jpj,jpk,   eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi )
828      !
829      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls')
830      !
831      !
832   END SUBROUTINE zdf_gls
833
834
835   SUBROUTINE zdf_gls_init
836      !!----------------------------------------------------------------------
837      !!                  ***  ROUTINE zdf_gls_init  ***
838      !!                     
839      !! ** Purpose :   Initialization of the vertical eddy diffivity and
840      !!      viscosity when using a gls turbulent closure scheme
841      !!
842      !! ** Method  :   Read the namzdf_gls namelist and check the parameters
843      !!      called at the first timestep (nit000)
844      !!
845      !! ** input   :   Namlist namzdf_gls
846      !!
847      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
848      !!
849      !!----------------------------------------------------------------------
850      USE dynzdf_exp
851      USE trazdf_exp
852      !
853      INTEGER ::   jk    ! dummy loop indices
854      INTEGER ::   ios   ! Local integer output status for namelist read
855      REAL(wp)::   zcr   ! local scalar
856      !!
857      NAMELIST/namzdf_gls/rn_emin, rn_epsmin, ln_length_lim, &
858         &            rn_clim_galp, ln_sigpsi, rn_hsro,      &
859         &            rn_crban, rn_charn, rn_frac_hs,        &
860         &            nn_bc_surf, nn_bc_bot, nn_z0_met,      &
861         &            nn_stab_func, nn_clos
862      !!----------------------------------------------------------
863      !
864      IF( nn_timing == 1 )  CALL timing_start('zdf_gls_init')
865      !
866      REWIND( numnam_ref )              ! Namelist namzdf_gls in reference namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
867      READ  ( numnam_ref, namzdf_gls, IOSTAT = ios, ERR = 901)
868901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in reference namelist', lwp )
869
870      REWIND( numnam_cfg )              ! Namelist namzdf_gls in configuration namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
871      READ  ( numnam_cfg, namzdf_gls, IOSTAT = ios, ERR = 902 )
872902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in configuration namelist', lwp )
873      IF(lwm) WRITE ( numond, namzdf_gls )
874
875      IF(lwp) THEN                     !* Control print
876         WRITE(numout,*)
877         WRITE(numout,*) 'zdf_gls_init : gls turbulent closure scheme'
878         WRITE(numout,*) '~~~~~~~~~~~~'
879         WRITE(numout,*) '   Namelist namzdf_gls : set gls mixing parameters'
880         WRITE(numout,*) '      minimum value of en                           rn_emin        = ', rn_emin
881         WRITE(numout,*) '      minimum value of eps                          rn_epsmin      = ', rn_epsmin
882         WRITE(numout,*) '      Limit dissipation rate under stable stratif.  ln_length_lim  = ', ln_length_lim
883         WRITE(numout,*) '      Galperin limit (Standard: 0.53, Holt: 0.26)   rn_clim_galp   = ', rn_clim_galp
884         WRITE(numout,*) '      TKE Surface boundary condition                nn_bc_surf     = ', nn_bc_surf
885         WRITE(numout,*) '      TKE Bottom boundary condition                 nn_bc_bot      = ', nn_bc_bot
886         WRITE(numout,*) '      Modify psi Schmidt number (wb case)           ln_sigpsi      = ', ln_sigpsi
887         WRITE(numout,*) '      Craig and Banner coefficient                  rn_crban       = ', rn_crban
888         WRITE(numout,*) '      Charnock coefficient                          rn_charn       = ', rn_charn
889         WRITE(numout,*) '      Surface roughness formula                     nn_z0_met      = ', nn_z0_met
890         WRITE(numout,*) '      Wave height frac. (used if nn_z0_met=2)       rn_frac_hs     = ', rn_frac_hs
891         WRITE(numout,*) '      Stability functions                           nn_stab_func   = ', nn_stab_func
892         WRITE(numout,*) '      Type of closure                               nn_clos        = ', nn_clos
893         WRITE(numout,*) '      Surface roughness (m)                         rn_hsro        = ', rn_hsro
894         WRITE(numout,*) '      Bottom roughness (m) (nambfr namelist)        rn_bfrz0       = ', rn_bfrz0
895      ENDIF
896
897      !                                !* allocate gls arrays
898      IF( zdf_gls_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_gls_init : unable to allocate arrays' )
899
900      !                                !* Check of some namelist values
901      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_bc_surf is 0 or 1' )
902      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_bc_surf is 0 or 1' )
903      IF( nn_z0_met < 0 .OR. nn_z0_met > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_z0_met is 0, 1, 2 or 3' )
904      IF( nn_z0_met == 3 .AND. .NOT.ln_wave ) CALL ctl_stop( 'zdf_gls_init: nn_z0_met=3 requires ln_wave=T' )
905      IF( nn_stab_func  < 0 .OR. nn_stab_func  > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_stab_func is 0, 1, 2 and 3' )
906      IF( nn_clos       < 0 .OR. nn_clos       > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_clos is 0, 1, 2 or 3' )
907
908      SELECT CASE ( nn_clos )          !* set the parameters for the chosen closure
909      !
910      CASE( 0 )                              ! k-kl  (Mellor-Yamada)
911         !
912         IF(lwp) WRITE(numout,*) 'The choosen closure is k-kl closed to the classical Mellor-Yamada'
913         rpp     = 0._wp
914         rmm     = 1._wp
915         rnn     = 1._wp
916         rsc_tke = 1.96_wp
917         rsc_psi = 1.96_wp
918         rpsi1   = 0.9_wp
919         rpsi3p  = 1._wp
920         rpsi2   = 0.5_wp
921         !
922         SELECT CASE ( nn_stab_func )
923         CASE( 0, 1 )   ;   rpsi3m = 2.53_wp       ! G88 or KC stability functions
924         CASE( 2 )      ;   rpsi3m = 2.62_wp       ! Canuto A stability functions
925         CASE( 3 )      ;   rpsi3m = 2.38          ! Canuto B stability functions (caution : constant not identified)
926         END SELECT
927         !
928      CASE( 1 )                              ! k-eps
929         !
930         IF(lwp) WRITE(numout,*) 'The choosen closure is k-eps'
931         rpp     =  3._wp
932         rmm     =  1.5_wp
933         rnn     = -1._wp
934         rsc_tke =  1._wp
935         rsc_psi =  1.2_wp  ! Schmidt number for psi
936         rpsi1   =  1.44_wp
937         rpsi3p  =  1._wp
938         rpsi2   =  1.92_wp
939         !
940         SELECT CASE ( nn_stab_func )
941         CASE( 0, 1 )   ;   rpsi3m = -0.52_wp      ! G88 or KC stability functions
942         CASE( 2 )      ;   rpsi3m = -0.629_wp     ! Canuto A stability functions
943         CASE( 3 )      ;   rpsi3m = -0.566        ! Canuto B stability functions
944         END SELECT
945         !
946      CASE( 2 )                              ! k-omega
947         !
948         IF(lwp) WRITE(numout,*) 'The choosen closure is k-omega'
949         rpp     = -1._wp
950         rmm     =  0.5_wp
951         rnn     = -1._wp
952         rsc_tke =  2._wp
953         rsc_psi =  2._wp
954         rpsi1   =  0.555_wp
955         rpsi3p  =  1._wp
956         rpsi2   =  0.833_wp
957         !
958         SELECT CASE ( nn_stab_func )
959         CASE( 0, 1 )   ;   rpsi3m = -0.58_wp       ! G88 or KC stability functions
960         CASE( 2 )      ;   rpsi3m = -0.64_wp       ! Canuto A stability functions
961         CASE( 3 )      ;   rpsi3m = -0.64_wp       ! Canuto B stability functions caution : constant not identified)
962         END SELECT
963         !
964      CASE( 3 )                              ! generic
965         !
966         IF(lwp) WRITE(numout,*) 'The choosen closure is generic'
967         rpp     = 2._wp
968         rmm     = 1._wp
969         rnn     = -0.67_wp
970         rsc_tke = 0.8_wp
971         rsc_psi = 1.07_wp
972         rpsi1   = 1._wp
973         rpsi3p  = 1._wp
974         rpsi2   = 1.22_wp
975         !
976         SELECT CASE ( nn_stab_func )
977         CASE( 0, 1 )   ;   rpsi3m = 0.1_wp         ! G88 or KC stability functions
978         CASE( 2 )      ;   rpsi3m = 0.05_wp        ! Canuto A stability functions
979         CASE( 3 )      ;   rpsi3m = 0.05_wp        ! Canuto B stability functions caution : constant not identified)
980         END SELECT
981         !
982      END SELECT
983
984      !
985      SELECT CASE ( nn_stab_func )     !* set the parameters of the stability functions
986      !
987      CASE ( 0 )                             ! Galperin stability functions
988         !
989         IF(lwp) WRITE(numout,*) 'Stability functions from Galperin'
990         rc2     =  0._wp
991         rc3     =  0._wp
992         rc_diff =  1._wp
993         rc0     =  0.5544_wp
994         rcm_sf  =  0.9884_wp
995         rghmin  = -0.28_wp
996         rgh0    =  0.0233_wp
997         rghcri  =  0.02_wp
998         !
999      CASE ( 1 )                             ! Kantha-Clayson stability functions
1000         !
1001         IF(lwp) WRITE(numout,*) 'Stability functions from Kantha-Clayson'
1002         rc2     =  0.7_wp
1003         rc3     =  0.2_wp
1004         rc_diff =  1._wp
1005         rc0     =  0.5544_wp
1006         rcm_sf  =  0.9884_wp
1007         rghmin  = -0.28_wp
1008         rgh0    =  0.0233_wp
1009         rghcri  =  0.02_wp
1010         !
1011      CASE ( 2 )                             ! Canuto A stability functions
1012         !
1013         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto A'
1014         rs0 = 1.5_wp * rl1 * rl5*rl5
1015         rs1 = -rl4*(rl6+rl7) + 2._wp*rl4*rl5*(rl1-(1._wp/3._wp)*rl2-rl3) + 1.5_wp*rl1*rl5*rl8
1016         rs2 = -(3._wp/8._wp) * rl1*(rl6*rl6-rl7*rl7)
1017         rs4 = 2._wp * rl5
1018         rs5 = 2._wp * rl4
1019         rs6 = (2._wp/3._wp) * rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.5_wp * rl5*rl1 * (3._wp*rl3-rl2)   &
1020            &                                                    + 0.75_wp * rl1 * ( rl6 - rl7 )
1021         rd0 = 3._wp * rl5*rl5
1022         rd1 = rl5 * ( 7._wp*rl4 + 3._wp*rl8 )
1023         rd2 = rl5*rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.75_wp*(rl6*rl6 - rl7*rl7 )
1024         rd3 = rl4 * ( 4._wp*rl4 + 3._wp*rl8)
1025         rd4 = rl4 * ( rl2 * rl6 - 3._wp*rl3*rl7 - rl5*(rl2*rl2 - rl3*rl3 ) ) + rl5*rl8 * ( 3._wp*rl3*rl3 - rl2*rl2 )
1026         rd5 = 0.25_wp * ( rl2*rl2 - 3._wp *rl3*rl3 ) * ( rl6*rl6 - rl7*rl7 )
1027         rc0 = 0.5268_wp
1028         rf6 = 8._wp / (rc0**6._wp)
1029         rc_diff = SQRT(2._wp) / (rc0**3._wp)
1030         rcm_sf  =  0.7310_wp
1031         rghmin  = -0.28_wp
1032         rgh0    =  0.0329_wp
1033         rghcri  =  0.03_wp
1034         !
1035      CASE ( 3 )                             ! Canuto B stability functions
1036         !
1037         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto B'
1038         rs0 = 1.5_wp * rm1 * rm5*rm5
1039         rs1 = -rm4 * (rm6+rm7) + 2._wp * rm4*rm5*(rm1-(1._wp/3._wp)*rm2-rm3) + 1.5_wp * rm1*rm5*rm8
1040         rs2 = -(3._wp/8._wp) * rm1 * (rm6*rm6-rm7*rm7 )
1041         rs4 = 2._wp * rm5
1042         rs5 = 2._wp * rm4
1043         rs6 = (2._wp/3._wp) * rm5 * (3._wp*rm3*rm3-rm2*rm2) - 0.5_wp * rm5*rm1*(3._wp*rm3-rm2) + 0.75_wp * rm1*(rm6-rm7)
1044         rd0 = 3._wp * rm5*rm5
1045         rd1 = rm5 * (7._wp*rm4 + 3._wp*rm8)
1046         rd2 = rm5*rm5 * (3._wp*rm3*rm3 - rm2*rm2) - 0.75_wp * (rm6*rm6 - rm7*rm7)
1047         rd3 = rm4 * ( 4._wp*rm4 + 3._wp*rm8 )
1048         rd4 = rm4 * ( rm2*rm6 -3._wp*rm3*rm7 - rm5*(rm2*rm2 - rm3*rm3) ) + rm5 * rm8 * ( 3._wp*rm3*rm3 - rm2*rm2 )
1049         rd5 = 0.25_wp * ( rm2*rm2 - 3._wp*rm3*rm3 ) * ( rm6*rm6 - rm7*rm7 )
1050         rc0 = 0.5268_wp            !!       rc0 = 0.5540_wp (Warner ...) to verify !
1051         rf6 = 8._wp / ( rc0**6._wp )
1052         rc_diff = SQRT(2._wp)/(rc0**3.)
1053         rcm_sf  =  0.7470_wp
1054         rghmin  = -0.28_wp
1055         rgh0    =  0.0444_wp
1056         rghcri  =  0.0414_wp
1057         !
1058      END SELECT
1059   
1060      !                                !* Set Schmidt number for psi diffusion in the wave breaking case
1061      !                                     ! See Eq. (13) of Carniel et al, OM, 30, 225-239, 2009
1062      !                                     !  or Eq. (17) of Burchard, JPO, 31, 3133-3145, 2001
1063      IF( ln_sigpsi ) THEN
1064         ra_sf = -1.5 ! Set kinetic energy slope, then deduce rsc_psi and rl_sf
1065         ! Verification: retrieve Burchard (2001) results by uncomenting the line below:
1066         ! Note that the results depend on the value of rn_cm_sf which is constant (=rc0) in his work
1067         ! ra_sf = -SQRT(2./3.*rc0**3./rn_cm_sf*rn_sc_tke)/vkarmn
1068         rsc_psi0 = rsc_tke/(24.*rpsi2)*(-1.+(4.*rnn + ra_sf*(1.+4.*rmm))**2./(ra_sf**2.))
1069      ELSE
1070         rsc_psi0 = rsc_psi
1071      ENDIF
1072 
1073      !                                !* Shear free turbulence parameters
1074      !
1075      ra_sf  = -4._wp*rnn*SQRT(rsc_tke) / ( (1._wp+4._wp*rmm)*SQRT(rsc_tke) &
1076               &                              - SQRT(rsc_tke + 24._wp*rsc_psi0*rpsi2 ) )
1077
1078      IF ( rn_crban==0._wp ) THEN
1079         rl_sf = vkarmn
1080      ELSE
1081         rl_sf = rc0 * SQRT(rc0/rcm_sf) * SQRT( ( (1._wp + 4._wp*rmm + 8._wp*rmm**2_wp)*rsc_tke          &
1082                 &                                       + 12._wp * rsc_psi0*rpsi2 - (1._wp + 4._wp*rmm) &
1083                 &                                                *SQRT(rsc_tke*(rsc_tke                 &
1084                 &                                                   + 24._wp*rsc_psi0*rpsi2)) )         &
1085                 &                                         /(12._wp*rnn**2.)                             &
1086                 &                                       )
1087      ENDIF
1088
1089      !
1090      IF(lwp) THEN                     !* Control print
1091         WRITE(numout,*)
1092         WRITE(numout,*) 'Limit values'
1093         WRITE(numout,*) '~~~~~~~~~~~~'
1094         WRITE(numout,*) 'Parameter  m = ',rmm
1095         WRITE(numout,*) 'Parameter  n = ',rnn
1096         WRITE(numout,*) 'Parameter  p = ',rpp
1097         WRITE(numout,*) 'rpsi1   = ',rpsi1
1098         WRITE(numout,*) 'rpsi2   = ',rpsi2
1099         WRITE(numout,*) 'rpsi3m  = ',rpsi3m
1100         WRITE(numout,*) 'rpsi3p  = ',rpsi3p
1101         WRITE(numout,*) 'rsc_tke = ',rsc_tke
1102         WRITE(numout,*) 'rsc_psi = ',rsc_psi
1103         WRITE(numout,*) 'rsc_psi0 = ',rsc_psi0
1104         WRITE(numout,*) 'rc0     = ',rc0
1105         WRITE(numout,*)
1106         WRITE(numout,*) 'Shear free turbulence parameters:'
1107         WRITE(numout,*) 'rcm_sf  = ',rcm_sf
1108         WRITE(numout,*) 'ra_sf   = ',ra_sf
1109         WRITE(numout,*) 'rl_sf   = ',rl_sf
1110         WRITE(numout,*)
1111      ENDIF
1112
1113      !                                !* Constants initialization
1114      rc02  = rc0  * rc0   ;   rc02r = 1. / rc02
1115      rc03  = rc02 * rc0
1116      rc04  = rc03 * rc0
1117      rsbc_tke1 = -3._wp/2._wp*rn_crban*ra_sf*rl_sf                      ! Dirichlet + Wave breaking
1118      rsbc_tke2 = rdt * rn_crban / rl_sf                                 ! Neumann + Wave breaking
1119      zcr = MAX(rsmall, rsbc_tke1**(1./(-ra_sf*3._wp/2._wp))-1._wp )
1120      rtrans = 0.2_wp / zcr                                              ! Ad. inverse transition length between log and wave layer
1121      rsbc_zs1  = rn_charn/grav                                          ! Charnock formula for surface roughness
1122      rsbc_zs2  = rn_frac_hs / 0.85_wp / grav * 665._wp                  ! Rascle formula for surface roughness
1123      rsbc_psi1 = -0.5_wp * rdt * rc0**(rpp-2._wp*rmm) / rsc_psi
1124      rsbc_psi2 = -0.5_wp * rdt * rc0**rpp * rnn * vkarmn**rnn / rsc_psi ! Neumann + NO Wave breaking
1125
1126      rfact_tke = -0.5_wp / rsc_tke * rdt                                ! Cst used for the Diffusion term of tke
1127      rfact_psi = -0.5_wp / rsc_psi * rdt                                ! Cst used for the Diffusion term of tke
1128
1129      !                                !* Wall proximity function
1130      zwall (:,:,:) = 1._wp * tmask(:,:,:)
1131
1132      !                                !* set vertical eddy coef. to the background value
1133      DO jk = 1, jpk
1134         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
1135         avm (:,:,jk) = avmb(jk) * tmask(:,:,jk)
1136         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
1137         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
1138      END DO
1139      !                             
1140      CALL gls_rst( nit000, 'READ' )   !* read or initialize all required files
1141      !
1142      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls_init')
1143      !
1144   END SUBROUTINE zdf_gls_init
1145
1146
1147   SUBROUTINE gls_rst( kt, cdrw )
1148      !!---------------------------------------------------------------------
1149      !!                   ***  ROUTINE ts_rst  ***
1150      !!                     
1151      !! ** Purpose :   Read or write TKE file (en) in restart file
1152      !!
1153      !! ** Method  :   use of IOM library
1154      !!                if the restart does not contain TKE, en is either
1155      !!                set to rn_emin or recomputed (nn_igls/=0)
1156      !!----------------------------------------------------------------------
1157      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1158      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1159      !
1160      INTEGER ::   jit, jk   ! dummy loop indices
1161      INTEGER ::   id1, id2, id3, id4, id5, id6
1162      INTEGER ::   ji, jj, ikbu, ikbv
1163      REAL(wp)::   cbx, cby
1164      !!----------------------------------------------------------------------
1165      !
1166      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
1167         !                                   ! ---------------
1168         IF( ln_rstart ) THEN                   !* Read the restart file
1169            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
1170            id2 = iom_varid( numror, 'avt'  , ldstop = .FALSE. )
1171            id3 = iom_varid( numror, 'avm'  , ldstop = .FALSE. )
1172            id4 = iom_varid( numror, 'avmu' , ldstop = .FALSE. )
1173            id5 = iom_varid( numror, 'avmv' , ldstop = .FALSE. )
1174            id6 = iom_varid( numror, 'mxln' , ldstop = .FALSE. )
1175            !
1176            IF( MIN( id1, id2, id3, id4, id5, id6 ) > 0 ) THEN        ! all required arrays exist
1177               CALL iom_get( numror, jpdom_autoglo, 'en'    , en     )
1178               CALL iom_get( numror, jpdom_autoglo, 'avt'   , avt    )
1179               CALL iom_get( numror, jpdom_autoglo, 'avm'   , avm    )
1180               CALL iom_get( numror, jpdom_autoglo, 'avmu'  , avmu   )
1181               CALL iom_get( numror, jpdom_autoglo, 'avmv'  , avmv   )
1182               CALL iom_get( numror, jpdom_autoglo, 'mxln'  , mxln   )
1183            ELSE                       
1184               IF(lwp) WRITE(numout,*) ' ===>>>> : previous run without gls scheme, en and mxln computed by iterative loop'
1185               en  (:,:,:) = rn_emin
1186               mxln(:,:,:) = 0.05       
1187               avt_k (:,:,:) = avt (:,:,:)
1188               avm_k (:,:,:) = avm (:,:,:)
1189               avmu_k(:,:,:) = avmu(:,:,:)
1190               avmv_k(:,:,:) = avmv(:,:,:)
1191               DO jit = nit000 + 1, nit000 + 10   ;   CALL zdf_gls( jit )   ;   END DO
1192            ENDIF
1193         ELSE                                   !* Start from rest
1194            IF(lwp) WRITE(numout,*) ' ===>>>> : Initialisation of en and mxln by background values'
1195            en  (:,:,:) = rn_emin
1196            mxln(:,:,:) = 0.05       
1197         ENDIF
1198         !
1199      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
1200         !                                   ! -------------------
1201         IF(lwp) WRITE(numout,*) '---- gls-rst ----'
1202         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en     ) 
1203         CALL iom_rstput( kt, nitrst, numrow, 'avt'  , avt_k  )
1204         CALL iom_rstput( kt, nitrst, numrow, 'avm'  , avm_k  )
1205         CALL iom_rstput( kt, nitrst, numrow, 'avmu' , avmu_k ) 
1206         CALL iom_rstput( kt, nitrst, numrow, 'avmv' , avmv_k )
1207         CALL iom_rstput( kt, nitrst, numrow, 'mxln' , mxln   )
1208         !
1209      ENDIF
1210      !
1211   END SUBROUTINE gls_rst
1212
1213#else
1214   !!----------------------------------------------------------------------
1215   !!   Dummy module :                                        NO TKE scheme
1216   !!----------------------------------------------------------------------
1217   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfgls = .FALSE.   !: TKE flag
1218CONTAINS
1219   SUBROUTINE zdf_gls_init           ! Empty routine
1220      WRITE(*,*) 'zdf_gls_init: You should not have seen this print! error?'
1221   END SUBROUTINE zdf_gls_init
1222   SUBROUTINE zdf_gls( kt )          ! Empty routine
1223      WRITE(*,*) 'zdf_gls: You should not have seen this print! error?', kt
1224   END SUBROUTINE zdf_gls
1225   SUBROUTINE gls_rst( kt, cdrw )          ! Empty routine
1226      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1227      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1228      WRITE(*,*) 'gls_rst: You should not have seen this print! error?', kt, cdrw
1229   END SUBROUTINE gls_rst
1230#endif
1231
1232   !!======================================================================
1233END MODULE zdfgls
1234
Note: See TracBrowser for help on using the repository browser.