New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfmxl.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfmxl.F90 @ 2758

Last change on this file since 2758 was 2758, checked in by cetlod, 13 years ago

Minor modifications on zdfmxl.F90 in order to be used when running in OFFLINE mode, see ticket #820

  • Property svn:keywords set to Id
File size: 6.0 KB
Line 
1MODULE zdfmxl
2   !!======================================================================
3   !!                       ***  MODULE  zdfmxl  ***
4   !! Ocean physics: mixed layer depth
5   !!======================================================================
6   !! History :  1.0  ! 2003-08  (G. Madec)  original code
7   !!            3.2  ! 2009-07  (S. Masson, G. Madec)  IOM + merge of DO-loop
8   !!----------------------------------------------------------------------
9   !!   zdf_mxl      : Compute the turbocline and mixed layer depths.
10   !!----------------------------------------------------------------------
11   USE oce             ! ocean dynamics and tracers variables
12   USE dom_oce         ! ocean space and time domain variables
13   USE zdf_oce         ! ocean vertical physics
14   USE in_out_manager  ! I/O manager
15   USE prtctl          ! Print control
16   USE iom             ! I/O library
17   USE lib_mpp         ! MPP library
18   USE trc_oce, ONLY : lk_offline ! offline flag
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   zdf_mxl       ! called by step.F90
24
25   INTEGER , PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   nmln    !: number of level in the mixed layer (used by TOP)
26   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmld    !: mixing layer depth (turbocline)      [m]
27   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlp    !: mixed layer depth  (rho=rho0+zdcrit) [m]
28   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlpt   !: mixed layer depth at t-points        [m]
29
30   !! * Substitutions
31#  include "domzgr_substitute.h90"
32   !!----------------------------------------------------------------------
33   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
34   !! $Id$
35   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   INTEGER FUNCTION zdf_mxl_alloc()
40      !!----------------------------------------------------------------------
41      !!               ***  FUNCTION zdf_mxl_alloc  ***
42      !!----------------------------------------------------------------------
43      IF( .NOT. ALLOCATED( nmln ) ) THEN
44         ALLOCATE( nmln(jpi,jpj), hmld(jpi,jpj), hmlp(jpi,jpj), hmlpt(jpi,jpj), STAT= zdf_mxl_alloc )
45         !
46         IF( lk_mpp             )   CALL mpp_sum ( zdf_mxl_alloc )
47         IF( zdf_mxl_alloc /= 0 )   CALL ctl_warn('zdf_mxl_alloc: failed to allocate arrays.')
48         !
49      ENDIF
50   END FUNCTION zdf_mxl_alloc
51
52
53   SUBROUTINE zdf_mxl( kt )
54      !!----------------------------------------------------------------------
55      !!                  ***  ROUTINE zdfmxl  ***
56      !!                   
57      !! ** Purpose :   Compute the turbocline depth and the mixed layer depth
58      !!              with density criteria.
59      !!
60      !! ** Method  :   The mixed layer depth is the shallowest W depth with
61      !!      the density of the corresponding T point (just bellow) bellow a
62      !!      given value defined locally as rho(10m) + zrho_c
63      !!               The turbocline depth is the depth at which the vertical
64      !!      eddy diffusivity coefficient (resulting from the vertical physics
65      !!      alone, not the isopycnal part, see trazdf.F) fall below a given
66      !!      value defined locally (avt_c here taken equal to 5 cm/s2)
67      !!
68      !! ** Action  :   nmln, hmld, hmlp, hmlpt
69      !!----------------------------------------------------------------------
70      USE wrk_nemo, ONLY:   iwrk_in_use, iwrk_not_released
71      USE wrk_nemo, ONLY:   imld => iwrk_2d_1    ! 2D integer workspace
72      !!
73      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
74      !!
75      INTEGER  ::   ji, jj, jk          ! dummy loop indices
76      INTEGER  ::   iikn, iiki          ! temporary integer within a do loop
77      REAL(wp) ::   zrho_c = 0.01_wp    ! density criterion for mixed layer depth
78      REAL(wp) ::   zavt_c = 5.e-4_wp   ! Kz criterion for the turbocline depth
79      !!----------------------------------------------------------------------
80
81      IF( iwrk_in_use(2, 1) ) THEN
82         CALL ctl_stop('zdf_mxl : requested workspace array unavailable')   ;   RETURN
83      ENDIF
84
85      IF( kt == nit000 ) THEN
86         IF(lwp) WRITE(numout,*)
87         IF(lwp) WRITE(numout,*) 'zdf_mxl : mixed layer depth'
88         IF(lwp) WRITE(numout,*) '~~~~~~~ '
89         !                             ! allocate zdfmxl arrays
90         IF( zdf_mxl_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_mxl : unable to allocate arrays' )
91      ENDIF
92
93      ! w-level of the mixing and mixed layers
94      nmln(:,:) = mbkt(:,:) + 1        ! Initialization to the number of w ocean point
95      imld(:,:) = mbkt(:,:) + 1
96      DO jk = jpkm1, nlb10, -1         ! from the bottom to nlb10
97         DO jj = 1, jpj
98            DO ji = 1, jpi
99               IF( rhop(ji,jj,jk) > rhop(ji,jj,nla10) + zrho_c )   nmln(ji,jj) = jk      ! Mixed layer
100               IF( avt (ji,jj,jk) < zavt_c                     )   imld(ji,jj) = jk      ! Turbocline
101            END DO
102         END DO
103      END DO
104      ! depth of the mixing and mixed layers
105      DO jj = 1, jpj
106         DO ji = 1, jpi
107            iiki = imld(ji,jj)
108            iikn = nmln(ji,jj)
109            hmld (ji,jj) = fsdepw(ji,jj,iiki  ) * tmask(ji,jj,1)    ! Turbocline depth
110            hmlp (ji,jj) = fsdepw(ji,jj,iikn  ) * tmask(ji,jj,1)    ! Mixed layer depth
111            hmlpt(ji,jj) = fsdept(ji,jj,iikn-1)                     ! depth of the last T-point inside the mixed layer
112         END DO
113      END DO
114      IF( .NOT.lk_offline ) THEN            ! no need to output in offline mode
115         CALL iom_put( "mldr10_1", hmlp )   ! mixed layer depth
116         CALL iom_put( "mldkz5"  , hmld )   ! turbocline depth
117      ENDIF
118     
119      IF(ln_ctl)   CALL prt_ctl( tab2d_1=REAL(nmln,wp), clinfo1=' nmln : ', tab2d_2=hmlp, clinfo2=' hmlp : ', ovlap=1 )
120      !
121      IF( iwrk_not_released(2, 1) )   CALL ctl_stop('zdf_mxl: failed to release workspace array')
122      !
123   END SUBROUTINE zdf_mxl
124
125   !!======================================================================
126END MODULE zdfmxl
Note: See TracBrowser for help on using the repository browser.