New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zlys.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zlys.F90 @ 2715

Last change on this file since 2715 was 2715, checked in by rblod, 13 years ago

First attempt to put dynamic allocation on the trunk
  • Property svn:keywords set to Id
File size: 9.1 KB
Line 
1MODULE p4zlys
2   !!======================================================================
3   !!                         ***  MODULE p4zlys  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!----------------------------------------------------------------------
12#if defined key_pisces
13   !!----------------------------------------------------------------------
14   !!   'key_pisces'                                       PISCES bio-model
15   !!----------------------------------------------------------------------
16   !!   p4z_lys        :   Compute the CaCO3 dissolution
17   !!   p4z_lys_init   :   Read the namelist parameters
18   !!----------------------------------------------------------------------
19   USE trc
20   USE oce_trc         !
21   USE trc
22   USE sms_pisces
23   USE prtctl_trc
24   USE iom
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_lys         ! called in trcsms_pisces.F90
30   PUBLIC   p4z_lys_init    ! called in trcsms_pisces.F90
31
32   !! * Shared module variables
33   REAL(wp), PUBLIC :: kdca = 0.327e3_wp  !: diss. rate constant calcite
34   REAL(wp), PUBLIC :: nca  = 1.0_wp      !: order of reaction for calcite dissolution
35
36   !! * Module variables
37   REAL(wp) :: calcon = 1.03E-2           !: mean calcite concentration [Ca2+] in sea water [mole/kg solution]
38 
39   INTEGER  :: rmtss                      !: number of seconds per month
40
41   !!----------------------------------------------------------------------
42   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46
47CONTAINS
48
49   SUBROUTINE p4z_lys( kt )
50      !!---------------------------------------------------------------------
51      !!                     ***  ROUTINE p4z_lys  ***
52      !!
53      !! ** Purpose :   CALCULATES DEGREE OF CACO3 SATURATION IN THE WATER
54      !!                COLUMN, DISSOLUTION/PRECIPITATION OF CACO3 AND LOSS
55      !!                OF CACO3 TO THE CACO3 SEDIMENT POOL.
56      !!
57      !! ** Method  : - ???
58      !!---------------------------------------------------------------------
59      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
60      USE wrk_nemo, ONLY: zco3 => wrk_3d_2, zcaldiss => wrk_3d_3 
61      !
62      INTEGER, INTENT(in) ::   kt ! ocean time step
63      INTEGER  ::   ji, jj, jk, jn
64      REAL(wp) ::   zbot, zalk, zdic, zph, zremco3, zah2
65      REAL(wp) ::   zdispot, zfact, zalka
66      REAL(wp) ::   zomegaca, zexcess, zexcess0
67#if defined key_diatrc && defined key_iomput
68      REAL(wp) ::   zrfact2
69#endif
70      CHARACTER (len=25) :: charout
71      !!---------------------------------------------------------------------
72
73      IF(  wrk_in_use(3, 2,3) ) THEN
74         CALL ctl_stop('p4z_lys: requested workspace arrays unavailable')  ;  RETURN
75      END IF
76
77      zco3(:,:,:) = 0.
78# if defined key_diatrc && defined key_iomput
79      zcaldiss(:,:,:) = 0.
80# endif
81      !     -------------------------------------------
82      !     COMPUTE [CO3--] and [H+] CONCENTRATIONS
83      !     -------------------------------------------
84     
85      DO jn = 1, 5                               !  BEGIN OF ITERATION
86         !
87!CDIR NOVERRCHK
88         DO jk = 1, jpkm1
89!CDIR NOVERRCHK
90            DO jj = 1, jpj
91!CDIR NOVERRCHK
92               DO ji = 1, jpi
93
94                  ! SET DUMMY VARIABLE FOR TOTAL BORATE
95                  zbot  = borat(ji,jj,jk)
96
97                  ! SET DUMMY VARIABLE FOR TOTAL BORATE
98                  zbot  = borat(ji,jj,jk)
99                  zfact = rhop (ji,jj,jk) / 1000. + rtrn
100
101                  ! SET DUMMY VARIABLE FOR [H+]
102                  zph   = hi(ji,jj,jk) * tmask(ji,jj,jk) / zfact + ( 1.-tmask(ji,jj,jk) ) * 1.e-9
103
104                  ! SET DUMMY VARIABLE FOR [SUM(CO2)]GIVEN
105                  zdic  = trn(ji,jj,jk,jpdic) / zfact
106                  zalka = trn(ji,jj,jk,jptal) / zfact
107
108                  ! CALCULATE [ALK]([CO3--], [HCO3-])
109                  zalk  = zalka - (  akw3(ji,jj,jk) / zph - zph   &
110                     &             + zbot / (1.+ zph / akb3(ji,jj,jk) )  )
111
112                  ! CALCULATE [H+] and [CO3--]
113                  zah2 = SQRT( (zdic-zalk)*(zdic-zalk)+   &
114                     &     4.*(zalk*ak23(ji,jj,jk)/ak13(ji,jj,jk))   &
115                     &     *(2*zdic-zalk))
116
117                  zah2=0.5*ak13(ji,jj,jk)/zalk*((zdic-zalk)+zah2)
118                  zco3(ji,jj,jk) = zalk/(2.+zah2/ak23(ji,jj,jk))*zfact
119
120                  hi(ji,jj,jk)  = zah2*zfact
121
122               END DO
123            END DO
124         END DO
125         !
126      END DO 
127
128      !     ---------------------------------------------------------
129      !        CALCULATE DEGREE OF CACO3 SATURATION AND CORRESPONDING
130      !        DISSOLOUTION AND PRECIPITATION OF CACO3 (BE AWARE OF
131      !        MGCO3)
132      !     ---------------------------------------------------------
133
134      DO jk = 1, jpkm1
135         DO jj = 1, jpj
136            DO ji = 1, jpi
137
138               ! DEVIATION OF [CO3--] FROM SATURATION VALUE
139               zomegaca = ( calcon * zco3(ji,jj,jk) ) / aksp(ji,jj,jk)
140
141               ! SET DEGREE OF UNDER-/SUPERSATURATION
142               zexcess0 = MAX( 0., ( 1.- zomegaca ) )
143               zexcess  = zexcess0**nca
144
145               ! AMOUNT CACO3 (12C) THAT RE-ENTERS SOLUTION
146               !       (ACCORDING TO THIS FORMULATION ALSO SOME PARTICULATE
147               !       CACO3 GETS DISSOLVED EVEN IN THE CASE OF OVERSATURATION)
148# if defined key_degrad
149              zdispot = kdca * zexcess * trn(ji,jj,jk,jpcal) * facvol(ji,jj,jk)
150# else
151              zdispot = kdca * zexcess * trn(ji,jj,jk,jpcal)
152# endif
153
154              !  CHANGE OF [CO3--] , [ALK], PARTICULATE [CACO3],
155              !       AND [SUM(CO2)] DUE TO CACO3 DISSOLUTION/PRECIPITATION
156              zremco3 = zdispot / rmtss
157              zco3(ji,jj,jk) = zco3(ji,jj,jk) + zremco3 * rfact
158              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2. * zremco3
159              tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) -      zremco3
160              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +      zremco3
161
162# if defined key_diatrc && defined key_iomput
163              zcaldiss(ji,jj,jk) = zremco3  ! calcite dissolution
164# endif
165            END DO
166         END DO
167      END DO
168
169# if defined key_diatrc
170#  if ! defined key_iomput
171      trc3d(:,:,:,jp_pcs0_3d    ) = hi  (:,:,:)          * tmask(:,:,:)
172      trc3d(:,:,:,jp_pcs0_3d + 1) = zco3(:,:,:)          * tmask(:,:,:)
173      trc3d(:,:,:,jp_pcs0_3d + 2) = aksp(:,:,:) / calcon * tmask(:,:,:)
174#  else
175      zrfact2 = 1.e3 * rfact2r
176      CALL iom_put( "PH"    , hi      (:,:,:)           * tmask(:,:,:) )
177      CALL iom_put( "CO3"   , zco3    (:,:,:)           * tmask(:,:,:) )
178      CALL iom_put( "CO3sat", aksp    (:,:,:) / calcon  * tmask(:,:,:) )
179      CALL iom_put( "DCAL"  , zcaldiss(:,:,:) * zrfact2 * tmask(:,:,:) )
180#  endif
181# endif
182      !
183       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
184         WRITE(charout, FMT="('lys ')")
185         CALL prt_ctl_trc_info(charout)
186         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
187       ENDIF
188
189      IF( wrk_not_released(3, 2,3) ) CALL ctl_stop('p4z_lys: failed to release workspace arrays')
190      !
191   END SUBROUTINE p4z_lys
192
193   SUBROUTINE p4z_lys_init
194
195      !!----------------------------------------------------------------------
196      !!                  ***  ROUTINE p4z_lys_init  ***
197      !!
198      !! ** Purpose :   Initialization of CaCO3 dissolution parameters
199      !!
200      !! ** Method  :   Read the nampiscal namelist and check the parameters
201      !!      called at the first timestep (nit000)
202      !!
203      !! ** input   :   Namelist nampiscal
204      !!
205      !!----------------------------------------------------------------------
206
207      NAMELIST/nampiscal/ kdca, nca
208
209      REWIND( numnat )                     ! read numnat
210      READ  ( numnat, nampiscal )
211
212      IF(lwp) THEN                         ! control print
213         WRITE(numout,*) ' '
214         WRITE(numout,*) ' Namelist parameters for CaCO3 dissolution, nampiscal'
215         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
216         WRITE(numout,*) '    diss. rate constant calcite (per month)   kdca      =', kdca
217         WRITE(numout,*) '    order of reaction for calcite dissolution nca       =', nca
218      ENDIF
219
220      ! Number of seconds per month
221      rmtss =  nyear_len(1) * rday / raamo
222
223   END SUBROUTINE p4z_lys_init
224
225#else
226   !!======================================================================
227   !!  Dummy module :                                   No PISCES bio-model
228   !!======================================================================
229CONTAINS
230   SUBROUTINE p4z_lys( kt )                   ! Empty routine
231      INTEGER, INTENT( in ) ::   kt
232      WRITE(*,*) 'p4z_lys: You should not have seen this print! error?', kt
233   END SUBROUTINE p4z_lys
234#endif 
235   !!======================================================================
236END MODULE  p4zlys
Note: See TracBrowser for help on using the repository browser.