New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcsbc.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/TRP/trcsbc.F90 @ 7753

Last change on this file since 7753 was 7753, checked in by mocavero, 7 years ago

Reverting trunk to remove OpenMP

  • Property svn:keywords set to Id
File size: 9.9 KB
Line 
1MODULE trcsbc
2   !!==============================================================================
3   !!                       ***  MODULE  trcsbc  ***
4   !! Ocean passive tracers:  surface boundary condition
5   !!======================================================================
6   !! History :  8.2  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            9.0  !  2004-03  (C. Ethe)  adapted for passive tracers
10   !!                 !  2006-08  (C. Deltel) Diagnose ML trends for passive tracers
11   !!==============================================================================
12#if defined key_top
13   !!----------------------------------------------------------------------
14   !!   'key_top'                                                TOP models
15   !!----------------------------------------------------------------------
16   !!   trc_sbc      : update the tracer trend at ocean surface
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! ocean dynamics and active tracers variables
19   USE trc             ! ocean  passive tracers variables
20   USE prtctl_trc      ! Print control for debbuging
21   USE iom
22   USE trd_oce
23   USE trdtra
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   trc_sbc   ! routine called by step.F90
29
30   !! * Substitutions
31#  include "vectopt_loop_substitute.h90"
32   !!----------------------------------------------------------------------
33   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
34   !! $Id$
35   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE trc_sbc ( kt )
40      !!----------------------------------------------------------------------
41      !!                  ***  ROUTINE trc_sbc  ***
42      !!                   
43      !! ** Purpose :   Compute the tracer surface boundary condition trend of
44      !!      (concentration/dilution effect) and add it to the general
45      !!       trend of tracer equations.
46      !!
47      !! ** Method :
48      !!      * concentration/dilution effect:
49      !!            The surface freshwater flux modify the ocean volume
50      !!         and thus the concentration of a tracer as :
51      !!            tra = tra + emp * trn / e3t   for k=1
52      !!         where emp, the surface freshwater budget (evaporation minus
53      !!         precipitation ) given in kg/m2/s is divided
54      !!         by 1035 kg/m3 (density of ocean water) to obtain m/s.
55      !!
56      !! ** Action  : - Update the 1st level of tra with the trend associated
57      !!                with the tracer surface boundary condition
58      !!
59      !!----------------------------------------------------------------------
60      !
61      INTEGER, INTENT( in ) ::   kt          ! ocean time-step index
62      !
63      INTEGER  ::   ji, jj, jn                                     ! dummy loop indices
64      REAL(wp) ::   zse3t, zrtrn, zratio, zfact                    ! temporary scalars
65      REAL(wp) ::   zswitch, zftra, zcd, zdtra, ztfx, ztra         ! temporary scalars
66      CHARACTER (len=22) :: charout
67      REAL(wp), POINTER, DIMENSION(:,:  ) :: zsfx
68      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrtrd
69
70      !!---------------------------------------------------------------------
71      !
72      IF( nn_timing == 1 )  CALL timing_start('trc_sbc')
73      !
74      ! Allocate temporary workspace
75                      CALL wrk_alloc( jpi,jpj,       zsfx   )
76      IF( l_trdtrc )  CALL wrk_alloc( jpi,jpj,jpk,   ztrtrd )
77      !
78      zrtrn = 1.e-15_wp
79
80      SELECT CASE( nn_ice_embd )         ! levitating or embedded sea-ice option
81         CASE( 0    )   ;   zswitch = 1  ! (0) standard levitating sea-ice : salt exchange only
82         CASE( 1, 2 )   ;   zswitch = 0  ! (1) levitating sea-ice: salt and volume exchange but no pressure effect                               
83      !                                  ! (2) embedded sea-ice : salt and volume fluxes and pressure
84      END SELECT
85
86      IF( kt == nittrc000 ) THEN
87         IF(lwp) WRITE(numout,*)
88         IF(lwp) WRITE(numout,*) 'trc_sbc : Passive tracers surface boundary condition'
89         IF(lwp) WRITE(numout,*) '~~~~~~~ '
90
91         IF( ln_rsttr .AND. .NOT.ln_top_euler .AND.   &                     ! Restart: read in restart  file
92            iom_varid( numrtr, 'sbc_'//TRIM(ctrcnm(1))//'_b', ldstop = .FALSE. ) > 0 ) THEN
93            IF(lwp) WRITE(numout,*) '          nittrc000-nn_dttrc surface tracer content forcing fields red in the restart file'
94            zfact = 0.5_wp
95            DO jn = 1, jptra
96               CALL iom_get( numrtr, jpdom_autoglo, 'sbc_'//TRIM(ctrcnm(jn))//'_b', sbc_trc_b(:,:,jn) )   ! before tracer content sbc
97            END DO
98         ELSE                                         ! No restart or restart not found: Euler forward time stepping
99           zfact = 1._wp
100           sbc_trc_b(:,:,:) = 0._wp
101         ENDIF
102      ELSE                                         ! Swap of forcing fields
103         IF( ln_top_euler ) THEN
104            zfact = 1._wp
105            sbc_trc_b(:,:,:) = 0._wp
106         ELSE
107            zfact = 0.5_wp
108            sbc_trc_b(:,:,:) = sbc_trc(:,:,:)
109         ENDIF
110         !
111      ENDIF
112
113      ! Coupling online : river runoff is added to the horizontal divergence (hdivn) in the subroutine sbc_rnf_div
114      ! one only consider the concentration/dilution effect due to evaporation minus precipitation + freezing/melting of sea-ice
115      ! Coupling offline : runoff are in emp which contains E-P-R
116      !
117      IF( .NOT.ln_linssh ) THEN  ! online coupling with vvl
118         zsfx(:,:) = 0._wp
119      ELSE                                      ! online coupling free surface or offline with free surface
120         zsfx(:,:) = emp(:,:)
121      ENDIF
122
123      ! 0. initialization
124      DO jn = 1, jptra
125         !
126         IF( l_trdtrc )   ztrtrd(:,:,:) = tra(:,:,:,jn)  ! save trends
127
128         IF ( nn_ice_tr == -1 ) THEN  ! No tracers in sea ice (null concentration in sea ice)
129
130            DO jj = 2, jpj
131               DO ji = fs_2, fs_jpim1   ! vector opt.
132                  sbc_trc(ji,jj,jn) = zsfx(ji,jj) * r1_rau0 * trn(ji,jj,1,jn)
133               END DO
134            END DO
135
136         ELSE
137
138            DO jj = 2, jpj
139               DO ji = fs_2, fs_jpim1   ! vector opt.
140                  zse3t = 1. / e3t_n(ji,jj,1)
141                  ! tracer flux at the ice/ocean interface (tracer/m2/s)
142                  zftra = - trc_i(ji,jj,jn) * fmmflx(ji,jj) ! uptake of tracer in the sea ice
143                  zcd   =   trc_o(ji,jj,jn) * fmmflx(ji,jj) ! concentration dilution due to freezing-melting,
144                                                               ! only used in the levitating sea ice case
145                  ! tracer flux only       : add concentration dilution term in net tracer flux, no F-M in volume flux
146                  ! tracer and mass fluxes : no concentration dilution term in net tracer flux, F-M term in volume flux
147                  ztfx  = zftra + zswitch * zcd                ! net tracer flux (+C/D if no ice/ocean mass exchange)
148   
149                  zdtra = r1_rau0 * ( ztfx + zsfx(ji,jj) * trn(ji,jj,1,jn) ) 
150                  IF ( zdtra < 0. ) THEN
151                     zratio = -zdtra * zse3t * r2dttrc / ( trn(ji,jj,1,jn) + zrtrn )
152                     zdtra = MIN(1.0, zratio) * zdtra ! avoid negative concentrations to arise
153                  ENDIF
154                  sbc_trc(ji,jj,jn) =  zdtra 
155               END DO
156            END DO
157         ENDIF
158         !
159         CALL lbc_lnk( sbc_trc(:,:,jn), 'T', 1. )
160         !                                       Concentration dilution effect on tracers due to evaporation & precipitation
161         DO jj = 2, jpj
162            DO ji = fs_2, fs_jpim1   ! vector opt.
163               zse3t = zfact / e3t_n(ji,jj,1)
164               tra(ji,jj,1,jn) = tra(ji,jj,1,jn) + ( sbc_trc_b(ji,jj,jn) + sbc_trc(ji,jj,jn) ) * zse3t
165            END DO
166         END DO
167         !
168         IF( l_trdtrc ) THEN
169            ztrtrd(:,:,:) = tra(:,:,:,jn) - ztrtrd(:,:,:)
170            CALL trd_tra( kt, 'TRC', jn, jptra_nsr, ztrtrd )
171         END IF
172         !                                                       ! ===========
173      END DO                                                     ! tracer loop
174      !                                                          ! ===========
175
176      !                                           Write in the tracer restar  file
177      !                                          *******************************
178      IF( lrst_trc .AND. .NOT.ln_top_euler ) THEN
179         IF(lwp) WRITE(numout,*)
180         IF(lwp) WRITE(numout,*) 'sbc : ocean surface tracer content forcing fields written in tracer restart file ',   &
181            &                    'at it= ', kt,' date= ', ndastp
182         IF(lwp) WRITE(numout,*) '~~~~'
183         DO jn = 1, jptra
184            CALL iom_rstput( kt, nitrst, numrtw, 'sbc_'//TRIM(ctrcnm(jn))//'_b', sbc_trc(:,:,jn) )
185         END DO
186      ENDIF
187      !
188      IF( ln_ctl )   THEN
189         WRITE(charout, FMT="('sbc ')") ;  CALL prt_ctl_trc_info(charout)
190                                           CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
191      ENDIF
192                      CALL wrk_dealloc( jpi,jpj,       zsfx   )
193      IF( l_trdtrc )  CALL wrk_dealloc( jpi,jpj,jpk,   ztrtrd )
194      !
195      IF( nn_timing == 1 )  CALL timing_stop('trc_sbc')
196      !
197   END SUBROUTINE trc_sbc
198
199#else
200   !!----------------------------------------------------------------------
201   !!   Dummy module :                      NO passive tracer
202   !!----------------------------------------------------------------------
203CONTAINS
204   SUBROUTINE trc_sbc (kt)              ! Empty routine
205      INTEGER, INTENT(in) :: kt
206      WRITE(*,*) 'trc_sbc: You should not have seen this print! error?', kt
207   END SUBROUTINE trc_sbc
208#endif
209   
210   !!======================================================================
211END MODULE trcsbc
Note: See TracBrowser for help on using the repository browser.