New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmicro.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmicro.F90 @ 7698

Last change on this file since 7698 was 7698, checked in by mocavero, 7 years ago

update trunk with OpenMP parallelization

File size: 14.2 KB
Line 
1MODULE p4zmicro
2   !!======================================================================
3   !!                         ***  MODULE p4zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_micro       :   Compute the sources/sinks for microzooplankton
11   !!   p4z_micro_init  :   Initialize and read the appropriate namelist
12   !!----------------------------------------------------------------------
13   USE oce_trc         !  shared variables between ocean and passive tracers
14   USE trc             !  passive tracers common variables
15   USE sms_pisces      !  PISCES Source Minus Sink variables
16   USE p4zlim          !  Co-limitations
17   USE p4zprod         !  production
18   USE iom             !  I/O manager
19   USE prtctl_trc      !  print control for debugging
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_micro         ! called in p4zbio.F90
25   PUBLIC   p4z_micro_init    ! called in trcsms_pisces.F90
26
27   !! * Shared module variables
28   REAL(wp), PUBLIC ::  part        !: part of calcite not dissolved in microzoo guts
29   REAL(wp), PUBLIC ::  xpref2c     !: microzoo preference for POC
30   REAL(wp), PUBLIC ::  xpref2p     !: microzoo preference for nanophyto
31   REAL(wp), PUBLIC ::  xpref2d     !: microzoo preference for diatoms
32   REAL(wp), PUBLIC ::  xthreshdia  !: diatoms feeding threshold for microzooplankton
33   REAL(wp), PUBLIC ::  xthreshphy  !: nanophyto threshold for microzooplankton
34   REAL(wp), PUBLIC ::  xthreshpoc  !: poc threshold for microzooplankton
35   REAL(wp), PUBLIC ::  xthresh     !: feeding threshold for microzooplankton
36   REAL(wp), PUBLIC ::  resrat      !: exsudation rate of microzooplankton
37   REAL(wp), PUBLIC ::  mzrat       !: microzooplankton mortality rate
38   REAL(wp), PUBLIC ::  grazrat     !: maximal microzoo grazing rate
39   REAL(wp), PUBLIC ::  xkgraz      !: non assimilated fraction of P by microzoo
40   REAL(wp), PUBLIC ::  unass       !: Efficicency of microzoo growth
41   REAL(wp), PUBLIC ::  sigma1      !: Fraction of microzoo excretion as DOM
42   REAL(wp), PUBLIC ::  epsher      !: half sturation constant for grazing 1
43
44
45   !!----------------------------------------------------------------------
46   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
47   !! $Id: p4zmicro.F90 3160 2011-11-20 14:27:18Z cetlod $
48   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50
51CONTAINS
52
53   SUBROUTINE p4z_micro( kt, knt )
54      !!---------------------------------------------------------------------
55      !!                     ***  ROUTINE p4z_micro  ***
56      !!
57      !! ** Purpose :   Compute the sources/sinks for microzooplankton
58      !!
59      !! ** Method  : - ???
60      !!---------------------------------------------------------------------
61      INTEGER, INTENT(in) ::  kt  ! ocean time step
62      INTEGER, INTENT(in) ::  knt 
63      !
64      INTEGER  :: ji, jj, jk
65      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc
66      REAL(wp) :: zgraze  , zdenom, zdenom2
67      REAL(wp) :: zfact   , zfood, zfoodlim
68      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotn, zgraztotf
69      REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz
70      REAL(wp) :: zrespz, ztortz, zgrasrat, zgrasratn
71      REAL(wp) :: zgrazp, zgrazm, zgrazsd
72      REAL(wp) :: zgrazmf, zgrazsf, zgrazpf
73      REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing, zw3d
74      CHARACTER (len=25) :: charout
75      !!---------------------------------------------------------------------
76      !
77      IF( nn_timing == 1 )  CALL timing_start('p4z_micro')
78      !
79      CALL wrk_alloc( jpi, jpj, jpk, zgrazing )
80      !
81!$OMP PARALLEL DO schedule(static) private(jk,jj,ji,zcompaz,zfact,zrespz,ztortz,zcompadi,zcompaph,zcompapoc,zfood) &
82!$OMP& private(zfoodlim,zdenom,zdenom2,zgraze,zgrazp,zgrazm,zgrazsd,zgrazpf,zgrazmf,zgrazsf,zgraztot,zgraztotf) &
83!$OMP& private(zgraztotn,zgrasrat,zgrasratn,zepshert,zepsherv,zgrafer,zgrarem,zgrapoc,zgrarsig,zmortz,zprcaca)
84      DO jk = 1, jpkm1
85         DO jj = 1, jpj
86            DO ji = 1, jpi
87               zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
88               zfact   = xstep * tgfunc2(ji,jj,jk) * zcompaz
89
90               !  Respiration rates of both zooplankton
91               !  -------------------------------------
92               zrespz = resrat * zfact * trb(ji,jj,jk,jpzoo) / ( xkmort + trb(ji,jj,jk,jpzoo) )  &
93                  &   + resrat * zfact * 3. * nitrfac(ji,jj,jk)
94
95               !  Zooplankton mortality. A square function has been selected with
96               !  no real reason except that it seems to be more stable and may mimic predation.
97               !  ---------------------------------------------------------------
98               ztortz = mzrat * 1.e6 * zfact * trb(ji,jj,jk,jpzoo)
99
100               zcompadi  = MIN( MAX( ( trb(ji,jj,jk,jpdia) - xthreshdia ), 0.e0 ), xsizedia )
101               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthreshphy ), 0.e0 )
102               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthreshpoc ), 0.e0 )
103               
104               !     Microzooplankton grazing
105               !     ------------------------
106               zfood     = xpref2p * zcompaph + xpref2c * zcompapoc + xpref2d * zcompadi
107               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
108               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
109               zdenom2   = zdenom / ( zfood + rtrn )
110               zgraze    = grazrat * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpzoo) 
111
112               zgrazp    = zgraze  * xpref2p * zcompaph  * zdenom2 
113               zgrazm    = zgraze  * xpref2c * zcompapoc * zdenom2 
114               zgrazsd   = zgraze  * xpref2d * zcompadi  * zdenom2 
115
116               zgrazpf   = zgrazp  * trb(ji,jj,jk,jpnfe) / (trb(ji,jj,jk,jpphy) + rtrn)
117               zgrazmf   = zgrazm  * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
118               zgrazsf   = zgrazsd * trb(ji,jj,jk,jpdfe) / (trb(ji,jj,jk,jpdia) + rtrn)
119               !
120               zgraztot  = zgrazp  + zgrazm  + zgrazsd 
121               zgraztotf = zgrazpf + zgrazsf + zgrazmf 
122               zgraztotn = zgrazp * quotan(ji,jj,jk) + zgrazm + zgrazsd * quotad(ji,jj,jk)
123
124               ! Grazing by microzooplankton
125               zgrazing(ji,jj,jk) = zgraztot
126
127               !    Various remineralization and excretion terms
128               !    --------------------------------------------
129               zgrasrat  = ( zgraztotf + rtrn ) / ( zgraztot + rtrn )
130               zgrasratn = ( zgraztotn + rtrn ) / ( zgraztot + rtrn )
131               zepshert  =  MIN( 1., zgrasratn, zgrasrat / ferat3)
132               zepsherv  = zepshert * MIN( epsher, (1. - unass) * zgrasrat / ferat3, (1. - unass) * zgrasratn )
133               zgrafer   = zgraztot * MAX( 0. , ( 1. - unass ) * zgrasrat - ferat3 * zepsherv ) 
134               zgrarem   = zgraztot * ( 1. - zepsherv - unass )
135               zgrapoc   = zgraztot * unass
136
137               !  Update of the TRA arrays
138               !  ------------------------
139               zgrarsig  = zgrarem * sigma1
140               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
141               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
142               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem - zgrarsig
143               !
144               IF( ln_ligand ) tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + (zgrarem - zgrarsig) * ldocz
145               !
146               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
147               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer
148               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc
149               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zgrapoc
150               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zgraztotf * unass
151               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
152               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig
153               !   Update the arrays TRA which contain the biological sources and sinks
154               !   --------------------------------------------------------------------
155               zmortz = ztortz + zrespz
156               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zmortz + zepsherv * zgraztot 
157               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazp
158               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazsd
159               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazp  * trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
160               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazsd * trb(ji,jj,jk,jpdch)/(trb(ji,jj,jk,jpdia)+rtrn)
161               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
162               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
163               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgrazpf
164               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazsf
165               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz - zgrazm
166               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zmortz
167               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazm
168               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz - zgrazmf
169               !
170               ! calcite production
171               zprcaca = xfracal(ji,jj,jk) * zgrazp
172               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
173               !
174               zprcaca = part * zprcaca
175               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
176               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
177               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
178            END DO
179         END DO
180      END DO
181      !
182      IF( lk_iomput ) THEN
183         IF( knt == nrdttrc ) THEN
184           CALL wrk_alloc( jpi, jpj, jpk, zw3d )
185           IF( iom_use( "GRAZ1" ) ) THEN
186!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
187              DO jk = 1, jpk
188                 DO jj = 1, jpj
189                    DO ji = 1, jpi
190                       zw3d(ji,jj,jk) = zgrazing(ji,jj,jk) * 1.e+3 * rfact2r * tmask(ji,jj,jk)  !  Total grazing of phyto by zooplankton
191                    END DO
192                 END DO
193              END DO
194              CALL iom_put( "GRAZ1", zw3d )
195           ENDIF
196           CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
197         ENDIF
198      ENDIF
199      !
200      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
201         WRITE(charout, FMT="('micro')")
202         CALL prt_ctl_trc_info(charout)
203         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
204      ENDIF
205      !
206      CALL wrk_dealloc( jpi, jpj, jpk, zgrazing )
207      !
208      IF( nn_timing == 1 )  CALL timing_stop('p4z_micro')
209      !
210   END SUBROUTINE p4z_micro
211
212
213   SUBROUTINE p4z_micro_init
214
215      !!----------------------------------------------------------------------
216      !!                  ***  ROUTINE p4z_micro_init  ***
217      !!
218      !! ** Purpose :   Initialization of microzooplankton parameters
219      !!
220      !! ** Method  :   Read the nampiszoo namelist and check the parameters
221      !!                called at the first timestep (nittrc000)
222      !!
223      !! ** input   :   Namelist nampiszoo
224      !!
225      !!----------------------------------------------------------------------
226
227      NAMELIST/namp4zzoo/ part, grazrat, resrat, mzrat, xpref2c, xpref2p, &
228         &                xpref2d,  xthreshdia,  xthreshphy,  xthreshpoc, &
229         &                xthresh, xkgraz, epsher, sigma1, unass
230      INTEGER :: ios                 ! Local integer output status for namelist read
231
232      REWIND( numnatp_ref )              ! Namelist nampiszoo in reference namelist : Pisces microzooplankton
233      READ  ( numnatp_ref, namp4zzoo, IOSTAT = ios, ERR = 901)
234901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zzoo in reference namelist', lwp )
235
236      REWIND( numnatp_cfg )              ! Namelist nampiszoo in configuration namelist : Pisces microzooplankton
237      READ  ( numnatp_cfg, namp4zzoo, IOSTAT = ios, ERR = 902 )
238902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zzoo in configuration namelist', lwp )
239      IF(lwm) WRITE ( numonp, namp4zzoo )
240
241      IF(lwp) THEN                         ! control print
242         WRITE(numout,*) ' '
243         WRITE(numout,*) ' Namelist parameters for microzooplankton, namp4zzoo'
244         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
245         WRITE(numout,*) '    part of calcite not dissolved in microzoo guts  part        =', part
246         WRITE(numout,*) '    microzoo preference for POC                     xpref2c     =', xpref2c
247         WRITE(numout,*) '    microzoo preference for nano                    xpref2p     =', xpref2p
248         WRITE(numout,*) '    microzoo preference for diatoms                 xpref2d     =', xpref2d
249         WRITE(numout,*) '    diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
250         WRITE(numout,*) '    nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
251         WRITE(numout,*) '    poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
252         WRITE(numout,*) '    feeding threshold for microzooplankton          xthresh     =', xthresh
253         WRITE(numout,*) '    exsudation rate of microzooplankton             resrat      =', resrat
254         WRITE(numout,*) '    microzooplankton mortality rate                 mzrat       =', mzrat
255         WRITE(numout,*) '    maximal microzoo grazing rate                   grazrat     =', grazrat
256         WRITE(numout,*) '    non assimilated fraction of P by microzoo       unass       =', unass
257         WRITE(numout,*) '    Efficicency of microzoo growth                  epsher      =', epsher
258         WRITE(numout,*) '    Fraction of microzoo excretion as DOM           sigma1      =', sigma1
259         WRITE(numout,*) '    half sturation constant for grazing 1           xkgraz      =', xkgraz
260      ENDIF
261
262   END SUBROUTINE p4z_micro_init
263
264   !!======================================================================
265END MODULE p4zmicro
Note: See TracBrowser for help on using the repository browser.