New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zopt.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zopt.F90 @ 3294

Last change on this file since 3294 was 3294, checked in by rblod, 12 years ago

Merge of 3.4beta into the trunk

  • Property svn:keywords set to Id
File size: 11.8 KB
Line 
1MODULE p4zopt
2   !!======================================================================
3   !!                         ***  MODULE p4zopt  ***
4   !! TOP - PISCES : Compute the light availability in the water column
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.2  !  2009-04  (C. Ethe, G. Madec)  optimisation
9   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Improve light availability of nano & diat
10   !!----------------------------------------------------------------------
11#if defined  key_pisces
12   !!----------------------------------------------------------------------
13   !!   'key_pisces'                                       PISCES bio-model
14   !!----------------------------------------------------------------------
15   !!   p4z_opt       : light availability in the water column
16   !!----------------------------------------------------------------------
17   USE trc            ! tracer variables
18   USE oce_trc        ! tracer-ocean share variables
19   USE sms_pisces     ! Source Minus Sink of PISCES
20   USE iom            ! I/O manager
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p4z_opt        ! called in p4zbio.F90 module
26   PUBLIC   p4z_opt_init   ! called in trcsms_pisces.F90 module
27   PUBLIC   p4z_opt_alloc
28
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: etot, enano, ediat   !: PAR for phyto, nano and diat
30   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: emoy                 !: averaged PAR in the mixed layer
31
32   INTEGER  ::   nksrp   ! levels below which the light cannot penetrate ( depth larger than 391 m)
33   REAL(wp) ::   parlux = 0.43_wp / 3._wp
34
35   REAL(wp), DIMENSION(3,61), PUBLIC ::   xkrgb   !: tabulated attenuation coefficients for RGB absorption
36   
37   !!* Substitution
38#  include "top_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
41   !! $Id$
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE p4z_opt( kt, jnt )
47      !!---------------------------------------------------------------------
48      !!                     ***  ROUTINE p4z_opt  ***
49      !!
50      !! ** Purpose :   Compute the light availability in the water column
51      !!              depending on the depth and the chlorophyll concentration
52      !!
53      !! ** Method  : - ???
54      !!---------------------------------------------------------------------
55      !
56      INTEGER, INTENT(in) ::   kt, jnt   ! ocean time step
57      !
58      INTEGER  ::   ji, jj, jk
59      INTEGER  ::   irgb
60      REAL(wp) ::   zchl, zxsi0r
61      REAL(wp) ::   zc0 , zc1 , zc2, zc3, z1_dep
62      REAL(wp), POINTER, DIMENSION(:,:  ) :: zdepmoy, zetmp, zetmp1, zetmp2
63      REAL(wp), POINTER, DIMENSION(:,:,:) :: zekg, zekr, zekb, ze0, ze1, ze2, ze3
64      !!---------------------------------------------------------------------
65      !
66      IF( nn_timing == 1 )  CALL timing_start('p4z_opt')
67      !
68      ! Allocate temporary workspace
69      CALL wrk_alloc( jpi, jpj,      zdepmoy, zetmp, zetmp1, zetmp2       )
70      CALL wrk_alloc( jpi, jpj, jpk, zekg, zekr, zekb, ze0, ze1, ze2, ze3 )
71
72      !     Initialisation of variables used to compute PAR
73      !     -----------------------------------------------
74      ze1 (:,:,jpk) = 0._wp
75      ze2 (:,:,jpk) = 0._wp
76      ze3 (:,:,jpk) = 0._wp
77
78      !                                        !* attenuation coef. function of Chlorophyll and wavelength (Red-Green-Blue)
79      DO jk = 1, jpkm1                         !  --------------------------------------------------------
80!CDIR NOVERRCHK
81         DO jj = 1, jpj
82!CDIR NOVERRCHK
83            DO ji = 1, jpi
84               zchl = ( trn(ji,jj,jk,jpnch) + trn(ji,jj,jk,jpdch) + rtrn ) * 1.e6
85               zchl = MIN(  10. , MAX( 0.05, zchl )  )
86               irgb = NINT( 41 + 20.* LOG10( zchl ) + rtrn )
87               !                                                         
88               zekb(ji,jj,jk) = xkrgb(1,irgb) * fse3t(ji,jj,jk)
89               zekg(ji,jj,jk) = xkrgb(2,irgb) * fse3t(ji,jj,jk)
90               zekr(ji,jj,jk) = xkrgb(3,irgb) * fse3t(ji,jj,jk)
91            END DO
92         END DO
93      END DO
94
95
96      !                                        !* Photosynthetically Available Radiation (PAR)
97      !                                        !  --------------------------------------
98!CDIR NOVERRCHK
99      DO jj = 1, jpj
100!CDIR NOVERRCHK
101         DO ji = 1, jpi
102            zc1 = parlux * qsr(ji,jj) * EXP( -0.5 * zekb(ji,jj,1) )
103            zc2 = parlux * qsr(ji,jj) * EXP( -0.5 * zekg(ji,jj,1) )
104            zc3 = parlux * qsr(ji,jj) * EXP( -0.5 * zekr(ji,jj,1) )
105            ze1  (ji,jj,1) = zc1
106            ze2  (ji,jj,1) = zc2
107            ze3  (ji,jj,1) = zc3
108            etot (ji,jj,1) = (       zc1 +        zc2 +       zc3 )
109            enano(ji,jj,1) = ( 2.1 * zc1 + 0.42 * zc2 + 0.4 * zc3 )
110            ediat(ji,jj,1) = ( 1.6 * zc1 + 0.69 * zc2 + 0.7 * zc3 )
111         END DO
112      END DO
113
114   
115      DO jk = 2, nksrp     
116!CDIR NOVERRCHK
117         DO jj = 1, jpj
118!CDIR NOVERRCHK
119            DO ji = 1, jpi
120               zc1 = ze1(ji,jj,jk-1) * EXP( -0.5 * ( zekb(ji,jj,jk-1) + zekb(ji,jj,jk) ) )
121               zc2 = ze2(ji,jj,jk-1) * EXP( -0.5 * ( zekg(ji,jj,jk-1) + zekg(ji,jj,jk) ) )
122               zc3 = ze3(ji,jj,jk-1) * EXP( -0.5 * ( zekr(ji,jj,jk-1) + zekr(ji,jj,jk) ) )
123               ze1  (ji,jj,jk) = zc1
124               ze2  (ji,jj,jk) = zc2
125               ze3  (ji,jj,jk) = zc3
126               etot (ji,jj,jk) = (       zc1 +        zc2 +       zc3 )
127               enano(ji,jj,jk) = ( 2.1 * zc1 + 0.42 * zc2 + 0.4 * zc3 )
128               ediat(ji,jj,jk) = ( 1.6 * zc1 + 0.69 * zc2 + 0.7 * zc3 )
129            END DO
130         END DO
131      END DO
132
133      IF( ln_qsr_bio ) THEN                    !* heat flux accros w-level (used in the dynamics)
134         !                                     !  ------------------------
135         zxsi0r = 1.e0 / rn_si0
136         !
137         ze0  (:,:,1) = rn_abs * qsr(:,:)
138         ze1  (:,:,1) = parlux * qsr(:,:)             ! surface value : separation in R-G-B + near surface
139         ze2  (:,:,1) = parlux * qsr(:,:)
140         ze3  (:,:,1) = parlux * qsr(:,:)
141         etot3(:,:,1) =          qsr(:,:) * tmask(:,:,1)
142         !
143         DO jk = 2, nksrp + 1
144!CDIR NOVERRCHK
145            DO jj = 1, jpj
146!CDIR NOVERRCHK
147               DO ji = 1, jpi
148                  zc0 = ze0(ji,jj,jk-1) * EXP( -fse3t(ji,jj,jk-1) * zxsi0r )
149                  zc1 = ze1(ji,jj,jk-1) * EXP( -zekb(ji,jj,jk-1 ) )
150                  zc2 = ze2(ji,jj,jk-1) * EXP( -zekg(ji,jj,jk-1 ) )
151                  zc3 = ze3(ji,jj,jk-1) * EXP( -zekr(ji,jj,jk-1 ) )
152                  ze0(ji,jj,jk) = zc0
153                  ze1(ji,jj,jk) = zc1
154                  ze2(ji,jj,jk) = zc2
155                  ze3(ji,jj,jk) = zc3
156                  etot3(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
157              END DO
158              !
159            END DO
160            !
161        END DO
162        !
163      ENDIF
164
165      !                                        !* Euphotic depth and level
166      neln(:,:) = 1                            !  ------------------------
167      heup(:,:) = 300.
168
169      DO jk = 2, nksrp
170         DO jj = 1, jpj
171           DO ji = 1, jpi
172              IF( etot(ji,jj,jk) >= 0.0043 * qsr(ji,jj) )  THEN
173                 neln(ji,jj) = jk+1                    ! Euphotic level : 1rst T-level strictly below Euphotic layer
174                 !                                     ! nb: ensure the compatibility with nmld_trc definition in trd_mld_trc_zint
175                 heup(ji,jj) = fsdepw(ji,jj,jk+1)      ! Euphotic layer depth
176              ENDIF
177           END DO
178        END DO
179      END DO
180 
181      heup(:,:) = MIN( 300., heup(:,:) )
182
183      !                                        !* mean light over the mixed layer
184      zdepmoy(:,:)   = 0.e0                    !  -------------------------------
185      zetmp  (:,:)   = 0.e0
186      zetmp1 (:,:)   = 0.e0
187      zetmp2 (:,:)   = 0.e0
188
189      DO jk = 1, nksrp
190!CDIR NOVERRCHK
191         DO jj = 1, jpj
192!CDIR NOVERRCHK
193            DO ji = 1, jpi
194               IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
195                  zetmp  (ji,jj) = zetmp  (ji,jj) + etot (ji,jj,jk) * fse3t(ji,jj,jk)
196                  zetmp1 (ji,jj) = zetmp1 (ji,jj) + enano(ji,jj,jk) * fse3t(ji,jj,jk)
197                  zetmp2 (ji,jj) = zetmp2 (ji,jj) + ediat(ji,jj,jk) * fse3t(ji,jj,jk)
198                  zdepmoy(ji,jj) = zdepmoy(ji,jj) + fse3t(ji,jj,jk)
199               ENDIF
200            END DO
201         END DO
202      END DO
203      !
204      emoy(:,:,:) = etot(:,:,:)
205      !
206      DO jk = 1, nksrp
207!CDIR NOVERRCHK
208         DO jj = 1, jpj
209!CDIR NOVERRCHK
210            DO ji = 1, jpi
211               IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
212                  z1_dep = 1. / ( zdepmoy(ji,jj) + rtrn )
213                  emoy (ji,jj,jk) = zetmp (ji,jj) * z1_dep
214                  enano(ji,jj,jk) = zetmp1(ji,jj) * z1_dep
215                  ediat(ji,jj,jk) = zetmp2(ji,jj) * z1_dep
216               ENDIF
217            END DO
218         END DO
219      END DO
220
221      IF( ln_diatrc ) THEN        ! save output diagnostics
222        !
223        IF( lk_iomput ) THEN
224           IF( jnt == nrdttrc ) THEN
225              CALL iom_put( "Heup", heup(:,:  ) * tmask(:,:,1) )  ! euphotic layer deptht
226              CALL iom_put( "PAR" , etot(:,:,:) * tmask(:,:,:) )  ! Photosynthetically Available Radiation
227           ENDIF
228        ELSE
229           trc2d(:,:,  jp_pcs0_2d + 10) = heup(:,:  ) * tmask(:,:,1) 
230           trc3d(:,:,:,jp_pcs0_3d + 3)  = etot(:,:,:) * tmask(:,:,:)
231        ENDIF
232        !
233      ENDIF
234      !
235      CALL wrk_dealloc( jpi, jpj,      zdepmoy, zetmp, zetmp1, zetmp2 )
236      CALL wrk_dealloc( jpi, jpj, jpk, zekg, zekr, zekb, ze0, ze1, ze2, ze3 )
237      !
238      IF( nn_timing == 1 )  CALL timing_stop('p4z_opt')
239      !
240   END SUBROUTINE p4z_opt
241
242
243   SUBROUTINE p4z_opt_init
244      !!----------------------------------------------------------------------
245      !!                  ***  ROUTINE p4z_opt_init  ***
246      !!
247      !! ** Purpose :   Initialization of tabulated attenuation coef
248      !!----------------------------------------------------------------------
249      !
250      IF( nn_timing == 1 )  CALL timing_start('p4z_opt_init')
251      !
252      CALL trc_oce_rgb( xkrgb )                  ! tabulated attenuation coefficients
253      nksrp = trc_oce_ext_lev( r_si2, 0.33e2 )     ! max level of light extinction (Blue Chl=0.01)
254      !
255      IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksrp, ' ref depth = ', gdepw_0(nksrp+1), ' m'
256      !
257                         etot (:,:,:) = 0._wp
258                         enano(:,:,:) = 0._wp
259                         ediat(:,:,:) = 0._wp
260      IF( ln_qsr_bio )   etot3(:,:,:) = 0._wp
261      !
262      IF( nn_timing == 1 )  CALL timing_stop('p4z_opt_init')
263      !
264   END SUBROUTINE p4z_opt_init
265
266
267   INTEGER FUNCTION p4z_opt_alloc()
268      !!----------------------------------------------------------------------
269      !!                     ***  ROUTINE p4z_opt_alloc  ***
270      !!----------------------------------------------------------------------
271      ALLOCATE( etot (jpi,jpj,jpk) , enano(jpi,jpj,jpk) ,     &
272         &      ediat(jpi,jpj,jpk) , emoy (jpi,jpj,jpk) , STAT=p4z_opt_alloc )
273         !
274      IF( p4z_opt_alloc /= 0 ) CALL ctl_warn('p4z_opt_alloc : failed to allocate arrays.')
275      !
276   END FUNCTION p4z_opt_alloc
277
278#else
279   !!----------------------------------------------------------------------
280   !!  Dummy module :                                   No PISCES bio-model
281   !!----------------------------------------------------------------------
282CONTAINS
283   SUBROUTINE p4z_opt                   ! Empty routine
284   END SUBROUTINE p4z_opt
285#endif 
286
287   !!======================================================================
288END MODULE  p4zopt
Note: See TracBrowser for help on using the repository browser.