New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zrem.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zrem.F90 @ 3295

Last change on this file since 3295 was 3295, checked in by cetlod, 12 years ago

trunk:A few additional diagnostics added in PISCES
  • Property svn:keywords set to Id
File size: 21.0 KB
Line 
1MODULE p4zrem
2   !!======================================================================
3   !!                         ***  MODULE p4zrem  ***
4   !! TOP :   PISCES Compute remineralization/scavenging of organic compounds
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_top'       and                                      TOP models
13   !!   'key_pisces'                                       PISCES bio-model
14   !!----------------------------------------------------------------------
15   !!   p4z_rem       :  Compute remineralization/scavenging of organic compounds
16   !!   p4z_rem_init  :  Initialisation of parameters for remineralisation
17   !!   p4z_rem_alloc :  Allocate remineralisation variables
18   !!----------------------------------------------------------------------
19   USE oce_trc         !  shared variables between ocean and passive tracers
20   USE trc             !  passive tracers common variables
21   USE sms_pisces      !  PISCES Source Minus Sink variables
22   USE p4zopt          !  optical model
23   USE p4zche          !  chemical model
24   USE p4zprod         !  Growth rate of the 2 phyto groups
25   USE p4zmeso         !  Sources and sinks of mesozooplankton
26   USE p4zint          !  interpolation and computation of various fields
27   USE prtctl_trc      !  print control for debugging
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   p4z_rem         ! called in p4zbio.F90
33   PUBLIC   p4z_rem_init    ! called in trcsms_pisces.F90
34   PUBLIC   p4z_rem_alloc
35
36   !! * Shared module variables
37   REAL(wp), PUBLIC ::  xremik    = 0.3_wp     !: remineralisation rate of POC
38   REAL(wp), PUBLIC ::  xremip    = 0.025_wp   !: remineralisation rate of DOC
39   REAL(wp), PUBLIC ::  nitrif    = 0.05_wp    !: NH4 nitrification rate
40   REAL(wp), PUBLIC ::  xsirem    = 0.003_wp   !: remineralisation rate of POC
41   REAL(wp), PUBLIC ::  xsiremlab = 0.025_wp   !: fast remineralisation rate of POC
42   REAL(wp), PUBLIC ::  xsilab    = 0.31_wp    !: fraction of labile biogenic silica
43   REAL(wp), PUBLIC ::  xlam1     = 0.005_wp   !: scavenging rate of Iron
44   REAL(wp), PUBLIC ::  oxymin    = 1.e-6_wp   !: halk saturation constant for anoxia
45   REAL(wp), PUBLIC ::  ligand    = 0.6E-9_wp  !: ligand concentration in the ocean
46
47
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitr     !: denitrification array
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitnh4   !: -    -    -    -   -
50
51
52   !!* Substitution
53#  include "top_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
56   !! $Id$
57   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59CONTAINS
60
61   SUBROUTINE p4z_rem( kt )
62      !!---------------------------------------------------------------------
63      !!                     ***  ROUTINE p4z_rem  ***
64      !!
65      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
66      !!
67      !! ** Method  : - ???
68      !!---------------------------------------------------------------------
69      !
70      INTEGER, INTENT(in) ::   kt ! ocean time step
71      !
72      INTEGER  ::   ji, jj, jk
73      REAL(wp) ::   zremip, zremik , zlam1b, zdepbac2
74      REAL(wp) ::   zkeq  , zfeequi, zsiremin, zfesatur
75      REAL(wp) ::   zsatur, zsatur2, znusil, zdep, zfactdep
76      REAL(wp) ::   zbactfer, zorem, zorem2, zofer
77      REAL(wp) ::   zosil, zdenom1, zscave, zaggdfe, zcoag
78#if ! defined key_kriest
79      REAL(wp) ::   zofer2, zdenom, zdenom2
80#endif
81      REAL(wp) ::   zlamfac, zonitr, zstep
82      CHARACTER (len=25) :: charout
83      REAL(wp), POINTER, DIMENSION(:,:  ) :: ztempbac 
84      REAL(wp), POINTER, DIMENSION(:,:,:) :: zdepbac, zolimi, zolimi2
85      !!---------------------------------------------------------------------
86      !
87      IF( nn_timing == 1 )  CALL timing_start('p4z_rem')
88      !
89      ! Allocate temporary workspace
90      CALL wrk_alloc( jpi, jpj,      ztempbac                 )
91      CALL wrk_alloc( jpi, jpj, jpk, zdepbac, zolimi, zolimi2 )
92
93       ! Initialisation of temprary arrys
94       zdepbac (:,:,:) = 0._wp
95       zolimi  (:,:,:) = 0._wp
96       zolimi2 (:,:,:) = 0._wp
97       ztempbac(:,:)   = 0._wp
98
99      !  Computation of the mean phytoplankton concentration as
100      !  a crude estimate of the bacterial biomass
101      !   --------------------------------------------------
102      DO jk = 1, jpkm1
103         DO jj = 1, jpj
104            DO ji = 1, jpi
105               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
106               IF( fsdept(ji,jj,jk) < zdep ) THEN
107                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trn(ji,jj,jk,jpzoo) + 2.* trn(ji,jj,jk,jpmes) ), 4.e-6 )
108                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
109               ELSE
110                  zdepbac(ji,jj,jk) = MIN( 1., zdep / fsdept(ji,jj,jk) ) * ztempbac(ji,jj)
111               ENDIF
112            END DO
113         END DO
114      END DO
115
116      DO jk = 1, jpkm1
117         DO jj = 1, jpj
118            DO ji = 1, jpi
119               ! denitrification factor computed from O2 levels
120               nitrfac(ji,jj,jk) = MAX(  0.e0, 0.4 * ( 6.e-6  - trn(ji,jj,jk,jpoxy) )    &
121                  &                                / ( oxymin + trn(ji,jj,jk,jpoxy) )  )
122               nitrfac(ji,jj,jk) = MIN( 1., nitrfac(ji,jj,jk) )
123            END DO
124         END DO
125      END DO
126
127      DO jk = 1, jpkm1
128         DO jj = 1, jpj
129            DO ji = 1, jpi
130               zstep   = xstep
131# if defined key_degrad
132               zstep = zstep * facvol(ji,jj,jk)
133# endif
134               ! DOC ammonification. Depends on depth, phytoplankton biomass
135               !     and a limitation term which is supposed to be a parameterization
136               !     of the bacterial activity.
137               zremik = xremik * zstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) 
138               zremik = MAX( zremik, 2.e-4 * xstep )
139               !     Ammonification in oxic waters with oxygen consumption
140               !     -----------------------------------------------------
141               zolimi (ji,jj,jk) = zremik * ( 1.- nitrfac(ji,jj,jk) ) * trn(ji,jj,jk,jpdoc) 
142               zolimi2(ji,jj,jk) = MIN( ( trn(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimi(ji,jj,jk) ) 
143               !     Ammonification in suboxic waters with denitrification
144               !     -------------------------------------------------------
145               denitr(ji,jj,jk)  = MIN(  ( trn(ji,jj,jk,jpno3) - rtrn ) / rdenit,   &
146                  &                     zremik * nitrfac(ji,jj,jk) * trn(ji,jj,jk,jpdoc)  )
147               !
148               zolimi (ji,jj,jk) = MAX( 0.e0, zolimi (ji,jj,jk) )
149               zolimi2(ji,jj,jk) = MAX( 0.e0, zolimi2(ji,jj,jk) )
150               denitr (ji,jj,jk) = MAX( 0.e0, denitr (ji,jj,jk) )
151               !
152            END DO
153         END DO
154      END DO
155
156
157      DO jk = 1, jpkm1
158         DO jj = 1, jpj
159            DO ji = 1, jpi
160               zstep   = xstep
161# if defined key_degrad
162               zstep = zstep * facvol(ji,jj,jk)
163# endif
164               !    NH4 nitrification to NO3. Ceased for oxygen concentrations
165               !    below 2 umol/L. Inhibited at strong light
166               !    ----------------------------------------------------------
167               zonitr  =nitrif * zstep * trn(ji,jj,jk,jpnh4) / ( 1.+ emoy(ji,jj,jk) ) * ( 1.- nitrfac(ji,jj,jk) ) 
168               denitnh4(ji,jj,jk) = nitrif * zstep * trn(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk) 
169               !   Update of the tracers trends
170               !   ----------------------------
171               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - denitnh4(ji,jj,jk)
172               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * denitnh4(ji,jj,jk)
173               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
174               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * denitnh4(ji,jj,jk)
175            END DO
176         END DO
177      END DO
178
179       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
180         WRITE(charout, FMT="('rem1')")
181         CALL prt_ctl_trc_info(charout)
182         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
183       ENDIF
184
185      DO jk = 1, jpkm1
186         DO jj = 1, jpj
187            DO ji = 1, jpi
188
189               !    Bacterial uptake of iron. No iron is available in DOC. So
190               !    Bacteries are obliged to take up iron from the water. Some
191               !    studies (especially at Papa) have shown this uptake to be significant
192               !    ----------------------------------------------------------
193               zdepbac2 = zdepbac(ji,jj,jk) * zdepbac(ji,jj,jk)
194               zbactfer = 20.e-6 * rfact2 * prmax(ji,jj,jk)                                 &
195                  &              * trn(ji,jj,jk,jpfer) / ( 5E-10 + trn(ji,jj,jk,jpfer) )    &
196                  &              * zdepbac2 / ( xkgraz2 + zdepbac(ji,jj,jk) )               &
197                  &              * ( 0.5 + SIGN( 0.5, trn(ji,jj,jk,jpfer) -2.e-11 )  )
198
199               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer
200#if defined key_kriest
201               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer
202#else
203               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer
204#endif
205            END DO
206         END DO
207      END DO
208
209       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
210         WRITE(charout, FMT="('rem2')")
211         CALL prt_ctl_trc_info(charout)
212         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
213       ENDIF
214
215      DO jk = 1, jpkm1
216         DO jj = 1, jpj
217            DO ji = 1, jpi
218               zstep   = xstep
219# if defined key_degrad
220               zstep = zstep * facvol(ji,jj,jk)
221# endif
222               !    POC disaggregation by turbulence and bacterial activity.
223               !    -------------------------------------------------------------
224               zremip = xremip * zstep * tgfunc(ji,jj,jk) * ( 1.- 0.7 * nitrfac(ji,jj,jk) ) 
225
226               !    POC disaggregation rate is reduced in anoxic zone as shown by
227               !    sediment traps data. In oxic area, the exponent of the martin s
228               !    law is around -0.87. In anoxic zone, it is around -0.35. This
229               !    means a disaggregation constant about 0.5 the value in oxic zones
230               !    -----------------------------------------------------------------
231               zorem  = zremip * trn(ji,jj,jk,jppoc)
232               zofer  = zremip * trn(ji,jj,jk,jpsfe)
233#if ! defined key_kriest
234               zorem2 = zremip * trn(ji,jj,jk,jpgoc)
235               zofer2 = zremip * trn(ji,jj,jk,jpbfe)
236#else
237               zorem2 = zremip * trn(ji,jj,jk,jpnum)
238#endif
239
240               !  Update the appropriate tracers trends
241               !  -------------------------------------
242
243               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zorem
244               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zofer
245#if defined key_kriest
246               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zorem
247               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) - zorem2
248               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zofer
249#else
250               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zorem2 - zorem
251               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) - zorem2
252               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zofer2 - zofer
253               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) - zofer2
254#endif
255
256            END DO
257         END DO
258      END DO
259
260       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
261         WRITE(charout, FMT="('rem3')")
262         CALL prt_ctl_trc_info(charout)
263         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
264       ENDIF
265
266      DO jk = 1, jpkm1
267         DO jj = 1, jpj
268            DO ji = 1, jpi
269               zstep   = xstep
270# if defined key_degrad
271               zstep = zstep * facvol(ji,jj,jk)
272# endif
273               !     Remineralization rate of BSi depedant on T and saturation
274               !     ---------------------------------------------------------
275               zsatur   = ( sio3eq(ji,jj,jk) - trn(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn )
276               zsatur   = MAX( rtrn, zsatur )
277               zsatur2  = zsatur * ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**4
278               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2**9.25
279               zdep     = MAX( hmld(ji,jj), heup(ji,jj) ) 
280               zdep     = MAX( 0., fsdept(ji,jj,jk) - zdep )
281               zfactdep = xsilab * EXP(-( xsiremlab - xsirem ) * zdep / wsbio2 )
282               zsiremin = ( xsiremlab * zfactdep + xsirem * ( 1. - zfactdep ) ) * zstep * znusil
283               zosil    = zsiremin * trn(ji,jj,jk,jpgsi)
284               !
285               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
286               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
287               !
288            END DO
289         END DO
290      END DO
291
292      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
293         WRITE(charout, FMT="('rem4')")
294         CALL prt_ctl_trc_info(charout)
295         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
296       ENDIF
297
298      zfesatur = ligand
299!CDIR NOVERRCHK
300      DO jk = 1, jpkm1
301!CDIR NOVERRCHK
302         DO jj = 1, jpj
303!CDIR NOVERRCHK
304            DO ji = 1, jpi
305               zstep   = xstep
306# if defined key_degrad
307               zstep = zstep * facvol(ji,jj,jk)
308# endif
309               !  Compute de different ratios for scavenging of iron
310               !  --------------------------------------------------
311
312#if  defined key_kriest
313               zdenom1 = trn(ji,jj,jk,jppoc) / &
314           &           ( trn(ji,jj,jk,jppoc) + trn(ji,jj,jk,jpgsi) + trn(ji,jj,jk,jpcal) + rtrn )
315#else
316               zdenom = 1. / ( trn(ji,jj,jk,jppoc) + trn(ji,jj,jk,jpgoc) + trn(ji,jj,jk,jpgsi) + trn(ji,jj,jk,jpcal) + rtrn )
317               zdenom1 = trn(ji,jj,jk,jppoc) * zdenom
318               zdenom2 = trn(ji,jj,jk,jpgoc) * zdenom
319#endif
320               !  scavenging rate of iron. this scavenging rate depends on the load in particles
321               !  on which they are adsorbed. The  parameterization has been taken from studies on Th
322               !     ------------------------------------------------------------
323               zkeq = fekeq(ji,jj,jk)
324               zfeequi = ( -( 1. + zfesatur * zkeq - zkeq * trn(ji,jj,jk,jpfer) )               &
325                  &        + SQRT( ( 1. + zfesatur * zkeq - zkeq * trn(ji,jj,jk,jpfer) )**2       &
326                  &               + 4. * trn(ji,jj,jk,jpfer) * zkeq) ) / ( 2. * zkeq )
327
328#if defined key_kriest
329               zlam1b = 3.e-5 + xlam1 * (  trn(ji,jj,jk,jppoc)                   &
330                  &                      + trn(ji,jj,jk,jpcal) + trn(ji,jj,jk,jpgsi)  ) * 1.e6
331#else
332               zlam1b = 3.e-5 + xlam1 * (  trn(ji,jj,jk,jppoc) + trn(ji,jj,jk,jpgoc)   &
333                  &                      + trn(ji,jj,jk,jpcal) + trn(ji,jj,jk,jpgsi)  ) * 1.e6
334#endif
335               zscave = zfeequi * zlam1b * zstep
336
337               !  Increased scavenging for very high iron concentrations
338               !  found near the coasts due to increased lithogenic particles
339               !  and let say it is unknown processes (precipitation, ...)
340               !  -----------------------------------------------------------
341               zlam1b  = xlam1 * MAX( 0.e0, ( trn(ji,jj,jk,jpfer) * 1.e9 - 1. ) )
342               zcoag   = zfeequi * zlam1b * zstep
343               zlamfac = MAX( 0.e0, ( gphit(ji,jj) + 55.) / 30. )
344               zlamfac = MIN( 1.  , zlamfac )
345               zdep    =  MIN(1., 1000. / fsdept(ji,jj,jk) )
346#if ! defined key_kriest
347               zlam1b = (  80.* ( trn(ji,jj,jk,jpdoc) + 35.e-6 )                           &
348                  &     + 698.*   trn(ji,jj,jk,jppoc) + 1.05e4 * trn(ji,jj,jk,jpgoc)  )    &
349                  &   * xdiss(ji,jj,jk) + 1E-4 * ( 1. - zlamfac ) * zdep
350#else
351               zlam1b = (  80.* (trn(ji,jj,jk,jpdoc) + 35E-6)              &
352                  &     + 698.*  trn(ji,jj,jk,jppoc)  )                    &
353                  &   * xdiss(ji,jj,jk) + 1E-4 * ( 1. - zlamfac ) * zdep
354#endif
355               zaggdfe = zlam1b * zstep * 0.5 * ( trn(ji,jj,jk,jpfer) - zfeequi )
356               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zscave - zaggdfe - zcoag
357#if defined key_kriest
358               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zscave * zdenom1
359#else
360               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zscave * zdenom1
361               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zscave * zdenom2
362#endif
363            END DO
364         END DO
365      END DO
366      !
367
368      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
369         WRITE(charout, FMT="('rem5')")
370         CALL prt_ctl_trc_info(charout)
371         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
372      ENDIF
373
374      !     Update the arrays TRA which contain the biological sources and sinks
375      !     --------------------------------------------------------------------
376
377      DO jk = 1, jpkm1
378         tra(:,:,jk,jppo4) = tra(:,:,jk,jppo4) + zolimi (:,:,jk) + denitr(:,:,jk)
379         tra(:,:,jk,jpnh4) = tra(:,:,jk,jpnh4) + zolimi (:,:,jk) + denitr(:,:,jk)
380         tra(:,:,jk,jpno3) = tra(:,:,jk,jpno3) - denitr (:,:,jk) * rdenit
381         tra(:,:,jk,jpdoc) = tra(:,:,jk,jpdoc) - zolimi (:,:,jk) - denitr(:,:,jk)
382         tra(:,:,jk,jpoxy) = tra(:,:,jk,jpoxy) - zolimi2(:,:,jk) * o2ut
383         tra(:,:,jk,jpdic) = tra(:,:,jk,jpdic) + zolimi (:,:,jk) + denitr(:,:,jk)
384         tra(:,:,jk,jptal) = tra(:,:,jk,jptal) + rno3 * ( zolimi(:,:,jk) + ( rdenit + 1.) * denitr(:,:,jk) )
385      END DO
386
387      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
388         WRITE(charout, FMT="('rem6')")
389         CALL prt_ctl_trc_info(charout)
390         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
391      ENDIF
392      !
393      CALL wrk_dealloc( jpi, jpj,      ztempbac                 )
394      CALL wrk_dealloc( jpi, jpj, jpk, zdepbac, zolimi, zolimi2 )
395      !
396      IF( nn_timing == 1 )  CALL timing_stop('p4z_rem')
397      !
398   END SUBROUTINE p4z_rem
399
400
401   SUBROUTINE p4z_rem_init
402      !!----------------------------------------------------------------------
403      !!                  ***  ROUTINE p4z_rem_init  ***
404      !!
405      !! ** Purpose :   Initialization of remineralization parameters
406      !!
407      !! ** Method  :   Read the nampisrem namelist and check the parameters
408      !!      called at the first timestep
409      !!
410      !! ** input   :   Namelist nampisrem
411      !!
412      !!----------------------------------------------------------------------
413      NAMELIST/nampisrem/ xremik, xremip, nitrif, xsirem, xsiremlab, xsilab,   &
414      &                   xlam1, oxymin, ligand 
415
416      REWIND( numnatp )                     ! read numnatp
417      READ  ( numnatp, nampisrem )
418
419      IF(lwp) THEN                         ! control print
420         WRITE(numout,*) ' '
421         WRITE(numout,*) ' Namelist parameters for remineralization, nampisrem'
422         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
423         WRITE(numout,*) '    remineralisation rate of POC              xremip    =', xremip
424         WRITE(numout,*) '    remineralization rate of DOC              xremik    =', xremik
425         WRITE(numout,*) '    remineralization rate of Si               xsirem    =', xsirem
426         WRITE(numout,*) '    fast remineralization rate of Si          xsiremlab =', xsiremlab
427         WRITE(numout,*) '    fraction of labile biogenic silica        xsilab    =', xsilab
428         WRITE(numout,*) '    scavenging rate of Iron                   xlam1     =', xlam1
429         WRITE(numout,*) '    NH4 nitrification rate                    nitrif    =', nitrif
430         WRITE(numout,*) '    halk saturation constant for anoxia       oxymin    =', oxymin
431         WRITE(numout,*) '    ligand concentration in the ocean         ligand    =', ligand
432      ENDIF
433      !
434      nitrfac (:,:,:) = 0._wp
435      denitr  (:,:,:) = 0._wp
436      denitnh4(:,:,:) = 0._wp
437      !
438   END SUBROUTINE p4z_rem_init
439
440
441   INTEGER FUNCTION p4z_rem_alloc()
442      !!----------------------------------------------------------------------
443      !!                     ***  ROUTINE p4z_rem_alloc  ***
444      !!----------------------------------------------------------------------
445      ALLOCATE( denitr(jpi,jpj,jpk), denitnh4(jpi,jpj,jpk), STAT=p4z_rem_alloc )
446      !
447      IF( p4z_rem_alloc /= 0 )   CALL ctl_warn('p4z_rem_alloc: failed to allocate arrays')
448      !
449   END FUNCTION p4z_rem_alloc
450
451#else
452   !!======================================================================
453   !!  Dummy module :                                   No PISCES bio-model
454   !!======================================================================
455CONTAINS
456   SUBROUTINE p4z_rem                    ! Empty routine
457   END SUBROUTINE p4z_rem
458#endif 
459
460   !!======================================================================
461END MODULE p4zrem
Note: See TracBrowser for help on using the repository browser.