New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zrem.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zrem.F90 @ 2773

Last change on this file since 2773 was 2773, checked in by cetlod, 13 years ago

PISCES trunk, bug in p4zrem.F90 : wrk_3d_2 is used twice

  • Property svn:keywords set to Id
File size: 18.9 KB
Line 
1MODULE p4zrem
2   !!======================================================================
3   !!                         ***  MODULE p4zrem  ***
4   !! TOP :   PISCES Compute remineralization/scavenging of organic compounds
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9#if defined key_pisces
10   !!----------------------------------------------------------------------
11   !!   'key_top'       and                                      TOP models
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_rem       :   Compute remineralization/scavenging of organic compounds
15   !!----------------------------------------------------------------------
16   USE trc
17   USE oce_trc         !
18   USE sms_pisces      !
19   USE prtctl_trc
20   USE p4zint
21   USE p4zopt
22   USE p4zmeso
23   USE p4zprod
24   USE p4zche
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_rem         ! called in p4zbio.F90
30   PUBLIC   p4z_rem_init    ! called in trcsms_pisces.F90
31   PUBLIC   p4z_rem_alloc
32
33   REAL(wp), PUBLIC ::   &
34     xremik  = 0.3_wp      ,  & !:
35     xremip  = 0.025_wp    ,  & !:
36     nitrif  = 0.05_wp     ,  & !:
37     xsirem  = 0.015_wp    ,  & !:
38     xlam1   = 0.005_wp    ,  & !:
39     oxymin  = 1.e-6_wp         !:
40
41   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitr   !: denitrification array
42
43
44   !!* Substitution
45#  include "top_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE p4z_rem( kt )
54      !!---------------------------------------------------------------------
55      !!                     ***  ROUTINE p4z_rem  ***
56      !!
57      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
58      !!
59      !! ** Method  : - ???
60      !!---------------------------------------------------------------------
61      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
62      USE wrk_nemo, ONLY:   ztempbac => wrk_2d_1
63      USE wrk_nemo, ONLY:   zdepbac  => wrk_3d_2 , zolimi => wrk_3d_3
64      !
65      INTEGER, INTENT(in) ::   kt ! ocean time step
66      !
67      INTEGER  ::   ji, jj, jk
68      REAL(wp) ::   zremip, zremik , zlam1b
69      REAL(wp) ::   zkeq  , zfeequi, zsiremin, zfesatur
70      REAL(wp) ::   zsatur, zsatur2, znusil
71      REAL(wp) ::   zbactfer, zorem, zorem2, zofer
72      REAL(wp) ::   zosil, zdenom1, zscave, zaggdfe
73#if ! defined key_kriest
74      REAL(wp) ::   zofer2, zdenom, zdenom2
75#endif
76      REAL(wp) ::   zlamfac, zonitr, zstep
77      CHARACTER (len=25) :: charout
78      !!---------------------------------------------------------------------
79
80      IF(  wrk_in_use(2, 1)  .OR.  wrk_in_use(3, 2,3)  ) THEN
81         CALL ctl_stop('p4z_rem: requested workspace arrays unavailable')   ;   RETURN
82      ENDIF
83
84       ! Initialisation of temprary arrys
85       zdepbac (:,:,:) = 0._wp
86       zolimi  (:,:,:) = 0._wp
87       ztempbac(:,:)   = 0._wp
88
89      !  Computation of the mean phytoplankton concentration as
90      !  a crude estimate of the bacterial biomass
91      !   --------------------------------------------------
92      DO jk = 1, jpkm1
93         DO jj = 1, jpj
94            DO ji = 1, jpi
95               IF( fsdept(ji,jj,jk) < 120. ) THEN
96                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trn(ji,jj,jk,jpzoo) + 2.* trn(ji,jj,jk,jpmes) ), 4.e-6 )
97                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
98               ELSE
99                  zdepbac(ji,jj,jk) = MIN( 1., 120./ fsdept(ji,jj,jk) ) * ztempbac(ji,jj)
100               ENDIF
101            END DO
102         END DO
103      END DO
104
105      DO jk = 1, jpkm1
106         DO jj = 1, jpj
107            DO ji = 1, jpi
108               ! denitrification factor computed from O2 levels
109               nitrfac(ji,jj,jk) = MAX(  0.e0, 0.4 * ( 6.e-6  - trn(ji,jj,jk,jpoxy) )    &
110                  &                                / ( oxymin + trn(ji,jj,jk,jpoxy) )  )
111               nitrfac(ji,jj,jk) = MIN( 1., nitrfac(ji,jj,jk) )
112            END DO
113         END DO
114      END DO
115
116      DO jk = 1, jpkm1
117         DO jj = 1, jpj
118            DO ji = 1, jpi
119# if defined key_degrad
120               zstep = xstep * facvol(ji,jj,jk)
121# else
122               zstep = xstep
123# endif
124               ! DOC ammonification. Depends on depth, phytoplankton biomass
125               !     and a limitation term which is supposed to be a parameterization
126               !     of the bacterial activity.
127               zremik = xremik * zstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) 
128               zremik = MAX( zremik, 5.5e-4 * xstep )
129
130               !     Ammonification in oxic waters with oxygen consumption
131               !     -----------------------------------------------------
132               zolimi(ji,jj,jk) = MIN(  ( trn(ji,jj,jk,jpoxy) - rtrn ) / o2ut,  &
133                  &                    zremik * ( 1.- nitrfac(ji,jj,jk) ) * trn(ji,jj,jk,jpdoc)  ) 
134
135               !     Ammonification in suboxic waters with denitrification
136               !     -------------------------------------------------------
137               denitr(ji,jj,jk) = MIN(  ( trn(ji,jj,jk,jpno3) - rtrn ) / rdenit,   &
138                  &                     zremik * nitrfac(ji,jj,jk) * trn(ji,jj,jk,jpdoc)  )
139            END DO
140         END DO
141      END DO
142
143      DO jk = 1, jpkm1
144         DO jj = 1, jpj
145            DO ji = 1, jpi
146               zolimi (ji,jj,jk) = MAX( 0.e0, zolimi (ji,jj,jk) )
147               denitr (ji,jj,jk) = MAX( 0.e0, denitr (ji,jj,jk) )
148            END DO
149         END DO
150      END DO
151
152      DO jk = 1, jpkm1
153         DO jj = 1, jpj
154            DO ji = 1, jpi
155# if defined key_degrad
156               zstep = xstep * facvol(ji,jj,jk)
157# else
158               zstep = xstep
159# endif
160               !    NH4 nitrification to NO3. Ceased for oxygen concentrations
161               !    below 2 umol/L. Inhibited at strong light
162               !    ----------------------------------------------------------
163               zonitr  = nitrif * zstep * trn(ji,jj,jk,jpnh4) / ( 1.+ emoy(ji,jj,jk) ) * ( 1.- nitrfac(ji,jj,jk) ) 
164
165               !   Update of the tracers trends
166               !   ----------------------------
167
168               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr
169               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr
170               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
171               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - rno3  * zonitr
172
173            END DO
174         END DO
175      END DO
176
177       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
178         WRITE(charout, FMT="('rem1')")
179         CALL prt_ctl_trc_info(charout)
180         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
181       ENDIF
182
183      DO jk = 1, jpkm1
184         DO jj = 1, jpj
185            DO ji = 1, jpi
186
187               !    Bacterial uptake of iron. No iron is available in DOC. So
188               !    Bacteries are obliged to take up iron from the water. Some
189               !    studies (especially at Papa) have shown this uptake to be significant
190               !    ----------------------------------------------------------
191               zbactfer = 15.e-6 * rfact2 * 4.* 0.4 * prmax(ji,jj,jk)           &
192                  &               * ( xlimphy(ji,jj,jk) * zdepbac(ji,jj,jk))           &
193                  &               * ( xlimphy(ji,jj,jk) * zdepbac(ji,jj,jk))           &
194                  &                  / ( xkgraz2 + zdepbac(ji,jj,jk) )                    &
195                  &                  * ( 0.5 + SIGN( 0.5, trn(ji,jj,jk,jpfer) -2.e-11 )  )
196
197               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer
198#if defined key_kriest
199               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer
200#else
201               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer
202#endif
203            END DO
204         END DO
205      END DO
206
207       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
208         WRITE(charout, FMT="('rem2')")
209         CALL prt_ctl_trc_info(charout)
210         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
211       ENDIF
212
213      DO jk = 1, jpkm1
214         DO jj = 1, jpj
215            DO ji = 1, jpi
216# if defined key_degrad
217               zstep = xstep * facvol(ji,jj,jk)
218# else
219               zstep = xstep
220# endif
221               !    POC disaggregation by turbulence and bacterial activity.
222               !    -------------------------------------------------------------
223               zremip = xremip * zstep * tgfunc(ji,jj,jk) * ( 1.- 0.5 * nitrfac(ji,jj,jk) ) 
224
225               !    POC disaggregation rate is reduced in anoxic zone as shown by
226               !    sediment traps data. In oxic area, the exponent of the martin s
227               !    law is around -0.87. In anoxic zone, it is around -0.35. This
228               !    means a disaggregation constant about 0.5 the value in oxic zones
229               !    -----------------------------------------------------------------
230               zorem  = zremip * trn(ji,jj,jk,jppoc)
231               zofer  = zremip * trn(ji,jj,jk,jpsfe)
232#if ! defined key_kriest
233               zorem2 = zremip * trn(ji,jj,jk,jpgoc)
234               zofer2 = zremip * trn(ji,jj,jk,jpbfe)
235#else
236               zorem2 = zremip * trn(ji,jj,jk,jpnum)
237#endif
238
239               !  Update the appropriate tracers trends
240               !  -------------------------------------
241
242               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zorem
243               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zofer
244#if defined key_kriest
245               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zorem
246               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) - zorem2
247               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zofer
248#else
249               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zorem2 - zorem
250               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) - zorem2
251               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zofer2 - zofer
252               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) - zofer2
253#endif
254
255            END DO
256         END DO
257      END DO
258
259       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
260         WRITE(charout, FMT="('rem3')")
261         CALL prt_ctl_trc_info(charout)
262         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
263       ENDIF
264
265      DO jk = 1, jpkm1
266         DO jj = 1, jpj
267            DO ji = 1, jpi
268# if defined key_degrad
269               zstep = xstep * facvol(ji,jj,jk)
270# else
271               zstep = xstep
272# endif
273               !     Remineralization rate of BSi depedant on T and saturation
274               !     ---------------------------------------------------------
275               zsatur  = ( sio3eq(ji,jj,jk) - trn(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn )
276               zsatur  = MAX( rtrn, zsatur )
277               zsatur2 = zsatur * ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**4
278               znusil  = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2**9
279               zsiremin = xsirem * zstep * znusil
280               zosil = zsiremin * trn(ji,jj,jk,jpdsi)
281
282               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zosil
283               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
284               !
285            END DO
286         END DO
287      END DO
288
289      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
290         WRITE(charout, FMT="('rem4')")
291         CALL prt_ctl_trc_info(charout)
292         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
293       ENDIF
294
295      zfesatur = 0.6e-9
296!CDIR NOVERRCHK
297      DO jk = 1, jpkm1
298!CDIR NOVERRCHK
299         DO jj = 1, jpj
300!CDIR NOVERRCHK
301            DO ji = 1, jpi
302# if defined key_degrad
303               zstep = xstep * facvol(ji,jj,jk)
304# else
305               zstep = xstep
306# endif
307               !  Compute de different ratios for scavenging of iron
308               !  --------------------------------------------------
309
310#if  defined key_kriest
311               zdenom1 = trn(ji,jj,jk,jppoc) / &
312           &           ( trn(ji,jj,jk,jppoc) + trn(ji,jj,jk,jpdsi) + trn(ji,jj,jk,jpcal) + rtrn )
313#else
314               zdenom = 1. / ( trn(ji,jj,jk,jppoc) + trn(ji,jj,jk,jpgoc)  &
315           &            + trn(ji,jj,jk,jpdsi) + trn(ji,jj,jk,jpcal) + rtrn )
316
317               zdenom1 = trn(ji,jj,jk,jppoc) * zdenom
318               zdenom2 = trn(ji,jj,jk,jpgoc) * zdenom
319#endif
320               !  scavenging rate of iron. this scavenging rate depends on the load in particles
321               !  on which they are adsorbed. The  parameterization has been taken from studies on Th
322               !     ------------------------------------------------------------
323               zkeq = fekeq(ji,jj,jk)
324               zfeequi = ( -( 1. + zfesatur * zkeq - zkeq * trn(ji,jj,jk,jpfer) )               &
325                  &        + SQRT( ( 1. + zfesatur * zkeq - zkeq * trn(ji,jj,jk,jpfer) )**2       &
326                  &               + 4. * trn(ji,jj,jk,jpfer) * zkeq) ) / ( 2. * zkeq )
327
328#if defined key_kriest
329               zlam1b = 3.e-5 + xlam1 * (  trn(ji,jj,jk,jppoc)                   &
330                  &                      + trn(ji,jj,jk,jpcal) + trn(ji,jj,jk,jpdsi)  ) * 1.e6
331#else
332               zlam1b = 3.e-5 + xlam1 * (  trn(ji,jj,jk,jppoc) + trn(ji,jj,jk,jpgoc)   &
333                  &                      + trn(ji,jj,jk,jpcal) + trn(ji,jj,jk,jpdsi)  ) * 1.e6
334#endif
335               zscave = zfeequi * zlam1b * zstep
336
337               !  Increased scavenging for very high iron concentrations
338               !  found near the coasts due to increased lithogenic particles
339               !  and let s say it unknown processes (precipitation, ...)
340               !  -----------------------------------------------------------
341               zlamfac = MAX( 0.e0, ( gphit(ji,jj) + 55.) / 30. )
342               zlamfac = MIN( 1.  , zlamfac )
343#if ! defined key_kriest
344               zlam1b = (  80.* ( trn(ji,jj,jk,jpdoc) + 35.e-6 )                           &
345                  &     + 698.*   trn(ji,jj,jk,jppoc) + 1.05e4 * trn(ji,jj,jk,jpgoc)  )                    &
346                  &   * xdiss(ji,jj,jk) + 1E-4 * (1.-zlamfac)                &
347                  &   + xlam1 * MAX( 0.e0, ( trn(ji,jj,jk,jpfer) * 1.e9 - 1.)  )
348#else
349               zlam1b = (  80.* (trn(ji,jj,jk,jpdoc) + 35E-6)           &
350                  &     + 698.*  trn(ji,jj,jk,jppoc)  )                    &
351                  &   * xdiss(ji,jj,jk) + 1E-4 * (1.-zlamfac)           &
352                  &   + xlam1 * MAX( 0.e0, ( trn(ji,jj,jk,jpfer) * 1.e9 - 1.)  )
353#endif
354
355               zaggdfe = zlam1b * zstep * 0.5 * ( trn(ji,jj,jk,jpfer) - zfeequi )
356
357               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zscave - zaggdfe
358
359#if defined key_kriest
360               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zscave * zdenom1
361#else
362               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zscave * zdenom1
363               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zscave * zdenom2
364#endif
365            END DO
366         END DO
367      END DO
368      !
369
370      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
371         WRITE(charout, FMT="('rem5')")
372         CALL prt_ctl_trc_info(charout)
373         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
374      ENDIF
375
376      !     Update the arrays TRA which contain the biological sources and sinks
377      !     --------------------------------------------------------------------
378
379      DO jk = 1, jpkm1
380         tra(:,:,jk,jppo4) = tra(:,:,jk,jppo4) + zolimi(:,:,jk) + denitr(:,:,jk)
381         tra(:,:,jk,jpnh4) = tra(:,:,jk,jpnh4) + zolimi(:,:,jk) + denitr(:,:,jk)
382         tra(:,:,jk,jpno3) = tra(:,:,jk,jpno3) - denitr(:,:,jk) * rdenit
383         tra(:,:,jk,jpdoc) = tra(:,:,jk,jpdoc) - zolimi(:,:,jk) - denitr(:,:,jk)
384         tra(:,:,jk,jpoxy) = tra(:,:,jk,jpoxy) - zolimi(:,:,jk) * o2ut
385         tra(:,:,jk,jpdic) = tra(:,:,jk,jpdic) + zolimi(:,:,jk) + denitr(:,:,jk)
386         tra(:,:,jk,jptal) = tra(:,:,jk,jptal) + denitr(:,:,jk) * rno3 * rdenit
387      END DO
388
389      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
390         WRITE(charout, FMT="('rem6')")
391         CALL prt_ctl_trc_info(charout)
392         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
393      ENDIF
394      !
395      IF(  wrk_not_released(2, 1)     .OR.   &
396           wrk_not_released(3, 2,3)  )   CALL ctl_stop('p4z_rem: failed to release workspace arrays')
397      !
398   END SUBROUTINE p4z_rem
399
400
401   SUBROUTINE p4z_rem_init
402      !!----------------------------------------------------------------------
403      !!                  ***  ROUTINE p4z_rem_init  ***
404      !!
405      !! ** Purpose :   Initialization of remineralization parameters
406      !!
407      !! ** Method  :   Read the nampisrem namelist and check the parameters
408      !!      called at the first timestep
409      !!
410      !! ** input   :   Namelist nampisrem
411      !!
412      !!----------------------------------------------------------------------
413      NAMELIST/nampisrem/ xremik, xremip, nitrif, xsirem, xlam1, oxymin
414      !!----------------------------------------------------------------------
415
416      REWIND( numnat )                     ! read numnat
417      READ  ( numnat, nampisrem )
418
419      IF(lwp) THEN                         ! control print
420         WRITE(numout,*) ' '
421         WRITE(numout,*) ' Namelist parameters for remineralization, nampisrem'
422         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
423         WRITE(numout,*) '    remineralisation rate of POC              xremip    =', xremip
424         WRITE(numout,*) '    remineralization rate of DOC              xremik    =', xremik
425         WRITE(numout,*) '    remineralization rate of Si               xsirem    =', xsirem
426         WRITE(numout,*) '    scavenging rate of Iron                   xlam1     =', xlam1
427         WRITE(numout,*) '    NH4 nitrification rate                    nitrif    =', nitrif
428         WRITE(numout,*) '    halk saturation constant for anoxia       oxymin    =', oxymin
429      ENDIF
430      !
431      nitrfac(:,:,:) = 0._wp
432      denitr (:,:,:) = 0._wp
433      !
434   END SUBROUTINE p4z_rem_init
435
436
437   INTEGER FUNCTION p4z_rem_alloc()
438      !!----------------------------------------------------------------------
439      !!                     ***  ROUTINE p4z_rem_alloc  ***
440      !!----------------------------------------------------------------------
441      ALLOCATE( denitr(jpi,jpj,jpk), STAT=p4z_rem_alloc )
442      !
443      IF( p4z_rem_alloc /= 0 )   CALL ctl_warn('p4z_rem_alloc: failed to allocate arrays')
444      !
445   END FUNCTION p4z_rem_alloc
446
447#else
448   !!======================================================================
449   !!  Dummy module :                                   No PISCES bio-model
450   !!======================================================================
451CONTAINS
452   SUBROUTINE p4z_rem                    ! Empty routine
453   END SUBROUTINE p4z_rem
454#endif 
455
456   !!======================================================================
457END MODULE p4zrem
Note: See TracBrowser for help on using the repository browser.