New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsink.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zsink.F90 @ 2528

Last change on this file since 2528 was 2528, checked in by rblod, 13 years ago

Update NEMOGCM from branch nemo_v3_3_beta
  • Property svn:keywords set to Id
File size: 29.8 KB
Line 
1MODULE p4zsink
2   !!======================================================================
3   !!                         ***  MODULE p4zsink  ***
4   !! TOP :   PISCES Compute vertical flux of particulate matter due to gravitational sinking
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8#if defined key_pisces
9   !!----------------------------------------------------------------------
10   !!   p4z_sink       :  Compute vertical flux of particulate matter due to gravitational sinking
11   !!----------------------------------------------------------------------
12   USE trc
13   USE oce_trc         !
14   USE sms_pisces
15   USE prtctl_trc
16   USE iom
17
18   IMPLICIT NONE
19   PRIVATE
20
21   PUBLIC   p4z_sink         ! called in p4zbio.F90
22   PUBLIC   p4z_sink_init    ! called in trcsms_pisces.F90
23
24   !! * Shared module variables
25   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   &   !:
26     wsbio3, wsbio4,      &    !: POC and GOC sinking speeds
27     wscal                     !: Calcite and BSi sinking speeds
28
29   !! * Module variables
30   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   &   !:
31     sinking, sinking2,   &    !: POC sinking fluxes (different meanings depending on the parameterization
32     sinkcal, sinksil,    &    !: CaCO3 and BSi sinking fluxes
33     sinkfer                   !: Small BFe sinking flux
34
35   INTEGER  :: &
36      iksed  = 10              !
37
38#if  defined key_kriest
39   REAL(wp)          ::       &   
40      xkr_sfact    = 250.  ,  &   !: Sinking factor
41      xkr_stick    = 0.2   ,  &   !: Stickiness
42      xkr_nnano    = 2.337 ,  &   !: Nbr of cell in nano size class
43      xkr_ndiat    = 3.718 ,  &   !: Nbr of cell in diatoms size class
44      xkr_nmeso    = 7.147 ,  &   !: Nbr of cell in mesozoo  size class
45      xkr_naggr    = 9.877        !: Nbr of cell in aggregates  size class
46
47   REAL(wp)          ::       &   
48      xkr_frac
49
50   REAL(wp), PUBLIC ::        &
51      xkr_dnano            ,  &   !: Size of particles in nano pool
52      xkr_ddiat            ,  &   !: Size of particles in diatoms pool
53      xkr_dmeso            ,  &   !: Size of particles in mesozoo pool
54      xkr_daggr            ,  &   !: Size of particles in aggregates pool
55      xkr_wsbio_min        ,  &   !: min vertical particle speed
56      xkr_wsbio_max               !: max vertical particle speed
57
58   REAL(wp), PUBLIC, DIMENSION(jpk) ::   &   !:
59      xnumm                       !:     maximum number of particles in aggregates
60
61#endif
62
63#if ! defined key_kriest
64   REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &   !:
65     sinkfer2                  !: Big Fe sinking flux
66#endif 
67
68   !!* Substitution
69#  include "top_substitute.h90"
70   !!----------------------------------------------------------------------
71   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
72   !! $Id$
73   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
74   !!----------------------------------------------------------------------
75
76CONTAINS
77
78#if defined key_kriest
79
80   SUBROUTINE p4z_sink ( kt, jnt )
81      !!---------------------------------------------------------------------
82      !!                ***  ROUTINE p4z_sink  ***
83      !!
84      !! ** Purpose :   Compute vertical flux of particulate matter due to
85      !!              gravitational sinking - Kriest parameterization
86      !!
87      !! ** Method  : - ???
88      !!---------------------------------------------------------------------
89
90      INTEGER, INTENT(in) :: kt, jnt
91      INTEGER  :: ji, jj, jk
92      REAL(wp) :: zagg1, zagg2, zagg3, zagg4, zagg5, zaggsi, zaggsh
93      REAL(wp) :: zagg , zaggdoc, znumdoc
94      REAL(wp) :: znum , zeps, zfm, zgm, zsm
95      REAL(wp) :: zdiv , zdiv1, zdiv2, zdiv3, zdiv4, zdiv5
96      REAL(wp) :: zval1, zval2, zval3, zval4
97#if defined key_diatrc
98      REAL(wp) :: zrfact2
99      INTEGER  :: ik1
100#endif
101      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   znum3d
102      CHARACTER (len=25) :: charout
103
104      !!---------------------------------------------------------------------
105
106      !     Initialisation of variables used to compute Sinking Speed
107      !     ---------------------------------------------------------
108
109       znum3d(:,:,:) = 0.e0
110       zval1 = 1. + xkr_zeta
111       zval2 = 1. + xkr_zeta + xkr_eta
112       zval3 = 1. + xkr_eta
113
114     !     Computation of the vertical sinking speed : Kriest et Evans, 2000
115     !     -----------------------------------------------------------------
116
117      DO jk = 1, jpkm1
118         DO jj = 1, jpj
119            DO ji = 1, jpi
120               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
121                  znum = trn(ji,jj,jk,jppoc) / ( trn(ji,jj,jk,jpnum) + rtrn ) / xkr_massp
122                  ! -------------- To avoid sinking speed over 50 m/day -------
123                  znum  = MIN( xnumm(jk), znum )
124                  znum  = MAX( 1.1      , znum )
125                  znum3d(ji,jj,jk) = znum
126                  !------------------------------------------------------------
127                  zeps  = ( zval1 * znum - 1. )/ ( znum - 1. )
128                  zfm   = xkr_frac**( 1. - zeps )
129                  zgm   = xkr_frac**( zval1 - zeps )
130                  zdiv  = MAX( 1.e-4, ABS( zeps - zval2 ) ) * SIGN( 1., ( zeps - zval2 ) )
131                  zdiv1 = zeps - zval3
132                  wsbio3(ji,jj,jk) = xkr_wsbio_min * ( zeps - zval1 ) / zdiv    &
133     &                             - xkr_wsbio_max *   zgm * xkr_eta  / zdiv
134                  wsbio4(ji,jj,jk) = xkr_wsbio_min *   ( zeps-1. )    / zdiv1   &
135     &                             - xkr_wsbio_max *   zfm * xkr_eta  / zdiv1
136                  IF( znum == 1.1)   wsbio3(ji,jj,jk) = wsbio4(ji,jj,jk)
137               ENDIF
138            END DO
139         END DO
140      END DO
141
142      wscal(:,:,:) = MAX( wsbio3(:,:,:), 50. )
143
144      !   INITIALIZE TO ZERO ALL THE SINKING ARRAYS
145      !   -----------------------------------------
146
147      sinking (:,:,:) = 0.e0
148      sinking2(:,:,:) = 0.e0
149      sinkcal (:,:,:) = 0.e0
150      sinkfer (:,:,:) = 0.e0
151      sinksil (:,:,:) = 0.e0
152
153     !   Compute the sedimentation term using p4zsink2 for all the sinking particles
154     !   -----------------------------------------------------
155
156      CALL p4z_sink2( wsbio3, sinking , jppoc )
157      CALL p4z_sink2( wsbio4, sinking2, jpnum )
158      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
159      CALL p4z_sink2( wscal , sinksil , jpdsi )
160      CALL p4z_sink2( wscal , sinkcal , jpcal )
161
162     !  Exchange between organic matter compartments due to coagulation/disaggregation
163     !  ---------------------------------------------------
164
165      zval1 = 1. + xkr_zeta
166      zval2 = 1. + xkr_eta
167      zval3 = 3. + xkr_eta
168      zval4 = 4. + xkr_eta
169
170      DO jk = 1,jpkm1
171         DO jj = 1,jpj
172            DO ji = 1,jpi
173               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
174
175                  znum = trn(ji,jj,jk,jppoc)/(trn(ji,jj,jk,jpnum)+rtrn) / xkr_massp
176                  !-------------- To avoid sinking speed over 50 m/day -------
177                  znum  = min(xnumm(jk),znum)
178                  znum  = MAX( 1.1,znum)
179                  !------------------------------------------------------------
180                  zeps  = ( zval1 * znum - 1.) / ( znum - 1.)
181                  zdiv  = MAX( 1.e-4, ABS( zeps - zval3) ) * SIGN( 1., zeps - zval3 )
182                  zdiv1 = MAX( 1.e-4, ABS( zeps - 4.   ) ) * SIGN( 1., zeps - 4.    )
183                  zdiv2 = zeps - 2.
184                  zdiv3 = zeps - 3.
185                  zdiv4 = zeps - zval2
186                  zdiv5 = 2.* zeps - zval4
187                  zfm   = xkr_frac**( 1.- zeps )
188                  zsm   = xkr_frac**xkr_eta
189
190                  !    Part I : Coagulation dependant on turbulence
191                  !    ----------------------------------------------
192
193                  zagg1 = ( 0.163 * trn(ji,jj,jk,jpnum)**2               &
194                     &            * 2.*( (zfm-1.)*(zfm*xkr_mass_max**3-xkr_mass_min**3)    &
195                     &            * (zeps-1)/zdiv1 + 3.*(zfm*xkr_mass_max-xkr_mass_min)    &
196                     &            * (zfm*xkr_mass_max**2-xkr_mass_min**2)                  &
197                     &            * (zeps-1.)**2/(zdiv2*zdiv3))            &
198# if defined key_degrad
199                     &                 *facvol(ji,jj,jk)       &
200# endif
201                     &    )
202
203                  zagg2 = (  2*0.163*trn(ji,jj,jk,jpnum)**2*zfm*                       &
204                     &                   ((xkr_mass_max**3+3.*(xkr_mass_max**2          &
205                     &                    *xkr_mass_min*(zeps-1.)/zdiv2                 &
206                     &                    +xkr_mass_max*xkr_mass_min**2*(zeps-1.)/zdiv3)    &
207                     &                    +xkr_mass_min**3*(zeps-1)/zdiv1)                  &
208                     &                    -zfm*xkr_mass_max**3*(1.+3.*((zeps-1.)/           &
209                     &                    (zeps-2.)+(zeps-1.)/zdiv3)+(zeps-1.)/zdiv1))      &
210#    if defined key_degrad
211                     &                 *facvol(ji,jj,jk)             &
212#    endif
213                     &    )
214
215                  zagg3 = (  0.163*trn(ji,jj,jk,jpnum)**2*zfm**2*8. * xkr_mass_max**3   &
216#    if defined key_degrad
217                     &                 *facvol(ji,jj,jk)             &
218#    endif
219                     &    )
220
221                  zaggsh = ( zagg1 + zagg2 + zagg3 ) * rfact2 * xdiss(ji,jj,jk) / 1000.
222
223                 !    Aggregation of small into large particles
224                 !    Part II : Differential settling
225                 !    ----------------------------------------------
226
227                  zagg4 = (  2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2*                       &
228                     &                 xkr_wsbio_min*(zeps-1.)**2                         &
229                     &                 *(xkr_mass_min**2*((1.-zsm*zfm)/(zdiv3*zdiv4)      &
230                     &                 -(1.-zfm)/(zdiv*(zeps-1.)))-                       &
231                     &                 ((zfm*zfm*xkr_mass_max**2*zsm-xkr_mass_min**2)     &
232                     &                 *xkr_eta)/(zdiv*zdiv3*zdiv5) )                     &
233# if defined key_degrad
234                     &                 *facvol(ji,jj,jk)        &
235# endif
236                     &    )
237
238                  zagg5 = (  2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2                         &
239                     &                 *(zeps-1.)*zfm*xkr_wsbio_min                        &
240                     &                 *(zsm*(xkr_mass_min**2-zfm*xkr_mass_max**2)         &
241                     &                 /zdiv3-(xkr_mass_min**2-zfm*zsm*xkr_mass_max**2)    &
242                     &                 /zdiv)                   &
243# if defined key_degrad
244                     &                 *facvol(ji,jj,jk)        &
245# endif
246                     &    )
247
248                  zaggsi = ( zagg4 + zagg5 ) * xstep / 10.
249
250                  zagg = 0.5 * xkr_stick * ( zaggsh + zaggsi )
251
252                  !     Aggregation of DOC to small particles
253                  !     --------------------------------------
254
255                  zaggdoc = ( 0.4 * trn(ji,jj,jk,jpdoc)               &
256                     &        + 1018.  * trn(ji,jj,jk,jppoc)  ) * xstep    &
257# if defined key_degrad
258                     &        * facvol(ji,jj,jk)                              &
259# endif
260                     &        * xdiss(ji,jj,jk) * trn(ji,jj,jk,jpdoc)
261
262                  znumdoc = trn(ji,jj,jk,jpnum) / ( trn(ji,jj,jk,jppoc) + rtrn )
263                  tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zaggdoc
264                  tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zaggdoc * znumdoc - zagg
265                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc
266
267               ENDIF
268            END DO
269         END DO
270      END DO
271
272#if defined key_diatrc
273      zrfact2 = 1.e3 * rfact2r
274      ik1 = iksed + 1
275#  if ! defined key_iomput
276      trc2d(:,:  ,jp_pcs0_2d + 4)  = sinking (:,:,ik1) * zrfact2 * tmask(:,:,1)
277      trc2d(:,:  ,jp_pcs0_2d + 5)  = sinking2(:,:,ik1) * zrfact2 * tmask(:,:,1)
278      trc2d(:,:  ,jp_pcs0_2d + 6)  = sinkfer (:,:,ik1) * zrfact2 * tmask(:,:,1)
279      trc2d(:,:  ,jp_pcs0_2d + 7)  = sinksil (:,:,ik1) * zrfact2 * tmask(:,:,1)
280      trc2d(:,:  ,jp_pcs0_2d + 8)  = sinkcal (:,:,ik1) * zrfact2 * tmask(:,:,1)
281      trc3d(:,:,:,jp_pcs0_3d + 11) = sinking (:,:,:)      * zrfact2 * tmask(:,:,:)
282      trc3d(:,:,:,jp_pcs0_3d + 12) = sinking2(:,:,:)      * zrfact2 * tmask(:,:,:)
283      trc3d(:,:,:,jp_pcs0_3d + 13) = sinksil (:,:,:)      * zrfact2 * tmask(:,:,:)
284      trc3d(:,:,:,jp_pcs0_3d + 14) = sinkcal (:,:,:)      * zrfact2 * tmask(:,:,:)
285      trc3d(:,:,:,jp_pcs0_3d + 15) = znum3d  (:,:,:)                * tmask(:,:,:)
286      trc3d(:,:,:,jp_pcs0_3d + 16) = wsbio3  (:,:,:)                * tmask(:,:,:)
287      trc3d(:,:,:,jp_pcs0_3d + 17) = wsbio4  (:,:,:)                * tmask(:,:,:)
288#else
289      IF( jnt == nrdttrc ) then
290        CALL iom_put( "POCFlx"  , sinking (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! POC export
291        CALL iom_put( "NumFlx"  , sinking2 (:,:,:)     * zrfact2 * tmask(:,:,:) )  ! Num export
292        CALL iom_put( "SiFlx"   , sinksil (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! Silica export
293        CALL iom_put( "CaCO3Flx", sinkcal (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! Calcite export
294        CALL iom_put( "xnum"    , znum3d  (:,:,:)                * tmask(:,:,:) )  ! Number of particles in aggregats
295        CALL iom_put( "W1"      , wsbio3  (:,:,:)                * tmask(:,:,:) )  ! sinking speed of POC
296        CALL iom_put( "W2"      , wsbio4  (:,:,:)                * tmask(:,:,:) )  ! sinking speed of aggregats
297        CALL iom_put( "PMO"     , sinking (:,:,ik1) * zrfact2 * tmask(:,:,1) )  ! POC export at 100m
298        CALL iom_put( "PMO2"    , sinking2(:,:,ik1) * zrfact2 * tmask(:,:,1) )  ! Num export at 100m
299        CALL iom_put( "ExpFe1"  , sinkfer (:,:,ik1) * zrfact2 * tmask(:,:,1) )  ! Export of iron at 100m
300        CALL iom_put( "ExpSi"   , sinksil (:,:,ik1) * zrfact2 * tmask(:,:,1) )  ! export of silica at 100m
301        CALL iom_put( "ExpCaCO3", sinkcal (:,:,ik1) * zrfact2 * tmask(:,:,1) )  ! export of calcite at 100m
302     ENDIF
303#  endif
304
305#endif
306      !
307       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
308         WRITE(charout, FMT="('sink')")
309         CALL prt_ctl_trc_info(charout)
310         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
311       ENDIF
312
313   END SUBROUTINE p4z_sink
314
315   SUBROUTINE p4z_sink_init
316      !!----------------------------------------------------------------------
317      !!                  ***  ROUTINE p4z_sink_init  ***
318      !!
319      !! ** Purpose :   Initialization of sinking parameters
320      !!                Kriest parameterization only
321      !!
322      !! ** Method  :   Read the nampiskrs namelist and check the parameters
323      !!      called at the first timestep
324      !!
325      !! ** input   :   Namelist nampiskrs
326      !!
327      !!----------------------------------------------------------------------
328      INTEGER  ::   jk, jn, kiter
329      REAL(wp) ::   znum, zdiv
330      REAL(wp) ::   zws, zwr, zwl,wmax, znummax
331      REAL(wp) ::   zmin, zmax, zl, zr, xacc
332
333      NAMELIST/nampiskrs/ xkr_sfact, xkr_stick ,  &
334         &                xkr_nnano, xkr_ndiat, xkr_nmeso, xkr_naggr
335
336      !!----------------------------------------------------------------------
337      REWIND( numnat )                     ! read nampiskrs
338      READ  ( numnat, nampiskrs )
339
340      IF(lwp) THEN
341         WRITE(numout,*)
342         WRITE(numout,*) ' Namelist : nampiskrs'
343         WRITE(numout,*) '    Sinking factor                           xkr_sfact    = ', xkr_sfact
344         WRITE(numout,*) '    Stickiness                               xkr_stick    = ', xkr_stick
345         WRITE(numout,*) '    Nbr of cell in nano size class           xkr_nnano    = ', xkr_nnano
346         WRITE(numout,*) '    Nbr of cell in diatoms size class        xkr_ndiat    = ', xkr_ndiat
347         WRITE(numout,*) '    Nbr of cell in mesozoo size class        xkr_nmeso    = ', xkr_nmeso
348         WRITE(numout,*) '    Nbr of cell in aggregates size class     xkr_naggr    = ', xkr_naggr
349     ENDIF
350
351
352     ! max and min vertical particle speed
353     xkr_wsbio_min = xkr_sfact * xkr_mass_min**xkr_eta
354     xkr_wsbio_max = xkr_sfact * xkr_mass_max**xkr_eta
355     WRITE(numout,*) ' max and min vertical particle speed ', xkr_wsbio_min, xkr_wsbio_max
356
357     !
358     !    effect of the sizes of the different living pools on particle numbers
359     !    nano = 2um-20um -> mean size=6.32 um -> ws=2.596 -> xnum=xnnano=2.337
360     !    diat and microzoo = 10um-200um -> 44.7 -> 8.732 -> xnum=xndiat=3.718
361     !    mesozoo = 200um-2mm -> 632.45 -> 45.14 -> xnum=xnmeso=7.147
362     !    aggregates = 200um-10mm -> 1414 -> 74.34 -> xnum=xnaggr=9.877
363     !    doc aggregates = 1um
364     ! ----------------------------------------------------------
365
366     xkr_dnano = 1. / ( xkr_massp * xkr_nnano )
367     xkr_ddiat = 1. / ( xkr_massp * xkr_ndiat )
368     xkr_dmeso = 1. / ( xkr_massp * xkr_nmeso )
369     xkr_daggr = 1. / ( xkr_massp * xkr_naggr )
370
371      !!---------------------------------------------------------------------
372      !!    'key_kriest'                                                  ???
373      !!---------------------------------------------------------------------
374      !  COMPUTATION OF THE VERTICAL PROFILE OF MAXIMUM SINKING SPEED
375      !  Search of the maximum number of particles in aggregates for each k-level.
376      !  Bissection Method
377      !--------------------------------------------------------------------
378      WRITE(numout,*)
379      WRITE(numout,*)'    kriest : Compute maximum number of particles in aggregates'
380
381      xacc     =  0.001
382      kiter    = 50
383      zmin     =  1.10
384      zmax     = xkr_mass_max / xkr_mass_min
385      xkr_frac = zmax
386
387      DO jk = 1,jpk
388         zl = zmin
389         zr = zmax
390         wmax = 0.5 * fse3t(1,1,jk) * rday / rfact2
391         zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
392         znum = zl - 1.
393         zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
394            & - ( xkr_wsbio_max * xkr_eta * znum * &
395            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
396            & - wmax
397
398         zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
399         znum = zr - 1.
400         zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
401            & - ( xkr_wsbio_max * xkr_eta * znum * &
402            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
403            & - wmax
404iflag:  DO jn = 1, kiter
405           IF( zwl == 0.e0 ) THEN
406              znummax = zl
407           ELSE IF ( zwr == 0.e0 ) THEN
408              znummax = zr
409           ELSE
410              znummax = ( zr + zl ) / 2.
411              zdiv = xkr_zeta + xkr_eta - xkr_eta * znummax
412              znum = znummax - 1.
413              zws =  xkr_wsbio_min * xkr_zeta / zdiv &
414                 & - ( xkr_wsbio_max * xkr_eta * znum * &
415                 &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
416                 & - wmax
417              IF( zws * zwl < 0. ) THEN
418                 zr = znummax
419              ELSE
420                 zl = znummax
421              ENDIF
422              zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
423              znum = zl - 1.
424              zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
425                 & - ( xkr_wsbio_max * xkr_eta * znum * &
426                 &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
427                 & - wmax
428
429              zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
430              znum = zr - 1.
431              zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
432                 & - ( xkr_wsbio_max * xkr_eta * znum * &
433                 &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
434                 & - wmax
435
436              IF ( ABS ( zws )  <= xacc ) EXIT iflag
437
438           ENDIF
439
440        END DO iflag
441
442        xnumm(jk) = znummax
443        WRITE(numout,*) '       jk = ', jk, ' wmax = ', wmax,' xnum max = ', xnumm(jk)
444
445     END DO
446
447  END SUBROUTINE p4z_sink_init
448
449#else
450
451   SUBROUTINE p4z_sink ( kt, jnt )
452      !!---------------------------------------------------------------------
453      !!                     ***  ROUTINE p4z_sink  ***
454      !!
455      !! ** Purpose :   Compute vertical flux of particulate matter due to
456      !!                gravitational sinking
457      !!
458      !! ** Method  : - ???
459      !!---------------------------------------------------------------------
460      INTEGER, INTENT(in) :: kt, jnt
461      INTEGER  ::   ji, jj, jk
462      REAL(wp) ::   zagg1, zagg2, zagg3, zagg4
463      REAL(wp) ::   zagg , zaggfe, zaggdoc, zaggdoc2
464      REAL(wp) ::   zfact, zwsmax, zstep
465#if defined key_diatrc
466      REAL(wp) ::   zrfact2
467      INTEGER  ::   ik1
468#endif
469      CHARACTER (len=25) :: charout
470      !!---------------------------------------------------------------------
471
472      !    Sinking speeds of detritus is increased with depth as shown
473      !    by data and from the coagulation theory
474      !    -----------------------------------------------------------
475      DO jk = 1, jpkm1
476         DO jj = 1, jpj
477            DO ji=1,jpi
478               zfact = MAX( 0., fsdepw(ji,jj,jk+1) - hmld(ji,jj) ) / 4000.
479               wsbio4(ji,jj,jk) = wsbio2 + ( 200.- wsbio2 ) * zfact
480            END DO
481         END DO
482      END DO
483
484      ! limit the values of the sinking speeds to avoid numerical instabilities 
485      wsbio3(:,:,:) = wsbio
486      !
487      ! OA Below, this is garbage. the ideal would be to find a time-splitting
488      ! OA algorithm that does not increase the computing cost by too much
489      ! OA In ROMS, I have included a time-splitting procedure. But it is
490      ! OA too expensive as the loop is computed globally. Thus, a small e3t
491      ! OA at one place determines the number of subtimesteps globally
492      ! OA AWFULLY EXPENSIVE !! Not able to find a better approach. Damned !!
493
494      DO jk = 1,jpkm1
495         DO jj = 1, jpj
496            DO ji = 1, jpi
497               zwsmax = 0.8 * fse3t(ji,jj,jk) / xstep
498               wsbio4(ji,jj,jk) = MIN( wsbio4(ji,jj,jk), zwsmax )
499               wsbio3(ji,jj,jk) = MIN( wsbio3(ji,jj,jk), zwsmax )
500            END DO
501         END DO
502      END DO
503
504      wscal(:,:,:) = wsbio4(:,:,:)
505
506      !  Initializa to zero all the sinking arrays
507      !   -----------------------------------------
508
509      sinking (:,:,:) = 0.e0
510      sinking2(:,:,:) = 0.e0
511      sinkcal (:,:,:) = 0.e0
512      sinkfer (:,:,:) = 0.e0
513      sinksil (:,:,:) = 0.e0
514      sinkfer2(:,:,:) = 0.e0
515
516      !   Compute the sedimentation term using p4zsink2 for all the sinking particles
517      !   -----------------------------------------------------
518
519      CALL p4z_sink2( wsbio3, sinking , jppoc )
520      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
521      CALL p4z_sink2( wsbio4, sinking2, jpgoc )
522      CALL p4z_sink2( wsbio4, sinkfer2, jpbfe )
523      CALL p4z_sink2( wsbio4, sinksil , jpdsi )
524      CALL p4z_sink2( wscal , sinkcal , jpcal )
525
526      !  Exchange between organic matter compartments due to coagulation/disaggregation
527      !  ---------------------------------------------------
528
529      DO jk = 1, jpkm1
530         DO jj = 1, jpj
531            DO ji = 1, jpi
532# if defined key_degrad
533               zstep = xstep * facvol(ji,jj,jk)
534# else
535               zstep = xstep 
536# endif
537               zfact = zstep * xdiss(ji,jj,jk)
538               !  Part I : Coagulation dependent on turbulence
539               zagg1 = 940.* zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
540               zagg2 = 1.054e4 * zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
541
542               ! Part II : Differential settling
543
544               !  Aggregation of small into large particles
545               zagg3 = 0.66 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
546               zagg4 = 0.e0 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
547
548               zagg   = zagg1 + zagg2 + zagg3 + zagg4
549               zaggfe = zagg * trn(ji,jj,jk,jpsfe) / ( trn(ji,jj,jk,jppoc) + rtrn )
550
551               ! Aggregation of DOC to small particles
552               zaggdoc = ( 80.* trn(ji,jj,jk,jpdoc) + 698. * trn(ji,jj,jk,jppoc) ) *  zfact * trn(ji,jj,jk,jpdoc) 
553               zaggdoc2 = 1.05e4 * zfact * trn(ji,jj,jk,jpgoc) * trn(ji,jj,jk,jpdoc)
554
555               !  Update the trends
556               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zagg + zaggdoc
557               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zagg + zaggdoc2
558               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zaggfe
559               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zaggfe
560               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc - zaggdoc2
561               !
562            END DO
563         END DO
564      END DO
565
566#if defined key_diatrc
567      zrfact2 = 1.e3 * rfact2r
568      ik1  = iksed + 1
569#  if ! defined key_iomput
570      trc2d(:,:,jp_pcs0_2d + 4) = sinking (:,:,ik1) * zrfact2 * tmask(:,:,1)
571      trc2d(:,:,jp_pcs0_2d + 5) = sinking2(:,:,ik1) * zrfact2 * tmask(:,:,1)
572      trc2d(:,:,jp_pcs0_2d + 6) = sinkfer (:,:,ik1) * zrfact2 * tmask(:,:,1)
573      trc2d(:,:,jp_pcs0_2d + 7) = sinkfer2(:,:,ik1) * zrfact2 * tmask(:,:,1)
574      trc2d(:,:,jp_pcs0_2d + 8) = sinksil (:,:,ik1) * zrfact2 * tmask(:,:,1)
575      trc2d(:,:,jp_pcs0_2d + 9) = sinkcal (:,:,ik1) * zrfact2 * tmask(:,:,1)
576#  else
577      IF( jnt == nrdttrc )  then
578         CALL iom_put( "EPC100"  , ( sinking(:,:,ik1) + sinking2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of carbon at 100m
579         CALL iom_put( "EPFE100" , ( sinkfer(:,:,ik1) + sinkfer2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of iron at 100m
580         CALL iom_put( "EPCAL100",   sinkcal(:,:,ik1)                       * zrfact2 * tmask(:,:,1) ) ! Export of calcite  at 100m
581         CALL iom_put( "EPSI100" ,   sinksil(:,:,ik1)                       * zrfact2 * tmask(:,:,1) ) ! Export of biogenic silica at 100m
582      ENDIF
583#endif
584#endif
585      !
586       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
587         WRITE(charout, FMT="('sink')")
588         CALL prt_ctl_trc_info(charout)
589         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
590       ENDIF
591
592   END SUBROUTINE p4z_sink
593
594   SUBROUTINE p4z_sink_init
595      !!----------------------------------------------------------------------
596      !!                  ***  ROUTINE p4z_sink_init  ***
597      !!----------------------------------------------------------------------
598   END SUBROUTINE p4z_sink_init
599
600#endif
601
602   SUBROUTINE p4z_sink2( pwsink, psinkflx, jp_tra )
603      !!---------------------------------------------------------------------
604      !!                     ***  ROUTINE p4z_sink2  ***
605      !!
606      !! ** Purpose :   Compute the sedimentation terms for the various sinking
607      !!     particles. The scheme used to compute the trends is based
608      !!     on MUSCL.
609      !!
610      !! ** Method  : - this ROUTINE compute not exactly the advection but the
611      !!      transport term, i.e.  div(u*tra).
612      !!---------------------------------------------------------------------
613      INTEGER , INTENT(in   )                         ::   jp_tra    ! tracer index index     
614      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pwsink    ! sinking speed
615      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   psinkflx  ! sinking fluxe
616      !!
617      INTEGER  ::   ji, jj, jk, jn
618      REAL(wp) ::   zigma,zew,zign, zflx, zstep
619      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  ztraz, zakz
620      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zwsink2
621      !!---------------------------------------------------------------------
622
623
624      zstep = rfact2 / 2.
625
626      ztraz(:,:,:) = 0.e0
627      zakz (:,:,:) = 0.e0
628
629      DO jk = 1, jpkm1
630# if defined key_degrad
631         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rday * tmask(:,:,jk+1) * facvol(:,:,jk)
632# else
633         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rday * tmask(:,:,jk+1)
634# endif
635      END DO
636      zwsink2(:,:,1) = 0.e0
637
638
639      ! Vertical advective flux
640      DO jn = 1, 2
641         !  first guess of the slopes interior values
642         DO jk = 2, jpkm1
643            ztraz(:,:,jk) = ( trn(:,:,jk-1,jp_tra) - trn(:,:,jk,jp_tra) ) * tmask(:,:,jk)
644         END DO
645         ztraz(:,:,1  ) = 0.0
646         ztraz(:,:,jpk) = 0.0
647
648         ! slopes
649         DO jk = 2, jpkm1
650            DO jj = 1,jpj
651               DO ji = 1, jpi
652                  zign = 0.25 + SIGN( 0.25, ztraz(ji,jj,jk) * ztraz(ji,jj,jk+1) )
653                  zakz(ji,jj,jk) = ( ztraz(ji,jj,jk) + ztraz(ji,jj,jk+1) ) * zign
654               END DO
655            END DO
656         END DO
657         
658         ! Slopes limitation
659         DO jk = 2, jpkm1
660            DO jj = 1, jpj
661               DO ji = 1, jpi
662                  zakz(ji,jj,jk) = SIGN( 1., zakz(ji,jj,jk) ) *        &
663                     &             MIN( ABS( zakz(ji,jj,jk) ), 2. * ABS(ztraz(ji,jj,jk+1)), 2. * ABS(ztraz(ji,jj,jk) ) )
664               END DO
665            END DO
666         END DO
667         
668         ! vertical advective flux
669         DO jk = 1, jpkm1
670            DO jj = 1, jpj     
671               DO ji = 1, jpi   
672                  zigma = zwsink2(ji,jj,jk+1) * zstep / fse3w(ji,jj,jk+1)
673                  zew   = zwsink2(ji,jj,jk+1)
674                  psinkflx(ji,jj,jk+1) = -zew * ( trn(ji,jj,jk,jp_tra) - 0.5 * ( 1 + zigma ) * zakz(ji,jj,jk) ) * zstep
675               END DO
676            END DO
677         END DO
678         !
679         ! Boundary conditions
680         psinkflx(:,:,1  ) = 0.e0
681         psinkflx(:,:,jpk) = 0.e0
682         
683         DO jk=1,jpkm1
684            DO jj = 1,jpj
685               DO ji = 1, jpi
686                  zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
687                  trn(ji,jj,jk,jp_tra) = trn(ji,jj,jk,jp_tra) + zflx
688               END DO
689            END DO
690         END DO
691
692      ENDDO
693
694      DO jk=1,jpkm1
695         DO jj = 1,jpj
696            DO ji = 1, jpi
697               zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
698               trb(ji,jj,jk,jp_tra) = trb(ji,jj,jk,jp_tra) + 2. * zflx
699            END DO
700         END DO
701      END DO
702
703      trn(:,:,:,jp_tra) = trb(:,:,:,jp_tra)
704      psinkflx(:,:,:)   = 2. * psinkflx(:,:,:)
705
706      !
707   END SUBROUTINE p4z_sink2
708
709#else
710   !!======================================================================
711   !!  Dummy module :                                   No PISCES bio-model
712   !!======================================================================
713CONTAINS
714   SUBROUTINE p4z_sink                    ! Empty routine
715   END SUBROUTINE p4z_sink
716#endif 
717
718   !!======================================================================
719END MODULE  p4zsink
Note: See TracBrowser for help on using the repository browser.