source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zlim.F90 @ 7753

Last change on this file since 7753 was 7753, checked in by mocavero, 4 years ago

Reverting trunk to remove OpenMP

File size: 17.4 KB
Line 
1MODULE p4zlim
2   !!======================================================================
3   !!                         ***  MODULE p4zlim  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-04  (O. Aumont, C. Ethe) Limitation for iron modelled in quota
9   !!----------------------------------------------------------------------
10   !!   p4z_lim        :   Compute the nutrients limitation terms
11   !!   p4z_lim_init   :   Read the namelist
12   !!----------------------------------------------------------------------
13   USE oce_trc         ! Shared ocean-passive tracers variables
14   USE trc             ! Tracers defined
15   USE sms_pisces      ! PISCES variables
16   USE iom             !  I/O manager
17
18   IMPLICIT NONE
19   PRIVATE
20
21   PUBLIC p4z_lim   
22   PUBLIC p4z_lim_init   
23   PUBLIC p4z_lim_alloc
24
25   !! * Shared module variables
26   REAL(wp), PUBLIC ::  concnno3    !:  NO3, PO4 half saturation   
27   REAL(wp), PUBLIC ::  concdno3    !:  Phosphate half saturation for diatoms 
28   REAL(wp), PUBLIC ::  concnnh4    !:  NH4 half saturation for phyto 
29   REAL(wp), PUBLIC ::  concdnh4    !:  NH4 half saturation for diatoms
30   REAL(wp), PUBLIC ::  concnfer    !:  Iron half saturation for nanophyto
31   REAL(wp), PUBLIC ::  concdfer    !:  Iron half saturation for diatoms 
32   REAL(wp), PUBLIC ::  concbno3    !:  NO3 half saturation  for bacteria
33   REAL(wp), PUBLIC ::  concbnh4    !:  NH4 half saturation for bacteria
34   REAL(wp), PUBLIC ::  xsizedia    !:  Minimum size criteria for diatoms
35   REAL(wp), PUBLIC ::  xsizephy    !:  Minimum size criteria for nanophyto
36   REAL(wp), PUBLIC ::  xsizern     !:  Size ratio for nanophytoplankton
37   REAL(wp), PUBLIC ::  xsizerd     !:  Size ratio for diatoms
38   REAL(wp), PUBLIC ::  xksi1       !:  half saturation constant for Si uptake
39   REAL(wp), PUBLIC ::  xksi2       !:  half saturation constant for Si/C
40   REAL(wp), PUBLIC ::  xkdoc       !:  2nd half-sat. of DOC remineralization 
41   REAL(wp), PUBLIC ::  concbfe     !:  Fe half saturation for bacteria
42   REAL(wp), PUBLIC ::  oxymin      !:  half saturation constant for anoxia
43   REAL(wp), PUBLIC ::  qnfelim     !:  optimal Fe quota for nanophyto
44   REAL(wp), PUBLIC ::  qdfelim     !:  optimal Fe quota for diatoms
45   REAL(wp), PUBLIC ::  caco3r      !:  mean rainratio
46
47   !!* Phytoplankton limitation terms
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xnanono3   !: ???
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xdiatno3   !: ???
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xnanonh4   !: ???
51   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xdiatnh4   !: ???
52   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xnanopo4   !: ???
53   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xdiatpo4   !: ???
54   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimphy    !: ???
55   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimdia    !: ???
56   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimnfe    !: ???
57   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimdfe    !: ???
58   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimsi     !: ???
59   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimbac    !: ??
60   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimbacl   !: ??
61   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   concdfe    !: ???
62   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   concnfe    !: ???
63
64   ! Coefficient for iron limitation
65   REAL(wp) ::  xcoef1   = 0.0016  / 55.85 
66   REAL(wp) ::  xcoef2   = 1.21E-5 * 14. / 55.85 / 7.625 * 0.5 * 1.5
67   REAL(wp) ::  xcoef3   = 1.15E-4 * 14. / 55.85 / 7.625 * 0.5 
68
69   !!----------------------------------------------------------------------
70   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
71   !! $Id: p4zlim.F90 3160 2011-11-20 14:27:18Z cetlod $
72   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
73   !!----------------------------------------------------------------------
74
75CONTAINS
76
77   SUBROUTINE p4z_lim( kt, knt )
78      !!---------------------------------------------------------------------
79      !!                     ***  ROUTINE p4z_lim  ***
80      !!
81      !! ** Purpose :   Compute the co-limitations by the various nutrients
82      !!              for the various phytoplankton species
83      !!
84      !! ** Method  : - ???
85      !!---------------------------------------------------------------------
86      !
87      INTEGER, INTENT(in)  :: kt, knt
88      !
89      INTEGER  ::   ji, jj, jk
90      REAL(wp) ::   zlim1, zlim2, zlim3, zlim4, zno3, zferlim
91      REAL(wp) ::   zconcd, zconcd2, zconcn, zconcn2
92      REAL(wp) ::   z1_trbdia, z1_trbphy, ztem1, ztem2, zetot1, zetot2
93      REAL(wp) ::   zdenom, zratio, zironmin
94      REAL(wp) ::   zconc1d, zconc1dnh4, zconc0n, zconc0nnh4   
95      !!---------------------------------------------------------------------
96      !
97      IF( nn_timing == 1 )  CALL timing_start('p4z_lim')
98      !
99      DO jk = 1, jpkm1
100         DO jj = 1, jpj
101            DO ji = 1, jpi
102               
103               ! Tuning of the iron concentration to a minimum level that is set to the detection limit
104               !-------------------------------------
105               zno3    = trb(ji,jj,jk,jpno3) / 40.e-6
106               zferlim = MAX( 3e-11 * zno3 * zno3, 5e-12 )
107               zferlim = MIN( zferlim, 7e-11 )
108               trb(ji,jj,jk,jpfer) = MAX( trb(ji,jj,jk,jpfer), zferlim )
109
110               ! Computation of a variable Ks for iron on diatoms taking into account
111               ! that increasing biomass is made of generally bigger cells
112               !------------------------------------------------
113               zconcd   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
114               zconcd2  = trb(ji,jj,jk,jpdia) - zconcd
115               zconcn   = MAX( 0.e0 , trb(ji,jj,jk,jpphy) - xsizephy )
116               zconcn2  = trb(ji,jj,jk,jpphy) - zconcn
117               z1_trbphy   = 1. / ( trb(ji,jj,jk,jpphy) + rtrn )
118               z1_trbdia   = 1. / ( trb(ji,jj,jk,jpdia) + rtrn )
119
120               concdfe(ji,jj,jk) = MAX( concdfer, ( zconcd2 * concdfer + concdfer * xsizerd * zconcd ) * z1_trbdia )
121               zconc1d           = MAX( concdno3, ( zconcd2 * concdno3 + concdno3 * xsizerd * zconcd ) * z1_trbdia )
122               zconc1dnh4        = MAX( concdnh4, ( zconcd2 * concdnh4 + concdnh4 * xsizerd * zconcd ) * z1_trbdia )
123
124               concnfe(ji,jj,jk) = MAX( concnfer, ( zconcn2 * concnfer + concnfer * xsizern * zconcn ) * z1_trbphy )
125               zconc0n           = MAX( concnno3, ( zconcn2 * concnno3 + concnno3 * xsizern * zconcn ) * z1_trbphy )
126               zconc0nnh4        = MAX( concnnh4, ( zconcn2 * concnnh4 + concnnh4 * xsizern * zconcn ) * z1_trbphy )
127
128               ! Michaelis-Menten Limitation term for nutrients Small bacteria
129               ! -------------------------------------------------------------
130               zdenom = 1. /  ( concbno3 * concbnh4 + concbnh4 * trb(ji,jj,jk,jpno3) + concbno3 * trb(ji,jj,jk,jpnh4) )
131               xnanono3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * concbnh4 * zdenom
132               xnanonh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * concbno3 * zdenom
133               !
134               zlim1    = xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk)
135               zlim2    = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + concbnh4 )
136               zlim3    = trb(ji,jj,jk,jpfer) / ( concbfe + trb(ji,jj,jk,jpfer) )
137               zlim4    = trb(ji,jj,jk,jpdoc) / ( xkdoc   + trb(ji,jj,jk,jpdoc) )
138               xlimbacl(ji,jj,jk) = MIN( zlim1, zlim2, zlim3 )
139               xlimbac (ji,jj,jk) = MIN( zlim1, zlim2, zlim3 ) * zlim4
140
141               ! Michaelis-Menten Limitation term for nutrients Small flagellates
142               ! -----------------------------------------------
143               zdenom = 1. /  ( zconc0n * zconc0nnh4 + zconc0nnh4 * trb(ji,jj,jk,jpno3) + zconc0n * trb(ji,jj,jk,jpnh4) )
144               xnanono3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * zconc0nnh4 * zdenom
145               xnanonh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * zconc0n    * zdenom
146               !
147               zlim1    = xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk)
148               zlim2    = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zconc0nnh4 )
149               zratio   = trb(ji,jj,jk,jpnfe) * z1_trbphy 
150               zironmin = xcoef1 * trb(ji,jj,jk,jpnch) * z1_trbphy + xcoef2 * zlim1 + xcoef3 * xnanono3(ji,jj,jk)
151               zlim3    = MAX( 0.,( zratio - zironmin ) / qnfelim )
152               xnanopo4(ji,jj,jk) = zlim2
153               xlimnfe (ji,jj,jk) = MIN( 1., zlim3 )
154               xlimphy (ji,jj,jk) = MIN( zlim1, zlim2, zlim3 )
155               !
156               !   Michaelis-Menten Limitation term for nutrients Diatoms
157               !   ----------------------------------------------
158               zdenom   = 1. / ( zconc1d * zconc1dnh4 + zconc1dnh4 * trb(ji,jj,jk,jpno3) + zconc1d * trb(ji,jj,jk,jpnh4) )
159               xdiatno3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * zconc1dnh4 * zdenom
160               xdiatnh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * zconc1d    * zdenom
161               !
162               zlim1    = xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk)
163               zlim2    = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zconc1dnh4  )
164               zlim3    = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi(ji,jj) )
165               zratio   = trb(ji,jj,jk,jpdfe) * z1_trbdia
166               zironmin = xcoef1 * trb(ji,jj,jk,jpdch) * z1_trbdia + xcoef2 * zlim1 + xcoef3 * xdiatno3(ji,jj,jk)
167               zlim4    = MAX( 0., ( zratio - zironmin ) / qdfelim )
168               xdiatpo4(ji,jj,jk) = zlim2
169               xlimdfe (ji,jj,jk) = MIN( 1., zlim4 )
170               xlimdia (ji,jj,jk) = MIN( zlim1, zlim2, zlim3, zlim4 )
171               xlimsi  (ji,jj,jk) = MIN( zlim1, zlim2, zlim4 )
172           END DO
173         END DO
174      END DO
175
176      ! Compute the fraction of nanophytoplankton that is made of calcifiers
177      ! --------------------------------------------------------------------
178      DO jk = 1, jpkm1
179         DO jj = 1, jpj
180            DO ji = 1, jpi
181               zlim1 =  ( trb(ji,jj,jk,jpno3) * concnnh4 + trb(ji,jj,jk,jpnh4) * concnno3 )    &
182                  &   / ( concnno3 * concnnh4 + concnnh4 * trb(ji,jj,jk,jpno3) + concnno3 * trb(ji,jj,jk,jpnh4) ) 
183               zlim2  = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + concnnh4 )
184               zlim3  = trb(ji,jj,jk,jpfer) / ( trb(ji,jj,jk,jpfer) +  5.E-11   )
185               ztem1  = MAX( 0., tsn(ji,jj,jk,jp_tem) )
186               ztem2  = tsn(ji,jj,jk,jp_tem) - 10.
187               zetot1 = MAX( 0., etot_ndcy(ji,jj,jk) - 1.) / ( 4. + etot_ndcy(ji,jj,jk) ) 
188               zetot2 = 30. / ( 30. + etot_ndcy(ji,jj,jk) ) 
189
190               xfracal(ji,jj,jk) = caco3r * MIN( zlim1, zlim2, zlim3 )                  &
191                  &                       * ztem1 / ( 0.1 + ztem1 )                     &
192                  &                       * MAX( 1., trb(ji,jj,jk,jpphy) * 1.e6 / 2. )  &
193                  &                       * zetot1 * zetot2               &
194                  &                       * ( 1. + EXP(-ztem2 * ztem2 / 25. ) )         &
195                  &                       * MIN( 1., 50. / ( hmld(ji,jj) + rtrn ) )
196               xfracal(ji,jj,jk) = MIN( 0.8 , xfracal(ji,jj,jk) )
197               xfracal(ji,jj,jk) = MAX( 0.02, xfracal(ji,jj,jk) )
198            END DO
199         END DO
200      END DO
201      !
202      DO jk = 1, jpkm1
203         DO jj = 1, jpj
204            DO ji = 1, jpi
205               ! denitrification factor computed from O2 levels
206               nitrfac(ji,jj,jk) = MAX(  0.e0, 0.4 * ( 6.e-6  - trb(ji,jj,jk,jpoxy) )    &
207                  &                                / ( oxymin + trb(ji,jj,jk,jpoxy) )  )
208               nitrfac(ji,jj,jk) = MIN( 1., nitrfac(ji,jj,jk) )
209            END DO
210         END DO
211      END DO
212      !
213      IF( lk_iomput .AND. knt == nrdttrc ) THEN        ! save output diagnostics
214        IF( iom_use( "xfracal" ) ) CALL iom_put( "xfracal", xfracal(:,:,:) * tmask(:,:,:) )  ! euphotic layer deptht
215        IF( iom_use( "LNnut"   ) ) CALL iom_put( "LNnut"  , xlimphy(:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
216        IF( iom_use( "LDnut"   ) ) CALL iom_put( "LDnut"  , xlimdia(:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
217        IF( iom_use( "LNFe"    ) ) CALL iom_put( "LNFe"   , xlimnfe(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
218        IF( iom_use( "LDFe"    ) ) CALL iom_put( "LDFe"   , xlimdfe(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
219      ENDIF
220      !
221      IF( nn_timing == 1 )  CALL timing_stop('p4z_lim')
222      !
223   END SUBROUTINE p4z_lim
224
225   SUBROUTINE p4z_lim_init
226
227      !!----------------------------------------------------------------------
228      !!                  ***  ROUTINE p4z_lim_init  ***
229      !!
230      !! ** Purpose :   Initialization of nutrient limitation parameters
231      !!
232      !! ** Method  :   Read the nampislim namelist and check the parameters
233      !!      called at the first timestep (nittrc000)
234      !!
235      !! ** input   :   Namelist nampislim
236      !!
237      !!----------------------------------------------------------------------
238
239      NAMELIST/namp4zlim/ concnno3, concdno3, concnnh4, concdnh4, concnfer, concdfer, concbfe,   &
240         &                concbno3, concbnh4, xsizedia, xsizephy, xsizern, xsizerd,          & 
241         &                xksi1, xksi2, xkdoc, qnfelim, qdfelim, caco3r, oxymin
242      INTEGER :: ios                 ! Local integer output status for namelist read
243
244      REWIND( numnatp_ref )              ! Namelist nampislim in reference namelist : Pisces nutrient limitation parameters
245      READ  ( numnatp_ref, namp4zlim, IOSTAT = ios, ERR = 901)
246901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zlim in reference namelist', lwp )
247
248      REWIND( numnatp_cfg )              ! Namelist nampislim in configuration namelist : Pisces nutrient limitation parameters
249      READ  ( numnatp_cfg, namp4zlim, IOSTAT = ios, ERR = 902 )
250902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zlim in configuration namelist', lwp )
251      IF(lwm) WRITE ( numonp, namp4zlim )
252
253      IF(lwp) THEN                         ! control print
254         WRITE(numout,*) ' '
255         WRITE(numout,*) ' Namelist parameters for nutrient limitations, namp4zlim'
256         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
257         WRITE(numout,*) '    mean rainratio                           caco3r    = ', caco3r
258         WRITE(numout,*) '    NO3 half saturation of nanophyto         concnno3  = ', concnno3
259         WRITE(numout,*) '    NO3 half saturation of diatoms           concdno3  = ', concdno3
260         WRITE(numout,*) '    NH4 half saturation for phyto            concnnh4  = ', concnnh4
261         WRITE(numout,*) '    NH4 half saturation for diatoms          concdnh4  = ', concdnh4
262         WRITE(numout,*) '    half saturation constant for Si uptake   xksi1     = ', xksi1
263         WRITE(numout,*) '    half saturation constant for Si/C        xksi2     = ', xksi2
264         WRITE(numout,*) '    half-sat. of DOC remineralization        xkdoc     = ', xkdoc
265         WRITE(numout,*) '    Iron half saturation for nanophyto       concnfer  = ', concnfer
266         WRITE(numout,*) '    Iron half saturation for diatoms         concdfer  = ', concdfer
267         WRITE(numout,*) '    size ratio for nanophytoplankton         xsizern   = ', xsizern
268         WRITE(numout,*) '    size ratio for diatoms                   xsizerd   = ', xsizerd
269         WRITE(numout,*) '    NO3 half saturation of bacteria          concbno3  = ', concbno3
270         WRITE(numout,*) '    NH4 half saturation for bacteria         concbnh4  = ', concbnh4
271         WRITE(numout,*) '    Minimum size criteria for diatoms        xsizedia  = ', xsizedia
272         WRITE(numout,*) '    Minimum size criteria for nanophyto      xsizephy  = ', xsizephy
273         WRITE(numout,*) '    Fe half saturation for bacteria          concbfe   = ', concbfe
274         WRITE(numout,*) '    halk saturation constant for anoxia       oxymin   =' , oxymin
275         WRITE(numout,*) '    optimal Fe quota for nano.               qnfelim   = ', qnfelim
276         WRITE(numout,*) '    Optimal Fe quota for diatoms             qdfelim   = ', qdfelim
277      ENDIF
278      !
279      nitrfac (:,:,:) = 0._wp
280      !
281   END SUBROUTINE p4z_lim_init
282
283   INTEGER FUNCTION p4z_lim_alloc()
284      !!----------------------------------------------------------------------
285      !!                     ***  ROUTINE p5z_lim_alloc  ***
286      !!----------------------------------------------------------------------
287      USE lib_mpp , ONLY: ctl_warn
288      !!----------------------------------------------------------------------
289
290      !*  Biological arrays for phytoplankton growth
291      ALLOCATE( xnanono3(jpi,jpj,jpk), xdiatno3(jpi,jpj,jpk),       &
292         &      xnanonh4(jpi,jpj,jpk), xdiatnh4(jpi,jpj,jpk),       &
293         &      xnanopo4(jpi,jpj,jpk), xdiatpo4(jpi,jpj,jpk),       &
294         &      xlimphy (jpi,jpj,jpk), xlimdia (jpi,jpj,jpk),       &
295         &      xlimnfe (jpi,jpj,jpk), xlimdfe (jpi,jpj,jpk),       &
296         &      xlimbac (jpi,jpj,jpk), xlimbacl(jpi,jpj,jpk),       &
297         &      concnfe (jpi,jpj,jpk), concdfe (jpi,jpj,jpk),       &
298         &      xlimsi  (jpi,jpj,jpk), STAT=p4z_lim_alloc )
299      !
300      IF( p4z_lim_alloc /= 0 ) CALL ctl_warn('p4z_lim_alloc : failed to allocate arrays.')
301      !
302   END FUNCTION p4z_lim_alloc
303
304   !!======================================================================
305END MODULE p4zlim
Note: See TracBrowser for help on using the repository browser.