New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsed.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsed.F90 @ 7698

Last change on this file since 7698 was 7698, checked in by mocavero, 7 years ago

update trunk with OpenMP parallelization
  • Property svn:keywords set to Id
File size: 31.2 KB
Line 
1MODULE p4zsed
2   !!======================================================================
3   !!                         ***  MODULE p4sed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!----------------------------------------------------------------------
11   !!   p4z_sed        :  Compute loss of organic matter in the sediments
12   !!----------------------------------------------------------------------
13   USE oce_trc         !  shared variables between ocean and passive tracers
14   USE trc             !  passive tracers common variables
15   USE sms_pisces      !  PISCES Source Minus Sink variables
16   USE p4zlim          !  Co-limitations of differents nutrients
17   USE p4zsbc          !  External source of nutrients
18   USE p4zint          !  interpolation and computation of various fields
19   USE iom             !  I/O manager
20   USE prtctl_trc      !  print control for debugging
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p4z_sed 
26   PUBLIC   p4z_sed_alloc
27 
28   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: nitrpot    !: Nitrogen fixation
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:  ) :: sdenit     !: Nitrate reduction in the sediments
30   REAL(wp) :: r1_rday                  !: inverse of rday
31
32   !!----------------------------------------------------------------------
33   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
34   !! $Id$
35   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE p4z_sed( kt, knt )
40      !!---------------------------------------------------------------------
41      !!                     ***  ROUTINE p4z_sed  ***
42      !!
43      !! ** Purpose :   Compute loss of organic matter in the sediments. This
44      !!              is by no way a sediment model. The loss is simply
45      !!              computed to balance the inout from rivers and dust
46      !!
47      !! ** Method  : - ???
48      !!---------------------------------------------------------------------
49      !
50      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
51      INTEGER  ::   ji, jj, jk, ikt
52      REAL(wp) ::   zsumsedsi, zsumsedpo4, zsumsedcal
53      REAL(wp) ::   zrivalk, zrivsil, zrivno3
54      REAL(wp) ::  zwflux, zfminus, zfplus
55      REAL(wp) ::  zlim, zfact, zfactcal
56      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit, zdenitt, zolimit
57      REAL(wp) ::  zsiloss, zcaloss, zws3, zws4, zwsc, zdep
58      REAL(wp) ::  zwstpoc, zwstpon, zwstpop
59      REAL(wp) ::  ztrfer, ztrpo4s, ztrdp, zwdust, zmudia, ztemp
60      REAL(wp) ::  xdiano3, xdianh4
61      REAL(wp) ::  zwssfep
62      !
63      CHARACTER (len=25) :: charout
64      REAL(wp), POINTER, DIMENSION(:,:  ) :: zsidep, zwork1, zwork2, zwork3
65      REAL(wp), POINTER, DIMENSION(:,:  ) :: zdenit2d, zironice, zbureff
66      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwsbio3, zwsbio4, zwscal
67      REAL(wp), POINTER, DIMENSION(:,:  ) :: zsedcal, zsedsi, zsedc
68      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrpo4, ztrdop, zirondep, zsoufer, zpdep, zlight
69      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwsfep
70
71      !!---------------------------------------------------------------------
72      !
73      IF( nn_timing == 1 )  CALL timing_start('p4z_sed')
74      !
75      IF( kt == nittrc000 .AND. knt == 1 )   r1_rday  = 1. / rday
76      !
77      ! Allocate temporary workspace
78                      CALL wrk_alloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zbureff )
79                      CALL wrk_alloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
80                      CALL wrk_alloc( jpi, jpj, zsedcal,  zsedsi, zsedc )
81                      CALL wrk_alloc( jpi, jpj, jpk, zlight, zsoufer )
82      IF( ln_p5z )    CALL wrk_alloc( jpi, jpj, jpk, ztrpo4, ztrdop )
83      IF( ln_ligand ) CALL wrk_alloc( jpi, jpj, zwsfep )
84
85
86!$OMP PARALLEL DO schedule(static) private(jj,ji)
87      DO jj = 1, jpj
88         DO ji = 1, jpi
89            zdenit2d(ji,jj) = 0.e0
90            zbureff (ji,jj) = 0.e0
91            zwork1  (ji,jj) = 0.e0
92            zwork2  (ji,jj) = 0.e0
93            zwork3  (ji,jj) = 0.e0
94            zsedsi  (ji,jj) = 0.e0
95            zsedcal (ji,jj) = 0.e0
96            zsedc   (ji,jj) = 0.e0
97         END DO
98      END DO
99
100      ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al.
101      ! ----------------------------------------------------
102      IF( ln_ironice ) THEN 
103         !                                             
104         CALL wrk_alloc( jpi, jpj, zironice )
105         !                                             
106!$OMP PARALLEL
107!$OMP DO schedule(static) private(jj,ji,zdep,zwflux,zfminus,zfplus)
108         DO jj = 1, jpj
109            DO ji = 1, jpi
110               zdep    = rfact2 / e3t_n(ji,jj,1)
111               zwflux  = fmmflx(ji,jj) / 1000._wp
112               zfminus = MIN( 0._wp, -zwflux ) * trb(ji,jj,1,jpfer) * zdep
113               zfplus  = MAX( 0._wp, -zwflux ) * icefeinput * zdep
114               zironice(ji,jj) =  zfplus + zfminus
115            END DO
116         END DO
117         !
118!$OMP DO schedule(static) private(jj,ji)
119      DO jj = 1, jpj
120         DO ji = 1, jpi
121            tra(ji,jj,1,jpfer) = tra(ji,jj,1,jpfer) + zironice(ji,jj)
122         END DO
123      END DO
124!$OMP END PARALLEL
125         !
126         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironice" ) )   &
127            &   CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1) ) ! iron flux from ice
128         !
129         CALL wrk_dealloc( jpi, jpj, zironice )
130         !                                             
131      ENDIF
132
133      ! Add the external input of nutrients from dust deposition
134      ! ----------------------------------------------------------
135      IF( ln_dust ) THEN
136         !                                             
137         CALL wrk_alloc( jpi, jpj,      zsidep )
138         CALL wrk_alloc( jpi, jpj, jpk, zpdep, zirondep      )
139         !                                              ! Iron and Si deposition at the surface
140         IF( ln_solub ) THEN
141!$OMP PARALLEL DO schedule(static) private(jj,ji)
142           DO jj = 1, jpj
143              DO ji = 1, jpi
144                 zirondep(ji,jj,1) = solub(ji,jj) * dust(ji,jj) * mfrac * rfact2 / e3t_n(ji,jj,1) / 55.85 + 3.e-10 * r1_ryyss
145              END DO
146           END DO
147         ELSE
148!$OMP PARALLEL DO schedule(static) private(jj,ji)
149           DO jj = 1, jpj
150              DO ji = 1, jpi
151                 zirondep(ji,jj,1) = dustsolub  * dust(ji,jj) * mfrac * rfact2 / e3t_n(ji,jj,1) / 55.85 + 3.e-10 * r1_ryyss
152              END DO
153           END DO
154         ENDIF
155!$OMP PARALLEL DO schedule(static) private(jj,ji)
156         DO jj = 1, jpj
157            DO ji = 1, jpi
158               zsidep(ji,jj) = 8.8 * 0.075 * dust(ji,jj) * mfrac * rfact2 / e3t_n(ji,jj,1) / 28.1
159               zpdep (ji,jj,1) = 0.1 * 0.021 * dust(ji,jj) * mfrac * rfact2 / e3t_n(ji,jj,1) / 31. / po4r
160            END DO
161         END DO
162         !                                              ! Iron solubilization of particles in the water column
163         !                                              ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ;  wdust in m/j
164         zwdust = 0.03 * rday / ( wdust * 55.85 ) / ( 270. * rday )
165!$OMP PARALLEL
166!$OMP DO schedule(static) private(jk,jj,ji)
167         DO jk = 2, jpkm1
168            DO jj = 1, jpj
169               DO ji = 1, jpi
170                  zirondep(ji,jj,jk) = dust(ji,jj) * mfrac * zwdust * rfact2 * EXP( -gdept_n(ji,jj,jk) / 540. )
171                  zpdep   (ji,jj,jk) = zirondep(ji,jj,jk) * 0.023
172               END DO
173            END DO
174         END DO
175         !                                              ! Iron solubilization of particles in the water column
176!$OMP DO schedule(static) private(jj,ji)
177         DO jj = 1, jpj
178            DO ji = 1, jpi
179               tra(ji,jj,1,jpsil) = tra(ji,jj,1,jpsil) + zsidep  (ji,jj)
180            END DO
181         END DO
182!$OMP DO schedule(static) private(jk,jj,ji)
183         DO jk = 1, jpk
184            DO jj = 1, jpj
185               DO ji = 1, jpi
186                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zpdep   (ji,jj,jk)
187                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zirondep(ji,jj,jk)
188               END DO
189            END DO
190         END DO
191!$OMP END PARALLEL
192         !
193         IF( lk_iomput ) THEN
194            IF( knt == nrdttrc ) THEN
195                IF( iom_use( "Irondep" ) )   &
196                &  CALL iom_put( "Irondep", zirondep(:,:,1) * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron
197                IF( iom_use( "pdust" ) )   &
198                &  CALL iom_put( "pdust"  , dust(:,:) / ( wdust * rday )  * tmask(:,:,1) ) ! dust concentration at surface
199            ENDIF
200         ENDIF
201         CALL wrk_dealloc( jpi, jpj,      zsidep )
202         CALL wrk_dealloc( jpi, jpj, jpk, zpdep, zirondep      )
203         !                                             
204      ENDIF
205     
206      ! Add the external input of nutrients from river
207      ! ----------------------------------------------------------
208      IF( ln_river ) THEN
209!$OMP PARALLEL DO schedule(static) private(jj,ji,jk)
210         DO jj = 1, jpj
211            DO ji = 1, jpi
212               DO jk = 1, nk_rnf(ji,jj)
213                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) +  rivdip(ji,jj) * rfact2
214                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) +  rivdin(ji,jj) * rfact2
215                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) +  rivdic(ji,jj) * 5.e-5 * rfact2
216                  tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) +  rivdsi(ji,jj) * rfact2
217                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +  rivdic(ji,jj) * rfact2
218                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) +  ( rivalk(ji,jj) - rno3 * rivdin(ji,jj) ) * rfact2
219               ENDDO
220            ENDDO
221         ENDDO
222         IF( ln_p5z ) THEN
223!$OMP PARALLEL DO schedule(static) private(jj,ji,jk)
224            DO jj = 1, jpj
225               DO ji = 1, jpi
226                  DO jk = 1, nk_rnf(ji,jj)
227                     tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + rivdop(ji,jj) * rfact2
228                     tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + rivdon(ji,jj) * rfact2
229                     tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + rivdoc(ji,jj) * rfact2
230                  ENDDO
231               ENDDO
232            ENDDO
233         ENDIF
234      ENDIF
235     
236      ! Add the external input of nutrients from nitrogen deposition
237      ! ----------------------------------------------------------
238      IF( ln_ndepo ) THEN
239!$OMP PARALLEL DO schedule(static) private(jj,ji)
240         DO jj = 1, jpj
241            DO ji = 1, jpi
242               tra(ji,jj,1,jpno3) = tra(ji,jj,1,jpno3) + nitdep(ji,jj) * rfact2
243               tra(ji,jj,1,jptal) = tra(ji,jj,1,jptal) - rno3 * nitdep(ji,jj) * rfact2
244            ENDDO
245         ENDDO
246      ENDIF
247
248      ! Add the external input of iron from sediment mobilization
249      ! ------------------------------------------------------
250      IF( ln_ironsed ) THEN
251!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
252         DO jk = 1, jpk
253            DO jj = 1, jpj
254               DO ji = 1, jpi
255                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + ironsed(ji,jj,jk) * rfact2
256               END DO
257            END DO
258         END DO
259
260         IF( ln_ligand ) THEN
261!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
262            DO jk = 1, jpk
263               DO jj = 1, jpj
264                  DO ji = 1, jpi
265                     tra(ji,jj,jk,jpfep) = tra(ji,jj,jk,jpfep) + ( ironsed(ji,jj,jk) * fep_rats ) * rfact2
266                  END DO
267               END DO
268            END DO
269         END IF
270         !
271         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironsed" ) )   &
272            &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments
273      ENDIF
274
275      ! Add the external input of iron from hydrothermal vents
276      ! ------------------------------------------------------
277      IF( ln_hydrofe ) THEN
278!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
279         DO jk = 1, jpk
280            DO jj = 1, jpj
281               DO ji = 1, jpi
282                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + hydrofe(ji,jj,jk) * rfact2
283               END DO
284            END DO
285         END DO
286         IF( ln_ligand ) THEN
287!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
288            DO jk = 1, jpk
289               DO jj = 1, jpj
290                  DO ji = 1, jpi
291                     tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + ( hydrofe(ji,jj,jk) * fep_rath ) * rfact2
292                     tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + ( hydrofe(ji,jj,jk) * lgw_rath ) * rfact2
293                  END DO
294               END DO
295            END DO
296         ENDIF
297         !
298         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "HYDR" ) )   &
299            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
300      ENDIF
301
302      ! OA: Warning, the following part is necessary to avoid CFL problems above the sediments
303      ! --------------------------------------------------------------------
304!$OMP PARALLEL DO schedule(static) private(jj,ji,ikt,zdep)
305      DO jj = 1, jpj
306         DO ji = 1, jpi
307            ikt  = mbkt(ji,jj)
308            zdep = e3t_n(ji,jj,ikt) / xstep
309            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) )
310            zwscal (ji,jj) = MIN( 0.99 * zdep, wscal (ji,jj,ikt) )
311            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) )
312         END DO
313      END DO
314      !
315      IF( ln_ligand ) THEN
316!$OMP PARALLEL DO schedule(static) private(jj,ji,ikt,zdep)
317         DO jj = 1, jpj
318            DO ji = 1, jpi
319               ikt  = mbkt(ji,jj)
320               zdep = e3t_n(ji,jj,ikt) / xstep
321               zwsfep(ji,jj)  = MIN( 0.99 * zdep, wsfep(ji,jj,ikt)  )
322            END DO
323         ENDDO
324      ENDIF
325
326      IF( .NOT.lk_sed ) THEN
327         ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
328         ! Computation of the fraction of organic matter that is permanently buried from Dunne's model
329         ! -------------------------------------------------------
330!$OMP PARALLEL
331!$OMP DO schedule(static) private(jj,ji,ikt,zflx,zo2,zno3,zdep)
332         DO jj = 1, jpj
333            DO ji = 1, jpi
334              IF( tmask(ji,jj,1) == 1 ) THEN
335                 ikt = mbkt(ji,jj)
336                 zflx = (  trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
337                   &     + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) )  * 1E3 * 1E6 / 1E4
338                 zflx  = LOG10( MAX( 1E-3, zflx ) )
339                 zo2   = LOG10( MAX( 10. , trb(ji,jj,ikt,jpoxy) * 1E6 ) )
340                 zno3  = LOG10( MAX( 1.  , trb(ji,jj,ikt,jpno3) * 1E6 * rno3 ) )
341                 zdep  = LOG10( gdepw_n(ji,jj,ikt+1) )
342                 zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
343                   &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
344                 zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
345                   !
346                 zflx = (  trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
347                   &     + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) ) * 1E6
348                 zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2
349                ENDIF
350              END DO
351           END DO 
352
353           ! Loss of biogenic silicon, Caco3 organic carbon in the sediments.
354           ! First, the total loss is computed.
355           ! The factor for calcite comes from the alkalinity effect
356           ! -------------------------------------------------------------
357!$OMP DO schedule(static) private(jj,ji,ikt,zfactcal)
358           DO jj = 1, jpj
359              DO ji = 1, jpi
360                 IF( tmask(ji,jj,1) == 1 ) THEN
361                    ikt = mbkt(ji,jj) 
362                    zwork1(ji,jj) = trb(ji,jj,ikt,jpgsi) * zwsbio4(ji,jj)
363                    zwork2(ji,jj) = trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) 
364                    ! For calcite, burial efficiency is made a function of saturation
365                    zfactcal      = MIN( excess(ji,jj,ikt), 0.2 )
366                    zfactcal      = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
367                    zwork3(ji,jj) = trb(ji,jj,ikt,jpcal) * zwscal(ji,jj) * 2.e0 * zfactcal
368                ENDIF
369            END DO
370         END DO
371!$OMP END PARALLEL
372         zsumsedsi  = glob_sum( zwork1(:,:) * e1e2t(:,:) ) * r1_rday
373         zsumsedpo4 = glob_sum( zwork2(:,:) * e1e2t(:,:) ) * r1_rday
374         zsumsedcal = glob_sum( zwork3(:,:) * e1e2t(:,:) ) * r1_rday
375         !
376      ENDIF
377
378      ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean.
379      ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers)
380      ! ------------------------------------------------------
381      IF( .NOT.lk_sed )  zrivsil =  1._wp - ( sumdepsi + rivdsiinput * r1_ryyss ) / ( zsumsedsi + rtrn )
382
383!$OMP PARALLEL DO schedule(static) private(jj,ji,ikt,zdep,zwsc,zsiloss,zcaloss)
384      DO jj = 1, jpj
385         DO ji = 1, jpi
386            ikt  = mbkt(ji,jj)
387            zdep = xstep / e3t_n(ji,jj,ikt) 
388            zwsc = zwscal (ji,jj) * zdep
389            zsiloss = trb(ji,jj,ikt,jpgsi) * zwsc
390            zcaloss = trb(ji,jj,ikt,jpcal) * zwsc
391            !
392            tra(ji,jj,ikt,jpgsi) = tra(ji,jj,ikt,jpgsi) - zsiloss
393            tra(ji,jj,ikt,jpcal) = tra(ji,jj,ikt,jpcal) - zcaloss
394         END DO
395      END DO
396      !
397      IF( .NOT.lk_sed ) THEN
398!$OMP PARALLEL DO schedule(static) private(jj,ji,ikt,zdep,zwsc,zsiloss,zcaloss,zfactcal,zrivalk)
399         DO jj = 1, jpj
400            DO ji = 1, jpi
401               ikt  = mbkt(ji,jj)
402               zdep = xstep / e3t_n(ji,jj,ikt) 
403               zwsc = zwscal (ji,jj) * zdep
404               zsiloss = trb(ji,jj,ikt,jpgsi) * zwsc
405               zcaloss = trb(ji,jj,ikt,jpcal) * zwsc
406               tra(ji,jj,ikt,jpsil) = tra(ji,jj,ikt,jpsil) + zsiloss * zrivsil 
407               !
408               zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
409               zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
410               zrivalk  =  1._wp - ( rivalkinput * r1_ryyss ) * zfactcal / ( zsumsedcal + rtrn )
411               tra(ji,jj,ikt,jptal) =  tra(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0
412               tra(ji,jj,ikt,jpdic) =  tra(ji,jj,ikt,jpdic) + zcaloss * zrivalk
413               zsedcal(ji,jj) = (1.0 - zrivalk) * zcaloss / zdep
414               zsedsi (ji,jj) = (1.0 - zrivsil) * zsiloss / zdep
415            END DO
416         END DO
417      ENDIF
418      !
419!$OMP PARALLEL DO schedule(static) private(jj,ji,ikt,zdep,zws3,zws4)
420      DO jj = 1, jpj
421         DO ji = 1, jpi
422            ikt  = mbkt(ji,jj)
423            zdep = xstep / e3t_n(ji,jj,ikt) 
424            zws4 = zwsbio4(ji,jj) * zdep
425            zws3 = zwsbio3(ji,jj) * zdep
426            tra(ji,jj,ikt,jpgoc) = tra(ji,jj,ikt,jpgoc) - trb(ji,jj,ikt,jpgoc) * zws4 
427            tra(ji,jj,ikt,jppoc) = tra(ji,jj,ikt,jppoc) - trb(ji,jj,ikt,jppoc) * zws3
428            tra(ji,jj,ikt,jpbfe) = tra(ji,jj,ikt,jpbfe) - trb(ji,jj,ikt,jpbfe) * zws4
429            tra(ji,jj,ikt,jpsfe) = tra(ji,jj,ikt,jpsfe) - trb(ji,jj,ikt,jpsfe) * zws3
430         END DO
431      END DO
432      !
433      IF( ln_ligand ) THEN
434!$OMP PARALLEL DO schedule(static) private(jj,ji,ikt,zdep,zwssfep)
435         DO jj = 1, jpj
436            DO ji = 1, jpi
437               ikt     = mbkt(ji,jj)
438               zdep    = xstep / e3t_n(ji,jj,ikt) 
439               zwssfep = zwsfep(ji,jj) * zdep
440               tra(ji,jj,ikt,jpfep) = tra(ji,jj,ikt,jpfep) - trb(ji,jj,ikt,jpfep) * zwssfep
441            END DO
442         END DO
443      ENDIF
444      !
445      IF( ln_p5z ) THEN
446!$OMP PARALLEL DO schedule(static) private(jj,ji,ikt,zdep,zws3,zws4)
447         DO jj = 1, jpj
448            DO ji = 1, jpi
449               ikt  = mbkt(ji,jj)
450               zdep = xstep / e3t_n(ji,jj,ikt) 
451               zws4 = zwsbio4(ji,jj) * zdep
452               zws3 = zwsbio3(ji,jj) * zdep
453               tra(ji,jj,ikt,jpgon) = tra(ji,jj,ikt,jpgon) - trb(ji,jj,ikt,jpgon) * zws4
454               tra(ji,jj,ikt,jppon) = tra(ji,jj,ikt,jppon) - trb(ji,jj,ikt,jppon) * zws3
455               tra(ji,jj,ikt,jpgop) = tra(ji,jj,ikt,jpgop) - trb(ji,jj,ikt,jpgop) * zws4
456               tra(ji,jj,ikt,jppop) = tra(ji,jj,ikt,jppop) - trb(ji,jj,ikt,jppop) * zws3
457            END DO
458         END DO
459      ENDIF
460
461      IF( .NOT.lk_sed ) THEN
462         ! The 0.5 factor in zpdenit and zdenitt is to avoid negative NO3 concentration after both denitrification
463         ! in the sediments and just above the sediments. Not very clever, but simpliest option.
464!$OMP PARALLEL DO schedule(static) private(jj,ji,ikt,zdep,zws3,zws4,zrivno3,zwstpoc,zpdenit,z1pdenit,zolimit,zdenitt,zwstpop,zwstpon)
465         DO jj = 1, jpj
466            DO ji = 1, jpi
467               ikt  = mbkt(ji,jj)
468               zdep = xstep / e3t_n(ji,jj,ikt) 
469               zws4 = zwsbio4(ji,jj) * zdep
470               zws3 = zwsbio3(ji,jj) * zdep
471               zrivno3 = 1. - zbureff(ji,jj)
472               zwstpoc = trb(ji,jj,ikt,jpgoc) * zws4 + trb(ji,jj,ikt,jppoc) * zws3
473               zpdenit  = MIN( 0.5 * ( trb(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
474               z1pdenit = zwstpoc * zrivno3 - zpdenit
475               zolimit = MIN( ( trb(ji,jj,ikt,jpoxy) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) )
476               zdenitt = MIN(  0.5 * ( trb(ji,jj,ikt,jpno3) - rtrn ) / rdenit, z1pdenit * nitrfac(ji,jj,ikt) )
477               tra(ji,jj,ikt,jpdoc) = tra(ji,jj,ikt,jpdoc) + z1pdenit - zolimit - zdenitt
478               tra(ji,jj,ikt,jppo4) = tra(ji,jj,ikt,jppo4) + zpdenit + zolimit + zdenitt
479               tra(ji,jj,ikt,jpnh4) = tra(ji,jj,ikt,jpnh4) + zpdenit + zolimit + zdenitt
480               tra(ji,jj,ikt,jpno3) = tra(ji,jj,ikt,jpno3) - rdenit * (zpdenit + zdenitt)
481               tra(ji,jj,ikt,jpoxy) = tra(ji,jj,ikt,jpoxy) - zolimit * o2ut
482               tra(ji,jj,ikt,jptal) = tra(ji,jj,ikt,jptal) + rno3 * (zolimit + (1.+rdenit) * (zpdenit + zdenitt) )
483               tra(ji,jj,ikt,jpdic) = tra(ji,jj,ikt,jpdic) + zpdenit + zolimit + zdenitt
484               sdenit(ji,jj) = rdenit * zpdenit * e3t_n(ji,jj,ikt)
485               zsedc(ji,jj)   = (1. - zrivno3) * zwstpoc / zdep
486               IF( ln_p5z ) THEN
487                  zwstpop              = trb(ji,jj,ikt,jpgop) * zws4 + trb(ji,jj,ikt,jppop) * zws3
488                  zwstpon              = trb(ji,jj,ikt,jpgon) * zws4 + trb(ji,jj,ikt,jppon) * zws3
489                  tra(ji,jj,ikt,jpdon) = tra(ji,jj,ikt,jpdon) + (z1pdenit - zolimit - zdenitt) * zwstpon / (zwstpoc + rtrn)
490                  tra(ji,jj,ikt,jpdop) = tra(ji,jj,ikt,jpdop) + (z1pdenit - zolimit - zdenitt) * zwstpop / (zwstpoc + rtrn)
491               ENDIF
492            END DO
493         END DO
494       ENDIF
495
496
497      ! Nitrogen fixation process
498      ! Small source iron from particulate inorganic iron
499      !-----------------------------------
500!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
501      DO jk = 1, jpkm1
502         DO jj = 1, jpj
503            DO ji = 1, jpi
504               zlight (ji,jj,jk) =  ( 1.- EXP( -etot_ndcy(ji,jj,jk) / diazolight ) ) * ( 1. - fr_i(ji,jj) ) 
505               zsoufer(ji,jj,jk) = zlight(ji,jj,jk) * 2E-11 / ( 2E-11 + biron(ji,jj,jk) )
506           END DO
507         END DO
508      ENDDO
509      IF( ln_p4z ) THEN
510!$OMP PARALLEL DO schedule(static) private(jk,jj,ji,zlim,zfact,ztrfer,ztrpo4s)
511         DO jk = 1, jpkm1
512            DO jj = 1, jpj
513               DO ji = 1, jpi
514                  !                      ! Potential nitrogen fixation dependant on temperature and iron
515                  zlim = ( 1.- xnanono3(ji,jj,jk) - xnanonh4(ji,jj,jk) )
516                  IF( zlim <= 0.2 )   zlim = 0.01
517                  zfact = zlim * rfact2
518
519                  ztrfer  = biron(ji,jj,jk)       / ( concfediaz + biron(ji,jj,jk)       )
520                  ztrpo4s = trb  (ji,jj,jk,jppo4) / ( concnnh4   + trb  (ji,jj,jk,jppo4) ) 
521                  nitrpot(ji,jj,jk) =  MAX( 0.e0, ( 0.6 * tgfunc(ji,jj,jk) - 2.15 ) * r1_rday ) &
522                    &                *  zfact * MIN( ztrfer, ztrpo4s ) * zlight(ji,jj,jk)
523               END DO
524            END DO
525         END DO
526      ELSE       ! p5z
527!$OMP PARALLEL DO schedule(static) private(jk,jj,ji,ztemp,zmudia,xdianh4,xdiano3,zlim,zfact,ztrfer,ztrdp)
528         DO jk = 1, jpkm1
529            DO jj = 1, jpj
530               DO ji = 1, jpi
531                  !                      ! Potential nitrogen fixation dependant on temperature and iron
532                  ztemp = tsn(ji,jj,jk,jp_tem)
533                  zmudia = MAX( 0.,-0.001096*ztemp**2 + 0.057*ztemp -0.637 ) * 7.625
534                  !       Potential nitrogen fixation dependant on temperature and iron
535                  xdianh4 = trb(ji,jj,jk,jpnh4) / ( concnnh4 + trb(ji,jj,jk,jpnh4) )
536                  xdiano3 = trb(ji,jj,jk,jpno3) / ( concnno3 + trb(ji,jj,jk,jpno3) ) * (1. - xdianh4)
537                  zlim = ( 1.- xdiano3 - xdianh4 )
538                  IF( zlim <= 0.1 )   zlim = 0.01
539                  zfact = zlim * rfact2
540                  ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) )
541                  ztrpo4(ji,jj,jk) = trb(ji,jj,jk,jppo4) / ( 1E-6 + trb(ji,jj,jk,jppo4) )
542                  ztrdop(ji,jj,jk) = trb(ji,jj,jk,jpdop) / ( 1E-6 + trb(ji,jj,jk,jpdop) ) * (1. - ztrpo4(ji,jj,jk))
543                  ztrdp = ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk)
544                  nitrpot(ji,jj,jk) =  zmudia * r1_rday * zfact * MIN( ztrfer, ztrdp ) * zlight(ji,jj,jk)
545               END DO
546            END DO
547         END DO
548      ENDIF
549
550      ! Nitrogen change due to nitrogen fixation
551      ! ----------------------------------------
552      IF( ln_p4z ) THEN
553!$OMP PARALLEL DO schedule(static) private(jk,jj,ji,zfact)
554         DO jk = 1, jpkm1
555            DO jj = 1, jpj
556               DO ji = 1, jpi
557                  zfact = nitrpot(ji,jj,jk) * nitrfix
558                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) +             zfact
559                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3      * zfact
560                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2nit     * zfact 
561                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + concdnh4 / ( concdnh4 + trb(ji,jj,jk,jppo4) ) &
562                  &                     * 0.002 * trb(ji,jj,jk,jpdoc) * xstep
563                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * xstep
564              END DO
565            END DO
566         END DO
567      ELSE    ! p5z
568!$OMP PARALLEL DO schedule(static) private(jk,jj,ji,zfact)
569         DO jk = 1, jpkm1
570            DO jj = 1, jpj
571               DO ji = 1, jpi
572                  zfact = nitrpot(ji,jj,jk) * nitrfix
573                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zfact / 3.0
574                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zfact / 3.0
575                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - 16.0 / 46.0 * zfact * ( 1.0 - 1.0 / 3.0 ) &
576                  &                     * ztrpo4(ji,jj,jk) / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
577                  tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + zfact * 1.0 / 3.0
578                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zfact * 1.0 / 3.0
579                  tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + 16.0 / 46.0 * zfact / 3.0  &
580                  &                     - 16.0 / 46.0 * zfact * ztrdop(ji,jj,jk)   &
581                  &                     / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
582                  tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zfact * 1.0 / 3.0 * 2.0 / 3.0
583                  tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + zfact * 1.0 / 3.0 * 2.0 /3.0
584                  tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 2.0 /3.0
585                  tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zfact * 1.0 / 3.0 * 1.0 / 3.0
586                  tra(ji,jj,jk,jpgon) = tra(ji,jj,jk,jpgon) + zfact * 1.0 / 3.0 * 1.0 /3.0
587                  tra(ji,jj,jk,jpgop) = tra(ji,jj,jk,jpgop) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 1.0 /3.0
588                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + ( o2ut + o2nit ) * zfact * 2.0 / 3.0 + o2nit * zfact / 3.0
589                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - 30E-6 * zfact * 1.0 / 3.0 
590                  tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + 30E-6 * zfact * 1.0 / 3.0 * 2.0 / 3.0
591                  tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + 30E-6 * zfact * 1.0 / 3.0 * 1.0 / 3.0
592                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
593              END DO
594            END DO
595         END DO
596         !
597      ENDIF
598
599      IF( lk_iomput ) THEN
600         IF( knt == nrdttrc ) THEN
601            zfact = 1.e+3 * rfact2r * rno3  !  conversion from molC/l/kt  to molN/m3/s
602            IF( iom_use("Nfix"   ) ) CALL iom_put( "Nfix", nitrpot(:,:,:) * nitrfix * zfact * tmask(:,:,:) )  ! nitrogen fixation
603            IF( iom_use("INTNFIX") ) THEN   ! nitrogen fixation rate in ocean ( vertically integrated )
604!$OMP PARALLEL
605!$OMP DO schedule(static) private(jj,ji)
606               DO jj = 1, jpj
607                  DO ji = 1, jpi
608                     zwork1(ji,jj) = 0.
609                  END DO
610               ENDDO
611               DO jk = 1, jpkm1
612!$OMP DO schedule(static) private(jj,ji)
613                  DO jj = 1, jpj
614                     DO ji = 1, jpi
615                        zwork1(ji,jj) = zwork1(ji,jj) + nitrpot(ji,jj,jk) * nitrfix * zfact * e3t_n(ji,jj,jk) * tmask(ji,jj,jk)
616                     END DO
617                  END DO
618               ENDDO
619!$OMP END PARALLEL
620               CALL iom_put( "INTNFIX" , zwork1 ) 
621            ENDIF
622            IF( iom_use("SedCal" ) ) CALL iom_put( "SedCal", zsedcal(:,:) * 1.e+3 )
623            IF( iom_use("SedSi" ) )  CALL iom_put( "SedSi",  zsedsi (:,:) * 1.e+3 )
624            IF( iom_use("SedC" ) )   CALL iom_put( "SedC",   zsedc  (:,:) * 1.e+3 )
625            IF( iom_use("Sdenit" ) ) CALL iom_put( "Sdenit", sdenit (:,:) * 1.e+3 * rno3 )
626         ENDIF
627      ENDIF
628      !
629      IF(ln_ctl) THEN  ! print mean trends (USEd for debugging)
630         WRITE(charout, fmt="('sed ')")
631         CALL prt_ctl_trc_info(charout)
632         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
633      ENDIF
634      !
635                      CALL wrk_dealloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zbureff )
636                      CALL wrk_dealloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
637                      CALL wrk_dealloc( jpi, jpj, zsedcal,  zsedsi, zsedc )
638                      CALL wrk_dealloc( jpi, jpj, jpk, zlight, zsoufer )
639      IF( ln_p5z )    CALL wrk_dealloc( jpi, jpj, jpk, ztrpo4, ztrdop )
640      IF( ln_ligand ) CALL wrk_dealloc( jpi, jpj, zwsfep )
641      !
642      IF( nn_timing == 1 )  CALL timing_stop('p4z_sed')
643      !
644   END SUBROUTINE p4z_sed
645
646
647   INTEGER FUNCTION p4z_sed_alloc()
648      !!----------------------------------------------------------------------
649      !!                     ***  ROUTINE p4z_sed_alloc  ***
650      !!----------------------------------------------------------------------
651      ALLOCATE( nitrpot(jpi,jpj,jpk), sdenit(jpi,jpj), STAT=p4z_sed_alloc )
652      !
653      IF( p4z_sed_alloc /= 0 )   CALL ctl_warn('p4z_sed_alloc: failed to allocate arrays')
654      !
655   END FUNCTION p4z_sed_alloc
656
657
658   !!======================================================================
659END MODULE p4zsed
Note: See TracBrowser for help on using the repository browser.