source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmicro.F90 @ 8533

Last change on this file since 8533 was 8533, checked in by cetlod, 3 years ago

trunk: bugfixes to solve problem particle in PISCES, see ticket #1940

File size: 13.7 KB
Line 
1MODULE p4zmicro
2   !!======================================================================
3   !!                         ***  MODULE p4zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_micro       :   Compute the sources/sinks for microzooplankton
11   !!   p4z_micro_init  :   Initialize and read the appropriate namelist
12   !!----------------------------------------------------------------------
13   USE oce_trc         !  shared variables between ocean and passive tracers
14   USE trc             !  passive tracers common variables
15   USE sms_pisces      !  PISCES Source Minus Sink variables
16   USE p4zlim          !  Co-limitations
17   USE p4zprod         !  production
18   USE iom             !  I/O manager
19   USE prtctl_trc      !  print control for debugging
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_micro         ! called in p4zbio.F90
25   PUBLIC   p4z_micro_init    ! called in trcsms_pisces.F90
26
27   !! * Shared module variables
28   REAL(wp), PUBLIC ::  part        !: part of calcite not dissolved in microzoo guts
29   REAL(wp), PUBLIC ::  xpref2c     !: microzoo preference for POC
30   REAL(wp), PUBLIC ::  xpref2p     !: microzoo preference for nanophyto
31   REAL(wp), PUBLIC ::  xpref2d     !: microzoo preference for diatoms
32   REAL(wp), PUBLIC ::  xthreshdia  !: diatoms feeding threshold for microzooplankton
33   REAL(wp), PUBLIC ::  xthreshphy  !: nanophyto threshold for microzooplankton
34   REAL(wp), PUBLIC ::  xthreshpoc  !: poc threshold for microzooplankton
35   REAL(wp), PUBLIC ::  xthresh     !: feeding threshold for microzooplankton
36   REAL(wp), PUBLIC ::  resrat      !: exsudation rate of microzooplankton
37   REAL(wp), PUBLIC ::  mzrat       !: microzooplankton mortality rate
38   REAL(wp), PUBLIC ::  grazrat     !: maximal microzoo grazing rate
39   REAL(wp), PUBLIC ::  xkgraz      !: non assimilated fraction of P by microzoo
40   REAL(wp), PUBLIC ::  unass       !: Efficicency of microzoo growth
41   REAL(wp), PUBLIC ::  sigma1      !: Fraction of microzoo excretion as DOM
42   REAL(wp), PUBLIC ::  epsher      !: half sturation constant for grazing 1
43
44
45   !!----------------------------------------------------------------------
46   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
47   !! $Id: p4zmicro.F90 3160 2011-11-20 14:27:18Z cetlod $
48   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50
51CONTAINS
52
53   SUBROUTINE p4z_micro( kt, knt )
54      !!---------------------------------------------------------------------
55      !!                     ***  ROUTINE p4z_micro  ***
56      !!
57      !! ** Purpose :   Compute the sources/sinks for microzooplankton
58      !!
59      !! ** Method  : - ???
60      !!---------------------------------------------------------------------
61      INTEGER, INTENT(in) ::  kt  ! ocean time step
62      INTEGER, INTENT(in) ::  knt 
63      !
64      INTEGER  :: ji, jj, jk
65      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc
66      REAL(wp) :: zgraze  , zdenom, zdenom2
67      REAL(wp) :: zfact   , zfood, zfoodlim
68      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotn, zgraztotf
69      REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz
70      REAL(wp) :: zrespz, ztortz, zgrasrat, zgrasratn
71      REAL(wp) :: zgrazp, zgrazm, zgrazsd
72      REAL(wp) :: zgrazmf, zgrazsf, zgrazpf
73      REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing, zw3d
74      CHARACTER (len=25) :: charout
75      !!---------------------------------------------------------------------
76      !
77      IF( nn_timing == 1 )  CALL timing_start('p4z_micro')
78      !
79      CALL wrk_alloc( jpi, jpj, jpk, zgrazing )
80      !
81      DO jk = 1, jpkm1
82         DO jj = 1, jpj
83            DO ji = 1, jpi
84               zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
85               zfact   = xstep * tgfunc2(ji,jj,jk) * zcompaz
86
87               !  Respiration rates of both zooplankton
88               !  -------------------------------------
89               zrespz = resrat * zfact * trb(ji,jj,jk,jpzoo) / ( xkmort + trb(ji,jj,jk,jpzoo) )  &
90                  &   + resrat * zfact * 3. * nitrfac(ji,jj,jk)
91
92               !  Zooplankton mortality. A square function has been selected with
93               !  no real reason except that it seems to be more stable and may mimic predation.
94               !  ---------------------------------------------------------------
95               ztortz = mzrat * 1.e6 * zfact * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk))
96
97               zcompadi  = MIN( MAX( ( trb(ji,jj,jk,jpdia) - xthreshdia ), 0.e0 ), xsizedia )
98               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthreshphy ), 0.e0 )
99               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthreshpoc ), 0.e0 )
100               
101               !     Microzooplankton grazing
102               !     ------------------------
103               zfood     = xpref2p * zcompaph + xpref2c * zcompapoc + xpref2d * zcompadi
104               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
105               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
106               zdenom2   = zdenom / ( zfood + rtrn )
107               zgraze    = grazrat * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk))
108
109               zgrazp    = zgraze  * xpref2p * zcompaph  * zdenom2 
110               zgrazm    = zgraze  * xpref2c * zcompapoc * zdenom2 
111               zgrazsd   = zgraze  * xpref2d * zcompadi  * zdenom2 
112
113               zgrazpf   = zgrazp  * trb(ji,jj,jk,jpnfe) / (trb(ji,jj,jk,jpphy) + rtrn)
114               zgrazmf   = zgrazm  * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
115               zgrazsf   = zgrazsd * trb(ji,jj,jk,jpdfe) / (trb(ji,jj,jk,jpdia) + rtrn)
116               !
117               zgraztot  = zgrazp  + zgrazm  + zgrazsd 
118               zgraztotf = zgrazpf + zgrazsf + zgrazmf 
119               zgraztotn = zgrazp * quotan(ji,jj,jk) + zgrazm + zgrazsd * quotad(ji,jj,jk)
120
121               ! Grazing by microzooplankton
122               zgrazing(ji,jj,jk) = zgraztot
123
124               !    Various remineralization and excretion terms
125               !    --------------------------------------------
126               zgrasrat  = ( zgraztotf + rtrn ) / ( zgraztot + rtrn )
127               zgrasratn = ( zgraztotn + rtrn ) / ( zgraztot + rtrn )
128               zepshert  =  MIN( 1., zgrasratn, zgrasrat / ferat3)
129               zepsherv  = zepshert * MIN( epsher, (1. - unass) * zgrasrat / ferat3, (1. - unass) * zgrasratn )
130               zgrafer   = zgraztot * MAX( 0. , ( 1. - unass ) * zgrasrat - ferat3 * zepsherv ) 
131               zgrarem   = zgraztot * ( 1. - zepsherv - unass )
132               zgrapoc   = zgraztot * unass
133
134               !  Update of the TRA arrays
135               !  ------------------------
136               zgrarsig  = zgrarem * sigma1
137               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
138               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
139               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem - zgrarsig
140               !
141               IF( ln_ligand ) tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + (zgrarem - zgrarsig) * ldocz
142               !
143               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
144               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer
145               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc
146               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zgrapoc
147               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zgraztotf * unass
148               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
149               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig
150               !   Update the arrays TRA which contain the biological sources and sinks
151               !   --------------------------------------------------------------------
152               zmortz = ztortz + zrespz
153               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zmortz + zepsherv * zgraztot 
154               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazp
155               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazsd
156               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazp  * trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
157               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazsd * trb(ji,jj,jk,jpdch)/(trb(ji,jj,jk,jpdia)+rtrn)
158               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
159               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
160               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgrazpf
161               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazsf
162               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz - zgrazm
163               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zmortz
164               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazm
165               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz - zgrazmf
166               !
167               ! calcite production
168               zprcaca = xfracal(ji,jj,jk) * zgrazp
169               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
170               !
171               zprcaca = part * zprcaca
172               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
173               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
174               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
175            END DO
176         END DO
177      END DO
178      !
179      IF( lk_iomput ) THEN
180         IF( knt == nrdttrc ) THEN
181           CALL wrk_alloc( jpi, jpj, jpk, zw3d )
182           IF( iom_use( "GRAZ1" ) ) THEN
183              zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !  Total grazing of phyto by zooplankton
184              CALL iom_put( "GRAZ1", zw3d )
185           ENDIF
186           CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
187         ENDIF
188      ENDIF
189      !
190      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
191         WRITE(charout, FMT="('micro')")
192         CALL prt_ctl_trc_info(charout)
193         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
194      ENDIF
195      !
196      CALL wrk_dealloc( jpi, jpj, jpk, zgrazing )
197      !
198      IF( nn_timing == 1 )  CALL timing_stop('p4z_micro')
199      !
200   END SUBROUTINE p4z_micro
201
202
203   SUBROUTINE p4z_micro_init
204
205      !!----------------------------------------------------------------------
206      !!                  ***  ROUTINE p4z_micro_init  ***
207      !!
208      !! ** Purpose :   Initialization of microzooplankton parameters
209      !!
210      !! ** Method  :   Read the nampiszoo namelist and check the parameters
211      !!                called at the first timestep (nittrc000)
212      !!
213      !! ** input   :   Namelist nampiszoo
214      !!
215      !!----------------------------------------------------------------------
216
217      NAMELIST/namp4zzoo/ part, grazrat, resrat, mzrat, xpref2c, xpref2p, &
218         &                xpref2d,  xthreshdia,  xthreshphy,  xthreshpoc, &
219         &                xthresh, xkgraz, epsher, sigma1, unass
220      INTEGER :: ios                 ! Local integer output status for namelist read
221
222      REWIND( numnatp_ref )              ! Namelist nampiszoo in reference namelist : Pisces microzooplankton
223      READ  ( numnatp_ref, namp4zzoo, IOSTAT = ios, ERR = 901)
224901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zzoo in reference namelist', lwp )
225
226      REWIND( numnatp_cfg )              ! Namelist nampiszoo in configuration namelist : Pisces microzooplankton
227      READ  ( numnatp_cfg, namp4zzoo, IOSTAT = ios, ERR = 902 )
228902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zzoo in configuration namelist', lwp )
229      IF(lwm) WRITE ( numonp, namp4zzoo )
230
231      IF(lwp) THEN                         ! control print
232         WRITE(numout,*) ' '
233         WRITE(numout,*) ' Namelist parameters for microzooplankton, namp4zzoo'
234         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
235         WRITE(numout,*) '    part of calcite not dissolved in microzoo guts  part        =', part
236         WRITE(numout,*) '    microzoo preference for POC                     xpref2c     =', xpref2c
237         WRITE(numout,*) '    microzoo preference for nano                    xpref2p     =', xpref2p
238         WRITE(numout,*) '    microzoo preference for diatoms                 xpref2d     =', xpref2d
239         WRITE(numout,*) '    diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
240         WRITE(numout,*) '    nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
241         WRITE(numout,*) '    poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
242         WRITE(numout,*) '    feeding threshold for microzooplankton          xthresh     =', xthresh
243         WRITE(numout,*) '    exsudation rate of microzooplankton             resrat      =', resrat
244         WRITE(numout,*) '    microzooplankton mortality rate                 mzrat       =', mzrat
245         WRITE(numout,*) '    maximal microzoo grazing rate                   grazrat     =', grazrat
246         WRITE(numout,*) '    non assimilated fraction of P by microzoo       unass       =', unass
247         WRITE(numout,*) '    Efficicency of microzoo growth                  epsher      =', epsher
248         WRITE(numout,*) '    Fraction of microzoo excretion as DOM           sigma1      =', sigma1
249         WRITE(numout,*) '    half sturation constant for grazing 1           xkgraz      =', xkgraz
250      ENDIF
251
252   END SUBROUTINE p4z_micro_init
253
254   !!======================================================================
255END MODULE p4zmicro
Note: See TracBrowser for help on using the repository browser.