| 1 | MODULE zdftmx |
|---|
| 2 | !!======================================================================== |
|---|
| 3 | !! *** MODULE zdftmx *** |
|---|
| 4 | !! Ocean physics: vertical tidal mixing coefficient |
|---|
| 5 | !!======================================================================== |
|---|
| 6 | !! History : 1.0 ! 2004-04 (L. Bessieres, G. Madec) Original code |
|---|
| 7 | !! - ! 2006-08 (A. Koch-Larrouy) Indonesian strait |
|---|
| 8 | !! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | #if defined key_zdftmx || defined key_esopa |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | !! 'key_zdftmx' Tidal vertical mixing |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! zdf_tmx : global momentum & tracer Kz with tidal induced Kz |
|---|
| 15 | !! tmx_itf : Indonesian momentum & tracer Kz with tidal induced Kz |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and tracers variables |
|---|
| 18 | USE dom_oce ! ocean space and time domain variables |
|---|
| 19 | USE zdf_oce ! ocean vertical physics variables |
|---|
| 20 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 21 | USE eosbn2 ! ocean equation of state |
|---|
| 22 | USE phycst ! physical constants |
|---|
| 23 | USE prtctl ! Print control |
|---|
| 24 | USE in_out_manager ! I/O manager |
|---|
| 25 | USE iom ! I/O Manager |
|---|
| 26 | USE lib_mpp ! MPP library |
|---|
| 27 | USE wrk_nemo ! work arrays |
|---|
| 28 | USE timing ! Timing |
|---|
| 29 | |
|---|
| 30 | IMPLICIT NONE |
|---|
| 31 | PRIVATE |
|---|
| 32 | |
|---|
| 33 | PUBLIC zdf_tmx ! called in step module |
|---|
| 34 | PUBLIC zdf_tmx_init ! called in opa module |
|---|
| 35 | PUBLIC zdf_tmx_alloc ! called in nemogcm module |
|---|
| 36 | |
|---|
| 37 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .TRUE. !: tidal mixing flag |
|---|
| 38 | |
|---|
| 39 | ! !!* Namelist namzdf_tmx : tidal mixing * |
|---|
| 40 | REAL(wp) :: rn_htmx = 500. ! vertical decay scale for turbulence (meters) |
|---|
| 41 | REAL(wp) :: rn_n2min = 1.e-8 ! threshold of the Brunt-Vaisala frequency (s-1) |
|---|
| 42 | REAL(wp) :: rn_tfe = 1./3. ! tidal dissipation efficiency (St Laurent et al. 2002) |
|---|
| 43 | REAL(wp) :: rn_me = 0.2 ! mixing efficiency (Osborn 1980) |
|---|
| 44 | LOGICAL :: ln_tmx_itf = .TRUE. ! Indonesian Through Flow (ITF): Koch-Larrouy et al. (2007) parameterization |
|---|
| 45 | REAL(wp) :: rn_tfe_itf = 1. ! ITF tidal dissipation efficiency (St Laurent et al. 2002) |
|---|
| 46 | |
|---|
| 47 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: en_tmx ! energy available for tidal mixing (W/m2) |
|---|
| 48 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: mask_itf ! mask to use over Indonesian area |
|---|
| 49 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: az_tmx ! coefficient used to evaluate the tidal induced Kz |
|---|
| 50 | |
|---|
| 51 | !! * Substitutions |
|---|
| 52 | # include "domzgr_substitute.h90" |
|---|
| 53 | # include "vectopt_loop_substitute.h90" |
|---|
| 54 | !!---------------------------------------------------------------------- |
|---|
| 55 | !! NEMO/OPA 4.0 , NEMO Consortium (2011) |
|---|
| 56 | !! $Id$ |
|---|
| 57 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 58 | !!---------------------------------------------------------------------- |
|---|
| 59 | CONTAINS |
|---|
| 60 | |
|---|
| 61 | INTEGER FUNCTION zdf_tmx_alloc() |
|---|
| 62 | !!---------------------------------------------------------------------- |
|---|
| 63 | !! *** FUNCTION zdf_tmx_alloc *** |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | ALLOCATE(en_tmx(jpi,jpj), mask_itf(jpi,jpj), az_tmx(jpi,jpj,jpk), STAT=zdf_tmx_alloc ) |
|---|
| 66 | ! |
|---|
| 67 | IF( lk_mpp ) CALL mpp_sum ( zdf_tmx_alloc ) |
|---|
| 68 | IF( zdf_tmx_alloc /= 0 ) CALL ctl_warn('zdf_tmx_alloc: failed to allocate arrays') |
|---|
| 69 | END FUNCTION zdf_tmx_alloc |
|---|
| 70 | |
|---|
| 71 | |
|---|
| 72 | SUBROUTINE zdf_tmx( kt ) |
|---|
| 73 | !!---------------------------------------------------------------------- |
|---|
| 74 | !! *** ROUTINE zdf_tmx *** |
|---|
| 75 | !! |
|---|
| 76 | !! ** Purpose : add to the vertical mixing coefficients the effect of |
|---|
| 77 | !! tidal mixing (Simmons et al 2004). |
|---|
| 78 | !! |
|---|
| 79 | !! ** Method : - tidal-induced vertical mixing is given by: |
|---|
| 80 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
|---|
| 81 | !! where az_tmx is a coefficient that specified the 3D space |
|---|
| 82 | !! distribution of the faction of tidal energy taht is used |
|---|
| 83 | !! for mixing. Its expression is set in zdf_tmx_init routine, |
|---|
| 84 | !! following Simmons et al. 2004. |
|---|
| 85 | !! NB: a specific bounding procedure is performed on av_tide |
|---|
| 86 | !! so that the input tidal energy is actually almost used. The |
|---|
| 87 | !! basic maximum value is 60 cm2/s, but values of 300 cm2/s |
|---|
| 88 | !! can be reached in area where bottom stratification is too |
|---|
| 89 | !! weak. |
|---|
| 90 | !! |
|---|
| 91 | !! - update av_tide in the Indonesian Through Flow area |
|---|
| 92 | !! following Koch-Larrouy et al. (2007) parameterisation |
|---|
| 93 | !! (see tmx_itf routine). |
|---|
| 94 | !! |
|---|
| 95 | !! - update the model vertical eddy viscosity and diffusivity: |
|---|
| 96 | !! avt = avt + av_tides |
|---|
| 97 | !! avm = avm + av_tides |
|---|
| 98 | !! avmu = avmu + mi(av_tides) |
|---|
| 99 | !! avmv = avmv + mj(av_tides) |
|---|
| 100 | !! |
|---|
| 101 | !! ** Action : avt, avm, avmu, avmv increased by tidal mixing |
|---|
| 102 | !! |
|---|
| 103 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
|---|
| 104 | !! Koch-Larrouy et al. 2007, GRL. |
|---|
| 105 | !!---------------------------------------------------------------------- |
|---|
| 106 | USE oce, zav_tide => ua ! use ua as workspace |
|---|
| 107 | !! |
|---|
| 108 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 109 | !! |
|---|
| 110 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 111 | REAL(wp) :: ztpc ! scalar workspace |
|---|
| 112 | REAL(wp), POINTER, DIMENSION(:,:) :: zkz |
|---|
| 113 | !!---------------------------------------------------------------------- |
|---|
| 114 | ! |
|---|
| 115 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx') |
|---|
| 116 | ! |
|---|
| 117 | CALL wrk_alloc( jpi,jpj, zkz ) |
|---|
| 118 | |
|---|
| 119 | ! ! ----------------------- ! |
|---|
| 120 | ! ! Standard tidal mixing ! (compute zav_tide) |
|---|
| 121 | ! ! ----------------------- ! |
|---|
| 122 | ! !* First estimation (with n2 bound by rn_n2min) bounded by 60 cm2/s |
|---|
| 123 | zav_tide(:,:,:) = MIN( 60.e-4, az_tmx(:,:,:) / MAX( rn_n2min, rn2(:,:,:) ) ) |
|---|
| 124 | |
|---|
| 125 | zkz(:,:) = 0.e0 !* Associated potential energy consummed over the whole water column |
|---|
| 126 | DO jk = 2, jpkm1 |
|---|
| 127 | zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zav_tide(:,:,jk)* tmask(:,:,jk) |
|---|
| 128 | END DO |
|---|
| 129 | |
|---|
| 130 | DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
|---|
| 131 | DO ji = 1, jpi |
|---|
| 132 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
|---|
| 133 | END DO |
|---|
| 134 | END DO |
|---|
| 135 | |
|---|
| 136 | DO jk = 2, jpkm1 !* Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zav_tide bound by 300 cm2/s |
|---|
| 137 | zav_tide(:,:,jk) = zav_tide(:,:,jk) * MIN( zkz(:,:), 30./6. ) !kz max = 300 cm2/s |
|---|
| 138 | END DO |
|---|
| 139 | |
|---|
| 140 | IF( kt == nit000 ) THEN !* check at first time-step: diagnose the energy consumed by zav_tide |
|---|
| 141 | ztpc = 0.e0 |
|---|
| 142 | DO jk= 1, jpk |
|---|
| 143 | DO jj= 1, jpj |
|---|
| 144 | DO ji= 1, jpi |
|---|
| 145 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) & |
|---|
| 146 | & * MAX( 0.e0, rn2(ji,jj,jk) ) * zav_tide(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 147 | END DO |
|---|
| 148 | END DO |
|---|
| 149 | END DO |
|---|
| 150 | ztpc= rau0 / ( rn_tfe * rn_me ) * ztpc |
|---|
| 151 | IF(lwp) WRITE(numout,*) |
|---|
| 152 | IF(lwp) WRITE(numout,*) ' N Total power consumption by av_tide : ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 153 | ENDIF |
|---|
| 154 | |
|---|
| 155 | ! ! ----------------------- ! |
|---|
| 156 | ! ! ITF tidal mixing ! (update zav_tide) |
|---|
| 157 | ! ! ----------------------- ! |
|---|
| 158 | IF( ln_tmx_itf ) CALL tmx_itf( kt, zav_tide ) |
|---|
| 159 | |
|---|
| 160 | ! ! ----------------------- ! |
|---|
| 161 | ! ! Update mixing coefs ! |
|---|
| 162 | ! ! ----------------------- ! |
|---|
| 163 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with tidal mixing |
|---|
| 164 | avt(:,:,jk) = avt(:,:,jk) + zav_tide(:,:,jk) |
|---|
| 165 | avm(:,:,jk) = avm(:,:,jk) + zav_tide(:,:,jk) |
|---|
| 166 | DO jj = 2, jpjm1 |
|---|
| 167 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 168 | avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji+1,jj ,jk) ) * umask(ji,jj,jk) |
|---|
| 169 | avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji ,jj+1,jk) ) * vmask(ji,jj,jk) |
|---|
| 170 | END DO |
|---|
| 171 | END DO |
|---|
| 172 | END DO |
|---|
| 173 | CALL lbc_lnk( avmu, 'U', 1. ) ; CALL lbc_lnk( avmv, 'V', 1. ) ! lateral boundary condition |
|---|
| 174 | |
|---|
| 175 | ! !* output tidal mixing coefficient |
|---|
| 176 | CALL iom_put( "av_tide", zav_tide ) |
|---|
| 177 | |
|---|
| 178 | IF(ln_ctl) CALL prt_ctl(tab3d_1=zav_tide , clinfo1=' tmx - av_tide: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk) |
|---|
| 179 | ! |
|---|
| 180 | CALL wrk_dealloc( jpi,jpj, zkz ) |
|---|
| 181 | ! |
|---|
| 182 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx') |
|---|
| 183 | ! |
|---|
| 184 | END SUBROUTINE zdf_tmx |
|---|
| 185 | |
|---|
| 186 | |
|---|
| 187 | SUBROUTINE tmx_itf( kt, pav ) |
|---|
| 188 | !!---------------------------------------------------------------------- |
|---|
| 189 | !! *** ROUTINE tmx_itf *** |
|---|
| 190 | !! |
|---|
| 191 | !! ** Purpose : modify the vertical eddy diffusivity coefficients |
|---|
| 192 | !! (pav) in the Indonesian Through Flow area (ITF). |
|---|
| 193 | !! |
|---|
| 194 | !! ** Method : - Following Koch-Larrouy et al. (2007), in the ITF defined |
|---|
| 195 | !! by msk_itf (read in a file, see tmx_init), the tidal |
|---|
| 196 | !! mixing coefficient is computed with : |
|---|
| 197 | !! * q=1 (i.e. all the tidal energy remains trapped in |
|---|
| 198 | !! the area and thus is used for mixing) |
|---|
| 199 | !! * the vertical distribution of the tifal energy is a |
|---|
| 200 | !! proportional to N above the thermocline (d(N^2)/dz > 0) |
|---|
| 201 | !! and to N^2 below the thermocline (d(N^2)/dz < 0) |
|---|
| 202 | !! |
|---|
| 203 | !! ** Action : av_tide updated in the ITF area (msk_itf) |
|---|
| 204 | !! |
|---|
| 205 | !! References : Koch-Larrouy et al. 2007, GRL |
|---|
| 206 | !!---------------------------------------------------------------------- |
|---|
| 207 | INTEGER , INTENT(in ) :: kt ! ocean time-step |
|---|
| 208 | REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) :: pav ! Tidal mixing coef. |
|---|
| 209 | !! |
|---|
| 210 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 211 | REAL(wp) :: zcoef, ztpc ! temporary scalar |
|---|
| 212 | REAL(wp), DIMENSION(:,:) , POINTER :: zkz ! 2D workspace |
|---|
| 213 | REAL(wp), DIMENSION(:,:) , POINTER :: zsum1 , zsum2 , zsum ! - - |
|---|
| 214 | REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d_1, zempba_3d_2 ! 3D workspace |
|---|
| 215 | REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d , zdn2dz ! - - |
|---|
| 216 | REAL(wp), DIMENSION(:,:,:), POINTER :: zavt_itf ! - - |
|---|
| 217 | !!---------------------------------------------------------------------- |
|---|
| 218 | ! |
|---|
| 219 | IF( nn_timing == 1 ) CALL timing_start('tmx_itf') |
|---|
| 220 | ! |
|---|
| 221 | CALL wrk_alloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum ) |
|---|
| 222 | CALL wrk_alloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf ) |
|---|
| 223 | |
|---|
| 224 | ! ! compute the form function using N2 at each time step |
|---|
| 225 | zempba_3d_1(:,:,jpk) = 0.e0 |
|---|
| 226 | zempba_3d_2(:,:,jpk) = 0.e0 |
|---|
| 227 | DO jk = 1, jpkm1 |
|---|
| 228 | zdn2dz (:,:,jk) = rn2(:,:,jk) - rn2(:,:,jk+1) ! Vertical profile of dN2/dz |
|---|
| 229 | !CDIR NOVERRCHK |
|---|
| 230 | zempba_3d_1(:,:,jk) = SQRT( MAX( 0.e0, rn2(:,:,jk) ) ) ! - - of N |
|---|
| 231 | zempba_3d_2(:,:,jk) = MAX( 0.e0, rn2(:,:,jk) ) ! - - of N^2 |
|---|
| 232 | END DO |
|---|
| 233 | ! |
|---|
| 234 | zsum (:,:) = 0.e0 |
|---|
| 235 | zsum1(:,:) = 0.e0 |
|---|
| 236 | zsum2(:,:) = 0.e0 |
|---|
| 237 | DO jk= 2, jpk |
|---|
| 238 | zsum1(:,:) = zsum1(:,:) + zempba_3d_1(:,:,jk) * fse3w(:,:,jk) |
|---|
| 239 | zsum2(:,:) = zsum2(:,:) + zempba_3d_2(:,:,jk) * fse3w(:,:,jk) |
|---|
| 240 | END DO |
|---|
| 241 | DO jj = 1, jpj |
|---|
| 242 | DO ji = 1, jpi |
|---|
| 243 | IF( zsum1(ji,jj) /= 0.e0 ) zsum1(ji,jj) = 1.e0 / zsum1(ji,jj) |
|---|
| 244 | IF( zsum2(ji,jj) /= 0.e0 ) zsum2(ji,jj) = 1.e0 / zsum2(ji,jj) |
|---|
| 245 | END DO |
|---|
| 246 | END DO |
|---|
| 247 | |
|---|
| 248 | DO jk= 1, jpk |
|---|
| 249 | DO jj = 1, jpj |
|---|
| 250 | DO ji = 1, jpi |
|---|
| 251 | zcoef = 0.5 - SIGN( 0.5, zdn2dz(ji,jj,jk) ) ! =0 if dN2/dz > 0, =1 otherwise |
|---|
| 252 | ztpc = zempba_3d_1(ji,jj,jk) * zsum1(ji,jj) * zcoef & |
|---|
| 253 | & + zempba_3d_2(ji,jj,jk) * zsum2(ji,jj) * ( 1. - zcoef ) |
|---|
| 254 | ! |
|---|
| 255 | zempba_3d(ji,jj,jk) = ztpc |
|---|
| 256 | zsum (ji,jj) = zsum(ji,jj) + ztpc * fse3w(ji,jj,jk) |
|---|
| 257 | END DO |
|---|
| 258 | END DO |
|---|
| 259 | END DO |
|---|
| 260 | DO jj = 1, jpj |
|---|
| 261 | DO ji = 1, jpi |
|---|
| 262 | IF( zsum(ji,jj) > 0.e0 ) zsum(ji,jj) = 1.e0 / zsum(ji,jj) |
|---|
| 263 | END DO |
|---|
| 264 | END DO |
|---|
| 265 | |
|---|
| 266 | ! ! first estimation bounded by 10 cm2/s (with n2 bounded by rn_n2min) |
|---|
| 267 | zcoef = rn_tfe_itf / ( rn_tfe * rau0 ) |
|---|
| 268 | DO jk = 1, jpk |
|---|
| 269 | zavt_itf(:,:,jk) = MIN( 10.e-4, zcoef * en_tmx(:,:) * zsum(:,:) * zempba_3d(:,:,jk) & |
|---|
| 270 | & / MAX( rn_n2min, rn2(:,:,jk) ) * tmask(:,:,jk) ) |
|---|
| 271 | END DO |
|---|
| 272 | |
|---|
| 273 | zkz(:,:) = 0.e0 ! Associated potential energy consummed over the whole water column |
|---|
| 274 | DO jk = 2, jpkm1 |
|---|
| 275 | zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zavt_itf(:,:,jk) * tmask(:,:,jk) |
|---|
| 276 | END DO |
|---|
| 277 | |
|---|
| 278 | DO jj = 1, jpj ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
|---|
| 279 | DO ji = 1, jpi |
|---|
| 280 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) * rn_tfe_itf / rn_tfe / zkz(ji,jj) |
|---|
| 281 | END DO |
|---|
| 282 | END DO |
|---|
| 283 | |
|---|
| 284 | DO jk = 2, jpkm1 ! Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zavt_itf bound by 300 cm2/s |
|---|
| 285 | zavt_itf(:,:,jk) = zavt_itf(:,:,jk) * MIN( zkz(:,:), 120./10. ) ! kz max = 120 cm2/s |
|---|
| 286 | END DO |
|---|
| 287 | |
|---|
| 288 | IF( kt == nit000 ) THEN ! diagnose the nergy consumed by zavt_itf |
|---|
| 289 | ztpc = 0.e0 |
|---|
| 290 | DO jk= 1, jpk |
|---|
| 291 | DO jj= 1, jpj |
|---|
| 292 | DO ji= 1, jpi |
|---|
| 293 | ztpc = ztpc + e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk) * MAX( 0.e0, rn2(ji,jj,jk) ) & |
|---|
| 294 | & * zavt_itf(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 295 | END DO |
|---|
| 296 | END DO |
|---|
| 297 | END DO |
|---|
| 298 | ztpc= rau0 * ztpc / ( rn_me * rn_tfe_itf ) |
|---|
| 299 | IF(lwp) WRITE(numout,*) ' N Total power consumption by zavt_itf: ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 300 | ENDIF |
|---|
| 301 | |
|---|
| 302 | ! ! Update pav with the ITF mixing coefficient |
|---|
| 303 | DO jk = 2, jpkm1 |
|---|
| 304 | pav(:,:,jk) = pav (:,:,jk) * ( 1.e0 - mask_itf(:,:) ) & |
|---|
| 305 | & + zavt_itf(:,:,jk) * mask_itf(:,:) |
|---|
| 306 | END DO |
|---|
| 307 | ! |
|---|
| 308 | CALL wrk_dealloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum ) |
|---|
| 309 | CALL wrk_dealloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf ) |
|---|
| 310 | ! |
|---|
| 311 | IF( nn_timing == 1 ) CALL timing_stop('tmx_itf') |
|---|
| 312 | ! |
|---|
| 313 | END SUBROUTINE tmx_itf |
|---|
| 314 | |
|---|
| 315 | |
|---|
| 316 | SUBROUTINE zdf_tmx_init |
|---|
| 317 | !!---------------------------------------------------------------------- |
|---|
| 318 | !! *** ROUTINE zdf_tmx_init *** |
|---|
| 319 | !! |
|---|
| 320 | !! ** Purpose : Initialization of the vertical tidal mixing, Reading |
|---|
| 321 | !! of M2 and K1 tidal energy in nc files |
|---|
| 322 | !! |
|---|
| 323 | !! ** Method : - Read the namtmx namelist and check the parameters |
|---|
| 324 | !! |
|---|
| 325 | !! - Read the input data in NetCDF files : |
|---|
| 326 | !! M2 and K1 tidal energy. The total tidal energy, en_tmx, |
|---|
| 327 | !! is the sum of M2, K1 and S2 energy where S2 is assumed |
|---|
| 328 | !! to be: S2=(1/2)^2 * M2 |
|---|
| 329 | !! mask_itf, a mask array that determine where substituing |
|---|
| 330 | !! the standard Simmons et al. (2005) formulation with the |
|---|
| 331 | !! one of Koch_Larrouy et al. (2007). |
|---|
| 332 | !! |
|---|
| 333 | !! - Compute az_tmx, a 3D coefficient that allows to compute |
|---|
| 334 | !! the standard tidal-induced vertical mixing as follows: |
|---|
| 335 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
|---|
| 336 | !! with az_tmx a bottom intensified coefficient is given by: |
|---|
| 337 | !! az_tmx(z) = en_tmx / ( rau0 * rn_htmx ) * EXP( -(H-z)/rn_htmx ) |
|---|
| 338 | !! / ( 1. - EXP( - H /rn_htmx ) ) |
|---|
| 339 | !! where rn_htmx the characteristic length scale of the bottom |
|---|
| 340 | !! intensification, en_tmx the tidal energy, and H the ocean depth |
|---|
| 341 | !! |
|---|
| 342 | !! ** input : - Namlist namtmx |
|---|
| 343 | !! - NetCDF file : M2_ORCA2.nc, K1_ORCA2.nc, and mask_itf.nc |
|---|
| 344 | !! |
|---|
| 345 | !! ** Action : - Increase by 1 the nstop flag is setting problem encounter |
|---|
| 346 | !! - defined az_tmx used to compute tidal-induced mixing |
|---|
| 347 | !! |
|---|
| 348 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
|---|
| 349 | !! Koch-Larrouy et al. 2007, GRL. |
|---|
| 350 | !!---------------------------------------------------------------------- |
|---|
| 351 | USE oce , zav_tide => ua ! ua used as workspace |
|---|
| 352 | !! |
|---|
| 353 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 354 | INTEGER :: inum ! local integer |
|---|
| 355 | REAL(wp) :: ztpc, ze_z ! local scalars |
|---|
| 356 | REAL(wp), DIMENSION(:,:) , POINTER :: zem2, zek1 ! read M2 and K1 tidal energy |
|---|
| 357 | REAL(wp), DIMENSION(:,:) , POINTER :: zkz ! total M2, K1 and S2 tidal energy |
|---|
| 358 | REAL(wp), DIMENSION(:,:) , POINTER :: zfact ! used for vertical structure function |
|---|
| 359 | REAL(wp), DIMENSION(:,:) , POINTER :: zhdep ! Ocean depth |
|---|
| 360 | REAL(wp), DIMENSION(:,:,:), POINTER :: zpc ! power consumption |
|---|
| 361 | !! |
|---|
| 362 | NAMELIST/namzdf_tmx/ rn_htmx, rn_n2min, rn_tfe, rn_me, ln_tmx_itf, rn_tfe_itf |
|---|
| 363 | !!---------------------------------------------------------------------- |
|---|
| 364 | ! |
|---|
| 365 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx_init') |
|---|
| 366 | ! |
|---|
| 367 | CALL wrk_alloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep ) |
|---|
| 368 | CALL wrk_alloc( jpi,jpj,jpk, zpc ) |
|---|
| 369 | |
|---|
| 370 | REWIND( numnam ) ! Read Namelist namtmx : Tidal Mixing |
|---|
| 371 | READ ( numnam, namzdf_tmx ) |
|---|
| 372 | |
|---|
| 373 | IF(lwp) THEN ! Control print |
|---|
| 374 | WRITE(numout,*) |
|---|
| 375 | WRITE(numout,*) 'zdf_tmx_init : tidal mixing' |
|---|
| 376 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 377 | WRITE(numout,*) ' Namelist namzdf_tmx : set tidal mixing parameters' |
|---|
| 378 | WRITE(numout,*) ' Vertical decay scale for turbulence = ', rn_htmx |
|---|
| 379 | WRITE(numout,*) ' Brunt-Vaisala frequency threshold = ', rn_n2min |
|---|
| 380 | WRITE(numout,*) ' Tidal dissipation efficiency = ', rn_tfe |
|---|
| 381 | WRITE(numout,*) ' Mixing efficiency = ', rn_me |
|---|
| 382 | WRITE(numout,*) ' ITF specific parameterisation = ', ln_tmx_itf |
|---|
| 383 | WRITE(numout,*) ' ITF tidal dissipation efficiency = ', rn_tfe_itf |
|---|
| 384 | ENDIF |
|---|
| 385 | |
|---|
| 386 | ! ! allocate tmx arrays |
|---|
| 387 | IF( zdf_tmx_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_tmx_init : unable to allocate tmx arrays' ) |
|---|
| 388 | |
|---|
| 389 | IF( ln_tmx_itf ) THEN ! read the Indonesian Through Flow mask |
|---|
| 390 | CALL iom_open('mask_itf',inum) |
|---|
| 391 | CALL iom_get (inum, jpdom_data, 'tmaskitf',mask_itf,1) ! |
|---|
| 392 | CALL iom_close(inum) |
|---|
| 393 | ENDIF |
|---|
| 394 | |
|---|
| 395 | ! read M2 tidal energy flux : W/m2 ( zem2 < 0 ) |
|---|
| 396 | CALL iom_open('M2rowdrg',inum) |
|---|
| 397 | CALL iom_get (inum, jpdom_data, 'field',zem2,1) ! |
|---|
| 398 | CALL iom_close(inum) |
|---|
| 399 | |
|---|
| 400 | ! read K1 tidal energy flux : W/m2 ( zek1 < 0 ) |
|---|
| 401 | CALL iom_open('K1rowdrg',inum) |
|---|
| 402 | CALL iom_get (inum, jpdom_data, 'field',zek1,1) ! |
|---|
| 403 | CALL iom_close(inum) |
|---|
| 404 | |
|---|
| 405 | ! Total tidal energy ( M2, S2 and K1 with S2=(1/2)^2 * M2 ) |
|---|
| 406 | ! only the energy available for mixing is taken into account, |
|---|
| 407 | ! (mixing efficiency tidal dissipation efficiency) |
|---|
| 408 | en_tmx(:,:) = - rn_tfe * rn_me * ( zem2(:,:) * 1.25 + zek1(:,:) ) * tmask(:,:,1) |
|---|
| 409 | |
|---|
| 410 | ! Vertical structure (az_tmx) |
|---|
| 411 | DO jj = 1, jpj ! part independent of the level |
|---|
| 412 | DO ji = 1, jpi |
|---|
| 413 | zhdep(ji,jj) = fsdepw(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean |
|---|
| 414 | zfact(ji,jj) = rau0 * rn_htmx * ( 1. - EXP( -zhdep(ji,jj) / rn_htmx ) ) |
|---|
| 415 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = en_tmx(ji,jj) / zfact(ji,jj) |
|---|
| 416 | END DO |
|---|
| 417 | END DO |
|---|
| 418 | DO jk= 1, jpk ! complete with the level-dependent part |
|---|
| 419 | DO jj = 1, jpj |
|---|
| 420 | DO ji = 1, jpi |
|---|
| 421 | az_tmx(ji,jj,jk) = zfact(ji,jj) * EXP( -( zhdep(ji,jj)-fsdepw(ji,jj,jk) ) / rn_htmx ) * tmask(ji,jj,jk) |
|---|
| 422 | END DO |
|---|
| 423 | END DO |
|---|
| 424 | END DO |
|---|
| 425 | |
|---|
| 426 | IF( nprint == 1 .AND. lwp ) THEN |
|---|
| 427 | ! Control print |
|---|
| 428 | ! Total power consumption due to vertical mixing |
|---|
| 429 | ! zpc = rau0 * 1/rn_me * rn2 * zav_tide |
|---|
| 430 | zav_tide(:,:,:) = 0.e0 |
|---|
| 431 | DO jk = 2, jpkm1 |
|---|
| 432 | zav_tide(:,:,jk) = az_tmx(:,:,jk) / MAX( rn_n2min, rn2(:,:,jk) ) |
|---|
| 433 | END DO |
|---|
| 434 | |
|---|
| 435 | ztpc = 0.e0 |
|---|
| 436 | zpc(:,:,:) = MAX(rn_n2min,rn2(:,:,:)) * zav_tide(:,:,:) |
|---|
| 437 | DO jk= 2, jpkm1 |
|---|
| 438 | DO jj = 1, jpj |
|---|
| 439 | DO ji = 1, jpi |
|---|
| 440 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 441 | END DO |
|---|
| 442 | END DO |
|---|
| 443 | END DO |
|---|
| 444 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
|---|
| 445 | |
|---|
| 446 | WRITE(numout,*) |
|---|
| 447 | WRITE(numout,*) ' Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 448 | |
|---|
| 449 | |
|---|
| 450 | ! control print 2 |
|---|
| 451 | zav_tide(:,:,:) = MIN( zav_tide(:,:,:), 60.e-4 ) |
|---|
| 452 | zkz(:,:) = 0.e0 |
|---|
| 453 | DO jk = 2, jpkm1 |
|---|
| 454 | DO jj = 1, jpj |
|---|
| 455 | DO ji = 1, jpi |
|---|
| 456 | zkz(ji,jj) = zkz(ji,jj) + fse3w(ji,jj,jk) * MAX( 0.e0, rn2(ji,jj,jk) ) * rau0 * zav_tide(ji,jj,jk)* tmask(ji,jj,jk) |
|---|
| 457 | END DO |
|---|
| 458 | END DO |
|---|
| 459 | END DO |
|---|
| 460 | ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz |
|---|
| 461 | DO jj = 1, jpj |
|---|
| 462 | DO ji = 1, jpi |
|---|
| 463 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
|---|
| 464 | zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
|---|
| 465 | ENDIF |
|---|
| 466 | END DO |
|---|
| 467 | END DO |
|---|
| 468 | ztpc = 1.e50 |
|---|
| 469 | DO jj = 1, jpj |
|---|
| 470 | DO ji = 1, jpi |
|---|
| 471 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
|---|
| 472 | ztpc = Min( zkz(ji,jj), ztpc) |
|---|
| 473 | ENDIF |
|---|
| 474 | END DO |
|---|
| 475 | END DO |
|---|
| 476 | WRITE(numout,*) ' Min de zkz ', ztpc, ' Max = ', maxval(zkz(:,:) ) |
|---|
| 477 | |
|---|
| 478 | DO jk = 2, jpkm1 |
|---|
| 479 | zav_tide(:,:,jk) = zav_tide(:,:,jk) * MIN( zkz(:,:), 30./6. ) !kz max = 300 cm2/s |
|---|
| 480 | END DO |
|---|
| 481 | ztpc = 0.e0 |
|---|
| 482 | zpc(:,:,:) = Max(0.e0,rn2(:,:,:)) * zav_tide(:,:,:) |
|---|
| 483 | DO jk= 1, jpk |
|---|
| 484 | DO jj = 1, jpj |
|---|
| 485 | DO ji = 1, jpi |
|---|
| 486 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 487 | END DO |
|---|
| 488 | END DO |
|---|
| 489 | END DO |
|---|
| 490 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
|---|
| 491 | WRITE(numout,*) ' 2 Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 492 | |
|---|
| 493 | DO jk = 1, jpk |
|---|
| 494 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zav_tide(:,:,jk) * tmask_i(:,:) ) & |
|---|
| 495 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * tmask (:,:,jk) * tmask_i(:,:) ) ) |
|---|
| 496 | ztpc = 1.E50 |
|---|
| 497 | DO jj = 1, jpj |
|---|
| 498 | DO ji = 1, jpi |
|---|
| 499 | IF( zav_tide(ji,jj,jk) /= 0.e0 ) ztpc =Min( ztpc, zav_tide(ji,jj,jk) ) |
|---|
| 500 | END DO |
|---|
| 501 | END DO |
|---|
| 502 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',ztpc*1.e4, & |
|---|
| 503 | & 'max= ', MAXVAL(zav_tide(:,:,jk) )*1.e4, ' cm2/s' |
|---|
| 504 | END DO |
|---|
| 505 | |
|---|
| 506 | WRITE(numout,*) ' e_tide : ', SUM( e1t*e2t*en_tmx ) / ( rn_tfe * rn_me ) * 1.e-12, 'TW' |
|---|
| 507 | WRITE(numout,*) |
|---|
| 508 | WRITE(numout,*) ' Initial profile of tidal vertical mixing' |
|---|
| 509 | DO jk = 1, jpk |
|---|
| 510 | DO jj = 1,jpj |
|---|
| 511 | DO ji = 1,jpi |
|---|
| 512 | zkz(ji,jj) = az_tmx(ji,jj,jk) /MAX( rn_n2min, rn2(ji,jj,jk) ) |
|---|
| 513 | END DO |
|---|
| 514 | END DO |
|---|
| 515 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zkz(:,:) * tmask_i(:,:) ) & |
|---|
| 516 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * tmask (:,:,jk) * tmask_i(:,:) ) ) |
|---|
| 517 | WRITE(numout,*) ' jk= ', jk,' ', ze_z * 1.e4,' cm2/s' |
|---|
| 518 | END DO |
|---|
| 519 | DO jk = 1, jpk |
|---|
| 520 | zkz(:,:) = az_tmx(:,:,jk) /rn_n2min |
|---|
| 521 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zkz(:,:) * tmask_i(:,:) ) & |
|---|
| 522 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * tmask (:,:,jk) * tmask_i(:,:) ) ) |
|---|
| 523 | WRITE(numout,*) |
|---|
| 524 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',MINVAL(zkz)*1.e4, & |
|---|
| 525 | & 'max= ', MAXVAL(zkz)*1.e4, ' cm2/s' |
|---|
| 526 | END DO |
|---|
| 527 | ! |
|---|
| 528 | ENDIF |
|---|
| 529 | ! |
|---|
| 530 | CALL wrk_dealloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep ) |
|---|
| 531 | CALL wrk_dealloc( jpi,jpj,jpk, zpc ) |
|---|
| 532 | ! |
|---|
| 533 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx_init') |
|---|
| 534 | ! |
|---|
| 535 | END SUBROUTINE zdf_tmx_init |
|---|
| 536 | |
|---|
| 537 | #else |
|---|
| 538 | !!---------------------------------------------------------------------- |
|---|
| 539 | !! Default option Dummy module NO Tidal MiXing |
|---|
| 540 | !!---------------------------------------------------------------------- |
|---|
| 541 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .FALSE. !: tidal mixing flag |
|---|
| 542 | CONTAINS |
|---|
| 543 | SUBROUTINE zdf_tmx_init ! Dummy routine |
|---|
| 544 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?' |
|---|
| 545 | END SUBROUTINE zdf_tmx_init |
|---|
| 546 | SUBROUTINE zdf_tmx( kt ) ! Dummy routine |
|---|
| 547 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?', kt |
|---|
| 548 | END SUBROUTINE zdf_tmx |
|---|
| 549 | #endif |
|---|
| 550 | |
|---|
| 551 | !!====================================================================== |
|---|
| 552 | END MODULE zdftmx |
|---|
