source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsed.F90 @ 8541

Last change on this file since 8541 was 8541, checked in by cetlod, 3 years ago

trunk: minor correction to avoid compilation error related to ticket #1940

  • Property svn:keywords set to Id
File size: 26.9 KB
Line 
1MODULE p4zsed
2   !!======================================================================
3   !!                         ***  MODULE p4sed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!----------------------------------------------------------------------
11   !!   p4z_sed        :  Compute loss of organic matter in the sediments
12   !!----------------------------------------------------------------------
13   USE oce_trc         !  shared variables between ocean and passive tracers
14   USE trc             !  passive tracers common variables
15   USE sms_pisces      !  PISCES Source Minus Sink variables
16   USE p4zlim          !  Co-limitations of differents nutrients
17   USE p4zsbc          !  External source of nutrients
18   USE p4zint          !  interpolation and computation of various fields
19   USE iom             !  I/O manager
20   USE prtctl_trc      !  print control for debugging
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p4z_sed 
26   PUBLIC   p4z_sed_alloc
27 
28   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: nitrpot    !: Nitrogen fixation
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:  ) :: sdenit     !: Nitrate reduction in the sediments
30   REAL(wp) :: r1_rday                  !: inverse of rday
31
32   !!----------------------------------------------------------------------
33   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
34   !! $Id$
35   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE p4z_sed( kt, knt )
40      !!---------------------------------------------------------------------
41      !!                     ***  ROUTINE p4z_sed  ***
42      !!
43      !! ** Purpose :   Compute loss of organic matter in the sediments. This
44      !!              is by no way a sediment model. The loss is simply
45      !!              computed to balance the inout from rivers and dust
46      !!
47      !! ** Method  : - ???
48      !!---------------------------------------------------------------------
49      !
50      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
51      INTEGER  ::   ji, jj, jk, ikt
52      REAL(wp) ::   zsumsedsi, zsumsedpo4, zsumsedcal
53      REAL(wp) ::   zrivalk, zrivsil, zrivno3
54      REAL(wp) ::  zwflux, zfminus, zfplus
55      REAL(wp) ::  zlim, zfact, zfactcal
56      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit, zolimit
57      REAL(wp) ::  zsiloss, zcaloss, zws3, zws4, zwsc, zdep
58      REAL(wp) ::  zwstpoc, zwstpon, zwstpop
59      REAL(wp) ::  ztrfer, ztrpo4s, ztrdp, zwdust, zmudia, ztemp
60      REAL(wp) ::  xdiano3, xdianh4
61      REAL(wp) ::  zwssfep
62      !
63      CHARACTER (len=25) :: charout
64      REAL(wp), POINTER, DIMENSION(:,:  ) :: zsidep, zwork1, zwork2, zwork3
65      REAL(wp), POINTER, DIMENSION(:,:  ) :: zdenit2d, zironice, zbureff
66      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwsbio3, zwsbio4, zwscal
67      REAL(wp), POINTER, DIMENSION(:,:  ) :: zsedcal, zsedsi, zsedc
68      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrpo4, ztrdop, zirondep, zsoufer, zpdep, zlight
69      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwsfep
70
71      !!---------------------------------------------------------------------
72      !
73      IF( nn_timing == 1 )  CALL timing_start('p4z_sed')
74      !
75      IF( kt == nittrc000 .AND. knt == 1 )   r1_rday  = 1. / rday
76      !
77      ! Allocate temporary workspace
78                      CALL wrk_alloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zbureff )
79                      CALL wrk_alloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
80                      CALL wrk_alloc( jpi, jpj, zsedcal,  zsedsi, zsedc )
81                      CALL wrk_alloc( jpi, jpj, jpk, zlight, zsoufer )
82      IF( ln_p5z )    CALL wrk_alloc( jpi, jpj, jpk, ztrpo4, ztrdop )
83      IF( ln_ligand ) CALL wrk_alloc( jpi, jpj, zwsfep )
84
85
86      zdenit2d(:,:) = 0.e0
87      zbureff (:,:) = 0.e0
88      zwork1  (:,:) = 0.e0
89      zwork2  (:,:) = 0.e0
90      zwork3  (:,:) = 0.e0
91      zsedsi  (:,:) = 0.e0
92      zsedcal (:,:) = 0.e0
93      zsedc   (:,:) = 0.e0
94
95
96      ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al.
97      ! ----------------------------------------------------
98      IF( ln_ironice ) THEN 
99         !                                             
100         CALL wrk_alloc( jpi, jpj, zironice )
101         !                                             
102         DO jj = 1, jpj
103            DO ji = 1, jpi
104               zdep    = rfact2 / e3t_n(ji,jj,1)
105               zwflux  = fmmflx(ji,jj) / 1000._wp
106               zfminus = MIN( 0._wp, -zwflux ) * trb(ji,jj,1,jpfer) * zdep
107               zfplus  = MAX( 0._wp, -zwflux ) * icefeinput * zdep
108               zironice(ji,jj) =  zfplus + zfminus
109            END DO
110         END DO
111         !
112         tra(:,:,1,jpfer) = tra(:,:,1,jpfer) + zironice(:,:) 
113         !
114         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironice" ) )   &
115            &   CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1) ) ! iron flux from ice
116         !
117         CALL wrk_dealloc( jpi, jpj, zironice )
118         !                                             
119      ENDIF
120
121      ! Add the external input of nutrients from dust deposition
122      ! ----------------------------------------------------------
123      IF( ln_dust ) THEN
124         !                                             
125         CALL wrk_alloc( jpi, jpj,      zsidep )
126         CALL wrk_alloc( jpi, jpj, jpk, zpdep, zirondep      )
127         !                                              ! Iron and Si deposition at the surface
128         IF( ln_solub ) THEN
129            zirondep(:,:,1) = solub(:,:) * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
130         ELSE
131            zirondep(:,:,1) = dustsolub  * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
132         ENDIF
133         zsidep(:,:)   = 8.8 * 0.075 * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 28.1 
134         zpdep (:,:,1) = 0.1 * 0.021 * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 31. / po4r 
135         !                                              ! Iron solubilization of particles in the water column
136         !                                              ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ;  wdust in m/j
137         zwdust = 0.03 * rday / ( wdust * 55.85 ) / ( 270. * rday )
138         DO jk = 2, jpkm1
139            zirondep(:,:,jk) = dust(:,:) * mfrac * zwdust * rfact2 * EXP( -gdept_n(:,:,jk) / 540. )
140            zpdep   (:,:,jk) = zirondep(:,:,jk) * 0.023
141         END DO
142         !                                              ! Iron solubilization of particles in the water column
143         tra(:,:,1,jpsil) = tra(:,:,1,jpsil) + zsidep  (:,:)
144         tra(:,:,:,jppo4) = tra(:,:,:,jppo4) + zpdep   (:,:,:)
145         tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + zirondep(:,:,:) 
146         !
147         IF( lk_iomput ) THEN
148            IF( knt == nrdttrc ) THEN
149                IF( iom_use( "Irondep" ) )   &
150                &  CALL iom_put( "Irondep", zirondep(:,:,1) * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron
151                IF( iom_use( "pdust" ) )   &
152                &  CALL iom_put( "pdust"  , dust(:,:) / ( wdust * rday )  * tmask(:,:,1) ) ! dust concentration at surface
153            ENDIF
154         ENDIF
155         CALL wrk_dealloc( jpi, jpj,      zsidep )
156         CALL wrk_dealloc( jpi, jpj, jpk, zpdep, zirondep      )
157         !                                             
158      ENDIF
159     
160      ! Add the external input of nutrients from river
161      ! ----------------------------------------------------------
162      IF( ln_river ) THEN
163         DO jj = 1, jpj
164            DO ji = 1, jpi
165               DO jk = 1, nk_rnf(ji,jj)
166                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) +  rivdip(ji,jj) * rfact2
167                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) +  rivdin(ji,jj) * rfact2
168                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) +  rivdic(ji,jj) * 5.e-5 * rfact2
169                  tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) +  rivdsi(ji,jj) * rfact2
170                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +  rivdic(ji,jj) * rfact2
171                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) +  ( rivalk(ji,jj) - rno3 * rivdin(ji,jj) ) * rfact2
172               ENDDO
173            ENDDO
174         ENDDO
175         IF( ln_p5z ) THEN
176            DO jj = 1, jpj
177               DO ji = 1, jpi
178                  DO jk = 1, nk_rnf(ji,jj)
179                     tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + rivdop(ji,jj) * rfact2
180                     tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + rivdon(ji,jj) * rfact2
181                     tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + rivdoc(ji,jj) * rfact2
182                  ENDDO
183               ENDDO
184            ENDDO
185         ENDIF
186      ENDIF
187     
188      ! Add the external input of nutrients from nitrogen deposition
189      ! ----------------------------------------------------------
190      IF( ln_ndepo ) THEN
191         tra(:,:,1,jpno3) = tra(:,:,1,jpno3) + nitdep(:,:) * rfact2
192         tra(:,:,1,jptal) = tra(:,:,1,jptal) - rno3 * nitdep(:,:) * rfact2
193      ENDIF
194
195      ! Add the external input of iron from sediment mobilization
196      ! ------------------------------------------------------
197      IF( ln_ironsed ) THEN
198                         tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + ironsed(:,:,:) * rfact2
199         IF( ln_ligand ) tra(:,:,:,jpfep) = tra(:,:,:,jpfep) + ( ironsed(:,:,:) * fep_rats ) * rfact2
200         !
201         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironsed" ) )   &
202            &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments
203      ENDIF
204
205      ! Add the external input of iron from hydrothermal vents
206      ! ------------------------------------------------------
207      IF( ln_hydrofe ) THEN
208            tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + hydrofe(:,:,:) * rfact2
209         IF( ln_ligand ) THEN
210            tra(:,:,:,jpfep) = tra(:,:,:,jpfep) + ( hydrofe(:,:,:) * fep_rath ) * rfact2
211            tra(:,:,:,jplgw) = tra(:,:,:,jplgw) + ( hydrofe(:,:,:) * lgw_rath ) * rfact2
212         ENDIF
213         !
214         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "HYDR" ) )   &
215            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
216      ENDIF
217
218      ! OA: Warning, the following part is necessary to avoid CFL problems above the sediments
219      ! --------------------------------------------------------------------
220      DO jj = 1, jpj
221         DO ji = 1, jpi
222            ikt  = mbkt(ji,jj)
223            zdep = e3t_n(ji,jj,ikt) / xstep
224            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) )
225            zwscal (ji,jj) = MIN( 0.99 * zdep, wscal (ji,jj,ikt) )
226            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) )
227         END DO
228      END DO
229      !
230      IF( ln_ligand ) THEN
231         DO jj = 1, jpj
232            DO ji = 1, jpi
233               ikt  = mbkt(ji,jj)
234               zdep = e3t_n(ji,jj,ikt) / xstep
235               zwsfep(ji,jj)  = MIN( 0.99 * zdep, wsfep(ji,jj,ikt)  )
236            END DO
237         ENDDO
238      ENDIF
239
240      IF( .NOT.lk_sed ) THEN
241         ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
242         ! Computation of the fraction of organic matter that is permanently buried from Dunne's model
243         ! -------------------------------------------------------
244         DO jj = 1, jpj
245            DO ji = 1, jpi
246              IF( tmask(ji,jj,1) == 1 ) THEN
247                 ikt = mbkt(ji,jj)
248                 zflx = (  trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
249                   &     + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) )  * 1E3 * 1E6 / 1E4
250                 zflx  = LOG10( MAX( 1E-3, zflx ) )
251                 zo2   = LOG10( MAX( 10. , trb(ji,jj,ikt,jpoxy) * 1E6 ) )
252                 zno3  = LOG10( MAX( 1.  , trb(ji,jj,ikt,jpno3) * 1E6 * rno3 ) )
253                 zdep  = LOG10( gdepw_n(ji,jj,ikt+1) )
254                 zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
255                   &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
256                 zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
257                   !
258                 zflx = (  trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
259                   &     + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) ) * 1E6
260                 zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2
261                ENDIF
262              END DO
263           END DO 
264
265           ! Loss of biogenic silicon, Caco3 organic carbon in the sediments.
266           ! First, the total loss is computed.
267           ! The factor for calcite comes from the alkalinity effect
268           ! -------------------------------------------------------------
269           DO jj = 1, jpj
270              DO ji = 1, jpi
271                 IF( tmask(ji,jj,1) == 1 ) THEN
272                    ikt = mbkt(ji,jj) 
273                    zwork1(ji,jj) = trb(ji,jj,ikt,jpgsi) * zwsbio4(ji,jj)
274                    zwork2(ji,jj) = trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) 
275                    ! For calcite, burial efficiency is made a function of saturation
276                    zfactcal      = MIN( excess(ji,jj,ikt), 0.2 )
277                    zfactcal      = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
278                    zwork3(ji,jj) = trb(ji,jj,ikt,jpcal) * zwscal(ji,jj) * 2.e0 * zfactcal
279                ENDIF
280            END DO
281         END DO
282         zsumsedsi  = glob_sum( zwork1(:,:) * e1e2t(:,:) ) * r1_rday
283         zsumsedpo4 = glob_sum( zwork2(:,:) * e1e2t(:,:) ) * r1_rday
284         zsumsedcal = glob_sum( zwork3(:,:) * e1e2t(:,:) ) * r1_rday
285         !
286      ENDIF
287
288      ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean.
289      ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers)
290      ! ------------------------------------------------------
291      IF( .NOT.lk_sed )  zrivsil =  1._wp - ( sumdepsi + rivdsiinput * r1_ryyss ) / ( zsumsedsi + rtrn )
292
293      DO jj = 1, jpj
294         DO ji = 1, jpi
295            ikt  = mbkt(ji,jj)
296            zdep = xstep / e3t_n(ji,jj,ikt) 
297            zwsc = zwscal (ji,jj) * zdep
298            zsiloss = trb(ji,jj,ikt,jpgsi) * zwsc
299            zcaloss = trb(ji,jj,ikt,jpcal) * zwsc
300            !
301            tra(ji,jj,ikt,jpgsi) = tra(ji,jj,ikt,jpgsi) - zsiloss
302            tra(ji,jj,ikt,jpcal) = tra(ji,jj,ikt,jpcal) - zcaloss
303         END DO
304      END DO
305      !
306      IF( .NOT.lk_sed ) THEN
307         DO jj = 1, jpj
308            DO ji = 1, jpi
309               ikt  = mbkt(ji,jj)
310               zdep = xstep / e3t_n(ji,jj,ikt) 
311               zwsc = zwscal (ji,jj) * zdep
312               zsiloss = trb(ji,jj,ikt,jpgsi) * zwsc
313               zcaloss = trb(ji,jj,ikt,jpcal) * zwsc
314               tra(ji,jj,ikt,jpsil) = tra(ji,jj,ikt,jpsil) + zsiloss * zrivsil 
315               !
316               zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
317               zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
318               zrivalk  =  1._wp - ( rivalkinput * r1_ryyss ) * zfactcal / ( zsumsedcal + rtrn )
319               tra(ji,jj,ikt,jptal) =  tra(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0
320               tra(ji,jj,ikt,jpdic) =  tra(ji,jj,ikt,jpdic) + zcaloss * zrivalk
321               zsedcal(ji,jj) = (1.0 - zrivalk) * zcaloss * e3t_n(ji,jj,ikt) 
322               zsedsi (ji,jj) = (1.0 - zrivsil) * zsiloss * e3t_n(ji,jj,ikt) 
323            END DO
324         END DO
325      ENDIF
326      !
327      DO jj = 1, jpj
328         DO ji = 1, jpi
329            ikt  = mbkt(ji,jj)
330            zdep = xstep / e3t_n(ji,jj,ikt) 
331            zws4 = zwsbio4(ji,jj) * zdep
332            zws3 = zwsbio3(ji,jj) * zdep
333            tra(ji,jj,ikt,jpgoc) = tra(ji,jj,ikt,jpgoc) - trb(ji,jj,ikt,jpgoc) * zws4 
334            tra(ji,jj,ikt,jppoc) = tra(ji,jj,ikt,jppoc) - trb(ji,jj,ikt,jppoc) * zws3
335            tra(ji,jj,ikt,jpbfe) = tra(ji,jj,ikt,jpbfe) - trb(ji,jj,ikt,jpbfe) * zws4
336            tra(ji,jj,ikt,jpsfe) = tra(ji,jj,ikt,jpsfe) - trb(ji,jj,ikt,jpsfe) * zws3
337         END DO
338      END DO
339      !
340      IF( ln_ligand ) THEN
341         DO jj = 1, jpj
342            DO ji = 1, jpi
343               ikt     = mbkt(ji,jj)
344               zdep    = xstep / e3t_n(ji,jj,ikt) 
345               zwssfep = zwsfep(ji,jj) * zdep
346               tra(ji,jj,ikt,jpfep) = tra(ji,jj,ikt,jpfep) - trb(ji,jj,ikt,jpfep) * zwssfep
347            END DO
348         END DO
349      ENDIF
350      !
351      IF( ln_p5z ) THEN
352         DO jj = 1, jpj
353            DO ji = 1, jpi
354               ikt  = mbkt(ji,jj)
355               zdep = xstep / e3t_n(ji,jj,ikt) 
356               zws4 = zwsbio4(ji,jj) * zdep
357               zws3 = zwsbio3(ji,jj) * zdep
358               tra(ji,jj,ikt,jpgon) = tra(ji,jj,ikt,jpgon) - trb(ji,jj,ikt,jpgon) * zws4
359               tra(ji,jj,ikt,jppon) = tra(ji,jj,ikt,jppon) - trb(ji,jj,ikt,jppon) * zws3
360               tra(ji,jj,ikt,jpgop) = tra(ji,jj,ikt,jpgop) - trb(ji,jj,ikt,jpgop) * zws4
361               tra(ji,jj,ikt,jppop) = tra(ji,jj,ikt,jppop) - trb(ji,jj,ikt,jppop) * zws3
362            END DO
363         END DO
364      ENDIF
365
366      IF( .NOT.lk_sed ) THEN
367         ! The 0.5 factor in zpdenit is to avoid negative NO3 concentration after
368         ! denitrification in the sediments. Not very clever, but simpliest option.
369         DO jj = 1, jpj
370            DO ji = 1, jpi
371               ikt  = mbkt(ji,jj)
372               zdep = xstep / e3t_n(ji,jj,ikt) 
373               zws4 = zwsbio4(ji,jj) * zdep
374               zws3 = zwsbio3(ji,jj) * zdep
375               zrivno3 = 1. - zbureff(ji,jj)
376               zwstpoc = trb(ji,jj,ikt,jpgoc) * zws4 + trb(ji,jj,ikt,jppoc) * zws3
377               zpdenit  = MIN( 0.5 * ( trb(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
378               z1pdenit = zwstpoc * zrivno3 - zpdenit
379               zolimit = MIN( ( trb(ji,jj,ikt,jpoxy) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) )
380               tra(ji,jj,ikt,jpdoc) = tra(ji,jj,ikt,jpdoc) + z1pdenit - zolimit
381               tra(ji,jj,ikt,jppo4) = tra(ji,jj,ikt,jppo4) + zpdenit + zolimit
382               tra(ji,jj,ikt,jpnh4) = tra(ji,jj,ikt,jpnh4) + zpdenit + zolimit
383               tra(ji,jj,ikt,jpno3) = tra(ji,jj,ikt,jpno3) - rdenit * zpdenit
384               tra(ji,jj,ikt,jpoxy) = tra(ji,jj,ikt,jpoxy) - zolimit * o2ut
385               tra(ji,jj,ikt,jptal) = tra(ji,jj,ikt,jptal) + rno3 * (zolimit + (1.+rdenit) * zpdenit )
386               tra(ji,jj,ikt,jpdic) = tra(ji,jj,ikt,jpdic) + zpdenit + zolimit 
387               sdenit(ji,jj) = rdenit * zpdenit * e3t_n(ji,jj,ikt)
388               zsedc(ji,jj)   = (1. - zrivno3) * zwstpoc * e3t_n(ji,jj,ikt)
389               IF( ln_p5z ) THEN
390                  zwstpop              = trb(ji,jj,ikt,jpgop) * zws4 + trb(ji,jj,ikt,jppop) * zws3
391                  zwstpon              = trb(ji,jj,ikt,jpgon) * zws4 + trb(ji,jj,ikt,jppon) * zws3
392                  tra(ji,jj,ikt,jpdon) = tra(ji,jj,ikt,jpdon) + ( z1pdenit - zolimit ) * zwstpon / (zwstpoc + rtrn)
393                  tra(ji,jj,ikt,jpdop) = tra(ji,jj,ikt,jpdop) + ( z1pdenit - zolimit ) * zwstpop / (zwstpoc + rtrn)
394               ENDIF
395            END DO
396         END DO
397       ENDIF
398
399
400      ! Nitrogen fixation process
401      ! Small source iron from particulate inorganic iron
402      !-----------------------------------
403      DO jk = 1, jpkm1
404         zlight (:,:,jk) =  ( 1.- EXP( -etot_ndcy(:,:,jk) / diazolight ) ) * ( 1. - fr_i(:,:) ) 
405         zsoufer(:,:,jk) = zlight(:,:,jk) * 2E-11 / ( 2E-11 + biron(:,:,jk) )
406      ENDDO
407      IF( ln_p4z ) THEN
408         DO jk = 1, jpkm1
409            DO jj = 1, jpj
410               DO ji = 1, jpi
411                  !                      ! Potential nitrogen fixation dependant on temperature and iron
412                  zlim = ( 1.- xnanono3(ji,jj,jk) - xnanonh4(ji,jj,jk) )
413                  IF( zlim <= 0.2 )   zlim = 0.01
414                  zfact = zlim * rfact2
415
416                  ztrfer  = biron(ji,jj,jk)       / ( concfediaz + biron(ji,jj,jk)       )
417                  ztrpo4s = trb  (ji,jj,jk,jppo4) / ( concnnh4   + trb  (ji,jj,jk,jppo4) ) 
418                  nitrpot(ji,jj,jk) =  MAX( 0.e0, ( 0.6 * tgfunc(ji,jj,jk) - 2.15 ) * r1_rday ) &
419                    &                *  zfact * MIN( ztrfer, ztrpo4s ) * zlight(ji,jj,jk)
420               END DO
421            END DO
422         END DO
423      ELSE       ! p5z
424         DO jk = 1, jpkm1
425            DO jj = 1, jpj
426               DO ji = 1, jpi
427                  !                      ! Potential nitrogen fixation dependant on temperature and iron
428                  ztemp = tsn(ji,jj,jk,jp_tem)
429                  zmudia = MAX( 0.,-0.001096*ztemp**2 + 0.057*ztemp -0.637 ) * 7.625
430                  !       Potential nitrogen fixation dependant on temperature and iron
431                  xdianh4 = trb(ji,jj,jk,jpnh4) / ( concnnh4 + trb(ji,jj,jk,jpnh4) )
432                  xdiano3 = trb(ji,jj,jk,jpno3) / ( concnno3 + trb(ji,jj,jk,jpno3) ) * (1. - xdianh4)
433                  zlim = ( 1.- xdiano3 - xdianh4 )
434                  IF( zlim <= 0.1 )   zlim = 0.01
435                  zfact = zlim * rfact2
436                  ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) )
437                  ztrpo4(ji,jj,jk) = trb(ji,jj,jk,jppo4) / ( 1E-6 + trb(ji,jj,jk,jppo4) )
438                  ztrdop(ji,jj,jk) = trb(ji,jj,jk,jpdop) / ( 1E-6 + trb(ji,jj,jk,jpdop) ) * (1. - ztrpo4(ji,jj,jk))
439                  ztrdp = ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk)
440                  nitrpot(ji,jj,jk) =  zmudia * r1_rday * zfact * MIN( ztrfer, ztrdp ) * zlight(ji,jj,jk)
441               END DO
442            END DO
443         END DO
444      ENDIF
445
446      ! Nitrogen change due to nitrogen fixation
447      ! ----------------------------------------
448      IF( ln_p4z ) THEN
449         DO jk = 1, jpkm1
450            DO jj = 1, jpj
451               DO ji = 1, jpi
452                  zfact = nitrpot(ji,jj,jk) * nitrfix
453                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) +             zfact
454                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3      * zfact
455                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2nit     * zfact 
456                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + concdnh4 / ( concdnh4 + trb(ji,jj,jk,jppo4) ) &
457                  &                     * 0.002 * trb(ji,jj,jk,jpdoc) * xstep
458                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * xstep
459              END DO
460            END DO
461         END DO
462      ELSE    ! p5z
463         DO jk = 1, jpkm1
464            DO jj = 1, jpj
465               DO ji = 1, jpi
466                  zfact = nitrpot(ji,jj,jk) * nitrfix
467                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zfact / 3.0
468                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zfact / 3.0
469                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - 16.0 / 46.0 * zfact * ( 1.0 - 1.0 / 3.0 ) &
470                  &                     * ztrpo4(ji,jj,jk) / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
471                  tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + zfact * 1.0 / 3.0
472                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zfact * 1.0 / 3.0
473                  tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + 16.0 / 46.0 * zfact / 3.0  &
474                  &                     - 16.0 / 46.0 * zfact * ztrdop(ji,jj,jk)   &
475                  &                     / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
476                  tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zfact * 1.0 / 3.0 * 2.0 / 3.0
477                  tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + zfact * 1.0 / 3.0 * 2.0 /3.0
478                  tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 2.0 /3.0
479                  tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zfact * 1.0 / 3.0 * 1.0 / 3.0
480                  tra(ji,jj,jk,jpgon) = tra(ji,jj,jk,jpgon) + zfact * 1.0 / 3.0 * 1.0 /3.0
481                  tra(ji,jj,jk,jpgop) = tra(ji,jj,jk,jpgop) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 1.0 /3.0
482                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + ( o2ut + o2nit ) * zfact * 2.0 / 3.0 + o2nit * zfact / 3.0
483                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - 30E-6 * zfact * 1.0 / 3.0 
484                  tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + 30E-6 * zfact * 1.0 / 3.0 * 2.0 / 3.0
485                  tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + 30E-6 * zfact * 1.0 / 3.0 * 1.0 / 3.0
486                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
487              END DO
488            END DO
489         END DO
490         !
491      ENDIF
492
493      IF( lk_iomput ) THEN
494         IF( knt == nrdttrc ) THEN
495            zfact = 1.e+3 * rfact2r !  conversion from molC/l/kt  to molN/m3/s
496            IF( iom_use("Nfix"   ) ) CALL iom_put( "Nfix", nitrpot(:,:,:) * nitrfix * rno3 * zfact * tmask(:,:,:) )  ! nitrogen fixation
497            IF( iom_use("INTNFIX") ) THEN   ! nitrogen fixation rate in ocean ( vertically integrated )
498               zwork1(:,:) = 0.
499               DO jk = 1, jpkm1
500                 zwork1(:,:) = zwork1(:,:) + nitrpot(:,:,jk) * nitrfix * rno3 * zfact * e3t_n(:,:,jk) * tmask(:,:,jk)
501               ENDDO
502               CALL iom_put( "INTNFIX" , zwork1 ) 
503            ENDIF
504            IF( iom_use("SedCal" ) ) CALL iom_put( "SedCal", zsedcal(:,:) * zfact )
505            IF( iom_use("SedSi" ) )  CALL iom_put( "SedSi",  zsedsi (:,:) * zfact )
506            IF( iom_use("SedC" ) )   CALL iom_put( "SedC",   zsedc  (:,:) * zfact )
507            IF( iom_use("Sdenit" ) ) CALL iom_put( "Sdenit", sdenit (:,:) * zfact * rno3 )
508         ENDIF
509      ENDIF
510      !
511      IF(ln_ctl) THEN  ! print mean trends (USEd for debugging)
512         WRITE(charout, fmt="('sed ')")
513         CALL prt_ctl_trc_info(charout)
514         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
515      ENDIF
516      !
517                      CALL wrk_dealloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zbureff )
518                      CALL wrk_dealloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
519                      CALL wrk_dealloc( jpi, jpj, zsedcal,  zsedsi, zsedc )
520                      CALL wrk_dealloc( jpi, jpj, jpk, zlight, zsoufer )
521      IF( ln_p5z )    CALL wrk_dealloc( jpi, jpj, jpk, ztrpo4, ztrdop )
522      IF( ln_ligand ) CALL wrk_dealloc( jpi, jpj, zwsfep )
523      !
524      IF( nn_timing == 1 )  CALL timing_stop('p4z_sed')
525      !
526   END SUBROUTINE p4z_sed
527
528
529   INTEGER FUNCTION p4z_sed_alloc()
530      !!----------------------------------------------------------------------
531      !!                     ***  ROUTINE p4z_sed_alloc  ***
532      !!----------------------------------------------------------------------
533      ALLOCATE( nitrpot(jpi,jpj,jpk), sdenit(jpi,jpj), STAT=p4z_sed_alloc )
534      !
535      IF( p4z_sed_alloc /= 0 )   CALL ctl_warn('p4z_sed_alloc: failed to allocate arrays')
536      !
537   END FUNCTION p4z_sed_alloc
538
539
540   !!======================================================================
541END MODULE p4zsed
Note: See TracBrowser for help on using the repository browser.