New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p2zopt.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P2Z – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P2Z/p2zopt.F90 @ 7981

Last change on this file since 7981 was 7981, checked in by cetlod, 7 years ago

trunk : minor correction in p2zopt

  • Property svn:keywords set to Id
File size: 9.7 KB
Line 
1MODULE p2zopt
2   !!======================================================================
3   !!                         ***  MODULE p2zopt  ***
4   !! TOP :   LOBSTER Compute the light availability in the water column
5   !!======================================================================
6   !! History :    -   !  1995-05  (M. Levy) Original code
7   !!              -   !  1999-09  (J.-M. Andre, M. Levy)
8   !!              -   !  1999-11  (C. Menkes, M.-A. Foujols) itabe initial
9   !!              -   !  2000-02  (M.A. Foujols) change x**y par exp(y*log(x))
10   !!   NEMO      2.0  !  2007-12  (C. Deltel, G. Madec)  F90
11   !!             3.2  !  2009-04  (C. Ethe, G. Madec)  minor optimisation + style
12   !!----------------------------------------------------------------------
13   !!   p2z_opt        :   Compute the light availability in the water column
14   !!----------------------------------------------------------------------
15   USE oce_trc         !
16   USE trc
17   USE sms_pisces
18   USE prtctl_trc      ! Print control for debbuging
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   p2z_opt   !
24   PUBLIC   p2z_opt_init   !
25
26   REAL(wp), PUBLIC ::  xkr0      !: water coefficient absorption in red     
27   REAL(wp), PUBLIC ::  xkg0      !: water coefficient absorption in green   
28   REAL(wp), PUBLIC ::  xkrp      !: pigment coefficient absorption in red   
29   REAL(wp), PUBLIC ::  xkgp      !: pigment coefficient absorption in green 
30   REAL(wp), PUBLIC ::  xlr       !: exposant for pigment absorption in red 
31   REAL(wp), PUBLIC ::  xlg       !: exposant for pigment absorption in green
32   REAL(wp), PUBLIC ::  rpig      !: chla/chla+phea ratio   
33   !                 
34   REAL(wp), PUBLIC ::  rcchl     ! Carbone/Chlorophyl ratio [mgC.mgChla-1]
35   REAL(wp), PUBLIC ::  redf      ! redfield ratio (C:N) for phyto
36   REAL(wp), PUBLIC ::  reddom    ! redfield ratio (C:N) for DOM
37
38   !!----------------------------------------------------------------------
39   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
40   !! $Id$
41   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE p2z_opt( kt )
46      !!---------------------------------------------------------------------
47      !!                     ***  ROUTINE p2z_opt  ***
48      !!
49      !! ** Purpose :   computes the light propagation in the water column
50      !!              and the euphotic layer depth
51      !!
52      !! ** Method  :   local par is computed in w layers using light propagation
53      !!              mean par in t layers are computed by integration
54      !!
55!!gm please remplace the '???' by true comments
56      !! ** Action  :   etot   ???
57      !!                neln   ???
58      !!---------------------------------------------------------------------
59      !!
60      INTEGER, INTENT( in ) ::   kt   ! index of the time stepping
61      !!
62      INTEGER  ::   ji, jj, jk          ! dummy loop indices
63      CHARACTER (len=25) ::   charout   ! temporary character
64      REAL(wp) ::   zpig                ! log of the total pigment
65      REAL(wp) ::   zkr, zkg            ! total absorption coefficient in red and green
66      REAL(wp) ::   zcoef               ! temporary scalar
67      REAL(wp), POINTER, DIMENSION(:,:  ) :: zpar100, zpar0m
68      REAL(wp), POINTER, DIMENSION(:,:,:) :: zparr, zparg
69      !!---------------------------------------------------------------------
70      !
71      IF( nn_timing == 1 )  CALL timing_start('p2z_opt')
72      !
73      ! Allocate temporary workspace
74      CALL wrk_alloc( jpi, jpj,      zpar100, zpar0m )
75      CALL wrk_alloc( jpi, jpj, jpk, zparr, zparg    )
76
77      IF( kt == nittrc000 ) THEN
78         IF(lwp) WRITE(numout,*)
79         IF(lwp) WRITE(numout,*) ' p2z_opt : LOBSTER optic-model'
80         IF(lwp) WRITE(numout,*) ' ~~~~~~~ '
81      ENDIF
82
83      !                                          ! surface irradiance
84      !                                          ! ------------------
85      IF( ln_dm2dc ) THEN   ;   zpar0m(:,:) = qsr_mean(:,:) * 0.43
86      ELSE                  ;   zpar0m(:,:) = qsr     (:,:) * 0.43
87      ENDIF
88      zpar100(:,:)   = zpar0m(:,:) * 0.01
89      zparr  (:,:,1) = zpar0m(:,:) * 0.5
90      zparg  (:,:,1) = zpar0m(:,:) * 0.5
91
92      !                                          ! Photosynthetically Available Radiation (PAR)
93      zcoef = 12 * redf / rcchl / rpig           ! --------------------------------------
94      DO jk = 2, jpk                                  ! local par at w-levels
95         DO jj = 1, jpj
96            DO ji = 1, jpi
97               zpig = LOG(  MAX( TINY(0.), trn(ji,jj,jk-1,jpphy) ) * zcoef  )
98               zkr  = xkr0 + xkrp * EXP( xlr * zpig )
99               zkg  = xkg0 + xkgp * EXP( xlg * zpig )
100               zparr(ji,jj,jk) = zparr(ji,jj,jk-1) * EXP( -zkr * e3t_n(ji,jj,jk-1) )
101               zparg(ji,jj,jk) = zparg(ji,jj,jk-1) * EXP( -zkg * e3t_n(ji,jj,jk-1) )
102            END DO
103        END DO
104      END DO
105      DO jk = 1, jpkm1                                ! mean par at t-levels
106         DO jj = 1, jpj
107            DO ji = 1, jpi
108               zpig = LOG(  MAX( TINY(0.), trn(ji,jj,jk,jpphy) ) * zcoef  )
109               zkr  = xkr0 + xkrp * EXP( xlr * zpig )
110               zkg  = xkg0 + xkgp * EXP( xlg * zpig )
111               zparr(ji,jj,jk) = zparr(ji,jj,jk) / ( zkr * e3t_n(ji,jj,jk) ) * ( 1 - EXP( -zkr * e3t_n(ji,jj,jk) ) )
112               zparg(ji,jj,jk) = zparg(ji,jj,jk) / ( zkg * e3t_n(ji,jj,jk) ) * ( 1 - EXP( -zkg * e3t_n(ji,jj,jk) ) )
113               etot (ji,jj,jk) = MAX( zparr(ji,jj,jk) + zparg(ji,jj,jk), 1.e-15 )
114            END DO
115         END DO
116      END DO
117
118      !                                          ! Euphotic layer
119      !                                          ! --------------
120      neln(:,:) = 1                                   ! euphotic layer level
121      DO jk = 1, jpkm1                                  ! (i.e. 1rst T-level strictly below EL bottom)
122         DO jj = 1, jpj
123           DO ji = 1, jpi
124              IF( etot(ji,jj,jk) >= zpar100(ji,jj) )   neln(ji,jj) = jk + 1 
125           END DO
126         END DO
127      END DO
128      !                                               ! Euphotic layer depth
129      DO jj = 1, jpj
130         DO ji = 1, jpi
131            heup(ji,jj) = gdepw_n(ji,jj,neln(ji,jj))
132         END DO
133      END DO
134
135
136      IF(ln_ctl) THEN      ! print mean trends (used for debugging)
137         WRITE(charout, FMT="('opt')")
138         CALL prt_ctl_trc_info( charout )
139         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
140      ENDIF
141      !
142      CALL wrk_dealloc( jpi, jpj,      zpar100, zpar0m )
143      CALL wrk_dealloc( jpi, jpj, jpk, zparr, zparg    )
144      !
145      IF( nn_timing == 1 )  CALL timing_stop('p2z_opt')
146      !
147   END SUBROUTINE p2z_opt
148
149   SUBROUTINE p2z_opt_init
150      !!----------------------------------------------------------------------
151      !!                  ***  ROUTINE p2z_opt_init  ***
152      !!
153      !! ** Purpose :  optical parameters
154      !!
155      !! ** Method  :   Read the namlobopt namelist and check the parameters
156      !!
157      !!----------------------------------------------------------------------
158      NAMELIST/namlobopt/ xkg0, xkr0, xkgp, xkrp, xlg, xlr, rpig
159      NAMELIST/namlobrat/ rcchl, redf, reddom
160      INTEGER :: ios                 ! Local integer output status for namelist read
161      !!----------------------------------------------------------------------
162
163      REWIND( numnatp_ref )              ! Namelist namlobopt in reference namelist : Lobster options
164      READ  ( numnatp_ref, namlobopt, IOSTAT = ios, ERR = 901)
165901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namlobopt in reference namelist', lwp )
166
167      REWIND( numnatp_cfg )              ! Namelist namlobopt in configuration namelist : Lobster options
168      READ  ( numnatp_cfg, namlobopt, IOSTAT = ios, ERR = 902 )
169902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namlobopt in configuration namelist', lwp )
170      IF(lwm) WRITE ( numonp, namlobopt )
171
172      IF(lwp) THEN
173         WRITE(numout,*)
174         WRITE(numout,*) ' Namelist namlobopt'
175         WRITE(numout,*) '    green   water absorption coeff                       xkg0  = ', xkg0
176         WRITE(numout,*) '    red water absorption coeff                           xkr0  = ', xkr0
177         WRITE(numout,*) '    pigment red absorption coeff                         xkrp  = ', xkrp
178         WRITE(numout,*) '    pigment green absorption coeff                       xkgp  = ', xkgp
179         WRITE(numout,*) '    green chl exposant                                   xlg   = ', xlg
180         WRITE(numout,*) '    red   chl exposant                                   xlr   = ', xlr
181         WRITE(numout,*) '    chla/chla+phea ratio                                 rpig  = ', rpig
182         WRITE(numout,*) ' '
183      ENDIF
184      !
185      REWIND( numnatp_ref )              ! Namelist namlobrat in reference namelist : Lobster ratios
186      READ  ( numnatp_ref, namlobrat, IOSTAT = ios, ERR = 903)
187903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namlobrat in reference namelist', lwp )
188
189      REWIND( numnatp_cfg )              ! Namelist namlobrat in configuration namelist : Lobster ratios
190      READ  ( numnatp_cfg, namlobrat, IOSTAT = ios, ERR = 904 )
191904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namlobrat in configuration namelist', lwp )
192      IF(lwm) WRITE ( numonp, namlobrat )
193
194      IF(lwp) THEN
195          WRITE(numout,*) ' Namelist namlobrat'
196         WRITE(numout,*) '     carbone/chlorophyl ratio                             rcchl = ', rcchl
197          WRITE(numout,*) '    redfield ratio  c:n for phyto                        redf      =', redf
198          WRITE(numout,*) '    redfield ratio  c:n for DOM                          reddom    =', reddom
199          WRITE(numout,*) ' '
200      ENDIF
201      !
202   END SUBROUTINE p2z_opt_init
203
204   !!======================================================================
205END MODULE  p2zopt
Note: See TracBrowser for help on using the repository browser.