New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsink.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zsink.F90 @ 3404

Last change on this file since 3404 was 3404, checked in by cetlod, 12 years ago

Deallocate znum3d in Kriest sinking parameterisation, see ticket #973
  • Property svn:keywords set to Id
File size: 33.0 KB
Line 
1MODULE p4zsink
2   !!======================================================================
3   !!                         ***  MODULE p4zsink  ***
4   !! TOP :  PISCES  vertical flux of particulate matter due to gravitational sinking
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Change aggregation formula
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   p4z_sink       :  Compute vertical flux of particulate matter due to gravitational sinking
13   !!   p4z_sink_init  :  Unitialisation of sinking speed parameters
14   !!   p4z_sink_alloc :  Allocate sinking speed variables
15   !!----------------------------------------------------------------------
16   USE oce_trc         !  shared variables between ocean and passive tracers
17   USE trc             !  passive tracers common variables
18   USE sms_pisces      !  PISCES Source Minus Sink variables
19   USE prtctl_trc      !  print control for debugging
20   USE iom             !  I/O manager
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p4z_sink         ! called in p4zbio.F90
26   PUBLIC   p4z_sink_init    ! called in trcsms_pisces.F90
27   PUBLIC   p4z_sink_alloc
28
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wsbio3   !: POC sinking speed
30   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wsbio4   !: GOC sinking speed
31   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wscal    !: Calcite and BSi sinking speeds
32
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinking, sinking2  !: POC sinking fluxes
34   !                                                          !  (different meanings depending on the parameterization)
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkcal, sinksil   !: CaCO3 and BSi sinking fluxes
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer            !: Small BFe sinking fluxes
37#if ! defined key_kriest
38   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer2           !: Big iron sinking fluxes
39#endif
40
41   INTEGER  :: iksed  = 10
42
43#if  defined key_kriest
44   REAL(wp) ::  xkr_sfact    = 250.     !: Sinking factor
45   REAL(wp) ::  xkr_stick    = 0.2      !: Stickiness
46   REAL(wp) ::  xkr_nnano    = 2.337    !: Nbr of cell in nano size class
47   REAL(wp) ::  xkr_ndiat    = 3.718    !: Nbr of cell in diatoms size class
48   REAL(wp) ::  xkr_nmeso    = 7.147    !: Nbr of cell in mesozoo  size class
49   REAL(wp) ::  xkr_naggr    = 9.877    !: Nbr of cell in aggregates  size class
50
51   REAL(wp) ::  xkr_frac 
52
53   REAL(wp), PUBLIC ::  xkr_dnano       !: Size of particles in nano pool
54   REAL(wp), PUBLIC ::  xkr_ddiat       !: Size of particles in diatoms pool
55   REAL(wp), PUBLIC ::  xkr_dmeso       !: Size of particles in mesozoo pool
56   REAL(wp), PUBLIC ::  xkr_daggr       !: Size of particles in aggregates pool
57   REAL(wp), PUBLIC ::  xkr_wsbio_min   !: min vertical particle speed
58   REAL(wp), PUBLIC ::  xkr_wsbio_max   !: max vertical particle speed
59
60   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) ::   xnumm   !:  maximum number of particles in aggregates
61#endif
62
63   !!* Substitution
64#  include "top_substitute.h90"
65   !!----------------------------------------------------------------------
66   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
67   !! $Id$
68   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
69   !!----------------------------------------------------------------------
70CONTAINS
71
72#if defined key_kriest
73   !!----------------------------------------------------------------------
74   !!   'key_kriest'                                                    ???
75   !!----------------------------------------------------------------------
76
77   SUBROUTINE p4z_sink ( kt, jnt )
78      !!---------------------------------------------------------------------
79      !!                ***  ROUTINE p4z_sink  ***
80      !!
81      !! ** Purpose :   Compute vertical flux of particulate matter due to
82      !!              gravitational sinking - Kriest parameterization
83      !!
84      !! ** Method  : - ???
85      !!---------------------------------------------------------------------
86      !
87      INTEGER, INTENT(in) :: kt, jnt
88      !
89      INTEGER  :: ji, jj, jk
90      REAL(wp) :: zagg1, zagg2, zagg3, zagg4, zagg5, zaggsi, zaggsh
91      REAL(wp) :: zagg , zaggdoc, znumdoc
92      REAL(wp) :: znum , zeps, zfm, zgm, zsm
93      REAL(wp) :: zdiv , zdiv1, zdiv2, zdiv3, zdiv4, zdiv5
94      REAL(wp) :: zval1, zval2, zval3, zval4
95      REAL(wp) :: zrfact2
96      INTEGER  :: ik1
97      CHARACTER (len=25) :: charout
98      REAL(wp), POINTER, DIMENSION(:,:,:) :: znum3d 
99      !!---------------------------------------------------------------------
100      !
101      IF( nn_timing == 1 )  CALL timing_start('p4z_sink')
102      !
103      CALL wrk_alloc( jpi, jpj, jpk, znum3d )
104      !
105      !     Initialisation of variables used to compute Sinking Speed
106      !     ---------------------------------------------------------
107
108      znum3d(:,:,:) = 0.e0
109      zval1 = 1. + xkr_zeta
110      zval2 = 1. + xkr_zeta + xkr_eta
111      zval3 = 1. + xkr_eta
112
113      !     Computation of the vertical sinking speed : Kriest et Evans, 2000
114      !     -----------------------------------------------------------------
115
116      DO jk = 1, jpkm1
117         DO jj = 1, jpj
118            DO ji = 1, jpi
119               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
120                  znum = trn(ji,jj,jk,jppoc) / ( trn(ji,jj,jk,jpnum) + rtrn ) / xkr_massp
121                  ! -------------- To avoid sinking speed over 50 m/day -------
122                  znum  = MIN( xnumm(jk), znum )
123                  znum  = MAX( 1.1      , znum )
124                  znum3d(ji,jj,jk) = znum
125                  !------------------------------------------------------------
126                  zeps  = ( zval1 * znum - 1. )/ ( znum - 1. )
127                  zfm   = xkr_frac**( 1. - zeps )
128                  zgm   = xkr_frac**( zval1 - zeps )
129                  zdiv  = MAX( 1.e-4, ABS( zeps - zval2 ) ) * SIGN( 1., ( zeps - zval2 ) )
130                  zdiv1 = zeps - zval3
131                  wsbio3(ji,jj,jk) = xkr_wsbio_min * ( zeps - zval1 ) / zdiv    &
132                     &             - xkr_wsbio_max *   zgm * xkr_eta  / zdiv
133                  wsbio4(ji,jj,jk) = xkr_wsbio_min *   ( zeps-1. )    / zdiv1   &
134                     &             - xkr_wsbio_max *   zfm * xkr_eta  / zdiv1
135                  IF( znum == 1.1)   wsbio3(ji,jj,jk) = wsbio4(ji,jj,jk)
136               ENDIF
137            END DO
138         END DO
139      END DO
140
141      wscal(:,:,:) = MAX( wsbio3(:,:,:), 50._wp )
142
143      !   INITIALIZE TO ZERO ALL THE SINKING ARRAYS
144      !   -----------------------------------------
145
146      sinking (:,:,:) = 0.e0
147      sinking2(:,:,:) = 0.e0
148      sinkcal (:,:,:) = 0.e0
149      sinkfer (:,:,:) = 0.e0
150      sinksil (:,:,:) = 0.e0
151
152     !   Compute the sedimentation term using p4zsink2 for all the sinking particles
153     !   -----------------------------------------------------
154
155      CALL p4z_sink2( wsbio3, sinking , jppoc )
156      CALL p4z_sink2( wsbio4, sinking2, jpnum )
157      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
158      CALL p4z_sink2( wscal , sinksil , jpgsi )
159      CALL p4z_sink2( wscal , sinkcal , jpcal )
160
161     !  Exchange between organic matter compartments due to coagulation/disaggregation
162     !  ---------------------------------------------------
163
164      zval1 = 1. + xkr_zeta
165      zval2 = 1. + xkr_eta
166      zval3 = 3. + xkr_eta
167      zval4 = 4. + xkr_eta
168
169      DO jk = 1,jpkm1
170         DO jj = 1,jpj
171            DO ji = 1,jpi
172               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
173
174                  znum = trn(ji,jj,jk,jppoc)/(trn(ji,jj,jk,jpnum)+rtrn) / xkr_massp
175                  !-------------- To avoid sinking speed over 50 m/day -------
176                  znum  = min(xnumm(jk),znum)
177                  znum  = MAX( 1.1,znum)
178                  !------------------------------------------------------------
179                  zeps  = ( zval1 * znum - 1.) / ( znum - 1.)
180                  zdiv  = MAX( 1.e-4, ABS( zeps - zval3) ) * SIGN( 1., zeps - zval3 )
181                  zdiv1 = MAX( 1.e-4, ABS( zeps - 4.   ) ) * SIGN( 1., zeps - 4.    )
182                  zdiv2 = zeps - 2.
183                  zdiv3 = zeps - 3.
184                  zdiv4 = zeps - zval2
185                  zdiv5 = 2.* zeps - zval4
186                  zfm   = xkr_frac**( 1.- zeps )
187                  zsm   = xkr_frac**xkr_eta
188
189                  !    Part I : Coagulation dependant on turbulence
190                  !    ----------------------------------------------
191
192                  zagg1 = ( 0.163 * trn(ji,jj,jk,jpnum)**2               &
193                     &            * 2.*( (zfm-1.)*(zfm*xkr_mass_max**3-xkr_mass_min**3)    &
194                     &            * (zeps-1)/zdiv1 + 3.*(zfm*xkr_mass_max-xkr_mass_min)    &
195                     &            * (zfm*xkr_mass_max**2-xkr_mass_min**2)                  &
196                     &            * (zeps-1.)**2/(zdiv2*zdiv3)) 
197                  zagg2 =  2*0.163*trn(ji,jj,jk,jpnum)**2*zfm*                       &
198                     &                   ((xkr_mass_max**3+3.*(xkr_mass_max**2          &
199                     &                    *xkr_mass_min*(zeps-1.)/zdiv2                 &
200                     &                    +xkr_mass_max*xkr_mass_min**2*(zeps-1.)/zdiv3)    &
201                     &                    +xkr_mass_min**3*(zeps-1)/zdiv1)                  &
202                     &                    -zfm*xkr_mass_max**3*(1.+3.*((zeps-1.)/           &
203                     &                    (zeps-2.)+(zeps-1.)/zdiv3)+(zeps-1.)/zdiv1))   
204
205                  zagg3 =  0.163*trn(ji,jj,jk,jpnum)**2*zfm**2*8. * xkr_mass_max**3 
206                 
207                 !    Aggregation of small into large particles
208                 !    Part II : Differential settling
209                 !    ----------------------------------------------
210
211                  zagg4 =  2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2*                       &
212                     &                 xkr_wsbio_min*(zeps-1.)**2                         &
213                     &                 *(xkr_mass_min**2*((1.-zsm*zfm)/(zdiv3*zdiv4)      &
214                     &                 -(1.-zfm)/(zdiv*(zeps-1.)))-                       &
215                     &                 ((zfm*zfm*xkr_mass_max**2*zsm-xkr_mass_min**2)     &
216                     &                 *xkr_eta)/(zdiv*zdiv3*zdiv5) )   
217
218                  zagg5 =   2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2                         &
219                     &                 *(zeps-1.)*zfm*xkr_wsbio_min                        &
220                     &                 *(zsm*(xkr_mass_min**2-zfm*xkr_mass_max**2)         &
221                     &                 /zdiv3-(xkr_mass_min**2-zfm*zsm*xkr_mass_max**2)    &
222                     &                 /zdiv) 
223                  zaggsi = ( zagg4 + zagg5 ) * xstep / 10.
224
225                  zagg = 0.5 * xkr_stick * ( zaggsh + zaggsi )
226
227                  !     Aggregation of DOC to small particles
228                  !     --------------------------------------
229
230                  zaggdoc = ( 0.4 * trn(ji,jj,jk,jpdoc)               &
231                     &        + 1018.  * trn(ji,jj,jk,jppoc)  ) * xstep    &
232                     &        * xdiss(ji,jj,jk) * trn(ji,jj,jk,jpdoc)
233
234# if defined key_degrad
235                   zagg1   = zagg1   * facvol(ji,jj,jk)                 
236                   zagg2   = zagg2   * facvol(ji,jj,jk)                 
237                   zagg3   = zagg3   * facvol(ji,jj,jk)                 
238                   zagg4   = zagg4   * facvol(ji,jj,jk)                 
239                   zagg5   = zagg5   * facvol(ji,jj,jk)                 
240                   zaggdoc = zaggdoc * facvol(ji,jj,jk)                 
241# endif
242                  zaggsh = ( zagg1 + zagg2 + zagg3 ) * rfact2 * xdiss(ji,jj,jk) / 1000.
243                  zaggsi = ( zagg4 + zagg5 ) * xstep / 10.
244                  zagg = 0.5 * xkr_stick * ( zaggsh + zaggsi )
245                  !
246                  znumdoc = trn(ji,jj,jk,jpnum) / ( trn(ji,jj,jk,jppoc) + rtrn )
247                  tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zaggdoc
248                  tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zaggdoc * znumdoc - zagg
249                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc
250
251               ENDIF
252            END DO
253         END DO
254      END DO
255
256      IF( ln_diatrc ) THEN
257         !
258         ik1 = iksed + 1
259         zrfact2 = 1.e3 * rfact2r
260         IF( jnt == nrdttrc ) THEN
261           CALL iom_put( "POCFlx"  , sinking (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! POC export
262           CALL iom_put( "NumFlx"  , sinking2 (:,:,:)     * zrfact2 * tmask(:,:,:) )  ! Num export
263           CALL iom_put( "SiFlx"   , sinksil (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! Silica export
264           CALL iom_put( "CaCO3Flx", sinkcal (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! Calcite export
265           CALL iom_put( "xnum"    , znum3d  (:,:,:)                * tmask(:,:,:) )  ! Number of particles in aggregats
266           CALL iom_put( "W1"      , wsbio3  (:,:,:)                * tmask(:,:,:) )  ! sinking speed of POC
267           CALL iom_put( "W2"      , wsbio4  (:,:,:)                * tmask(:,:,:) )  ! sinking speed of aggregats
268           CALL iom_put( "PMO"     , sinking (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! POC export at 100m
269           CALL iom_put( "PMO2"    , sinking2(:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! Num export at 100m
270           CALL iom_put( "ExpFe1"  , sinkfer (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! Export of iron at 100m
271           CALL iom_put( "ExpSi"   , sinksil (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! export of silica at 100m
272           CALL iom_put( "ExpCaCO3", sinkcal (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! export of calcite at 100m
273         ENDIF
274# if ! defined key_iomput
275         trc2d(:,:  ,jp_pcs0_2d + 4)  = sinking (:,:,ik1)    * zrfact2 * tmask(:,:,1)
276         trc2d(:,:  ,jp_pcs0_2d + 5)  = sinking2(:,:,ik1)    * zrfact2 * tmask(:,:,1)
277         trc2d(:,:  ,jp_pcs0_2d + 6)  = sinkfer (:,:,ik1)    * zrfact2 * tmask(:,:,1)
278         trc2d(:,:  ,jp_pcs0_2d + 7)  = sinksil (:,:,ik1)    * zrfact2 * tmask(:,:,1)
279         trc2d(:,:  ,jp_pcs0_2d + 8)  = sinkcal (:,:,ik1)    * zrfact2 * tmask(:,:,1)
280         trc3d(:,:,:,jp_pcs0_3d + 11) = sinking (:,:,:)      * zrfact2 * tmask(:,:,:)
281         trc3d(:,:,:,jp_pcs0_3d + 12) = sinking2(:,:,:)      * zrfact2 * tmask(:,:,:)
282         trc3d(:,:,:,jp_pcs0_3d + 13) = sinksil (:,:,:)      * zrfact2 * tmask(:,:,:)
283         trc3d(:,:,:,jp_pcs0_3d + 14) = sinkcal (:,:,:)      * zrfact2 * tmask(:,:,:)
284         trc3d(:,:,:,jp_pcs0_3d + 15) = znum3d  (:,:,:)                * tmask(:,:,:)
285         trc3d(:,:,:,jp_pcs0_3d + 16) = wsbio3  (:,:,:)                * tmask(:,:,:)
286         trc3d(:,:,:,jp_pcs0_3d + 17) = wsbio4  (:,:,:)                * tmask(:,:,:)
287# endif
288        !
289      ENDIF
290      !
291      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
292         WRITE(charout, FMT="('sink')")
293         CALL prt_ctl_trc_info(charout)
294         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
295      ENDIF
296      !
297      CALL wrk_dealloc( jpi, jpj, jpk, znum3d )
298      !
299      IF( nn_timing == 1 )  CALL timing_stop('p4z_sink')
300      !
301   END SUBROUTINE p4z_sink
302
303
304   SUBROUTINE p4z_sink_init
305      !!----------------------------------------------------------------------
306      !!                  ***  ROUTINE p4z_sink_init  ***
307      !!
308      !! ** Purpose :   Initialization of sinking parameters
309      !!                Kriest parameterization only
310      !!
311      !! ** Method  :   Read the nampiskrs namelist and check the parameters
312      !!      called at the first timestep
313      !!
314      !! ** input   :   Namelist nampiskrs
315      !!----------------------------------------------------------------------
316      INTEGER  ::   jk, jn, kiter
317      REAL(wp) ::   znum, zdiv
318      REAL(wp) ::   zws, zwr, zwl,wmax, znummax
319      REAL(wp) ::   zmin, zmax, zl, zr, xacc
320      !
321      NAMELIST/nampiskrs/ xkr_sfact, xkr_stick ,  &
322         &                xkr_nnano, xkr_ndiat, xkr_nmeso, xkr_naggr
323      !!----------------------------------------------------------------------
324      !
325      IF( nn_timing == 1 )  CALL timing_start('p4z_sink_init')
326      !
327      REWIND( numnatp )                     ! read nampiskrs
328      READ  ( numnatp, nampiskrs )
329
330      IF(lwp) THEN
331         WRITE(numout,*)
332         WRITE(numout,*) ' Namelist : nampiskrs'
333         WRITE(numout,*) '    Sinking factor                           xkr_sfact    = ', xkr_sfact
334         WRITE(numout,*) '    Stickiness                               xkr_stick    = ', xkr_stick
335         WRITE(numout,*) '    Nbr of cell in nano size class           xkr_nnano    = ', xkr_nnano
336         WRITE(numout,*) '    Nbr of cell in diatoms size class        xkr_ndiat    = ', xkr_ndiat
337         WRITE(numout,*) '    Nbr of cell in mesozoo size class        xkr_nmeso    = ', xkr_nmeso
338         WRITE(numout,*) '    Nbr of cell in aggregates size class     xkr_naggr    = ', xkr_naggr
339      ENDIF
340
341
342      ! max and min vertical particle speed
343      xkr_wsbio_min = xkr_sfact * xkr_mass_min**xkr_eta
344      xkr_wsbio_max = xkr_sfact * xkr_mass_max**xkr_eta
345      WRITE(numout,*) ' max and min vertical particle speed ', xkr_wsbio_min, xkr_wsbio_max
346
347      !
348      !    effect of the sizes of the different living pools on particle numbers
349      !    nano = 2um-20um -> mean size=6.32 um -> ws=2.596 -> xnum=xnnano=2.337
350      !    diat and microzoo = 10um-200um -> 44.7 -> 8.732 -> xnum=xndiat=3.718
351      !    mesozoo = 200um-2mm -> 632.45 -> 45.14 -> xnum=xnmeso=7.147
352      !    aggregates = 200um-10mm -> 1414 -> 74.34 -> xnum=xnaggr=9.877
353      !    doc aggregates = 1um
354      ! ----------------------------------------------------------
355
356      xkr_dnano = 1. / ( xkr_massp * xkr_nnano )
357      xkr_ddiat = 1. / ( xkr_massp * xkr_ndiat )
358      xkr_dmeso = 1. / ( xkr_massp * xkr_nmeso )
359      xkr_daggr = 1. / ( xkr_massp * xkr_naggr )
360
361      !!---------------------------------------------------------------------
362      !!    'key_kriest'                                                  ???
363      !!---------------------------------------------------------------------
364      !  COMPUTATION OF THE VERTICAL PROFILE OF MAXIMUM SINKING SPEED
365      !  Search of the maximum number of particles in aggregates for each k-level.
366      !  Bissection Method
367      !--------------------------------------------------------------------
368      WRITE(numout,*)
369      WRITE(numout,*)'    kriest : Compute maximum number of particles in aggregates'
370
371      xacc     =  0.001_wp
372      kiter    = 50
373      zmin     =  1.10_wp
374      zmax     = xkr_mass_max / xkr_mass_min
375      xkr_frac = zmax
376
377      DO jk = 1,jpk
378         zl = zmin
379         zr = zmax
380         wmax = 0.5 * fse3t(1,1,jk) * rday / rfact2
381         zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
382         znum = zl - 1.
383         zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
384            & - ( xkr_wsbio_max * xkr_eta * znum * &
385            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
386            & - wmax
387
388         zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
389         znum = zr - 1.
390         zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
391            & - ( xkr_wsbio_max * xkr_eta * znum * &
392            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
393            & - wmax
394iflag:   DO jn = 1, kiter
395            IF    ( zwl == 0._wp ) THEN   ;   znummax = zl
396            ELSEIF( zwr == 0._wp ) THEN   ;   znummax = zr
397            ELSE
398               znummax = ( zr + zl ) / 2.
399               zdiv = xkr_zeta + xkr_eta - xkr_eta * znummax
400               znum = znummax - 1.
401               zws =  xkr_wsbio_min * xkr_zeta / zdiv &
402                  & - ( xkr_wsbio_max * xkr_eta * znum * &
403                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
404                  & - wmax
405               IF( zws * zwl < 0. ) THEN   ;   zr = znummax
406               ELSE                        ;   zl = znummax
407               ENDIF
408               zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
409               znum = zl - 1.
410               zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
411                  & - ( xkr_wsbio_max * xkr_eta * znum * &
412                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
413                  & - wmax
414
415               zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
416               znum = zr - 1.
417               zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
418                  & - ( xkr_wsbio_max * xkr_eta * znum * &
419                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
420                  & - wmax
421               !
422               IF ( ABS ( zws )  <= xacc ) EXIT iflag
423               !
424            ENDIF
425            !
426         END DO iflag
427
428         xnumm(jk) = znummax
429         WRITE(numout,*) '       jk = ', jk, ' wmax = ', wmax,' xnum max = ', xnumm(jk)
430         !
431      END DO
432      !
433      IF( nn_timing == 1 )  CALL timing_stop('p4z_sink_init')
434      !
435  END SUBROUTINE p4z_sink_init
436
437#else
438
439   SUBROUTINE p4z_sink ( kt, jnt )
440      !!---------------------------------------------------------------------
441      !!                     ***  ROUTINE p4z_sink  ***
442      !!
443      !! ** Purpose :   Compute vertical flux of particulate matter due to
444      !!                gravitational sinking
445      !!
446      !! ** Method  : - ???
447      !!---------------------------------------------------------------------
448      INTEGER, INTENT(in) :: kt, jnt
449      INTEGER  ::   ji, jj, jk
450      REAL(wp) ::   zagg1, zagg2, zagg3, zagg4
451      REAL(wp) ::   zagg , zaggfe, zaggdoc, zaggdoc2, zaggdoc3
452      REAL(wp) ::   zfact, zwsmax, zmax, zstep
453      REAL(wp) ::   zrfact2
454      INTEGER  ::   ik1
455      CHARACTER (len=25) :: charout
456      !!---------------------------------------------------------------------
457      !
458      IF( nn_timing == 1 )  CALL timing_start('p4z_sink')
459      !
460      !    Sinking speeds of detritus is increased with depth as shown
461      !    by data and from the coagulation theory
462      !    -----------------------------------------------------------
463      DO jk = 1, jpkm1
464         DO jj = 1, jpj
465            DO ji = 1,jpi
466      !         zmax  = MAX( heup(ji,jj), hmld(ji,jj) )
467      !         zfact = MAX( 0., fsdepw(ji,jj,jk+1) - zmax ) / 5000._wp
468               zmax = hmld(ji,jj)
469               zfact = MAX( 0., fsdepw(ji,jj,jk+1) - zmax ) / 4000._wp
470               wsbio4(ji,jj,jk) = wsbio2 + ( 200.- wsbio2 ) * zfact
471            END DO
472         END DO
473      END DO
474
475      ! limit the values of the sinking speeds to avoid numerical instabilities 
476      wsbio3(:,:,:) = wsbio
477      !
478      ! OA Below, this is garbage. the ideal would be to find a time-splitting
479      ! OA algorithm that does not increase the computing cost by too much
480      ! OA In ROMS, I have included a time-splitting procedure. But it is
481      ! OA too expensive as the loop is computed globally. Thus, a small e3t
482      ! OA at one place determines the number of subtimesteps globally
483      ! OA AWFULLY EXPENSIVE !! Not able to find a better approach. Damned !!
484
485      DO jk = 1,jpkm1
486         DO jj = 1, jpj
487            DO ji = 1, jpi
488               zwsmax = 0.8 * fse3t(ji,jj,jk) / xstep
489               wsbio4(ji,jj,jk) = MIN( wsbio4(ji,jj,jk), zwsmax )
490               wsbio3(ji,jj,jk) = MIN( wsbio3(ji,jj,jk), zwsmax )
491            END DO
492         END DO
493      END DO
494
495      wscal(:,:,:) = wsbio4(:,:,:)
496
497      !  Initializa to zero all the sinking arrays
498      !   -----------------------------------------
499
500      sinking (:,:,:) = 0.e0
501      sinking2(:,:,:) = 0.e0
502      sinkcal (:,:,:) = 0.e0
503      sinkfer (:,:,:) = 0.e0
504      sinksil (:,:,:) = 0.e0
505      sinkfer2(:,:,:) = 0.e0
506
507      !   Compute the sedimentation term using p4zsink2 for all the sinking particles
508      !   -----------------------------------------------------
509
510      CALL p4z_sink2( wsbio3, sinking , jppoc )
511      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
512      CALL p4z_sink2( wsbio4, sinking2, jpgoc )
513      CALL p4z_sink2( wsbio4, sinkfer2, jpbfe )
514      CALL p4z_sink2( wsbio4, sinksil , jpgsi )
515      CALL p4z_sink2( wscal , sinkcal , jpcal )
516
517      !  Exchange between organic matter compartments due to coagulation/disaggregation
518      !  ---------------------------------------------------
519
520      DO jk = 1, jpkm1
521         DO jj = 1, jpj
522            DO ji = 1, jpi
523               !
524               zstep = xstep 
525# if defined key_degrad
526               zstep = zstep * facvol(ji,jj,jk)
527# endif
528               zfact = zstep * xdiss(ji,jj,jk)
529               !  Part I : Coagulation dependent on turbulence
530               zagg1 = 354.  * zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
531               zagg2 = 4452. * zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
532
533               ! Part II : Differential settling
534
535               !  Aggregation of small into large particles
536               zagg3 =  4.7 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
537               zagg4 =  0.4 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
538
539               zagg   = zagg1 + zagg2 + zagg3 + zagg4
540               zaggfe = zagg * trn(ji,jj,jk,jpsfe) / ( trn(ji,jj,jk,jppoc) + rtrn )
541
542               ! Aggregation of DOC to small particles
543               zaggdoc  = ( 0.83 * trn(ji,jj,jk,jpdoc) + 271. * trn(ji,jj,jk,jppoc) ) * zfact * trn(ji,jj,jk,jpdoc)
544               zaggdoc2 = 1.07e4 * zfact * trn(ji,jj,jk,jpgoc) * trn(ji,jj,jk,jpdoc)
545               zaggdoc3 =   0.02 * ( 16706. * trn(ji,jj,jk,jppoc) + 231. * trn(ji,jj,jk,jpdoc) ) * zstep * trn(ji,jj,jk,jpdoc)
546
547               !  Update the trends
548               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zagg + zaggdoc + zaggdoc3
549               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zagg + zaggdoc2
550               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zaggfe
551               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zaggfe
552               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc - zaggdoc2 - zaggdoc3
553               !
554            END DO
555         END DO
556      END DO
557
558      IF( ln_diatrc ) THEN
559         zrfact2 = 1.e3 * rfact2r
560         ik1  = iksed + 1
561         IF( lk_iomput ) THEN
562           IF( jnt == nrdttrc ) THEN
563              CALL iom_put( "EPC100"  , ( sinking(:,:,ik1) + sinking2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of carbon at 100m
564              CALL iom_put( "EPFE100" , ( sinkfer(:,:,ik1) + sinkfer2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of iron at 100m
565              CALL iom_put( "EPCAL100",   sinkcal(:,:,ik1)                       * zrfact2 * tmask(:,:,1) ) ! Export of calcite  at 100m
566              CALL iom_put( "EPSI100" ,   sinksil(:,:,ik1)                       * zrfact2 * tmask(:,:,1) ) ! Export of biogenic silica at 100m
567           ENDIF
568         ELSE
569           trc2d(:,:,jp_pcs0_2d + 4) = sinking (:,:,ik1) * zrfact2 * tmask(:,:,1)
570           trc2d(:,:,jp_pcs0_2d + 5) = sinking2(:,:,ik1) * zrfact2 * tmask(:,:,1)
571           trc2d(:,:,jp_pcs0_2d + 6) = sinkfer (:,:,ik1) * zrfact2 * tmask(:,:,1)
572           trc2d(:,:,jp_pcs0_2d + 7) = sinkfer2(:,:,ik1) * zrfact2 * tmask(:,:,1)
573           trc2d(:,:,jp_pcs0_2d + 8) = sinksil (:,:,ik1) * zrfact2 * tmask(:,:,1)
574           trc2d(:,:,jp_pcs0_2d + 9) = sinkcal (:,:,ik1) * zrfact2 * tmask(:,:,1)
575         ENDIF
576      ENDIF
577      !
578      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
579         WRITE(charout, FMT="('sink')")
580         CALL prt_ctl_trc_info(charout)
581         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
582      ENDIF
583      !
584      IF( nn_timing == 1 )  CALL timing_stop('p4z_sink')
585      !
586   END SUBROUTINE p4z_sink
587
588   SUBROUTINE p4z_sink_init
589      !!----------------------------------------------------------------------
590      !!                  ***  ROUTINE p4z_sink_init  ***
591      !!----------------------------------------------------------------------
592   END SUBROUTINE p4z_sink_init
593
594#endif
595
596
597
598   SUBROUTINE p4z_sink2( pwsink, psinkflx, jp_tra )
599      !!---------------------------------------------------------------------
600      !!                     ***  ROUTINE p4z_sink2  ***
601      !!
602      !! ** Purpose :   Compute the sedimentation terms for the various sinking
603      !!     particles. The scheme used to compute the trends is based
604      !!     on MUSCL.
605      !!
606      !! ** Method  : - this ROUTINE compute not exactly the advection but the
607      !!      transport term, i.e.  div(u*tra).
608      !!---------------------------------------------------------------------
609      !
610      INTEGER , INTENT(in   )                         ::   jp_tra    ! tracer index index     
611      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pwsink    ! sinking speed
612      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   psinkflx  ! sinking fluxe
613      !!
614      INTEGER  ::   ji, jj, jk, jn
615      REAL(wp) ::   zigma,zew,zign, zflx, zstep
616      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztraz, zakz, zwsink2 
617      !!---------------------------------------------------------------------
618      !
619      IF( nn_timing == 1 )  CALL timing_start('p4z_sink2')
620      !
621      ! Allocate temporary workspace
622      CALL wrk_alloc( jpi, jpj, jpk, ztraz, zakz, zwsink2 )
623
624      zstep = rfact2 / 2.
625
626      ztraz(:,:,:) = 0.e0
627      zakz (:,:,:) = 0.e0
628
629      DO jk = 1, jpkm1
630         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rday * tmask(:,:,jk+1) 
631      END DO
632      zwsink2(:,:,1) = 0.e0
633      IF( lk_degrad ) THEN
634         zwsink2(:,:,:) = zwsink2(:,:,:) * facvol(:,:,:)
635      ENDIF
636
637
638      ! Vertical advective flux
639      DO jn = 1, 2
640         !  first guess of the slopes interior values
641         DO jk = 2, jpkm1
642            ztraz(:,:,jk) = ( trn(:,:,jk-1,jp_tra) - trn(:,:,jk,jp_tra) ) * tmask(:,:,jk)
643         END DO
644         ztraz(:,:,1  ) = 0.0
645         ztraz(:,:,jpk) = 0.0
646
647         ! slopes
648         DO jk = 2, jpkm1
649            DO jj = 1,jpj
650               DO ji = 1, jpi
651                  zign = 0.25 + SIGN( 0.25, ztraz(ji,jj,jk) * ztraz(ji,jj,jk+1) )
652                  zakz(ji,jj,jk) = ( ztraz(ji,jj,jk) + ztraz(ji,jj,jk+1) ) * zign
653               END DO
654            END DO
655         END DO
656         
657         ! Slopes limitation
658         DO jk = 2, jpkm1
659            DO jj = 1, jpj
660               DO ji = 1, jpi
661                  zakz(ji,jj,jk) = SIGN( 1., zakz(ji,jj,jk) ) *        &
662                     &             MIN( ABS( zakz(ji,jj,jk) ), 2. * ABS(ztraz(ji,jj,jk+1)), 2. * ABS(ztraz(ji,jj,jk) ) )
663               END DO
664            END DO
665         END DO
666         
667         ! vertical advective flux
668         DO jk = 1, jpkm1
669            DO jj = 1, jpj     
670               DO ji = 1, jpi   
671                  zigma = zwsink2(ji,jj,jk+1) * zstep / fse3w(ji,jj,jk+1)
672                  zew   = zwsink2(ji,jj,jk+1)
673                  psinkflx(ji,jj,jk+1) = -zew * ( trn(ji,jj,jk,jp_tra) - 0.5 * ( 1 + zigma ) * zakz(ji,jj,jk) ) * zstep
674               END DO
675            END DO
676         END DO
677         !
678         ! Boundary conditions
679         psinkflx(:,:,1  ) = 0.e0
680         psinkflx(:,:,jpk) = 0.e0
681         
682         DO jk=1,jpkm1
683            DO jj = 1,jpj
684               DO ji = 1, jpi
685                  zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
686                  trn(ji,jj,jk,jp_tra) = trn(ji,jj,jk,jp_tra) + zflx
687               END DO
688            END DO
689         END DO
690
691      ENDDO
692
693      DO jk=1,jpkm1
694         DO jj = 1,jpj
695            DO ji = 1, jpi
696               zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
697               trb(ji,jj,jk,jp_tra) = trb(ji,jj,jk,jp_tra) + 2. * zflx
698            END DO
699         END DO
700      END DO
701
702      trn     (:,:,:,jp_tra) = trb(:,:,:,jp_tra)
703      psinkflx(:,:,:)        = 2. * psinkflx(:,:,:)
704      !
705      CALL wrk_dealloc( jpi, jpj, jpk, ztraz, zakz, zwsink2 )
706      !
707      IF( nn_timing == 1 )  CALL timing_stop('p4z_sink2')
708      !
709   END SUBROUTINE p4z_sink2
710
711
712   INTEGER FUNCTION p4z_sink_alloc()
713      !!----------------------------------------------------------------------
714      !!                     ***  ROUTINE p4z_sink_alloc  ***
715      !!----------------------------------------------------------------------
716      ALLOCATE( wsbio3 (jpi,jpj,jpk) , wsbio4  (jpi,jpj,jpk) , wscal(jpi,jpj,jpk) ,     &
717         &      sinking(jpi,jpj,jpk) , sinking2(jpi,jpj,jpk)                      ,     &               
718         &      sinkcal(jpi,jpj,jpk) , sinksil (jpi,jpj,jpk)                      ,     &               
719#if defined key_kriest
720         &      xnumm(jpk)                                                        ,     &               
721#else
722         &      sinkfer2(jpi,jpj,jpk)                                             ,     &               
723#endif
724         &      sinkfer(jpi,jpj,jpk)                                              , STAT=p4z_sink_alloc )               
725         !
726      IF( p4z_sink_alloc /= 0 ) CALL ctl_warn('p4z_sink_alloc : failed to allocate arrays.')
727      !
728   END FUNCTION p4z_sink_alloc
729   
730#else
731   !!======================================================================
732   !!  Dummy module :                                   No PISCES bio-model
733   !!======================================================================
734CONTAINS
735   SUBROUTINE p4z_sink                    ! Empty routine
736   END SUBROUTINE p4z_sink
737#endif 
738
739   !!======================================================================
740END MODULE  p4zsink
Note: See TracBrowser for help on using the repository browser.