source: trunk/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 6140

Last change on this file since 6140 was 6140, checked in by timgraham, 5 years ago

Merge of branches/2015/dev_merge_2015 back into trunk. Merge excludes NEMOGCM/TOOLS/OBSTOOLS/ for now due to issues with the change of file type. Will sort these manually with further commits.

Branch merged as follows:
In the working copy of branch ran:
svn merge svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk@HEAD
Small conflicts due to bug fixes applied to trunk since the dev_merge_2015 was copied. Bug fixes were applied to the branch as well so these were easy to resolve.
Branch committed at this stage

In working copy run:
svn switch svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk
to switch working copy

Run:
svn merge —reintegrate svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/2015/dev_merge_2015
to merge the branch into the trunk and then commit - no conflicts at this stage.

  • Property svn:keywords set to Id
File size: 41.4 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE) add nemo_northcomms
31   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
32   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
33   !!             -   ! 2013-06  (I. Epicoco, S. Mocavero, CMCC) nemo_northcomms: setup avoiding MPI communication
34   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
35   !!----------------------------------------------------------------------
36
37   !!----------------------------------------------------------------------
38   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
39   !!   nemo_init     : initialization of the NEMO system
40   !!   nemo_ctl      : initialisation of the contol print
41   !!   nemo_closefile: close remaining open files
42   !!   nemo_alloc    : dynamical allocation
43   !!   nemo_partition: calculate MPP domain decomposition
44   !!   factorise     : calculate the factors of the no. of MPI processes
45   !!----------------------------------------------------------------------
46   USE step_oce       ! module used in the ocean time stepping module (step.F90)
47   USE domcfg         ! domain configuration               (dom_cfg routine)
48   USE mppini         ! shared/distributed memory setting (mpp_init routine)
49   USE domain         ! domain initialization             (dom_init routine)
50#if defined key_nemocice_decomp
51   USE ice_domain_size, only: nx_global, ny_global
52#endif
53   USE tideini        ! tidal components initialization   (tide_ini routine)
54   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
55   USE bdydta         ! open boundary cond. setting   (bdy_dta_init routine)
56   USE bdytides       ! open boundary cond. setting   (bdytide_init routine)
57   USE sbctide, ONLY  : lk_tide
58   USE istate         ! initial state setting          (istate_init routine)
59   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
60   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
61   USE zdfini         ! vertical physics setting          (zdf_init routine)
62   USE phycst         ! physical constant                  (par_cst routine)
63   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
64   USE asminc         ! assimilation increments     
65   USE asmbkg         ! writing out state trajectory
66   USE diaptr         ! poleward transports           (dia_ptr_init routine)
67   USE diadct         ! sections transports           (dia_dct_init routine)
68   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
69   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
70   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
71   USE step           ! NEMO time-stepping                 (stp     routine)
72   USE icbini         ! handle bergs, initialisation
73   USE icbstp         ! handle bergs, calving, themodynamics and transport
74   USE cpl_oasis3     ! OASIS3 coupling
75   USE c1d            ! 1D configuration
76   USE step_c1d       ! Time stepping loop for the 1D configuration
77   USE dyndmp         ! Momentum damping
78   USE stopar         ! Stochastic param.: ???
79   USE stopts         ! Stochastic param.: ???
80#if defined key_top
81   USE trcini         ! passive tracer initialisation
82#endif
83   USE lib_mpp        ! distributed memory computing
84   USE diurnal_bulk    ! diurnal bulk SST
85   USE step_diu        ! diurnal bulk SST timestepping (called from here if run offline)
86#if defined key_iomput
87   USE xios           ! xIOserver
88#endif
89   USE crsini         ! initialise grid coarsening utility
90   USE lbcnfd , ONLY  : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
91   USE sbc_oce, ONLY  : lk_oasis
92   USE diatmb          ! Top,middle,bottom output
93   USE dia25h          ! 25h mean output
94
95   IMPLICIT NONE
96   PRIVATE
97
98   PUBLIC   nemo_gcm    ! called by model.F90
99   PUBLIC   nemo_init   ! needed by AGRIF
100   PUBLIC   nemo_alloc  ! needed by TAM
101
102   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
103
104   !!----------------------------------------------------------------------
105   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
106   !! $Id$
107   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
108   !!----------------------------------------------------------------------
109CONTAINS
110
111   SUBROUTINE nemo_gcm
112      !!----------------------------------------------------------------------
113      !!                     ***  ROUTINE nemo_gcm  ***
114      !!
115      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
116      !!              curvilinear mesh on the sphere.
117      !!
118      !! ** Method  : - model general initialization
119      !!              - launch the time-stepping (stp routine)
120      !!              - finalize the run by closing files and communications
121      !!
122      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
123      !!              Madec, 2008, internal report, IPSL.
124      !!----------------------------------------------------------------------
125      INTEGER ::   istp       ! time step index
126      !!----------------------------------------------------------------------
127      !
128#if defined key_agrif
129      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
130#endif
131
132      !                            !-----------------------!
133      CALL nemo_init               !==  Initialisations  ==!
134      !                            !-----------------------!
135#if defined key_agrif
136      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
137      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
138# if defined key_top
139      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
140# endif
141# if defined key_lim2
142      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
143# endif
144#endif
145      ! check that all process are still there... If some process have an error,
146      ! they will never enter in step and other processes will wait until the end of the cpu time!
147      IF( lk_mpp )   CALL mpp_max( nstop )
148
149      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
150
151      !                            !-----------------------!
152      !                            !==   time stepping   ==!
153      !                            !-----------------------!
154      istp = nit000
155#if defined key_c1d
156         DO WHILE ( istp <= nitend .AND. nstop == 0 )
157            CALL stp_c1d( istp )
158            istp = istp + 1
159         END DO
160#else
161          IF( lk_asminc ) THEN
162             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
163             IF( ln_asmdin ) THEN                        ! Direct initialization
164                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
165                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
166                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
167             ENDIF
168          ENDIF
169
170#if defined key_agrif
171          CALL Agrif_Regrid()
172#endif
173
174         DO WHILE ( istp <= nitend .AND. nstop == 0 )
175#if defined key_agrif
176            CALL stp                         ! AGRIF: time stepping
177#else
178            IF ( .NOT. ln_diurnal_only ) THEN
179               CALL stp( istp )                 ! standard time stepping
180            ELSE
181               CALL stp_diurnal( istp )        ! time step only the diurnal SST
182            ENDIF 
183#endif
184            istp = istp + 1
185            IF( lk_mpp )   CALL mpp_max( nstop )
186         END DO
187#endif
188
189      IF( ln_diaobs   )   CALL dia_obs_wri
190      !
191      IF( ln_icebergs )   CALL icb_end( nitend )
192
193      !                            !------------------------!
194      !                            !==  finalize the run  ==!
195      !                            !------------------------!
196      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
197      !
198      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
199         WRITE(numout,cform_err)
200         WRITE(numout,*) nstop, ' error have been found'
201      ENDIF
202      !
203#if defined key_agrif
204      IF( .NOT. Agrif_Root() ) THEN
205                         CALL Agrif_ParentGrid_To_ChildGrid()
206         IF( ln_diaobs ) CALL dia_obs_wri
207         IF( nn_timing == 1 )   CALL timing_finalize
208                                CALL Agrif_ChildGrid_To_ParentGrid()
209      ENDIF
210#endif
211      IF( nn_timing == 1 )   CALL timing_finalize
212      !
213      CALL nemo_closefile
214      !
215#if defined key_iomput
216      CALL xios_finalize                  ! end mpp communications with xios
217      IF( lk_oasis )   CALL cpl_finalize  ! end coupling and mpp communications with OASIS
218#else
219      IF( lk_oasis ) THEN
220         CALL cpl_finalize              ! end coupling and mpp communications with OASIS
221      ELSE
222         IF( lk_mpp )   CALL mppstop    ! end mpp communications
223      ENDIF
224#endif
225      !
226   END SUBROUTINE nemo_gcm
227
228
229   SUBROUTINE nemo_init
230      !!----------------------------------------------------------------------
231      !!                     ***  ROUTINE nemo_init  ***
232      !!
233      !! ** Purpose :   initialization of the NEMO GCM
234      !!----------------------------------------------------------------------
235      INTEGER ::   ji            ! dummy loop indices
236      INTEGER ::   ilocal_comm   ! local integer
237      INTEGER ::   ios
238      CHARACTER(len=80), DIMENSION(16) ::   cltxt
239      !
240      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
241         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
242         &             nn_bench, nn_timing, nn_diacfl
243      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
244         &             jpizoom, jpjzoom, jperio, ln_use_jattr
245      !!----------------------------------------------------------------------
246      !
247      cltxt = ''
248      cxios_context = 'nemo'
249      !
250      !                             ! Open reference namelist and configuration namelist files
251      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
252      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
253      !
254      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
255      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
256901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
257
258      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
259      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
260902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
261
262      !
263      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
264      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
265903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
266
267      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
268      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
269904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
270
271! Force values for AGRIF zoom (cf. agrif_user.F90)
272#if defined key_agrif
273   IF( .NOT. Agrif_Root() ) THEN
274      jpiglo  = nbcellsx + 2 + 2*nbghostcells
275      jpjglo  = nbcellsy + 2 + 2*nbghostcells
276      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
277      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
278      jpidta  = jpiglo
279      jpjdta  = jpjglo
280      jpizoom = 1
281      jpjzoom = 1
282      nperio  = 0
283      jperio  = 0
284      ln_use_jattr = .false.
285   ENDIF
286#endif
287      !
288      !                             !--------------------------------------------!
289      !                             !  set communicator & select the local node  !
290      !                             !  NB: mynode also opens output.namelist.dyn !
291      !                             !      on unit number numond on first proc   !
292      !                             !--------------------------------------------!
293#if defined key_iomput
294      IF( Agrif_Root() ) THEN
295         IF( lk_oasis ) THEN
296            CALL cpl_init( "oceanx", ilocal_comm )                     ! nemo local communicator given by oasis
297            CALL xios_initialize( "not used",local_comm=ilocal_comm )    ! send nemo communicator to xios
298         ELSE
299            CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
300         ENDIF
301      ENDIF
302      ! Nodes selection (control print return in cltxt)
303      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
304#else
305      IF( lk_oasis ) THEN
306         IF( Agrif_Root() ) THEN
307            CALL cpl_init( "oceanx", ilocal_comm )                      ! nemo local communicator given by oasis
308         ENDIF
309         ! Nodes selection (control print return in cltxt)
310         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
311      ELSE
312         ilocal_comm = 0
313         ! Nodes selection (control print return in cltxt)
314         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
315      ENDIF
316#endif
317      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
318
319      lwm = (narea == 1)                                    ! control of output namelists
320      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
321
322      IF(lwm) THEN
323         ! write merged namelists from earlier to output namelist now that the
324         ! file has been opened in call to mynode. nammpp has already been
325         ! written in mynode (if lk_mpp_mpi)
326         WRITE( numond, namctl )
327         WRITE( numond, namcfg )
328      ENDIF
329
330      ! If dimensions of processor grid weren't specified in the namelist file
331      ! then we calculate them here now that we have our communicator size
332      IF( jpni < 1 .OR. jpnj < 1 ) THEN
333#if   defined key_mpp_mpi
334         IF( Agrif_Root() )   CALL nemo_partition( mppsize )
335#else
336         jpni  = 1
337         jpnj  = 1
338         jpnij = jpni*jpnj
339#endif
340      ENDIF
341
342      ! Calculate domain dimensions given calculated jpni and jpnj
343      ! This used to be done in par_oce.F90 when they were parameters rather than variables
344      IF( Agrif_Root() ) THEN
345#if defined key_nemocice_decomp
346         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci    ! first  dim.
347         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj    ! second dim.
348#else
349         jpi = ( jpiglo     -2*jpreci + (jpni-1) ) / jpni + 2*jpreci    ! first  dim.
350         jpj = ( jpjglo     -2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj    ! second dim.
351#endif
352      ENDIF         
353         jpk = jpkdta                                             ! third dim
354#if defined key_agrif
355         ! simple trick to use same vertical grid as parent but different number of levels:
356         ! Save maximum number of levels in jpkdta, then define all vertical grids with this number.
357         ! Suppress once vertical online interpolation is ok
358         IF(.NOT.Agrif_Root())   jpkdta = Agrif_Parent( jpkdta )
359#endif
360         jpim1 = jpi-1                                            ! inner domain indices
361         jpjm1 = jpj-1                                            !   "           "
362         jpkm1 = jpk-1                                            !   "           "
363         jpij  = jpi*jpj                                          !  jpi x j
364
365      IF(lwp) THEN                            ! open listing units
366         !
367         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
368         !
369         WRITE(numout,*)
370         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
371         WRITE(numout,*) '                       NEMO team'
372         WRITE(numout,*) '            Ocean General Circulation Model'
373         WRITE(numout,*) '                  version 3.7  (2015) '
374         WRITE(numout,*)
375         WRITE(numout,*)
376         DO ji = 1, SIZE(cltxt)
377            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
378         END DO
379         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
380         !
381      ENDIF
382
383      ! Now we know the dimensions of the grid and numout has been set we can
384      ! allocate arrays
385      CALL nemo_alloc()
386
387      !                             !-------------------------------!
388      !                             !  NEMO general initialization  !
389      !                             !-------------------------------!
390
391      CALL nemo_ctl                          ! Control prints & Benchmark
392
393      !                                      ! Domain decomposition
394      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
395      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
396      ENDIF
397      !
398      IF( nn_timing == 1 )  CALL timing_init
399      !
400      !                                      ! General initialization
401                            CALL     phy_cst    ! Physical constants
402                            CALL     eos_init   ! Equation of state
403      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
404                            CALL     dom_cfg    ! Domain configuration
405                            CALL     dom_init   ! Domain
406      IF( ln_crs        )   CALL     crs_init   ! coarsened grid: domain initialization
407      IF( ln_nnogather )    CALL nemo_northcomms! northfold neighbour lists (must be done after the masks are defined)
408      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
409     
410      CALL diurnal_sst_bulk_init            ! diurnal sst
411      IF ( ln_diurnal ) CALL diurnal_sst_coolskin_init   ! cool skin   
412     
413      ! IF ln_diurnal_only, then we only want a subset of the initialisation routines
414      IF ( ln_diurnal_only ) THEN
415         CALL  istate_init   ! ocean initial state (Dynamics and tracers)
416         CALL     sbc_init   ! Forcings : surface module
417         CALL tra_qsr_init   ! penetrative solar radiation qsr
418         IF( ln_diaobs     ) THEN                  ! Observation & model comparison
419            CALL dia_obs_init            ! Initialize observational data
420            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
421         ENDIF     
422         !                                     ! Assimilation increments
423         IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
424                 
425         IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
426         RETURN
427      ENDIF
428     
429                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
430
431      !                                      ! external forcing
432!!gm to be added : creation and call of sbc_apr_init
433      IF( lk_tide       )   CALL    tide_init   ! tidal harmonics
434                            CALL     sbc_init   ! surface boundary conditions (including sea-ice)
435!!gm ==>> bdy_init should call bdy_dta_init and bdytide_init  NOT in nemogcm !!!
436      IF( lk_bdy        )   CALL     bdy_init   ! Open boundaries initialisation
437      IF( lk_bdy        )   CALL bdy_dta_init   ! Open boundaries initialisation of external data arrays
438      IF( lk_bdy .AND. lk_tide )   &
439         &                  CALL bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
440         
441      !                                      ! Ocean physics
442      !                                         ! Vertical physics
443                            CALL     zdf_init      ! namelist read
444                            CALL zdf_bfr_init      ! bottom friction
445      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
446      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
447      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
448      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
449      IF( lk_zdfddm     )   CALL zdf_ddm_init      ! double diffusive mixing
450         
451      !                                         ! Lateral physics
452                            CALL ldf_tra_init      ! Lateral ocean tracer physics
453                            CALL ldf_eiv_init      ! eddy induced velocity param.
454                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
455
456      !                                         ! Active tracers
457                            CALL tra_qsr_init      ! penetrative solar radiation qsr
458                            CALL tra_bbc_init      ! bottom heat flux
459      IF( lk_trabbl     )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
460                            CALL tra_dmp_init      ! internal tracer damping
461                            CALL tra_adv_init      ! horizontal & vertical advection
462                            CALL tra_ldf_init      ! lateral mixing
463                            CALL tra_zdf_init      ! vertical mixing and after tracer fields
464
465      !                                         ! Dynamics
466      IF( lk_c1d        )   CALL dyn_dmp_init      ! internal momentum damping
467                            CALL dyn_adv_init      ! advection (vector or flux form)
468                            CALL dyn_vor_init      ! vorticity term including Coriolis
469                            CALL dyn_ldf_init      ! lateral mixing
470                            CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
471                            CALL dyn_zdf_init      ! vertical diffusion
472                            CALL dyn_spg_init      ! surface pressure gradient
473
474#if defined key_top
475      !                                      ! Passive tracers
476                            CALL     trc_init
477#endif
478      IF( l_ldfslp      )   CALL ldf_slp_init   ! slope of lateral mixing
479
480      !                                      ! Icebergs
481                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
482
483      !                                      ! Misc. options
484                            CALL sto_par_init   ! Stochastic parametrization
485      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
486     
487      !                                      ! Diagnostics
488      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
489                            CALL dia_cfl_init   ! Initialise CFL diagnostics
490      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
491                            CALL dia_ptr_init   ! Poleward TRansports initialization
492      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
493                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
494                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
495                            CALL dia_obs_init            ! Initialize observational data
496      IF( ln_diaobs     )   CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
497
498      !                                         ! Assimilation increments
499      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
500      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
501                            CALL dia_tmb_init  ! TMB outputs
502                            CALL dia_25h_init  ! 25h mean  outputs
503
504      !
505   END SUBROUTINE nemo_init
506
507
508   SUBROUTINE nemo_ctl
509      !!----------------------------------------------------------------------
510      !!                     ***  ROUTINE nemo_ctl  ***
511      !!
512      !! ** Purpose :   control print setting
513      !!
514      !! ** Method  : - print namctl information and check some consistencies
515      !!----------------------------------------------------------------------
516      !
517      IF(lwp) THEN                  ! control print
518         WRITE(numout,*)
519         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
520         WRITE(numout,*) '~~~~~~~ '
521         WRITE(numout,*) '   Namelist namctl'
522         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
523         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
524         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
525         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
526         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
527         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
528         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
529         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
530         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
531         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
532      ENDIF
533      !
534      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
535      nictls    = nn_ictls
536      nictle    = nn_ictle
537      njctls    = nn_jctls
538      njctle    = nn_jctle
539      isplt     = nn_isplt
540      jsplt     = nn_jsplt
541      nbench    = nn_bench
542
543      IF(lwp) THEN                  ! control print
544         WRITE(numout,*)
545         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
546         WRITE(numout,*) '~~~~~~~ '
547         WRITE(numout,*) '   Namelist namcfg'
548         WRITE(numout,*) '      configuration name                               cp_cfg  = ', TRIM(cp_cfg)
549         WRITE(numout,*) '      configuration zoom name                          cp_cfz  = ', TRIM(cp_cfz)
550         WRITE(numout,*) '      configuration resolution                         jp_cfg  = ', jp_cfg
551         WRITE(numout,*) '      1st lateral dimension ( >= jpiglo )              jpidta  = ', jpidta
552         WRITE(numout,*) '      2nd    "         "    ( >= jpjglo )              jpjdta  = ', jpjdta
553         WRITE(numout,*) '      3nd    "         "                               jpkdta  = ', jpkdta
554         WRITE(numout,*) '      1st dimension of global domain in i              jpiglo  = ', jpiglo
555         WRITE(numout,*) '      2nd    -                  -    in j              jpjglo  = ', jpjglo
556         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
557         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
558         WRITE(numout,*) '      lateral cond. type (between 0 and 6)             jperio  = ', jperio   
559         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
560      ENDIF
561      !                             ! Parameter control
562      !
563      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
564         IF( lk_mpp .AND. jpnij > 1 ) THEN
565            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
566         ELSE
567            IF( isplt == 1 .AND. jsplt == 1  ) THEN
568               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
569                  &           ' - the print control will be done over the whole domain' )
570            ENDIF
571            ijsplt = isplt * jsplt            ! total number of processors ijsplt
572         ENDIF
573         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
574         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
575         !
576         !                              ! indices used for the SUM control
577         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
578            lsp_area = .FALSE.
579         ELSE                                             ! print control done over a specific  area
580            lsp_area = .TRUE.
581            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
582               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
583               nictls = 1
584            ENDIF
585            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
586               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
587               nictle = jpiglo
588            ENDIF
589            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
590               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
591               njctls = 1
592            ENDIF
593            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
594               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
595               njctle = jpjglo
596            ENDIF
597         ENDIF
598      ENDIF
599      !
600      IF( nbench == 1 ) THEN              ! Benchmark
601         SELECT CASE ( cp_cfg )
602         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
603         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
604            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
605         END SELECT
606      ENDIF
607      !
608      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
609         &                                               'f2003 standard. '                              ,  &
610         &                                               'Compile with key_nosignedzero enabled' )
611      !
612   END SUBROUTINE nemo_ctl
613
614
615   SUBROUTINE nemo_closefile
616      !!----------------------------------------------------------------------
617      !!                     ***  ROUTINE nemo_closefile  ***
618      !!
619      !! ** Purpose :   Close the files
620      !!----------------------------------------------------------------------
621      !
622      IF( lk_mpp )   CALL mppsync
623      !
624      CALL iom_close                                 ! close all input/output files managed by iom_*
625      !
626      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
627      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
628      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
629      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
630      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
631      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
632      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
633      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
634      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
635      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
636      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
637      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
638      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
639      !
640      numout = 6                                     ! redefine numout in case it is used after this point...
641      !
642   END SUBROUTINE nemo_closefile
643
644
645   SUBROUTINE nemo_alloc
646      !!----------------------------------------------------------------------
647      !!                     ***  ROUTINE nemo_alloc  ***
648      !!
649      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
650      !!
651      !! ** Method  :
652      !!----------------------------------------------------------------------
653      USE diawri    , ONLY: dia_wri_alloc
654      USE dom_oce   , ONLY: dom_oce_alloc
655      USE trc_oce   , ONLY: trc_oce_alloc
656#if defined key_diadct 
657      USE diadct    , ONLY: diadct_alloc 
658#endif 
659#if defined key_bdy
660      USE bdy_oce   , ONLY: bdy_oce_alloc
661#endif
662      !
663      INTEGER :: ierr
664      !!----------------------------------------------------------------------
665      !
666      ierr =        oce_alloc       ()          ! ocean
667      ierr = ierr + dia_wri_alloc   ()
668      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
669      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
670      !
671      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
672      !
673#if defined key_diadct 
674      ierr = ierr + diadct_alloc    ()          !
675#endif 
676#if defined key_bdy
677      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
678#endif
679      !
680      IF( lk_mpp    )   CALL mpp_sum( ierr )
681      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
682      !
683   END SUBROUTINE nemo_alloc
684
685
686   SUBROUTINE nemo_partition( num_pes )
687      !!----------------------------------------------------------------------
688      !!                 ***  ROUTINE nemo_partition  ***
689      !!
690      !! ** Purpose :
691      !!
692      !! ** Method  :
693      !!----------------------------------------------------------------------
694      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
695      !
696      INTEGER, PARAMETER :: nfactmax = 20
697      INTEGER :: nfact ! The no. of factors returned
698      INTEGER :: ierr  ! Error flag
699      INTEGER :: ji
700      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
701      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
702      !!----------------------------------------------------------------------
703      !
704      ierr = 0
705      !
706      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
707      !
708      IF( nfact <= 1 ) THEN
709         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
710         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
711         jpnj = 1
712         jpni = num_pes
713      ELSE
714         ! Search through factors for the pair that are closest in value
715         mindiff = 1000000
716         imin    = 1
717         DO ji = 1, nfact-1, 2
718            idiff = ABS( ifact(ji) - ifact(ji+1) )
719            IF( idiff < mindiff ) THEN
720               mindiff = idiff
721               imin = ji
722            ENDIF
723         END DO
724         jpnj = ifact(imin)
725         jpni = ifact(imin + 1)
726      ENDIF
727      !
728      jpnij = jpni*jpnj
729      !
730   END SUBROUTINE nemo_partition
731
732
733   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
734      !!----------------------------------------------------------------------
735      !!                     ***  ROUTINE factorise  ***
736      !!
737      !! ** Purpose :   return the prime factors of n.
738      !!                knfax factors are returned in array kfax which is of
739      !!                maximum dimension kmaxfax.
740      !! ** Method  :
741      !!----------------------------------------------------------------------
742      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
743      INTEGER                    , INTENT(  out) ::   kerr, knfax
744      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
745      !
746      INTEGER :: ifac, jl, inu
747      INTEGER, PARAMETER :: ntest = 14
748      INTEGER, DIMENSION(ntest) ::   ilfax
749      !!----------------------------------------------------------------------
750      !
751      ! lfax contains the set of allowed factors.
752      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
753      !
754      ! Clear the error flag and initialise output vars
755      kerr  = 0
756      kfax  = 1
757      knfax = 0
758      !
759      ! Find the factors of n.
760      IF( kn == 1 )   GOTO 20
761
762      ! nu holds the unfactorised part of the number.
763      ! knfax holds the number of factors found.
764      ! l points to the allowed factor list.
765      ! ifac holds the current factor.
766      !
767      inu   = kn
768      knfax = 0
769      !
770      DO jl = ntest, 1, -1
771         !
772         ifac = ilfax(jl)
773         IF( ifac > inu )   CYCLE
774
775         ! Test whether the factor will divide.
776
777         IF( MOD(inu,ifac) == 0 ) THEN
778            !
779            knfax = knfax + 1            ! Add the factor to the list
780            IF( knfax > kmaxfax ) THEN
781               kerr = 6
782               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
783               return
784            ENDIF
785            kfax(knfax) = ifac
786            ! Store the other factor that goes with this one
787            knfax = knfax + 1
788            kfax(knfax) = inu / ifac
789            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
790         ENDIF
791         !
792      END DO
793      !
794   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
795      !
796   END SUBROUTINE factorise
797
798#if defined key_mpp_mpi
799
800   SUBROUTINE nemo_northcomms
801      !!----------------------------------------------------------------------
802      !!                     ***  ROUTINE  nemo_northcomms  ***
803      !! ** Purpose :   Setup for north fold exchanges with explicit
804      !!                point-to-point messaging
805      !!
806      !! ** Method :   Initialization of the northern neighbours lists.
807      !!----------------------------------------------------------------------
808      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
809      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
810      !!----------------------------------------------------------------------
811      INTEGER  ::   sxM, dxM, sxT, dxT, jn
812      INTEGER  ::   njmppmax
813      !!----------------------------------------------------------------------
814      !
815      njmppmax = MAXVAL( njmppt )
816      !
817      !initializes the north-fold communication variables
818      isendto(:) = 0
819      nsndto     = 0
820      !
821      !if I am a process in the north
822      IF ( njmpp == njmppmax ) THEN
823          !sxM is the first point (in the global domain) needed to compute the
824          !north-fold for the current process
825          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
826          !dxM is the last point (in the global domain) needed to compute the
827          !north-fold for the current process
828          dxM = jpiglo - nimppt(narea) + 2
829
830          !loop over the other north-fold processes to find the processes
831          !managing the points belonging to the sxT-dxT range
832 
833          DO jn = 1, jpni
834                !sxT is the first point (in the global domain) of the jn
835                !process
836                sxT = nfiimpp(jn, jpnj)
837                !dxT is the last point (in the global domain) of the jn
838                !process
839                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
840                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
841                   nsndto = nsndto + 1
842                     isendto(nsndto) = jn
843                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
844                   nsndto = nsndto + 1
845                     isendto(nsndto) = jn
846                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
847                   nsndto = nsndto + 1
848                     isendto(nsndto) = jn
849                END IF
850          END DO
851          nfsloop = 1
852          nfeloop = nlci
853          DO jn = 2,jpni-1
854           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
855              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
856                 nfsloop = nldi
857              ENDIF
858              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
859                 nfeloop = nlei
860              ENDIF
861           ENDIF
862        END DO
863
864      ENDIF
865      l_north_nogather = .TRUE.
866   END SUBROUTINE nemo_northcomms
867
868#else
869   SUBROUTINE nemo_northcomms      ! Dummy routine
870      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
871   END SUBROUTINE nemo_northcomms
872#endif
873
874   !!======================================================================
875END MODULE nemogcm
876
Note: See TracBrowser for help on using the repository browser.