Context Navigation

sbcssm.F90 @ 7646

Last change on this file since 7646 was 7646, checked in by timgraham, 7 years ago

Merge of dev_merge_2016 into trunk. UPDATE TO ARCHFILES NEEDED for XIOS2.
LIM_SRC_s/limrhg.F90 to follow in next commit due to change of kind (I'm unable to do it in this commit).
Merged using the following steps:

1) svn merge --reintegrate svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk .
2) Resolve minor conflicts in sette.sh and namelist_cfg for ORCA2LIM3 (due to a change in trunk after branch was created)
3) svn commit
4) svn switch svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk
5) svn merge svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/2016/dev_merge_2016 .
6) At this stage I checked out a clean copy of the branch to compare against what is about to be committed to the trunk.
6) svn commit #Commit code to the trunk

In this commit I have also reverted a change to Fcheck_archfile.sh which was causing problems on the Paris machine.

Property svn:keywords set to Id

File size: 15.3 KB

Line
1	MODULE sbcssm
2	!!======================================================================
3	!! * MODULE sbcssm *
4	!! Off-line : interpolation of the physical fields
5	!!======================================================================
6	!! History :
7	!! NEMO 3.4 ! 2012-03 First version by S. Alderson
8	!! ! Heavily derived from Christian's dtadyn routine
9	!! ! in OFF_SRC
10	!!----------------------------------------------------------------------
11
12	!!----------------------------------------------------------------------
13	!! sbc_ssm_init : initialization, namelist read, and SAVEs control
14	!! sbc_ssm : Interpolation of the fields
15	!!----------------------------------------------------------------------
16	USE oce ! ocean dynamics and tracers variables
17	USE c1d ! 1D configuration: lk_c1d
18	USE dom_oce ! ocean domain: variables
19	USE zdf_oce ! ocean vertical physics: variables
20	USE sbc_oce ! surface module: variables
21	USE phycst ! physical constants
22	USE eosbn2 ! equation of state - Brunt Vaisala frequency
23	USE lbclnk ! ocean lateral boundary conditions (or mpp link)
24	USE zpshde ! z-coord. with partial steps: horizontal derivatives
25	USE in_out_manager ! I/O manager
26	USE iom ! I/O library
27	USE lib_mpp ! distributed memory computing library
28	USE prtctl ! print control
29	USE fldread ! read input fields
30	USE timing ! Timing
31
32	IMPLICIT NONE
33	PRIVATE
34
35	PUBLIC sbc_ssm_init ! called by sbc_init
36	PUBLIC sbc_ssm ! called by sbc
37
38	CHARACTER(len=100) :: cn_dir !: Root directory for location of ssm files
39	LOGICAL :: ln_3d_uve !: specify whether input velocity data is 3D
40	LOGICAL :: ln_read_frq !: specify whether we must read frq or not
41	LOGICAL :: l_sasread !: Ice intilisation: read a file (.TRUE.) or anaytical initilaistion in namelist &namsbc_sas
42	LOGICAL :: l_initdone = .false.
43	INTEGER :: nfld_3d
44	INTEGER :: nfld_2d
45
46	INTEGER :: jf_tem ! index of temperature
47	INTEGER :: jf_sal ! index of salinity
48	INTEGER :: jf_usp ! index of u velocity component
49	INTEGER :: jf_vsp ! index of v velocity component
50	INTEGER :: jf_ssh ! index of sea surface height
51	INTEGER :: jf_e3t ! index of first T level thickness
52	INTEGER :: jf_frq ! index of fraction of qsr absorbed in the 1st T level
53
54	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_ssm_3d ! structure of input fields (file information, fields read)
55	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_ssm_2d ! structure of input fields (file information, fields read)
56
57	!!----------------------------------------------------------------------
58	!! NEMO/OFF 3.3 , NEMO Consortium (2010)
59	!! $Id$
60	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
61	!!----------------------------------------------------------------------
62	CONTAINS
63
64	SUBROUTINE sbc_ssm( kt )
65	!!----------------------------------------------------------------------
66	!! * ROUTINE sbc_ssm *
67	!!
68	!! ** Purpose : Prepares dynamics and physics fields from a NEMO run
69	!! for an off-line simulation using surface processes only
70	!!
71	!! ** Method : calculates the position of data
72	!! - interpolates data if needed
73	!!----------------------------------------------------------------------
74	!
75	INTEGER, INTENT(in) :: kt ! ocean time-step index
76	!
77	INTEGER :: ji, jj ! dummy loop indices
78	REAL(wp) :: ztinta ! ratio applied to after records when doing time interpolation
79	REAL(wp) :: ztintb ! ratio applied to before records when doing time interpolation
80	!!----------------------------------------------------------------------
81
82	!
83	IF( nn_timing == 1 ) CALL timing_start( 'sbc_ssm')
84
85	IF ( l_sasread ) THEN
86	IF( nfld_3d > 0 ) CALL fld_read( kt, 1, sf_ssm_3d ) !== read data at kt time step ==!
87	IF( nfld_2d > 0 ) CALL fld_read( kt, 1, sf_ssm_2d ) !== read data at kt time step ==!
88	!
89	IF( ln_3d_uve ) THEN
90	IF( .NOT. ln_linssh ) e3t_m(:,:) = sf_ssm_3d(jf_e3t)%fnow(:,:,1) * tmask(:,:,1) ! v-velocity
91	ssu_m(:,:) = sf_ssm_3d(jf_usp)%fnow(:,:,1) * umask(:,:,1) ! u-velocity
92	ssv_m(:,:) = sf_ssm_3d(jf_vsp)%fnow(:,:,1) * vmask(:,:,1) ! v-velocity
93	ELSE
94	IF( .NOT. ln_linssh ) e3t_m(:,:) = sf_ssm_2d(jf_e3t)%fnow(:,:,1) * tmask(:,:,1) ! v-velocity
95	ssu_m(:,:) = sf_ssm_2d(jf_usp)%fnow(:,:,1) * umask(:,:,1) ! u-velocity
96	ssv_m(:,:) = sf_ssm_2d(jf_vsp)%fnow(:,:,1) * vmask(:,:,1) ! v-velocity
97	ENDIF
98	!
99	sst_m(:,:) = sf_ssm_2d(jf_tem)%fnow(:,:,1) * tmask(:,:,1) ! temperature
100	sss_m(:,:) = sf_ssm_2d(jf_sal)%fnow(:,:,1) * tmask(:,:,1) ! salinity
101	ssh_m(:,:) = sf_ssm_2d(jf_ssh)%fnow(:,:,1) * tmask(:,:,1) ! sea surface height
102	IF( ln_read_frq ) THEN
103	frq_m(:,:) = sf_ssm_2d(jf_frq)%fnow(:,:,1) * tmask(:,:,1) ! solar penetration
104	ELSE
105	frq_m(:,:) = 1._wp
106	ENDIF
107	ELSE
108	sst_m(:,:) = 0._wp
109	sss_m(:,:) = 0._wp
110	ssu_m(:,:) = 0._wp
111	ssv_m(:,:) = 0._wp
112	ssh_m(:,:) = 0._wp
113	e3t_m(:,:) = e3t_0(:,:,1) !clem: necessary at least for sas2D
114	frq_m(:,:) = 1._wp ! - -
115	sshn (:,:) = 0._wp ! - -
116	ENDIF
117
118	IF ( nn_ice == 1 ) THEN
119	tsn(:,:,1,jp_tem) = sst_m(:,:)
120	tsn(:,:,1,jp_sal) = sss_m(:,:)
121	tsb(:,:,1,jp_tem) = sst_m(:,:)
122	tsb(:,:,1,jp_sal) = sss_m(:,:)
123	ENDIF
124	ub (:,:,1) = ssu_m(:,:)
125	vb (:,:,1) = ssv_m(:,:)
126
127	IF(ln_ctl) THEN ! print control
128	CALL prt_ctl(tab2d_1=sst_m, clinfo1=' sst_m - : ', mask1=tmask, ovlap=1 )
129	CALL prt_ctl(tab2d_1=sss_m, clinfo1=' sss_m - : ', mask1=tmask, ovlap=1 )
130	CALL prt_ctl(tab2d_1=ssu_m, clinfo1=' ssu_m - : ', mask1=umask, ovlap=1 )
131	CALL prt_ctl(tab2d_1=ssv_m, clinfo1=' ssv_m - : ', mask1=vmask, ovlap=1 )
132	CALL prt_ctl(tab2d_1=ssh_m, clinfo1=' ssh_m - : ', mask1=tmask, ovlap=1 )
133	IF( .NOT.ln_linssh ) CALL prt_ctl(tab2d_1=ssh_m, clinfo1=' e3t_m - : ', mask1=tmask, ovlap=1 )
134	IF( ln_read_frq ) CALL prt_ctl(tab2d_1=frq_m, clinfo1=' frq_m - : ', mask1=tmask, ovlap=1 )
135	ENDIF
136	!
137	IF( l_initdone ) THEN ! Mean value at each nn_fsbc time-step !
138	CALL iom_put( 'ssu_m', ssu_m )
139	CALL iom_put( 'ssv_m', ssv_m )
140	CALL iom_put( 'sst_m', sst_m )
141	CALL iom_put( 'sss_m', sss_m )
142	CALL iom_put( 'ssh_m', ssh_m )
143	IF( .NOT.ln_linssh ) CALL iom_put( 'e3t_m', e3t_m )
144	IF( ln_read_frq ) CALL iom_put( 'frq_m', frq_m )
145	ENDIF
146	!
147	IF( nn_timing == 1 ) CALL timing_stop( 'sbc_ssm')
148	!
149	END SUBROUTINE sbc_ssm
150
151
152	SUBROUTINE sbc_ssm_init
153	!!----------------------------------------------------------------------
154	!! * ROUTINE sbc_ssm_init *
155	!!
156	!! ** Purpose : Initialisation of the dynamical data
157	!! ** Method : - read the data namsbc_ssm namelist
158	!!
159	!! ** Action : - read parameters
160	!!----------------------------------------------------------------------
161	INTEGER :: ierr, ierr0, ierr1, ierr2, ierr3 ! return error code
162	INTEGER :: ifpr ! dummy loop indice
163	INTEGER :: inum, idv, idimv, jpm ! local integer
164	INTEGER :: ios ! Local integer output status for namelist read
165	!!
166	CHARACTER(len=100) :: cn_dir ! Root directory for location of core files
167	TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) :: slf_3d ! array of namelist information on the fields to read
168	TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) :: slf_2d ! array of namelist information on the fields to read
169	TYPE(FLD_N) :: sn_tem, sn_sal ! information about the fields to be read
170	TYPE(FLD_N) :: sn_usp, sn_vsp
171	TYPE(FLD_N) :: sn_ssh, sn_e3t, sn_frq
172	!
173	NAMELIST/namsbc_sas/l_sasread, cn_dir, ln_3d_uve, ln_read_frq, sn_tem, sn_sal, sn_usp, sn_vsp, sn_ssh, sn_e3t, sn_frq
174	!!----------------------------------------------------------------------
175
176	IF( ln_rstart .AND. nn_components == jp_iam_sas ) RETURN
177
178	REWIND( numnam_ref ) ! Namelist namsbc_sas in reference namelist : Input fields
179	READ ( numnam_ref, namsbc_sas, IOSTAT = ios, ERR = 901)
180	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_sas in reference namelist', lwp )
181
182	REWIND( numnam_cfg ) ! Namelist namsbc_sas in configuration namelist : Input fields
183	READ ( numnam_cfg, namsbc_sas, IOSTAT = ios, ERR = 902 )
184	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_sas in configuration namelist', lwp )
185	IF(lwm) WRITE ( numond, namsbc_sas )
186
187	! ! store namelist information in an array
188	! ! Control print
189	IF(lwp) THEN
190	WRITE(numout,*)
191	WRITE(numout,*) 'sbc_sas : standalone surface scheme '
192	WRITE(numout,*) '~~~~~~~~~~~ '
193	WRITE(numout,*) ' Namelist namsbc_sas'
194	WRITE(numout,*) ' Initialisation using an input file = ',l_sasread
195	WRITE(numout,*) ' Are we supplying a 3D u,v and e3 field ln_3d_uve = ', ln_3d_uve
196	WRITE(numout,*) ' Are we reading frq (fraction of qsr absorbed in the 1st T level) ln_read_frq = ', ln_read_frq
197	WRITE(numout,*)
198	ENDIF
199	!
200	!! switch off stuff that isn't sensible with a standalone module
201	!! note that we need sbc_ssm called first in sbc
202	!
203	IF( ln_apr_dyn ) THEN
204	IF( lwp ) WRITE(numout,*) 'No atmospheric gradient needed with StandAlone Surface scheme'
205	ln_apr_dyn = .FALSE.
206	ENDIF
207	IF( ln_rnf ) THEN
208	IF( lwp ) WRITE(numout,*) 'No runoff needed with StandAlone Surface scheme'
209	ln_rnf = .FALSE.
210	ENDIF
211	IF( ln_ssr ) THEN
212	IF( lwp ) WRITE(numout,*) 'No surface relaxation needed with StandAlone Surface scheme'
213	ln_ssr = .FALSE.
214	ENDIF
215	IF( nn_fwb > 0 ) THEN
216	IF( lwp ) WRITE(numout,*) 'No freshwater budget adjustment needed with StandAlone Surface scheme'
217	nn_fwb = 0
218	ENDIF
219	IF( nn_closea > 0 ) THEN
220	IF( lwp ) WRITE(numout,*) 'No closed seas adjustment needed with StandAlone Surface scheme'
221	nn_closea = 0
222	ENDIF
223	IF (l_sasread) THEN
224	!
225	!! following code is a bit messy, but distinguishes between when u,v are 3d arrays and
226	!! when we have other 3d arrays that we need to read in
227	!! so if a new field is added i.e. jf_new, just give it the next integer in sequence
228	!! for the corresponding dimension (currently if ln_3d_uve is true, 4 for 2d and 3 for 3d,
229	!! alternatively if ln_3d_uve is false, 6 for 2d and 1 for 3d), reset nfld_3d, nfld_2d,
230	!! and the rest of the logic should still work
231	!
232	jf_tem = 1 ; jf_sal = 2 ; jf_ssh = 3 ; jf_frq = 4 ! default 2D fields index
233	!
234	IF( ln_3d_uve ) THEN
235	jf_usp = 1 ; jf_vsp = 2 ; jf_e3t = 3 ! define 3D fields index
236	nfld_3d = 2 + COUNT( (/.NOT.ln_linssh/) ) ! number of 3D fields to read
237	nfld_2d = 3 + COUNT( (/ln_read_frq/) ) ! number of 2D fields to read
238	ELSE
239	jf_usp = 4 ; jf_vsp = 5 ; jf_e3t = 6 ; jf_frq = 6 + COUNT( (/.NOT.ln_linssh/) ) ! update 2D fields index
240	nfld_3d = 0 ! no 3D fields to read
241	nfld_2d = 5 + COUNT( (/.NOT.ln_linssh/) ) + COUNT( (/ln_read_frq/) ) ! number of 2D fields to read
242	ENDIF
243
244	IF( nfld_3d > 0 ) THEN
245	ALLOCATE( slf_3d(nfld_3d), STAT=ierr ) ! set slf structure
246	IF( ierr > 0 ) THEN
247	CALL ctl_stop( 'sbc_ssm_init: unable to allocate slf 3d structure' ) ; RETURN
248	ENDIF
249	slf_3d(jf_usp) = sn_usp
250	slf_3d(jf_vsp) = sn_vsp
251	IF( .NOT.ln_linssh ) slf_3d(jf_e3t) = sn_e3t
252	ENDIF
253
254	IF( nfld_2d > 0 ) THEN
255	ALLOCATE( slf_2d(nfld_2d), STAT=ierr ) ! set slf structure
256	IF( ierr > 0 ) THEN
257	CALL ctl_stop( 'sbc_ssm_init: unable to allocate slf 2d structure' ) ; RETURN
258	ENDIF
259	slf_2d(jf_tem) = sn_tem ; slf_2d(jf_sal) = sn_sal ; slf_2d(jf_ssh) = sn_ssh
260	IF( ln_read_frq ) slf_2d(jf_frq) = sn_frq
261	IF( .NOT. ln_3d_uve ) THEN
262	slf_2d(jf_usp) = sn_usp ; slf_2d(jf_vsp) = sn_vsp
263	IF( .NOT.ln_linssh ) slf_2d(jf_e3t) = sn_e3t
264	ENDIF
265	ENDIF
266	!
267	ierr1 = 0 ! default definition if slf_?d(ifpr)%ln_tint = .false.
268	IF( nfld_3d > 0 ) THEN
269	ALLOCATE( sf_ssm_3d(nfld_3d), STAT=ierr ) ! set sf structure
270	IF( ierr > 0 ) THEN
271	CALL ctl_stop( 'sbc_ssm_init: unable to allocate sf structure' ) ; RETURN
272	ENDIF
273	DO ifpr = 1, nfld_3d
274	ALLOCATE( sf_ssm_3d(ifpr)%fnow(jpi,jpj,jpk) , STAT=ierr0 )
275	IF( slf_3d(ifpr)%ln_tint ) ALLOCATE( sf_ssm_3d(ifpr)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 )
276	IF( ierr0 + ierr1 > 0 ) THEN
277	CALL ctl_stop( 'sbc_ssm_init : unable to allocate sf_ssm_3d array structure' ) ; RETURN
278	ENDIF
279	END DO
280	! ! fill sf with slf_i and control print
281	CALL fld_fill( sf_ssm_3d, slf_3d, cn_dir, 'sbc_ssm_init', '3D Data in file', 'namsbc_ssm' )
282	ENDIF
283
284	IF( nfld_2d > 0 ) THEN
285	ALLOCATE( sf_ssm_2d(nfld_2d), STAT=ierr ) ! set sf structure
286	IF( ierr > 0 ) THEN
287	CALL ctl_stop( 'sbc_ssm_init: unable to allocate sf 2d structure' ) ; RETURN
288	ENDIF
289	DO ifpr = 1, nfld_2d
290	ALLOCATE( sf_ssm_2d(ifpr)%fnow(jpi,jpj,1) , STAT=ierr0 )
291	IF( slf_2d(ifpr)%ln_tint ) ALLOCATE( sf_ssm_2d(ifpr)%fdta(jpi,jpj,1,2) , STAT=ierr1 )
292	IF( ierr0 + ierr1 > 0 ) THEN
293	CALL ctl_stop( 'sbc_ssm_init : unable to allocate sf_ssm_2d array structure' ) ; RETURN
294	ENDIF
295	END DO
296	!
297	CALL fld_fill( sf_ssm_2d, slf_2d, cn_dir, 'sbc_ssm_init', '2D Data in file', 'namsbc_ssm' )
298	ENDIF
299	!
300	! finally tidy up
301
302	IF( nfld_3d > 0 ) DEALLOCATE( slf_3d, STAT=ierr )
303	IF( nfld_2d > 0 ) DEALLOCATE( slf_2d, STAT=ierr )
304
305	ENDIF
306
307	CALL sbc_ssm( nit000 ) ! need to define ss?_m arrays used in limistate
308	IF( .NOT. ln_read_frq ) frq_m(:,:) = 1.
309	l_initdone = .TRUE.
310	!
311	END SUBROUTINE sbc_ssm_init
312
313	!!======================================================================
314	END MODULE sbcssm

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: trunk/NEMOGCM/NEMO/SAS_SRC/sbcssm.F90 @ 7646

Download in other formats: