New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in trunk/NEMOGCM/NEMO/SAS_SRC – NEMO

source: trunk/NEMOGCM/NEMO/SAS_SRC/sbcssm.F90 @ 3903

Last change on this file since 3903 was 3903, checked in by clevy, 11 years ago

Bugfix for ORCA2_SAS_LIM reference configuration, see ticket#1095

File size: 13.9 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Off-line : interpolation of the physical fields
5   !!======================================================================
6   !! History :
7   !!   NEMO         3.4  ! 2012-03 First version by S. Alderson
8   !!                     !         Heavily derived from Christian's dtadyn routine
9   !!                     !         in OFF_SRC
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   sbc_ssm_init : initialization, namelist read, and SAVEs control
14   !!   sbc_ssm      : Interpolation of the fields
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers variables
17   USE c1d             ! 1D configuration: lk_c1d
18   USE dom_oce         ! ocean domain: variables
19   USE zdf_oce         ! ocean vertical physics: variables
20   USE sbc_oce         ! surface module: variables
21   USE phycst          ! physical constants
22   USE eosbn2          ! equation of state - Brunt Vaisala frequency
23   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
24   USE zpshde          ! z-coord. with partial steps: horizontal derivatives
25   USE in_out_manager  ! I/O manager
26   USE iom             ! I/O library
27   USE lib_mpp         ! distributed memory computing library
28   USE prtctl          ! print control
29   USE fldread         ! read input fields
30   USE timing          ! Timing
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   sbc_ssm_init   ! called by sbc_init
36   PUBLIC   sbc_ssm        ! called by sbc
37
38   CHARACTER(len=100)   ::   cn_dir     = './'    !: Root directory for location of ssm files
39   LOGICAL              ::   ln_3d_uv   = .true.  !: specify whether input velocity data is 3D
40   INTEGER  , SAVE      ::   nfld_3d
41   INTEGER  , SAVE      ::   nfld_2d
42
43   INTEGER  , PARAMETER ::   jpfld_3d = 4   ! maximum number of files to read
44   INTEGER  , PARAMETER ::   jpfld_2d = 1   ! maximum number of files to read
45   INTEGER  , SAVE      ::   jf_tem         ! index of temperature
46   INTEGER  , SAVE      ::   jf_sal         ! index of salinity
47   INTEGER  , SAVE      ::   jf_usp         ! index of u velocity component
48   INTEGER  , SAVE      ::   jf_vsp         ! index of v velocity component
49   INTEGER  , SAVE      ::   jf_ssh         ! index of sea surface height
50
51   TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_ssm_3d  ! structure of input fields (file information, fields read)
52   TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_ssm_2d  ! structure of input fields (file information, fields read)
53
54   !! * Substitutions
55#  include "domzgr_substitute.h90"
56#  include "vectopt_loop_substitute.h90"
57   !!----------------------------------------------------------------------
58   !! NEMO/OFF 3.3 , NEMO Consortium (2010)
59   !! $Id: sbcssm.F90 3294 2012-01-28 16:44:18Z rblod $
60   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
61   !!----------------------------------------------------------------------
62CONTAINS
63
64   SUBROUTINE sbc_ssm( kt )
65      !!----------------------------------------------------------------------
66      !!                  ***  ROUTINE sbc_ssm  ***
67      !!
68      !! ** Purpose :  Prepares dynamics and physics fields from a NEMO run
69      !!               for an off-line simulation using surface processes only
70      !!
71      !! ** Method : calculates the position of data
72      !!             - interpolates data if needed
73      !!----------------------------------------------------------------------
74      !
75      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
76      !
77      INTEGER  ::   ji, jj     ! dummy loop indices
78      REAL(wp) ::   ztinta     ! ratio applied to after  records when doing time interpolation
79      REAL(wp) ::   ztintb     ! ratio applied to before records when doing time interpolation
80      !!----------------------------------------------------------------------
81     
82      !
83      IF (kt == nn_it000 ) CALL sbc_ssm_init()
84
85      IF( nn_timing == 1 )  CALL timing_start( 'sbc_ssm')
86
87      IF( nfld_3d > 0 ) CALL fld_read( kt, 1, sf_ssm_3d )      !==   read data at kt time step   ==!
88      IF( nfld_2d > 0 ) CALL fld_read( kt, 1, sf_ssm_2d )      !==   read data at kt time step   ==!
89      !
90      IF( ln_3d_uv ) THEN
91         ssu_m(:,:) = sf_ssm_3d(jf_usp)%fnow(:,:,1) * umask(:,:,1)    ! u-velocity
92         ssv_m(:,:) = sf_ssm_3d(jf_vsp)%fnow(:,:,1) * vmask(:,:,1)    ! v-velocity
93      ELSE
94         ssu_m(:,:) = sf_ssm_2d(jf_usp)%fnow(:,:,1) * umask(:,:,1)    ! u-velocity
95         ssv_m(:,:) = sf_ssm_2d(jf_vsp)%fnow(:,:,1) * vmask(:,:,1)    ! v-velocity
96      ENDIF
97      !
98      sst_m(:,:) = sf_ssm_2d(jf_tem)%fnow(:,:,1) * tmask(:,:,1)    ! temperature
99      sss_m(:,:) = sf_ssm_2d(jf_sal)%fnow(:,:,1) * tmask(:,:,1)    ! salinity
100      ssh_m(:,:) = sf_ssm_2d(jf_ssh)%fnow(:,:,1) * tmask(:,:,1)    ! sea surface height
101      !
102      tsn(:,:,1,jp_tem) = sst_m(:,:)
103      tsn(:,:,1,jp_sal) = sss_m(:,:)
104      IF ( nn_ice == 1 ) THEN
105         tsb(:,:,1,jp_tem) = sst_m(:,:)
106         tsb(:,:,1,jp_sal) = sss_m(:,:)
107      ENDIF
108      ub (:,:,1       ) = ssu_m(:,:)
109      vb (:,:,1       ) = ssv_m(:,:)
110
111      IF(ln_ctl) THEN                  ! print control
112         CALL prt_ctl(tab2d_1=sst_m, clinfo1=' sst_m   - : ', mask1=tmask, ovlap=1   )
113         CALL prt_ctl(tab2d_1=sss_m, clinfo1=' sss_m   - : ', mask1=tmask, ovlap=1   )
114         CALL prt_ctl(tab2d_1=ssu_m, clinfo1=' ssu_m   - : ', mask1=umask, ovlap=1   )
115         CALL prt_ctl(tab2d_1=ssv_m, clinfo1=' ssv_m   - : ', mask1=vmask, ovlap=1   )
116         CALL prt_ctl(tab2d_1=ssh_m, clinfo1=' ssh_m   - : ', mask1=tmask, ovlap=1   )
117      ENDIF
118      !
119      IF( nn_timing == 1 )  CALL timing_stop( 'sbc_ssm')
120      !
121   END SUBROUTINE sbc_ssm
122
123
124   SUBROUTINE sbc_ssm_init
125      !!----------------------------------------------------------------------
126      !!                  ***  ROUTINE sbc_ssm_init  ***
127      !!
128      !! ** Purpose :   Initialisation of the dynamical data     
129      !! ** Method  : - read the data namsbc_ssm namelist
130      !!
131      !! ** Action  : - read parameters
132      !!----------------------------------------------------------------------
133      INTEGER  :: ierr, ierr0, ierr1, ierr2, ierr3   ! return error code
134      INTEGER  :: ifpr                               ! dummy loop indice
135      INTEGER  :: inum, idv, idimv, jpm              ! local integer
136      !!
137      CHARACTER(len=100)                     ::  cn_dir       ! Root directory for location of core files
138      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::  slf_3d       ! array of namelist information on the fields to read
139      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::  slf_2d       ! array of namelist information on the fields to read
140      TYPE(FLD_N) :: sn_tem, sn_sal                     ! information about the fields to be read
141      TYPE(FLD_N) :: sn_usp, sn_vsp, sn_ssh
142      !
143      NAMELIST/namsbc_sas/cn_dir, ln_3d_uv, sn_tem, sn_sal, sn_usp, sn_vsp, sn_ssh
144
145      !!----------------------------------------------------------------------
146      !                                   ! ============
147      !                                   !   Namelist
148      !                                   ! ============
149      ! (NB: frequency positive => hours, negative => months)
150      !                !   file      ! frequency !  variable  ! time intep !  clim  ! 'yearly' or ! weights  ! rotation   !
151      !                !   name      !  (hours)  !   name     !   (T/F)    !  (T/F) !  'monthly'  ! filename ! pairs      !
152      sn_usp  = FLD_N( 'ssm_grid_U' ,    120    , 'vozocrtx' ,  .true.    , .true. ,   'yearly'  , ''       , ''         )
153      sn_vsp  = FLD_N( 'ssm_grid_V' ,    120    , 'vomecrty' ,  .true.    , .true. ,   'yearly'  , ''       , ''         )
154      sn_tem  = FLD_N( 'ssm_grid_T' ,    120    , 'sosstsst' ,  .true.    , .true. ,   'yearly'  , ''       , ''         )
155      sn_sal  = FLD_N( 'ssm_grid_T' ,    120    , 'sosaline' ,  .true.    , .true. ,   'yearly'  , ''       , ''         )
156      sn_ssh  = FLD_N( 'ssm_grid_T' ,    120    , 'sossheig' ,  .true.    , .true. ,   'yearly'  , ''       , ''         )
157      !
158      REWIND( numnam )                          ! read in namlist namsbc_ssm
159      READ  ( numnam, namsbc_sas )
160      !                                         ! store namelist information in an array
161      !                                         ! Control print
162      IF(lwp) THEN
163         WRITE(numout,*)
164         WRITE(numout,*) 'sbc_sas : standalone surface scheme '
165         WRITE(numout,*) '~~~~~~~~~~~ '
166         WRITE(numout,*) '   Namelist namsbc_sas'
167         WRITE(numout,*)
168      ENDIF
169     
170      !
171      !! switch off stuff that isn't sensible with a standalone module
172      !! note that we need sbc_ssm called first in sbc
173      !
174      IF( ln_cpl ) THEN
175         IF( lwp ) WRITE(numout,*) 'Coupled mode not sensible with StandAlone Surface scheme'
176         ln_cpl = .FALSE.
177      ENDIF
178      IF( ln_apr_dyn ) THEN
179         IF( lwp ) WRITE(numout,*) 'No atmospheric gradient needed with StandAlone Surface scheme'
180         ln_apr_dyn = .FALSE.
181      ENDIF
182      IF( ln_dm2dc ) THEN
183         IF( lwp ) WRITE(numout,*) 'No diurnal cycle needed with StandAlone Surface scheme'
184         ln_dm2dc = .FALSE.
185      ENDIF
186      IF( ln_rnf ) THEN
187         IF( lwp ) WRITE(numout,*) 'No runoff needed with StandAlone Surface scheme'
188         ln_rnf = .FALSE.
189      ENDIF
190      IF( ln_ssr ) THEN
191         IF( lwp ) WRITE(numout,*) 'No surface relaxation needed with StandAlone Surface scheme'
192         ln_ssr = .FALSE.
193      ENDIF
194      IF( nn_fwb > 0 ) THEN
195         IF( lwp ) WRITE(numout,*) 'No freshwater budget adjustment needed with StandAlone Surface scheme'
196         nn_fwb = 0
197      ENDIF
198      IF( nn_closea > 0 ) THEN
199         IF( lwp ) WRITE(numout,*) 'No closed seas adjustment needed with StandAlone Surface scheme'
200         nn_closea = 0
201      ENDIF
202
203      !
204      !! following code is a bit messy, but distinguishes between when u,v are 3d arrays and
205      !! when we have other 3d arrays that we need to read in
206      !! so if a new field is added i.e. jf_new, just give it the next integer in sequence
207      !! for the corresponding dimension (currently if ln_3d_uv is true, 4 for 2d and 3 for 3d,
208      !! alternatively if ln_3d_uv is false, 6 for 2d and 1 for 3d), reset nfld_3d, nfld_2d,
209      !! and the rest of the logic should still work
210      !
211      jf_tem = 1 ; jf_sal = 2 ; jf_ssh = 3
212      !
213      IF( ln_3d_uv ) THEN
214         jf_usp = 1 ; jf_vsp = 2
215         nfld_3d  = 2
216         nfld_2d  = 3
217      ELSE
218         jf_usp = 4 ; jf_vsp = 5
219         nfld_3d  = 0
220         nfld_2d  = 5
221      ENDIF
222
223      IF( nfld_3d > 0 ) THEN
224         ALLOCATE( slf_3d(nfld_3d), STAT=ierr )         ! set slf structure
225         IF( ierr > 0 ) THEN
226            CALL ctl_stop( 'sbc_ssm_init: unable to allocate slf 3d structure' )   ;   RETURN
227         ENDIF
228         IF( ln_3d_uv ) THEN
229            slf_3d(jf_usp) = sn_usp
230            slf_3d(jf_vsp) = sn_vsp
231         ENDIF
232      ENDIF
233
234      IF( nfld_2d > 0 ) THEN
235         ALLOCATE( slf_2d(nfld_2d), STAT=ierr )         ! set slf structure
236         IF( ierr > 0 ) THEN
237            CALL ctl_stop( 'sbc_ssm_init: unable to allocate slf 2d structure' )   ;   RETURN
238         ENDIF
239         slf_2d(jf_tem) = sn_tem ; slf_2d(jf_sal) = sn_sal ; slf_2d(jf_ssh) = sn_ssh
240         IF( .NOT. ln_3d_uv ) THEN
241            slf_2d(jf_usp) = sn_usp ; slf_2d(jf_vsp) = sn_vsp
242         ENDIF
243      ENDIF
244      !
245      IF( nfld_3d > 0 ) THEN
246         ALLOCATE( sf_ssm_3d(nfld_3d), STAT=ierr )         ! set sf structure
247         IF( ierr > 0 ) THEN
248            CALL ctl_stop( 'sbc_ssm_init: unable to allocate sf structure' )   ;   RETURN
249         ENDIF
250         DO ifpr = 1, nfld_3d
251                                       ALLOCATE( sf_ssm_3d(ifpr)%fnow(jpi,jpj,jpk)    , STAT=ierr0 )
252            IF( slf_3d(ifpr)%ln_tint ) ALLOCATE( sf_ssm_3d(ifpr)%fdta(jpi,jpj,jpk,2)  , STAT=ierr1 )
253            IF( ierr0 + ierr1 > 0 ) THEN
254               CALL ctl_stop( 'sbc_ssm_init : unable to allocate sf_ssm_3d array structure' )   ;   RETURN
255            ENDIF
256         END DO
257         !                                         ! fill sf with slf_i and control print
258         CALL fld_fill( sf_ssm_3d, slf_3d, cn_dir, 'sbc_ssm_init', '3D Data in file', 'namsbc_ssm' )
259      ENDIF
260
261      IF( nfld_2d > 0 ) THEN
262         ALLOCATE( sf_ssm_2d(nfld_2d), STAT=ierr )         ! set sf structure
263         IF( ierr > 0 ) THEN
264            CALL ctl_stop( 'sbc_ssm_init: unable to allocate sf 2d structure' )   ;   RETURN
265         ENDIF
266         DO ifpr = 1, nfld_2d
267                                       ALLOCATE( sf_ssm_2d(ifpr)%fnow(jpi,jpj,1)    , STAT=ierr0 )
268            IF( slf_2d(ifpr)%ln_tint ) ALLOCATE( sf_ssm_2d(ifpr)%fdta(jpi,jpj,1,2)  , STAT=ierr1 )
269            IF( ierr0 + ierr1 > 0 ) THEN
270               CALL ctl_stop( 'sbc_ssm_init : unable to allocate sf_ssm_2d array structure' )   ;   RETURN
271            ENDIF
272         END DO
273         !
274         CALL fld_fill( sf_ssm_2d, slf_2d, cn_dir, 'sbc_ssm_init', '2D Data in file', 'namsbc_ssm' )
275      ENDIF
276      !
277      ! lim code currently uses surface temperature and salinity in tsn array for initialisation
278      ! and ub, vb arrays in ice dynamics
279      ! so allocate enough of arrays to use
280      !
281      ierr3 = 0
282      jpm = MAX(jp_tem, jp_sal)
283      ALLOCATE( tsn(jpi,jpj,1,jpm), STAT=ierr0 )
284      ALLOCATE( ub(jpi,jpj,1)     , STAT=ierr1 )
285      ALLOCATE( vb(jpi,jpj,1)     , STAT=ierr2 )
286      IF ( nn_ice == 1 ) ALLOCATE( tsb(jpi,jpj,1,jpm), STAT=ierr3 )
287      ierr = ierr0 + ierr1 + ierr2 + ierr3
288      IF( ierr > 0 ) THEN
289         CALL ctl_stop('sbc_ssm_init: unable to allocate surface arrays')
290      ENDIF
291      !
292      ! finally tidy up
293
294      IF( nfld_3d > 0 ) DEALLOCATE( slf_3d, STAT=ierr )
295      IF( nfld_2d > 0 ) DEALLOCATE( slf_2d, STAT=ierr )
296      !
297   END SUBROUTINE sbc_ssm_init
298
299   !!======================================================================
300END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.