source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zprod.F90 @ 6945

Last change on this file since 6945 was 6945, checked in by cetlod, 4 years ago

trunk: bugfixes on PISCES carbon chemistry, see ticket #1774

File size: 30.0 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_prod       :   Compute the growth Rate of the two phytoplanktons groups
15   !!   p4z_prod_init  :   Initialization of the parameters for growth
16   !!   p4z_prod_alloc :   Allocate variables for growth
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p4zopt          !  optical model
22   USE p4zlim          !  Co-limitations of differents nutrients
23   USE prtctl_trc      !  print control for debugging
24   USE iom             !  I/O manager
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_prod         ! called in p4zbio.F90
30   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
31   PUBLIC   p4z_prod_alloc
32
33   !! * Shared module variables
34   LOGICAL , PUBLIC ::  ln_newprod      !:
35   REAL(wp), PUBLIC ::  pislope         !:
36   REAL(wp), PUBLIC ::  pislope2        !:
37   REAL(wp), PUBLIC ::  xadap           !:
38   REAL(wp), PUBLIC ::  excret          !:
39   REAL(wp), PUBLIC ::  excret2         !:
40   REAL(wp), PUBLIC ::  bresp           !:
41   REAL(wp), PUBLIC ::  chlcnm          !:
42   REAL(wp), PUBLIC ::  chlcdm          !:
43   REAL(wp), PUBLIC ::  chlcmin         !:
44   REAL(wp), PUBLIC ::  fecnm           !:
45   REAL(wp), PUBLIC ::  fecdm           !:
46   REAL(wp), PUBLIC ::  grosip          !:
47
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmax    !: optimal production = f(temperature)
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
51   
52   REAL(wp) :: r1_rday                !: 1 / rday
53   REAL(wp) :: texcret                !: 1 - excret
54   REAL(wp) :: texcret2               !: 1 - excret2       
55
56   !!----------------------------------------------------------------------
57   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
58   !! $Id: p4zprod.F90 3160 2011-11-20 14:27:18Z cetlod $
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE p4z_prod( kt , knt )
64      !!---------------------------------------------------------------------
65      !!                     ***  ROUTINE p4z_prod  ***
66      !!
67      !! ** Purpose :   Compute the phytoplankton production depending on
68      !!              light, temperature and nutrient availability
69      !!
70      !! ** Method  : - ???
71      !!---------------------------------------------------------------------
72      !
73      INTEGER, INTENT(in) :: kt, knt
74      !
75      INTEGER  ::   ji, jj, jk
76      REAL(wp) ::   zsilfac, znanotot, zdiattot, zconctemp, zconctemp2
77      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap
78      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zproreg, zproreg2
79      REAL(wp) ::   zmxltst, zmxlday, zmaxday
80      REAL(wp) ::   zpislopen  , zpislope2n
81      REAL(wp) ::   zrum, zcodel, zargu, zval
82      REAL(wp) ::   zfact
83      CHARACTER (len=25) :: charout
84      REAL(wp), POINTER, DIMENSION(:,:  ) :: zmixnano, zmixdiat, zstrn, zw2d
85      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt, zw3d   
86      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd
87      !!---------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('p4z_prod')
90      !
91      !  Allocate temporary workspace
92      CALL wrk_alloc( jpi, jpj,      zmixnano, zmixdiat, zstrn                                                  )
93      CALL wrk_alloc( jpi, jpj, jpk, zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt            ) 
94      CALL wrk_alloc( jpi, jpj, jpk, zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd )
95      !
96      zprorca (:,:,:) = 0._wp
97      zprorcad(:,:,:) = 0._wp
98      zprofed (:,:,:) = 0._wp
99      zprofen (:,:,:) = 0._wp
100      zprochln(:,:,:) = 0._wp
101      zprochld(:,:,:) = 0._wp
102      zpronew (:,:,:) = 0._wp
103      zpronewd(:,:,:) = 0._wp
104      zprdia  (:,:,:) = 0._wp
105      zprbio  (:,:,:) = 0._wp
106      zprdch  (:,:,:) = 0._wp
107      zprnch  (:,:,:) = 0._wp
108      zysopt  (:,:,:) = 0._wp
109
110      ! Computation of the optimal production
111      prmax(:,:,:) = 0.6_wp * r1_rday * tgfunc(:,:,:) 
112      IF( lk_degrad )  prmax(:,:,:) = prmax(:,:,:) * facvol(:,:,:) 
113
114      ! compute the day length depending on latitude and the day
115      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
116      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
117
118      ! day length in hours
119      zstrn(:,:) = 0.
120      DO jj = 1, jpj
121         DO ji = 1, jpi
122            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
123            zargu = MAX( -1., MIN(  1., zargu ) )
124            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
125         END DO
126      END DO
127
128      ! Impact of the day duration on phytoplankton growth
129      DO jk = 1, jpkm1
130         DO jj = 1 ,jpj
131            DO ji = 1, jpi
132               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
133                  zval = MAX( 1., zstrn(ji,jj) )
134                  zval = 1.5 * zval / ( 12. + zval )
135                  zprbio(ji,jj,jk) = prmax(ji,jj,jk) * zval * ( 1. - fr_i(ji,jj) )
136                  zprdia(ji,jj,jk) = zprbio(ji,jj,jk)
137               ENDIF
138            END DO
139         END DO
140      END DO
141
142      ! Maximum light intensity
143      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
144      zstrn(:,:) = 24. / zstrn(:,:)
145
146      IF( ln_newprod ) THEN
147         DO jk = 1, jpkm1
148            DO jj = 1, jpj
149               DO ji = 1, jpi
150                  ! Computation of the P-I slope for nanos and diatoms
151                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
152                      ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
153                      zadap       = xadap * ztn / ( 2.+ ztn )
154                      zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
155                      zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
156                      znanotot    = enano(ji,jj,jk) * zstrn(ji,jj)
157                      zdiattot    = ediat(ji,jj,jk) * zstrn(ji,jj)
158                      !
159                      zpislopead (ji,jj,jk) = pislope * ( 1.+ zadap  * EXP( -znanotot ) )  &
160                         &                   * trb(ji,jj,jk,jpnch) /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
161                      !
162                      zpislopead2(ji,jj,jk) = (pislope * zconctemp2 + pislope2 * zconctemp) / ( trb(ji,jj,jk,jpdia) + rtrn )   &
163                         &                   * trb(ji,jj,jk,jpdch) /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
164
165                      ! Computation of production function for Carbon
166                      !  ---------------------------------------------
167                      zpislopen  = zpislopead (ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) * rday + rtrn)
168                      zpislope2n = zpislopead2(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) * rday + rtrn)
169                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen  * znanotot )  )
170                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpislope2n * zdiattot )  )
171
172                      !  Computation of production function for Chlorophyll
173                      !--------------------------------------------------
174                      zmaxday  = 1._wp / ( prmax(ji,jj,jk) * rday + rtrn )
175                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopead (ji,jj,jk) * zmaxday * znanotot ) )
176                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopead2(ji,jj,jk) * zmaxday * zdiattot ) )
177                  ENDIF
178               END DO
179            END DO
180         END DO
181      ELSE
182         DO jk = 1, jpkm1
183            DO jj = 1, jpj
184               DO ji = 1, jpi
185
186                  ! Computation of the P-I slope for nanos and diatoms
187                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
188                      ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
189                      zadap       = ztn / ( 2.+ ztn )
190                      zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
191                      zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
192                      znanotot    = enano(ji,jj,jk) * zstrn(ji,jj)
193                      zdiattot    = ediat(ji,jj,jk) * zstrn(ji,jj)
194                      !
195                      zpislopead (ji,jj,jk) = pislope  * ( 1.+ zadap  * EXP( -znanotot ) )
196                      zpislopead2(ji,jj,jk) = (pislope * zconctemp2 + pislope2 * zconctemp)  / ( trb(ji,jj,jk,jpdia) + rtrn )
197
198                      zpislopen =  zpislopead(ji,jj,jk) * trb(ji,jj,jk,jpnch)                &
199                        &          / ( trb(ji,jj,jk,jpphy) * 12.                  + rtrn )   &
200                        &          / ( prmax(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
201
202                      zpislope2n = zpislopead2(ji,jj,jk) * trb(ji,jj,jk,jpdch)                &
203                        &          / ( trb(ji,jj,jk,jpdia) * 12.                  + rtrn )   &
204                        &          / ( prmax(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
205
206                      ! Computation of production function for Carbon
207                      !  ---------------------------------------------
208                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen  * znanotot ) )
209                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpislope2n * zdiattot ) )
210
211                      !  Computation of production function for Chlorophyll
212                      !--------------------------------------------------
213                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen  * enano(ji,jj,jk) ) )
214                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislope2n * ediat(ji,jj,jk) ) )
215                  ENDIF
216               END DO
217            END DO
218         END DO
219      ENDIF
220
221
222      !  Computation of a proxy of the N/C ratio
223      !  ---------------------------------------
224      DO jk = 1, jpkm1
225         DO jj = 1, jpj
226            DO ji = 1, jpi
227                zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) )   &
228                &      * prmax(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
229                quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
230                zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) )   &
231                &      * prmax(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
232                quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
233            END DO
234         END DO
235      END DO
236
237
238      DO jk = 1, jpkm1
239         DO jj = 1, jpj
240            DO ji = 1, jpi
241
242                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
243                   !    Si/C of diatoms
244                   !    ------------------------
245                   !    Si/C increases with iron stress and silicate availability
246                   !    Si/C is arbitrariliy increased for very high Si concentrations
247                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
248                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
249                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmax(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
250                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
251                  zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil)
252                  IF (gphit(ji,jj) < -30 ) THEN
253                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
254                  ELSE
255                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
256                  ENDIF
257                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
258              ENDIF
259            END DO
260         END DO
261      END DO
262
263      !  Computation of the limitation term due to a mixed layer deeper than the euphotic depth
264      DO jj = 1, jpj
265         DO ji = 1, jpi
266            zmxltst = MAX( 0.e0, hmld(ji,jj) - heup(ji,jj) )
267            zmxlday = zmxltst * zmxltst * r1_rday
268            zmixnano(ji,jj) = 1. - zmxlday / ( 2. + zmxlday )
269            zmixdiat(ji,jj) = 1. - zmxlday / ( 4. + zmxlday )
270         END DO
271      END DO
272 
273      !  Mixed-layer effect on production                                                                               
274      DO jk = 1, jpkm1
275         DO jj = 1, jpj
276            DO ji = 1, jpi
277               IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
278                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * zmixnano(ji,jj)
279                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * zmixdiat(ji,jj)
280               ENDIF
281               zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
282               zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
283            END DO
284         END DO
285      END DO
286
287      ! Computation of the various production terms
288      DO jk = 1, jpkm1
289         DO jj = 1, jpj
290            DO ji = 1, jpi
291               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
292                  !  production terms for nanophyto.
293                  zprorca(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
294                  zpronew(ji,jj,jk) = zprorca(ji,jj,jk) * xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
295                  !
296                  zratio = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn )
297                  zratio = zratio / fecnm 
298                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
299                  zprofen(ji,jj,jk) = fecnm * prmax(ji,jj,jk)  &
300                  &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
301                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) )  &
302                  &             * zmax * trb(ji,jj,jk,jpphy) * rfact2
303                  !  production terms for diatomees
304                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
305                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
306                  !
307                  zratio = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn )
308                  zratio = zratio / fecdm 
309                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
310                  zprofed(ji,jj,jk) = fecdm * prmax(ji,jj,jk)  &
311                  &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
312                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) )  &
313                  &             * zmax * trb(ji,jj,jk,jpdia) * rfact2
314               ENDIF
315            END DO
316         END DO
317      END DO
318
319      DO jk = 1, jpkm1
320         DO jj = 1, jpj
321            DO ji = 1, jpi
322               IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
323                  zprnch(ji,jj,jk) = zprnch(ji,jj,jk) * zmixnano(ji,jj)
324                  zprdch(ji,jj,jk) = zprdch(ji,jj,jk) * zmixdiat(ji,jj)
325               ENDIF
326               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
327                  !  production terms for nanophyto. ( chlorophyll )
328                  znanotot = enano(ji,jj,jk) * zstrn(ji,jj)
329                  zprod    = rday * zprorca(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
330                  zprochln(ji,jj,jk) = chlcmin * 12. * zprorca (ji,jj,jk)
331                  zprochln(ji,jj,jk) = zprochln(ji,jj,jk) + (chlcnm-chlcmin) * 12. * zprod / &
332                                     & (  zpislopead(ji,jj,jk) * znanotot +rtrn)
333                  !  production terms for diatomees ( chlorophyll )
334                  zdiattot = ediat(ji,jj,jk) * zstrn(ji,jj)
335                  zprod = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
336                  zprochld(ji,jj,jk) = chlcmin * 12. * zprorcad(ji,jj,jk)
337                  zprochld(ji,jj,jk) = zprochld(ji,jj,jk) + (chlcdm-chlcmin) * 12. * zprod / &
338                                     & ( zpislopead2(ji,jj,jk) * zdiattot +rtrn )
339               ENDIF
340            END DO
341         END DO
342      END DO
343
344      !   Update the arrays TRA which contain the biological sources and sinks
345      DO jk = 1, jpkm1
346         DO jj = 1, jpj
347           DO ji =1 ,jpi
348              zproreg  = zprorca(ji,jj,jk) - zpronew(ji,jj,jk)
349              zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
350              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
351              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronew(ji,jj,jk) - zpronewd(ji,jj,jk)
352              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
353              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorca(ji,jj,jk) * texcret
354              tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln(ji,jj,jk) * texcret
355              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcret
356              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcret2
357              tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld(ji,jj,jk) * texcret2
358              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcret2
359              tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcret2
360              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + excret2 * zprorcad(ji,jj,jk) + excret * zprorca(ji,jj,jk)
361              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
362                 &                + ( o2ut + o2nit ) * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) )
363              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - texcret * zprofen(ji,jj,jk) - texcret2 * zprofed(ji,jj,jk)
364              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcret2 * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
365              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
366              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
367                 &                                      - rno3 * ( zproreg + zproreg2 )
368          END DO
369        END DO
370     END DO
371
372
373    ! Total primary production per year
374    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
375         & tpp = glob_sum( ( zprorca(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
376
377    IF( lk_iomput ) THEN
378       IF( knt == nrdttrc ) THEN
379          CALL wrk_alloc( jpi, jpj,      zw2d )
380          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
381          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
382          !
383          IF( iom_use( "PPPHY" ) .OR. iom_use( "PPPHY2" ) )  THEN
384              zw3d(:,:,:) = zprorca (:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
385              CALL iom_put( "PPPHY"  , zw3d )
386              !
387              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatomes
388              CALL iom_put( "PPPHY2"  , zw3d )
389          ENDIF
390          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) )  THEN
391              zw3d(:,:,:) = zpronew (:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
392              CALL iom_put( "PPNEWN"  , zw3d )
393              !
394              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatomes
395              CALL iom_put( "PPNEWD"  , zw3d )
396          ENDIF
397          IF( iom_use( "PBSi" ) )  THEN
398              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
399              CALL iom_put( "PBSi"  , zw3d )
400          ENDIF
401          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) )  THEN
402              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by nanophyto
403              CALL iom_put( "PFeN"  , zw3d )
404              !
405              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by  diatomes
406              CALL iom_put( "PFeD"  , zw3d )
407          ENDIF
408          IF( iom_use( "Mumax" ) )  THEN
409              zw3d(:,:,:) = prmax(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
410              CALL iom_put( "Mumax"  , zw3d )
411          ENDIF
412          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) )  THEN
413              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
414              CALL iom_put( "MuN"  , zw3d )
415              !
416              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
417              CALL iom_put( "MuD"  , zw3d )
418          ENDIF
419          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) )  THEN
420              zw3d(:,:,:) = zprbio (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
421              CALL iom_put( "LNlight"  , zw3d )
422              !
423              zw3d(:,:,:) =  zprdia (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term
424              CALL iom_put( "LDlight"  , zw3d )
425          ENDIF
426          IF( iom_use( "TPP" ) )  THEN
427              zw3d(:,:,:) = ( zprorca(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  ! total primary production
428              CALL iom_put( "TPP"  , zw3d )
429          ENDIF
430          IF( iom_use( "TPNEW" ) )  THEN
431              zw3d(:,:,:) = ( zpronew(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ! total new production
432              CALL iom_put( "TPNEW"  , zw3d )
433          ENDIF
434          IF( iom_use( "TPBFE" ) )  THEN
435              zw3d(:,:,:) = ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:)  ! total biogenic iron production
436              CALL iom_put( "TPBFE"  , zw3d )
437          ENDIF
438          IF( iom_use( "INTPPPHY" ) .OR. iom_use( "INTPPPHY2" ) ) THEN 
439             zw2d(:,:) = 0.
440             DO jk = 1, jpkm1
441               zw2d(:,:) = zw2d(:,:) + zprorca (:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated  primary produc. by nano
442             ENDDO
443             CALL iom_put( "INTPPPHY" , zw2d )
444             !
445             zw2d(:,:) = 0.
446             DO jk = 1, jpkm1
447                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated  primary produc. by diatom
448             ENDDO
449             CALL iom_put( "INTPPPHY2" , zw2d )
450          ENDIF
451          IF( iom_use( "INTPP" ) ) THEN   
452             zw2d(:,:) = 0.
453             DO jk = 1, jpkm1
454                zw2d(:,:) = zw2d(:,:) + ( zprorca(:,:,jk) + zprorcad(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated pp
455             ENDDO
456             CALL iom_put( "INTPP" , zw2d )
457          ENDIF
458          IF( iom_use( "INTPNEW" ) ) THEN   
459             zw2d(:,:) = 0.
460             DO jk = 1, jpkm1
461                zw2d(:,:) = zw2d(:,:) + ( zpronew(:,:,jk) + zpronewd(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated new prod
462             ENDDO
463             CALL iom_put( "INTPNEW" , zw2d )
464          ENDIF
465          IF( iom_use( "INTPBFE" ) ) THEN           !   total biogenic iron production  ( vertically integrated )
466             zw2d(:,:) = 0.
467             DO jk = 1, jpkm1
468                zw2d(:,:) = zw2d(:,:) + ( zprofen(:,:,jk) + zprofed(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert integr. bfe prod
469             ENDDO
470            CALL iom_put( "INTPBFE" , zw2d )
471          ENDIF
472          IF( iom_use( "INTPBSI" ) ) THEN           !   total biogenic silica production  ( vertically integrated )
473             zw2d(:,:) = 0.
474             DO jk = 1, jpkm1
475                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * zysopt(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert integr. bsi prod
476             ENDDO
477             CALL iom_put( "INTPBSI" , zw2d )
478          ENDIF
479          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
480          !
481          CALL wrk_dealloc( jpi, jpj,      zw2d )
482          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
483       ENDIF
484     ELSE
485        IF( ln_diatrc ) THEN
486           zfact = 1.e+3 * rfact2r
487           trc3d(:,:,:,jp_pcs0_3d + 4)  = zprorca (:,:,:) * zfact * tmask(:,:,:)
488           trc3d(:,:,:,jp_pcs0_3d + 5)  = zprorcad(:,:,:) * zfact * tmask(:,:,:)
489           trc3d(:,:,:,jp_pcs0_3d + 6)  = zpronew (:,:,:) * zfact * tmask(:,:,:)
490           trc3d(:,:,:,jp_pcs0_3d + 7)  = zpronewd(:,:,:) * zfact * tmask(:,:,:)
491           trc3d(:,:,:,jp_pcs0_3d + 8)  = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:)
492           trc3d(:,:,:,jp_pcs0_3d + 9)  = zprofed (:,:,:) * zfact * tmask(:,:,:)
493#  if ! defined key_kriest
494           trc3d(:,:,:,jp_pcs0_3d + 10) = zprofen (:,:,:) * zfact * tmask(:,:,:)
495#  endif
496        ENDIF
497     ENDIF
498
499     IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
500         WRITE(charout, FMT="('prod')")
501         CALL prt_ctl_trc_info(charout)
502         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
503     ENDIF
504     !
505     CALL wrk_dealloc( jpi, jpj,      zmixnano, zmixdiat, zstrn                                                  )
506     CALL wrk_dealloc( jpi, jpj, jpk, zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt            ) 
507     CALL wrk_dealloc( jpi, jpj, jpk, zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd )
508     !
509     IF( nn_timing == 1 )  CALL timing_stop('p4z_prod')
510     !
511   END SUBROUTINE p4z_prod
512
513
514   SUBROUTINE p4z_prod_init
515      !!----------------------------------------------------------------------
516      !!                  ***  ROUTINE p4z_prod_init  ***
517      !!
518      !! ** Purpose :   Initialization of phytoplankton production parameters
519      !!
520      !! ** Method  :   Read the nampisprod namelist and check the parameters
521      !!      called at the first timestep (nittrc000)
522      !!
523      !! ** input   :   Namelist nampisprod
524      !!----------------------------------------------------------------------
525      !
526      NAMELIST/nampisprod/ pislope, pislope2, xadap, ln_newprod, bresp, excret, excret2,  &
527         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
528      INTEGER :: ios                 ! Local integer output status for namelist read
529      !!----------------------------------------------------------------------
530
531      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
532      READ  ( numnatp_ref, nampisprod, IOSTAT = ios, ERR = 901)
533901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in reference namelist', lwp )
534
535      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
536      READ  ( numnatp_cfg, nampisprod, IOSTAT = ios, ERR = 902 )
537902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in configuration namelist', lwp )
538      IF(lwm) WRITE ( numonp, nampisprod )
539
540      IF(lwp) THEN                         ! control print
541         WRITE(numout,*) ' '
542         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, nampisprod'
543         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
544         WRITE(numout,*) '    Enable new parame. of production (T/F)   ln_newprod   =', ln_newprod
545         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
546         WRITE(numout,*) '    P-I slope                                 pislope      =', pislope
547         WRITE(numout,*) '    Acclimation factor to low light           xadap       =', xadap
548         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excret       =', excret
549         WRITE(numout,*) '    excretion ratio of diatoms                excret2      =', excret2
550         IF( ln_newprod )  THEN
551            WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
552            WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
553         ENDIF
554         WRITE(numout,*) '    P-I slope  for diatoms                    pislope2     =', pislope2
555         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
556         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
557         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
558         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm        =', fecdm
559      ENDIF
560      !
561      r1_rday   = 1._wp / rday 
562      texcret   = 1._wp - excret
563      texcret2  = 1._wp - excret2
564      tpp       = 0._wp
565      !
566   END SUBROUTINE p4z_prod_init
567
568
569   INTEGER FUNCTION p4z_prod_alloc()
570      !!----------------------------------------------------------------------
571      !!                     ***  ROUTINE p4z_prod_alloc  ***
572      !!----------------------------------------------------------------------
573      ALLOCATE( prmax(jpi,jpj,jpk), quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
574      !
575      IF( p4z_prod_alloc /= 0 ) CALL ctl_warn('p4z_prod_alloc : failed to allocate arrays.')
576      !
577   END FUNCTION p4z_prod_alloc
578
579#else
580   !!======================================================================
581   !!  Dummy module :                                   No PISCES bio-model
582   !!======================================================================
583CONTAINS
584   SUBROUTINE p4z_prod                    ! Empty routine
585   END SUBROUTINE p4z_prod
586#endif 
587
588   !!======================================================================
589END MODULE p4zprod
Note: See TracBrowser for help on using the repository browser.