New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
domngb.F90 in utils/tools/DOMAINcfg/src – NEMO

source: utils/tools/DOMAINcfg/src/domngb.F90 @ 13204

Last change on this file since 13204 was 13204, checked in by smasson, 4 years ago

tools: update with tools_dev_r12970_AGRIF_CMEMS
File size: 4.9 KB
Line 
1MODULE domngb
2   !!======================================================================
3   !!                       ***  MODULE  domngb  ***
4   !! Grid search:  find the closest grid point from a given on/lat position
5   !!======================================================================
6   !! History : 3.2  !  2009-11  (S. Masson)  Original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   dom_ngb       : find the closest grid point from a given lon/lat position
11   !!----------------------------------------------------------------------
12   USE dom_oce        ! ocean space and time domain
13   !
14   USE in_out_manager ! I/O manager
15   USE lib_mpp        ! for mppsum
16   USE phycst
17
18   IMPLICIT NONE
19   PRIVATE
20
21   PUBLIC   dom_ngb   ! routine called in iom.F90 and domclo.F90 module
22   PUBLIC   dist
23
24   !!----------------------------------------------------------------------
25   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
26   !! $Id: domngb.F90 10425 2018-12-19 21:54:16Z smasson $
27   !! Software governed by the CeCILL license (see ./LICENSE)
28   !!----------------------------------------------------------------------
29CONTAINS
30
31   SUBROUTINE dom_ngb( plon, plat, kii, kjj, rdist, cdgrid, kkk )
32      !!----------------------------------------------------------------------
33      !!                    ***  ROUTINE dom_ngb  ***
34      !!
35      !! ** Purpose :   find the closest grid point from a given lon/lat position
36      !!
37      !! ** Method  :   look for minimum distance in cylindrical projection
38      !!                -> not good if located at too high latitude...
39      !!----------------------------------------------------------------------
40      REAL(wp)        , INTENT(in   ) ::   plon, plat   ! longitude,latitude of the point
41      REAL(wp)        , INTENT(  out) ::   rdist        ! distance between the located point and the source
42      INTEGER         , INTENT(  out) ::   kii, kjj     ! i-,j-index of the closes grid point
43      INTEGER         , INTENT(in   ), OPTIONAL :: kkk  ! k-index of the mask level used
44      CHARACTER(len=1), INTENT(in   ) ::   cdgrid       ! grid name 'T', 'U', 'V', 'W'
45      !
46      INTEGER :: ik         ! working level
47      INTEGER , DIMENSION(2) ::   iloc
48      REAL(wp)               ::   zlon, zmini
49      REAL(wp), DIMENSION(jpi,jpj) ::   zglam, zgphi, zmask, zdist
50      !!--------------------------------------------------------------------
51      !
52      zmask(:,:) = 0._wp
53      ik = 1
54      IF ( PRESENT(kkk) ) ik=kkk
55      SELECT CASE( cdgrid )
56      CASE( 'U' )  ; zglam(:,:) = glamu(:,:) ; zgphi(:,:) = gphiu(:,:) ; zmask(nldi:nlei,nldj:nlej) = umask(nldi:nlei,nldj:nlej,ik)
57      CASE( 'V' )  ; zglam(:,:) = glamv(:,:) ; zgphi(:,:) = gphiv(:,:) ; zmask(nldi:nlei,nldj:nlej) = vmask(nldi:nlei,nldj:nlej,ik)
58      CASE( 'F' )  ; zglam(:,:) = glamf(:,:) ; zgphi(:,:) = gphif(:,:) ; zmask(nldi:nlei,nldj:nlej) = fmask(nldi:nlei,nldj:nlej,ik)
59      CASE DEFAULT ; zglam(:,:) = glamt(:,:) ; zgphi(:,:) = gphit(:,:) ; zmask(nldi:nlei,nldj:nlej) = tmask(nldi:nlei,nldj:nlej,ik)
60      END SELECT
61
62      zlon       = MOD( plon       + 720., 360. )                                     ! plon between    0 and 360
63      zglam(:,:) = MOD( zglam(:,:) + 720., 360. )                                     ! glam between    0 and 360
64      IF( zlon > 270. )   zlon = zlon - 360.                                          ! zlon between  -90 and 270
65      IF( zlon <  90. )   WHERE( zglam(:,:) > 180. ) zglam(:,:) = zglam(:,:) - 360.   ! glam between -180 and 180
66      zglam(:,:) = zglam(:,:) - zlon
67
68      IF( lk_mpp ) THEN 
69         CALL mpp_minloc( 'domngb', zdist(:,:), zmask, rdist, iloc)
70         kii = iloc(1) ; kjj = iloc(2)
71      ELSE
72         iloc(:) = MINLOC( zdist(:,:), mask = zmask(:,:) == 1.e0 )
73         rdist = MINVAL( zdist(:,:) )
74         kii = iloc(1) + nimpp - 1
75         kjj = iloc(2) + njmpp - 1
76      ENDIF
77      !
78   END SUBROUTINE dom_ngb
79
80   FUNCTION dist(plonsrc, platsrc, plontrg, plattrg)
81      REAL(wp),                     INTENT(in) :: plonsrc, platsrc ! lat/lon of the source point
82      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: plontrg, plattrg ! lat/lon of the target (2d in this case)
83
84      REAL(wp) :: zxs, zys, zzs
85      REAL(wp), DIMENSION(jpi,jpj) :: zxt, zyt, zzt
86
87      REAL(wp), DIMENSION(jpi,jpj) :: dist ! distance between src and trg
88
89      zxs = COS( rad * platsrc ) * COS( rad * plonsrc )
90      zys = COS( rad * platsrc ) * SIN( rad * plonsrc )
91      zzs = SIN( rad * platsrc )
92
93      zxt = COS( rad * plattrg ) * COS( rad * plontrg )
94      zyt = COS( rad * plattrg ) * SIN( rad * plontrg )
95      zzt = SIN( rad * plattrg )
96
97      dist(:,:) = ( zxs - zxt(:,:) )**2   &
98         &      + ( zys - zyt(:,:) )**2   &
99         &      + ( zzs - zzt(:,:) )**2
100
101      dist(:,:) = ra * SQRT( dist(:,:) )
102
103   END FUNCTION dist
104
105   !!======================================================================
106END MODULE domngb
Note: See TracBrowser for help on using the repository browser.