source: trunk/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 6152

Last change on this file since 6152 was 6152, checked in by acc, 5 years ago

Add wetting and drying option from dev_r5803_NOC_WAD branch. Logically isolated code changes in domvvl.F90, domzgr.F90, dynhpg.F90, dynspg_ts.F90, sshwzv.F90 and nemogcm.F90. New module wet_dry.F90 in DYN. Fully SETTE tested with code deactivated (ln_wad=.false.). No test case yet available to justify activating option (still under development)

  • Property svn:keywords set to Id
File size: 41.6 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE) add nemo_northcomms
31   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
32   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
33   !!             -   ! 2013-06  (I. Epicoco, S. Mocavero, CMCC) nemo_northcomms: setup avoiding MPI communication
34   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
35   !!----------------------------------------------------------------------
36
37   !!----------------------------------------------------------------------
38   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
39   !!   nemo_init     : initialization of the NEMO system
40   !!   nemo_ctl      : initialisation of the contol print
41   !!   nemo_closefile: close remaining open files
42   !!   nemo_alloc    : dynamical allocation
43   !!   nemo_partition: calculate MPP domain decomposition
44   !!   factorise     : calculate the factors of the no. of MPI processes
45   !!----------------------------------------------------------------------
46   USE step_oce       ! module used in the ocean time stepping module (step.F90)
47   USE domcfg         ! domain configuration               (dom_cfg routine)
48   USE mppini         ! shared/distributed memory setting (mpp_init routine)
49   USE domain         ! domain initialization             (dom_init routine)
50#if defined key_nemocice_decomp
51   USE ice_domain_size, only: nx_global, ny_global
52#endif
53   USE tideini        ! tidal components initialization   (tide_ini routine)
54   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
55   USE bdydta         ! open boundary cond. setting   (bdy_dta_init routine)
56   USE bdytides       ! open boundary cond. setting   (bdytide_init routine)
57   USE sbctide, ONLY  : lk_tide
58   USE istate         ! initial state setting          (istate_init routine)
59   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
60   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
61   USE zdfini         ! vertical physics setting          (zdf_init routine)
62   USE phycst         ! physical constant                  (par_cst routine)
63   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
64   USE asminc         ! assimilation increments     
65   USE asmbkg         ! writing out state trajectory
66   USE diaptr         ! poleward transports           (dia_ptr_init routine)
67   USE diadct         ! sections transports           (dia_dct_init routine)
68   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
69   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
70   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
71   USE step           ! NEMO time-stepping                 (stp     routine)
72   USE icbini         ! handle bergs, initialisation
73   USE icbstp         ! handle bergs, calving, themodynamics and transport
74   USE cpl_oasis3     ! OASIS3 coupling
75   USE c1d            ! 1D configuration
76   USE step_c1d       ! Time stepping loop for the 1D configuration
77   USE dyndmp         ! Momentum damping
78   USE stopar         ! Stochastic param.: ???
79   USE stopts         ! Stochastic param.: ???
80#if defined key_top
81   USE trcini         ! passive tracer initialisation
82#endif
83   USE lib_mpp        ! distributed memory computing
84   USE diurnal_bulk    ! diurnal bulk SST
85   USE step_diu        ! diurnal bulk SST timestepping (called from here if run offline)
86#if defined key_iomput
87   USE xios           ! xIOserver
88#endif
89   USE crsini         ! initialise grid coarsening utility
90   USE lbcnfd , ONLY  : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
91   USE sbc_oce, ONLY  : lk_oasis
92   USE diatmb          ! Top,middle,bottom output
93   USE dia25h          ! 25h mean output
94   USE wet_dry         ! Wetting and drying setting   (wad_init routine)
95
96   IMPLICIT NONE
97   PRIVATE
98
99   PUBLIC   nemo_gcm    ! called by model.F90
100   PUBLIC   nemo_init   ! needed by AGRIF
101   PUBLIC   nemo_alloc  ! needed by TAM
102
103   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
104
105   !!----------------------------------------------------------------------
106   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
107   !! $Id$
108   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
109   !!----------------------------------------------------------------------
110CONTAINS
111
112   SUBROUTINE nemo_gcm
113      !!----------------------------------------------------------------------
114      !!                     ***  ROUTINE nemo_gcm  ***
115      !!
116      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
117      !!              curvilinear mesh on the sphere.
118      !!
119      !! ** Method  : - model general initialization
120      !!              - launch the time-stepping (stp routine)
121      !!              - finalize the run by closing files and communications
122      !!
123      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
124      !!              Madec, 2008, internal report, IPSL.
125      !!----------------------------------------------------------------------
126      INTEGER ::   istp       ! time step index
127      !!----------------------------------------------------------------------
128      !
129#if defined key_agrif
130      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
131#endif
132
133      !                            !-----------------------!
134      CALL nemo_init               !==  Initialisations  ==!
135      !                            !-----------------------!
136#if defined key_agrif
137      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
138      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
139# if defined key_top
140      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
141# endif
142# if defined key_lim2
143      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
144# endif
145#endif
146      ! check that all process are still there... If some process have an error,
147      ! they will never enter in step and other processes will wait until the end of the cpu time!
148      IF( lk_mpp )   CALL mpp_max( nstop )
149
150      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
151
152      !                            !-----------------------!
153      !                            !==   time stepping   ==!
154      !                            !-----------------------!
155      istp = nit000
156#if defined key_c1d
157         DO WHILE ( istp <= nitend .AND. nstop == 0 )
158            CALL stp_c1d( istp )
159            istp = istp + 1
160         END DO
161#else
162          IF( lk_asminc ) THEN
163             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
164             IF( ln_asmdin ) THEN                        ! Direct initialization
165                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
166                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
167                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
168             ENDIF
169          ENDIF
170
171#if defined key_agrif
172          CALL Agrif_Regrid()
173#endif
174
175         DO WHILE ( istp <= nitend .AND. nstop == 0 )
176#if defined key_agrif
177            CALL stp                         ! AGRIF: time stepping
178#else
179            IF ( .NOT. ln_diurnal_only ) THEN
180               CALL stp( istp )                 ! standard time stepping
181            ELSE
182               CALL stp_diurnal( istp )        ! time step only the diurnal SST
183            ENDIF 
184#endif
185            istp = istp + 1
186            IF( lk_mpp )   CALL mpp_max( nstop )
187         END DO
188#endif
189
190      IF( ln_diaobs   )   CALL dia_obs_wri
191      !
192      IF( ln_icebergs )   CALL icb_end( nitend )
193
194      !                            !------------------------!
195      !                            !==  finalize the run  ==!
196      !                            !------------------------!
197      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
198      !
199      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
200         WRITE(numout,cform_err)
201         WRITE(numout,*) nstop, ' error have been found'
202      ENDIF
203      !
204#if defined key_agrif
205      IF( .NOT. Agrif_Root() ) THEN
206                         CALL Agrif_ParentGrid_To_ChildGrid()
207         IF( ln_diaobs ) CALL dia_obs_wri
208         IF( nn_timing == 1 )   CALL timing_finalize
209                                CALL Agrif_ChildGrid_To_ParentGrid()
210      ENDIF
211#endif
212      IF( nn_timing == 1 )   CALL timing_finalize
213      !
214      CALL nemo_closefile
215      !
216#if defined key_iomput
217      CALL xios_finalize                  ! end mpp communications with xios
218      IF( lk_oasis )   CALL cpl_finalize  ! end coupling and mpp communications with OASIS
219#else
220      IF( lk_oasis ) THEN
221         CALL cpl_finalize              ! end coupling and mpp communications with OASIS
222      ELSE
223         IF( lk_mpp )   CALL mppstop    ! end mpp communications
224      ENDIF
225#endif
226      !
227   END SUBROUTINE nemo_gcm
228
229
230   SUBROUTINE nemo_init
231      !!----------------------------------------------------------------------
232      !!                     ***  ROUTINE nemo_init  ***
233      !!
234      !! ** Purpose :   initialization of the NEMO GCM
235      !!----------------------------------------------------------------------
236      INTEGER ::   ji            ! dummy loop indices
237      INTEGER ::   ilocal_comm   ! local integer
238      INTEGER ::   ios
239      CHARACTER(len=80), DIMENSION(16) ::   cltxt
240      !
241      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
242         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
243         &             nn_bench, nn_timing, nn_diacfl
244      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
245         &             jpizoom, jpjzoom, jperio, ln_use_jattr
246      !!----------------------------------------------------------------------
247      !
248      cltxt = ''
249      cxios_context = 'nemo'
250      !
251      !                             ! Open reference namelist and configuration namelist files
252      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
253      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
254      !
255      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
256      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
257901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
258
259      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
260      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
261902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
262
263      !
264      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
265      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
266903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
267
268      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
269      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
270904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
271
272! Force values for AGRIF zoom (cf. agrif_user.F90)
273#if defined key_agrif
274   IF( .NOT. Agrif_Root() ) THEN
275      jpiglo  = nbcellsx + 2 + 2*nbghostcells
276      jpjglo  = nbcellsy + 2 + 2*nbghostcells
277      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
278      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
279      jpidta  = jpiglo
280      jpjdta  = jpjglo
281      jpizoom = 1
282      jpjzoom = 1
283      nperio  = 0
284      jperio  = 0
285      ln_use_jattr = .false.
286   ENDIF
287#endif
288      !
289      !                             !--------------------------------------------!
290      !                             !  set communicator & select the local node  !
291      !                             !  NB: mynode also opens output.namelist.dyn !
292      !                             !      on unit number numond on first proc   !
293      !                             !--------------------------------------------!
294#if defined key_iomput
295      IF( Agrif_Root() ) THEN
296         IF( lk_oasis ) THEN
297            CALL cpl_init( "oceanx", ilocal_comm )                     ! nemo local communicator given by oasis
298            CALL xios_initialize( "not used",local_comm=ilocal_comm )    ! send nemo communicator to xios
299         ELSE
300            CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
301         ENDIF
302      ENDIF
303      ! Nodes selection (control print return in cltxt)
304      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
305#else
306      IF( lk_oasis ) THEN
307         IF( Agrif_Root() ) THEN
308            CALL cpl_init( "oceanx", ilocal_comm )                      ! nemo local communicator given by oasis
309         ENDIF
310         ! Nodes selection (control print return in cltxt)
311         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
312      ELSE
313         ilocal_comm = 0
314         ! Nodes selection (control print return in cltxt)
315         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
316      ENDIF
317#endif
318      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
319
320      lwm = (narea == 1)                                    ! control of output namelists
321      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
322
323      IF(lwm) THEN
324         ! write merged namelists from earlier to output namelist now that the
325         ! file has been opened in call to mynode. nammpp has already been
326         ! written in mynode (if lk_mpp_mpi)
327         WRITE( numond, namctl )
328         WRITE( numond, namcfg )
329      ENDIF
330
331      ! If dimensions of processor grid weren't specified in the namelist file
332      ! then we calculate them here now that we have our communicator size
333      IF( jpni < 1 .OR. jpnj < 1 ) THEN
334#if   defined key_mpp_mpi
335         IF( Agrif_Root() )   CALL nemo_partition( mppsize )
336#else
337         jpni  = 1
338         jpnj  = 1
339         jpnij = jpni*jpnj
340#endif
341      ENDIF
342
343      ! Calculate domain dimensions given calculated jpni and jpnj
344      ! This used to be done in par_oce.F90 when they were parameters rather than variables
345      IF( Agrif_Root() ) THEN
346#if defined key_nemocice_decomp
347         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci    ! first  dim.
348         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj    ! second dim.
349#else
350         jpi = ( jpiglo     -2*jpreci + (jpni-1) ) / jpni + 2*jpreci    ! first  dim.
351         jpj = ( jpjglo     -2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj    ! second dim.
352#endif
353      ENDIF         
354         jpk = jpkdta                                             ! third dim
355#if defined key_agrif
356         ! simple trick to use same vertical grid as parent but different number of levels:
357         ! Save maximum number of levels in jpkdta, then define all vertical grids with this number.
358         ! Suppress once vertical online interpolation is ok
359         IF(.NOT.Agrif_Root())   jpkdta = Agrif_Parent( jpkdta )
360#endif
361         jpim1 = jpi-1                                            ! inner domain indices
362         jpjm1 = jpj-1                                            !   "           "
363         jpkm1 = jpk-1                                            !   "           "
364         jpij  = jpi*jpj                                          !  jpi x j
365
366      IF(lwp) THEN                            ! open listing units
367         !
368         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
369         !
370         WRITE(numout,*)
371         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
372         WRITE(numout,*) '                       NEMO team'
373         WRITE(numout,*) '            Ocean General Circulation Model'
374         WRITE(numout,*) '                  version 3.7  (2015) '
375         WRITE(numout,*)
376         WRITE(numout,*)
377         DO ji = 1, SIZE(cltxt)
378            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
379         END DO
380         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
381         !
382      ENDIF
383
384      ! Now we know the dimensions of the grid and numout has been set we can
385      ! allocate arrays
386      CALL nemo_alloc()
387
388      !                             !-------------------------------!
389      !                             !  NEMO general initialization  !
390      !                             !-------------------------------!
391
392      CALL nemo_ctl                          ! Control prints & Benchmark
393
394      !                                      ! Domain decomposition
395      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
396      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
397      ENDIF
398      !
399      IF( nn_timing == 1 )  CALL timing_init
400      !
401      !                                      ! General initialization
402                            CALL     phy_cst    ! Physical constants
403                            CALL     eos_init   ! Equation of state
404      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
405                            CALL     wad_init   ! Wetting and drying options
406                            CALL     dom_cfg    ! Domain configuration
407                            CALL     dom_init   ! Domain
408      IF( ln_crs        )   CALL     crs_init   ! coarsened grid: domain initialization
409      IF( ln_nnogather )    CALL nemo_northcomms! northfold neighbour lists (must be done after the masks are defined)
410      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
411     
412      CALL diurnal_sst_bulk_init            ! diurnal sst
413      IF ( ln_diurnal ) CALL diurnal_sst_coolskin_init   ! cool skin   
414     
415      ! IF ln_diurnal_only, then we only want a subset of the initialisation routines
416      IF ( ln_diurnal_only ) THEN
417         CALL  istate_init   ! ocean initial state (Dynamics and tracers)
418         CALL     sbc_init   ! Forcings : surface module
419         CALL tra_qsr_init   ! penetrative solar radiation qsr
420         IF( ln_diaobs     ) THEN                  ! Observation & model comparison
421            CALL dia_obs_init            ! Initialize observational data
422            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
423         ENDIF     
424         !                                     ! Assimilation increments
425         IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
426                 
427         IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
428         RETURN
429      ENDIF
430     
431                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
432
433      !                                      ! external forcing
434!!gm to be added : creation and call of sbc_apr_init
435      IF( lk_tide       )   CALL    tide_init   ! tidal harmonics
436                            CALL     sbc_init   ! surface boundary conditions (including sea-ice)
437!!gm ==>> bdy_init should call bdy_dta_init and bdytide_init  NOT in nemogcm !!!
438      IF( lk_bdy        )   CALL     bdy_init   ! Open boundaries initialisation
439      IF( lk_bdy        )   CALL bdy_dta_init   ! Open boundaries initialisation of external data arrays
440      IF( lk_bdy .AND. lk_tide )   &
441         &                  CALL bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
442         
443      !                                      ! Ocean physics
444      !                                         ! Vertical physics
445                            CALL     zdf_init      ! namelist read
446                            CALL zdf_bfr_init      ! bottom friction
447      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
448      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
449      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
450      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
451      IF( lk_zdfddm     )   CALL zdf_ddm_init      ! double diffusive mixing
452         
453      !                                         ! Lateral physics
454                            CALL ldf_tra_init      ! Lateral ocean tracer physics
455                            CALL ldf_eiv_init      ! eddy induced velocity param.
456                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
457
458      !                                         ! Active tracers
459                            CALL tra_qsr_init      ! penetrative solar radiation qsr
460                            CALL tra_bbc_init      ! bottom heat flux
461      IF( lk_trabbl     )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
462                            CALL tra_dmp_init      ! internal tracer damping
463                            CALL tra_adv_init      ! horizontal & vertical advection
464                            CALL tra_ldf_init      ! lateral mixing
465                            CALL tra_zdf_init      ! vertical mixing and after tracer fields
466
467      !                                         ! Dynamics
468      IF( lk_c1d        )   CALL dyn_dmp_init      ! internal momentum damping
469                            CALL dyn_adv_init      ! advection (vector or flux form)
470                            CALL dyn_vor_init      ! vorticity term including Coriolis
471                            CALL dyn_ldf_init      ! lateral mixing
472                            CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
473                            CALL dyn_zdf_init      ! vertical diffusion
474                            CALL dyn_spg_init      ! surface pressure gradient
475
476#if defined key_top
477      !                                      ! Passive tracers
478                            CALL     trc_init
479#endif
480      IF( l_ldfslp      )   CALL ldf_slp_init   ! slope of lateral mixing
481
482      !                                      ! Icebergs
483                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
484
485      !                                      ! Misc. options
486                            CALL sto_par_init   ! Stochastic parametrization
487      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
488     
489      !                                      ! Diagnostics
490      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
491                            CALL dia_cfl_init   ! Initialise CFL diagnostics
492      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
493                            CALL dia_ptr_init   ! Poleward TRansports initialization
494      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
495                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
496                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
497                            CALL dia_obs_init            ! Initialize observational data
498      IF( ln_diaobs     )   CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
499
500      !                                         ! Assimilation increments
501      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
502      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
503                            CALL dia_tmb_init  ! TMB outputs
504                            CALL dia_25h_init  ! 25h mean  outputs
505
506      !
507   END SUBROUTINE nemo_init
508
509
510   SUBROUTINE nemo_ctl
511      !!----------------------------------------------------------------------
512      !!                     ***  ROUTINE nemo_ctl  ***
513      !!
514      !! ** Purpose :   control print setting
515      !!
516      !! ** Method  : - print namctl information and check some consistencies
517      !!----------------------------------------------------------------------
518      !
519      IF(lwp) THEN                  ! control print
520         WRITE(numout,*)
521         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
522         WRITE(numout,*) '~~~~~~~ '
523         WRITE(numout,*) '   Namelist namctl'
524         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
525         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
526         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
527         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
528         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
529         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
530         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
531         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
532         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
533         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
534      ENDIF
535      !
536      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
537      nictls    = nn_ictls
538      nictle    = nn_ictle
539      njctls    = nn_jctls
540      njctle    = nn_jctle
541      isplt     = nn_isplt
542      jsplt     = nn_jsplt
543      nbench    = nn_bench
544
545      IF(lwp) THEN                  ! control print
546         WRITE(numout,*)
547         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
548         WRITE(numout,*) '~~~~~~~ '
549         WRITE(numout,*) '   Namelist namcfg'
550         WRITE(numout,*) '      configuration name                               cp_cfg  = ', TRIM(cp_cfg)
551         WRITE(numout,*) '      configuration zoom name                          cp_cfz  = ', TRIM(cp_cfz)
552         WRITE(numout,*) '      configuration resolution                         jp_cfg  = ', jp_cfg
553         WRITE(numout,*) '      1st lateral dimension ( >= jpiglo )              jpidta  = ', jpidta
554         WRITE(numout,*) '      2nd    "         "    ( >= jpjglo )              jpjdta  = ', jpjdta
555         WRITE(numout,*) '      3nd    "         "                               jpkdta  = ', jpkdta
556         WRITE(numout,*) '      1st dimension of global domain in i              jpiglo  = ', jpiglo
557         WRITE(numout,*) '      2nd    -                  -    in j              jpjglo  = ', jpjglo
558         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
559         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
560         WRITE(numout,*) '      lateral cond. type (between 0 and 6)             jperio  = ', jperio   
561         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
562      ENDIF
563      !                             ! Parameter control
564      !
565      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
566         IF( lk_mpp .AND. jpnij > 1 ) THEN
567            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
568         ELSE
569            IF( isplt == 1 .AND. jsplt == 1  ) THEN
570               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
571                  &           ' - the print control will be done over the whole domain' )
572            ENDIF
573            ijsplt = isplt * jsplt            ! total number of processors ijsplt
574         ENDIF
575         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
576         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
577         !
578         !                              ! indices used for the SUM control
579         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
580            lsp_area = .FALSE.
581         ELSE                                             ! print control done over a specific  area
582            lsp_area = .TRUE.
583            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
584               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
585               nictls = 1
586            ENDIF
587            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
588               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
589               nictle = jpiglo
590            ENDIF
591            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
592               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
593               njctls = 1
594            ENDIF
595            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
596               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
597               njctle = jpjglo
598            ENDIF
599         ENDIF
600      ENDIF
601      !
602      IF( nbench == 1 ) THEN              ! Benchmark
603         SELECT CASE ( cp_cfg )
604         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
605         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
606            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
607         END SELECT
608      ENDIF
609      !
610      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
611         &                                               'f2003 standard. '                              ,  &
612         &                                               'Compile with key_nosignedzero enabled' )
613      !
614   END SUBROUTINE nemo_ctl
615
616
617   SUBROUTINE nemo_closefile
618      !!----------------------------------------------------------------------
619      !!                     ***  ROUTINE nemo_closefile  ***
620      !!
621      !! ** Purpose :   Close the files
622      !!----------------------------------------------------------------------
623      !
624      IF( lk_mpp )   CALL mppsync
625      !
626      CALL iom_close                                 ! close all input/output files managed by iom_*
627      !
628      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
629      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
630      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
631      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
632      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
633      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
634      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
635      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
636      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
637      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
638      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
639      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
640      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
641      !
642      numout = 6                                     ! redefine numout in case it is used after this point...
643      !
644   END SUBROUTINE nemo_closefile
645
646
647   SUBROUTINE nemo_alloc
648      !!----------------------------------------------------------------------
649      !!                     ***  ROUTINE nemo_alloc  ***
650      !!
651      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
652      !!
653      !! ** Method  :
654      !!----------------------------------------------------------------------
655      USE diawri    , ONLY: dia_wri_alloc
656      USE dom_oce   , ONLY: dom_oce_alloc
657      USE trc_oce   , ONLY: trc_oce_alloc
658#if defined key_diadct 
659      USE diadct    , ONLY: diadct_alloc 
660#endif 
661#if defined key_bdy
662      USE bdy_oce   , ONLY: bdy_oce_alloc
663#endif
664      !
665      INTEGER :: ierr
666      !!----------------------------------------------------------------------
667      !
668      ierr =        oce_alloc       ()          ! ocean
669      ierr = ierr + dia_wri_alloc   ()
670      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
671      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
672      !
673      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
674      !
675#if defined key_diadct 
676      ierr = ierr + diadct_alloc    ()          !
677#endif 
678#if defined key_bdy
679      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
680#endif
681      !
682      IF( lk_mpp    )   CALL mpp_sum( ierr )
683      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
684      !
685   END SUBROUTINE nemo_alloc
686
687
688   SUBROUTINE nemo_partition( num_pes )
689      !!----------------------------------------------------------------------
690      !!                 ***  ROUTINE nemo_partition  ***
691      !!
692      !! ** Purpose :
693      !!
694      !! ** Method  :
695      !!----------------------------------------------------------------------
696      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
697      !
698      INTEGER, PARAMETER :: nfactmax = 20
699      INTEGER :: nfact ! The no. of factors returned
700      INTEGER :: ierr  ! Error flag
701      INTEGER :: ji
702      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
703      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
704      !!----------------------------------------------------------------------
705      !
706      ierr = 0
707      !
708      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
709      !
710      IF( nfact <= 1 ) THEN
711         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
712         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
713         jpnj = 1
714         jpni = num_pes
715      ELSE
716         ! Search through factors for the pair that are closest in value
717         mindiff = 1000000
718         imin    = 1
719         DO ji = 1, nfact-1, 2
720            idiff = ABS( ifact(ji) - ifact(ji+1) )
721            IF( idiff < mindiff ) THEN
722               mindiff = idiff
723               imin = ji
724            ENDIF
725         END DO
726         jpnj = ifact(imin)
727         jpni = ifact(imin + 1)
728      ENDIF
729      !
730      jpnij = jpni*jpnj
731      !
732   END SUBROUTINE nemo_partition
733
734
735   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
736      !!----------------------------------------------------------------------
737      !!                     ***  ROUTINE factorise  ***
738      !!
739      !! ** Purpose :   return the prime factors of n.
740      !!                knfax factors are returned in array kfax which is of
741      !!                maximum dimension kmaxfax.
742      !! ** Method  :
743      !!----------------------------------------------------------------------
744      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
745      INTEGER                    , INTENT(  out) ::   kerr, knfax
746      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
747      !
748      INTEGER :: ifac, jl, inu
749      INTEGER, PARAMETER :: ntest = 14
750      INTEGER, DIMENSION(ntest) ::   ilfax
751      !!----------------------------------------------------------------------
752      !
753      ! lfax contains the set of allowed factors.
754      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
755      !
756      ! Clear the error flag and initialise output vars
757      kerr  = 0
758      kfax  = 1
759      knfax = 0
760      !
761      ! Find the factors of n.
762      IF( kn == 1 )   GOTO 20
763
764      ! nu holds the unfactorised part of the number.
765      ! knfax holds the number of factors found.
766      ! l points to the allowed factor list.
767      ! ifac holds the current factor.
768      !
769      inu   = kn
770      knfax = 0
771      !
772      DO jl = ntest, 1, -1
773         !
774         ifac = ilfax(jl)
775         IF( ifac > inu )   CYCLE
776
777         ! Test whether the factor will divide.
778
779         IF( MOD(inu,ifac) == 0 ) THEN
780            !
781            knfax = knfax + 1            ! Add the factor to the list
782            IF( knfax > kmaxfax ) THEN
783               kerr = 6
784               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
785               return
786            ENDIF
787            kfax(knfax) = ifac
788            ! Store the other factor that goes with this one
789            knfax = knfax + 1
790            kfax(knfax) = inu / ifac
791            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
792         ENDIF
793         !
794      END DO
795      !
796   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
797      !
798   END SUBROUTINE factorise
799
800#if defined key_mpp_mpi
801
802   SUBROUTINE nemo_northcomms
803      !!----------------------------------------------------------------------
804      !!                     ***  ROUTINE  nemo_northcomms  ***
805      !! ** Purpose :   Setup for north fold exchanges with explicit
806      !!                point-to-point messaging
807      !!
808      !! ** Method :   Initialization of the northern neighbours lists.
809      !!----------------------------------------------------------------------
810      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
811      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
812      !!----------------------------------------------------------------------
813      INTEGER  ::   sxM, dxM, sxT, dxT, jn
814      INTEGER  ::   njmppmax
815      !!----------------------------------------------------------------------
816      !
817      njmppmax = MAXVAL( njmppt )
818      !
819      !initializes the north-fold communication variables
820      isendto(:) = 0
821      nsndto     = 0
822      !
823      !if I am a process in the north
824      IF ( njmpp == njmppmax ) THEN
825          !sxM is the first point (in the global domain) needed to compute the
826          !north-fold for the current process
827          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
828          !dxM is the last point (in the global domain) needed to compute the
829          !north-fold for the current process
830          dxM = jpiglo - nimppt(narea) + 2
831
832          !loop over the other north-fold processes to find the processes
833          !managing the points belonging to the sxT-dxT range
834 
835          DO jn = 1, jpni
836                !sxT is the first point (in the global domain) of the jn
837                !process
838                sxT = nfiimpp(jn, jpnj)
839                !dxT is the last point (in the global domain) of the jn
840                !process
841                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
842                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
843                   nsndto = nsndto + 1
844                     isendto(nsndto) = jn
845                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
846                   nsndto = nsndto + 1
847                     isendto(nsndto) = jn
848                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
849                   nsndto = nsndto + 1
850                     isendto(nsndto) = jn
851                END IF
852          END DO
853          nfsloop = 1
854          nfeloop = nlci
855          DO jn = 2,jpni-1
856           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
857              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
858                 nfsloop = nldi
859              ENDIF
860              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
861                 nfeloop = nlei
862              ENDIF
863           ENDIF
864        END DO
865
866      ENDIF
867      l_north_nogather = .TRUE.
868   END SUBROUTINE nemo_northcomms
869
870#else
871   SUBROUTINE nemo_northcomms      ! Dummy routine
872      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
873   END SUBROUTINE nemo_northcomms
874#endif
875
876   !!======================================================================
877END MODULE nemogcm
878
Note: See TracBrowser for help on using the repository browser.