New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom_nf90.F90 in utils/tools_ticket2457/DOMAINcfg/src – NEMO

source: utils/tools_ticket2457/DOMAINcfg/src/iom_nf90.F90 @ 12871

Last change on this file since 12871 was 12414, checked in by smueller, 4 years ago

Reintegration of 2019 development branch /utils/tools_MERGE_2019 into the tools directory (/utils/tools)

File size: 43.9 KB
Line 
1MODULE iom_nf90
2   !!======================================================================
3   !!                    ***  MODULE  iom_nf90 ***
4   !! Input/Output manager :  Library to read input files with NF90 (only fliocom module)
5   !!======================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_nf90_gettime
9   !!            3.6  ! 2015-15  (J. Harle) Added procedure to read REAL attributes
10   !!            4.0  ! 2017-11 (M. Andrejczuk) Extend IOM interface to write any 3D fields
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   iom_open       : open a file read only
15   !!   iom_close      : close a file or all files opened by iom
16   !!   iom_get        : read a field (interfaced to several routines)
17   !!   iom_varid      : get the id of a variable in a file
18   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
19   !!----------------------------------------------------------------------
20   USE dom_oce         ! ocean space and time domain
21   USE lbclnk          ! lateal boundary condition / mpp exchanges
22   USE iom_def         ! iom variables definitions
23   USE netcdf          ! NetCDF library
24   USE in_out_manager  ! I/O manager
25   USE lib_mpp         ! MPP library
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC iom_nf90_open  , iom_nf90_close, iom_nf90_varid, iom_nf90_get, iom_nf90_rstput
31   PUBLIC iom_nf90_chkatt, iom_nf90_getatt, iom_nf90_putatt
32
33   INTERFACE iom_nf90_get
34      MODULE PROCEDURE iom_nf90_g0d, iom_nf90_g123d
35   END INTERFACE
36   INTERFACE iom_nf90_rstput
37      MODULE PROCEDURE iom_nf90_rp0123d
38   END INTERFACE
39
40   !!----------------------------------------------------------------------
41   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
42   !! $Id: iom_nf90.F90 10522 2019-01-16 08:35:15Z smasson $
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE iom_nf90_open( cdname, kiomid, ldwrt, ldok, kdompar, kdlev )
48      !!---------------------------------------------------------------------
49      !!                   ***  SUBROUTINE  iom_open  ***
50      !!
51      !! ** Purpose : open an input file with NF90
52      !!---------------------------------------------------------------------
53      CHARACTER(len=*)       , INTENT(inout)           ::   cdname      ! File name
54      INTEGER                , INTENT(  out)           ::   kiomid      ! nf90 identifier of the opened file
55      LOGICAL                , INTENT(in   )           ::   ldwrt       ! read or write the file?
56      LOGICAL                , INTENT(in   )           ::   ldok        ! check the existence
57      INTEGER, DIMENSION(2,5), INTENT(in   ), OPTIONAL ::   kdompar     ! domain parameters:
58      INTEGER                , INTENT(in   ), OPTIONAL ::   kdlev       ! size of the third dimension
59
60      CHARACTER(LEN=256) ::   clinfo           ! info character
61      CHARACTER(LEN=256) ::   cltmp            ! temporary character
62      INTEGER            ::   iln              ! lengths of character
63      INTEGER            ::   istop            ! temporary storage of nstop
64      INTEGER            ::   if90id           ! nf90 identifier of the opened file
65      INTEGER            ::   idmy             ! dummy variable
66      INTEGER            ::   jl               ! loop variable
67      INTEGER            ::   ichunk           ! temporary storage of nn_chunksz
68      INTEGER            ::   imode            ! creation mode flag: NF90_CLOBBER or NF90_NOCLOBBER or NF90_HDF5
69      INTEGER            ::   ihdf5            ! local variable for retrieval of value for NF90_HDF5
70      LOGICAL            ::   llclobber        ! local definition of ln_clobber
71      INTEGER            ::   ilevels           ! vertical levels
72      !---------------------------------------------------------------------
73      !
74      clinfo = '                    iom_nf90_open ~~~  '
75      istop = nstop     ! store the actual value of nstop
76      !
77      !                 !number of vertical levels
78      IF( PRESENT(kdlev) ) THEN   ;   ilevels = kdlev    ! use input value (useful for sea-ice)
79      ELSE                        ;   ilevels = jpk      ! by default jpk
80      ENDIF
81      !
82      IF( nn_chunksz > 0 ) THEN   ;   ichunk = nn_chunksz
83      ELSE                        ;   ichunk = NF90_SIZEHINT_DEFAULT
84      ENDIF
85      !
86      llclobber = ldwrt .AND. ln_clobber
87      IF( ldok .AND. .NOT. llclobber ) THEN      !==  Open existing file ==!
88         !                                       !=========================!
89         IF( ldwrt ) THEN  ! ... in write mode
90            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
91            IF( snc4set%luse ) THEN
92               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id ), clinfo)
93            ELSE
94               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id, chunksize = ichunk ), clinfo)
95            ENDIF
96            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                          ), clinfo)
97         ELSE              ! ... in read mode
98            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
99            CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_NOWRITE, if90id, chunksize = ichunk ), clinfo)
100         ENDIF
101      ELSE                                       !== the file doesn't exist ==!   (or we overwrite it)
102         !                                       !============================!
103         iln = INDEX( cdname, '.nc' )
104         IF( ldwrt ) THEN              !* the file should be open in write mode so we create it...
105            IF( jpnij > 1 ) THEN
106               WRITE(cltmp,'(a,a,i4.4,a)') cdname(1:iln-1), '_', narea-1, '.nc'
107               cdname = TRIM(cltmp)
108            ENDIF
109            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in WRITE mode'
110
111            IF( llclobber ) THEN   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_CLOBBER   )
112            ELSE                   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_NOCLOBBER ) 
113            ENDIF
114            IF( snc4set%luse ) THEN
115               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' creating file: '//TRIM(cdname)//' in hdf5 (netcdf4) mode'
116               CALL GET_NF90_SYMBOL("NF90_HDF5", ihdf5)
117               IF( llclobber ) THEN   ;   imode = IOR(ihdf5, NF90_CLOBBER)
118               ELSE                   ;   imode = IOR(ihdf5, NF90_NOCLOBBER)
119               ENDIF
120               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id ), clinfo)
121            ELSE
122               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id, chunksize = ichunk ), clinfo)
123            ENDIF
124            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL,                   idmy ), clinfo)
125            ! define dimensions
126            CALL iom_nf90_check(NF90_DEF_DIM( if90id,            'x',   kdompar(1,1), idmy ), clinfo)
127            CALL iom_nf90_check(NF90_DEF_DIM( if90id,            'y',   kdompar(2,1), idmy ), clinfo)
128            CALL iom_nf90_check(NF90_DEF_DIM( if90id,      'nav_lev',            jpk, idmy ), clinfo)
129            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'time_counter', NF90_UNLIMITED, idmy ), clinfo)
130            IF( PRESENT(kdlev) )   &
131               CALL iom_nf90_check(NF90_DEF_DIM( if90id,    'numcat',          kdlev, idmy ), clinfo)
132            ! global attributes
133            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij              ), clinfo)
134            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number'         , narea-1            ), clinfo)
135            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1     , 2     /) ), clinfo)
136            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_global'    , (/jpiglo, jpjglo/) ), clinfo)
137            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_local'     , kdompar(:,1)       ), clinfo)
138            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_first' , kdompar(:,2)       ), clinfo)
139            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_last'  , kdompar(:,3)       ), clinfo)
140            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_start', kdompar(:,4)       ), clinfo)
141            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , kdompar(:,5)       ), clinfo)
142            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'              ), clinfo)
143         ELSE                          !* the file should be open for read mode so it must exist...
144            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
145         ENDIF
146      ENDIF
147      !
148      ! start to fill file informations
149      ! =============
150      IF( istop == nstop ) THEN   ! no error within this routine
151!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
152         kiomid = 0
153         DO jl = jpmax_files, 1, -1
154            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
155         ENDDO
156         iom_file(kiomid)%name   = TRIM(cdname)
157         iom_file(kiomid)%nfid   = if90id
158         iom_file(kiomid)%nvars  = 0
159         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files, used to know if the file is in define mode
160         iom_file(kiomid)%nlev   = ilevels
161         CALL iom_nf90_check(NF90_Inquire(if90id, unlimitedDimId = iom_file(kiomid)%iduld), clinfo)
162         IF( iom_file(kiomid)%iduld .GE. 0 ) THEN
163            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, iom_file(kiomid)%iduld,    & 
164               &                                       name = iom_file(kiomid)%uldname,   &
165               &                                       len  = iom_file(kiomid)%lenuld ), clinfo )
166         ENDIF
167         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
168      ELSE
169         kiomid = 0               ! return error flag
170      ENDIF
171      !
172   END SUBROUTINE iom_nf90_open
173
174
175   SUBROUTINE iom_nf90_close( kiomid )
176      !!--------------------------------------------------------------------
177      !!                   ***  SUBROUTINE  iom_nf90_close  ***
178      !!
179      !! ** Purpose : close an input file with NF90
180      !!--------------------------------------------------------------------
181      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
182      CHARACTER(LEN=100)  ::   clinfo   ! info character
183      !---------------------------------------------------------------------
184      clinfo = '      iom_nf90_close    , file: '//TRIM(iom_file(kiomid)%name)
185      CALL iom_nf90_check(NF90_CLOSE(iom_file(kiomid)%nfid), clinfo)
186   END SUBROUTINE iom_nf90_close
187
188
189   FUNCTION iom_nf90_varid ( kiomid, cdvar, kiv, kdimsz, kndims ) 
190      !!-----------------------------------------------------------------------
191      !!                  ***  FUNCTION  iom_varid  ***
192      !!
193      !! ** Purpose : get the id of a variable in a file with NF90
194      !!-----------------------------------------------------------------------
195      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
196      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
197      INTEGER              , INTENT(in   )           ::   kiv   !
198      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of the dimensions
199      INTEGER,               INTENT(  out), OPTIONAL ::   kndims   ! size of the dimensions
200      !
201      INTEGER                        ::   iom_nf90_varid   ! iom variable Id
202      INTEGER                        ::   if90id           ! nf90 file identifier
203      INTEGER                        ::   ji               ! dummy loop index
204      INTEGER                        ::   ivarid           ! NetCDF  variable Id
205      INTEGER                        ::   i_nvd            ! number of dimension of the variable
206      INTEGER, DIMENSION(jpmax_dims) ::   idimid           ! dimension ids of the variable
207      LOGICAL                        ::   llok             ! ok  test
208      CHARACTER(LEN=100)             ::   clinfo           ! info character
209      !!-----------------------------------------------------------------------
210      clinfo = '          iom_nf90_varid, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
211      iom_nf90_varid = 0                    ! default definition
212      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
213      if90id = iom_file(kiomid)%nfid        ! get back NetCDF file id
214      !
215      llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! does the variable exist in the file
216      IF( llok ) THEN
217         iom_nf90_varid = kiv
218         iom_file(kiomid)%nvars       = kiv
219         iom_file(kiomid)%nvid(kiv)   = ivarid
220         iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
221         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, ndims = i_nvd), clinfo)   ! number of dimensions
222         iom_file(kiomid)%ndims(kiv)  = i_nvd
223         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, dimids = idimid(1:i_nvd)), clinfo)   ! dimensions ids
224         iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
225         iom_file(kiomid)%dimsz(:,kiv) = 0      ! reset dimsz in case previously used
226         DO ji = 1, i_nvd                       ! dimensions size
227            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, idimid(ji), len = iom_file(kiomid)%dimsz(ji,kiv)), clinfo)   
228            IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.   ! unlimited dimension?
229         END DO
230         !---------- Deal with scale_factor and add_offset
231         llok = NF90_Inquire_attribute(if90id, ivarid, 'scale_factor') == nf90_noerr
232         IF( llok) THEN
233            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'scale_factor', iom_file(kiomid)%scf(kiv)), clinfo)
234         ELSE
235            iom_file(kiomid)%scf(kiv) = 1.
236         END IF
237         llok = NF90_Inquire_attribute(if90id, ivarid, 'add_offset') == nf90_noerr
238         IF( llok ) THEN
239            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'add_offset', iom_file(kiomid)%ofs(kiv)), clinfo)
240         ELSE
241            iom_file(kiomid)%ofs(kiv) = 0.
242         END IF
243         ! return the simension size
244         IF( PRESENT(kdimsz) ) THEN
245            IF( i_nvd <= SIZE(kdimsz) ) THEN
246               kdimsz(1:i_nvd) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
247            ELSE
248               WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
249               CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
250            ENDIF
251         ENDIF
252         IF( PRESENT(kndims) )  kndims = iom_file(kiomid)%ndims(kiv)
253      ELSE 
254         iom_nf90_varid = -1   !   variable not found, return error code: -1
255      ENDIF
256      !
257   END FUNCTION iom_nf90_varid
258
259   !!----------------------------------------------------------------------
260   !!                   INTERFACE iom_nf90_get
261   !!----------------------------------------------------------------------
262
263   SUBROUTINE iom_nf90_g0d( kiomid, kvid, pvar, kstart )
264      !!-----------------------------------------------------------------------
265      !!                  ***  ROUTINE  iom_nf90_g0d  ***
266      !!
267      !! ** Purpose : read a scalar with NF90
268      !!-----------------------------------------------------------------------
269      INTEGER ,               INTENT(in   )            ::   kiomid   ! Identifier of the file
270      INTEGER ,               INTENT(in   )            ::   kvid     ! variable id
271      REAL(wp),               INTENT(  out)            ::   pvar     ! read field
272      INTEGER , DIMENSION(1), INTENT(in   ), OPTIONAL  ::   kstart   ! start position of the reading in each axis
273      !
274      CHARACTER(LEN=100)      ::   clinfo   ! info character
275      !---------------------------------------------------------------------
276      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
277      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar, start = kstart), clinfo )
278   END SUBROUTINE iom_nf90_g0d
279
280
281   SUBROUTINE iom_nf90_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
282         &                    pv_r1d, pv_r2d, pv_r3d )
283      !!-----------------------------------------------------------------------
284      !!                  ***  ROUTINE  iom_nf90_g123d  ***
285      !!
286      !! ** Purpose : read a 1D/2D/3D variable with NF90
287      !!
288      !! ** Method : read ONE record at each CALL
289      !!-----------------------------------------------------------------------
290      INTEGER                    , INTENT(in   )           ::   kiomid    ! iom identifier of the file
291      INTEGER                    , INTENT(in   )           ::   kvid      ! Name of the variable
292      INTEGER                    , INTENT(in   )           ::   knbdim    ! number of dimensions of the variable
293      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart    ! start position of the reading in each axis
294      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount    ! number of points to be read in each axis
295      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
296      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d    ! read field (1D case)
297      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d    ! read field (2D case)
298      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d    ! read field (3D case)
299      !
300      CHARACTER(LEN=100) ::   clinfo               ! info character
301      INTEGER            ::   if90id               ! nf90 identifier of the opened file
302      INTEGER            ::   ivid                 ! nf90 variable id
303      !---------------------------------------------------------------------
304      clinfo = 'iom_nf90_g123d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
305      if90id = iom_file(kiomid)%nfid         ! get back NetCDF file id
306      ivid   = iom_file(kiomid)%nvid(kvid)   ! get back NetCDF var id
307      !
308      IF(     PRESENT(pv_r1d) ) THEN
309         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r1d(:                ), start = kstart(1:knbdim),   &
310            &                                                                       count = kcount(1:knbdim)), clinfo )
311      ELSEIF( PRESENT(pv_r2d) ) THEN
312         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim),   &
313            &                                                                       count = kcount(1:knbdim)), clinfo )
314      ELSEIF( PRESENT(pv_r3d) ) THEN
315         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim),   &
316            &                                                                       count = kcount(1:knbdim)), clinfo )
317      ENDIF
318      !
319   END SUBROUTINE iom_nf90_g123d
320
321
322   SUBROUTINE iom_nf90_chkatt( kiomid, cdatt, llok, ksize, cdvar )
323      !!-----------------------------------------------------------------------
324      !!                  ***  ROUTINE  iom_nf90_chkatt  ***
325      !!
326      !! ** Purpose : check existence of attribute with NF90
327      !!              (either a global attribute (default) or a variable
328      !!               attribute if optional variable name is supplied (cdvar))
329      !!-----------------------------------------------------------------------
330      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
331      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
332      LOGICAL         , INTENT(  out) ::   llok     ! error code
333      INTEGER         , INTENT(  out), OPTIONAL     &
334                      &               ::   ksize    ! attribute size
335      CHARACTER(len=*), INTENT(in   ), OPTIONAL     &
336                      &               ::   cdvar    ! name of the variable
337      !
338      INTEGER                         ::   if90id   ! temporary integer
339      INTEGER                         ::   isize    ! temporary integer
340      INTEGER                         ::   ivarid   ! NetCDF variable Id
341      !---------------------------------------------------------------------
342      !
343      if90id = iom_file(kiomid)%nfid
344      IF( PRESENT(cdvar) ) THEN
345         ! check the variable exists in the file
346         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
347         IF( llok ) &
348            ! check the variable has the attribute required
349            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt, len=isize ) == nf90_noerr
350      ELSE
351         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt, len=isize ) == nf90_noerr
352      ENDIF
353      !
354      IF( PRESENT(ksize) ) ksize = isize
355      !
356      IF( .not. llok) &
357         CALL ctl_warn('iom_nf90_chkatt: no attribute '//cdatt//' found')
358      !
359   END SUBROUTINE iom_nf90_chkatt
360
361
362   !!----------------------------------------------------------------------
363   !!                   INTERFACE iom_nf90_getatt
364   !!----------------------------------------------------------------------
365
366   SUBROUTINE iom_nf90_getatt( kiomid, cdatt, katt0d, katt1d, patt0d, patt1d, cdatt0d, cdvar)
367      !!-----------------------------------------------------------------------
368      !!                  ***  ROUTINE  iom_nf90_getatt  ***
369      !!
370      !! ** Purpose : read an attribute with NF90
371      !!              (either a global attribute (default) or a variable
372      !!               attribute if optional variable name is supplied (cdvar))
373      !!-----------------------------------------------------------------------
374      INTEGER               , INTENT(in   )           ::   kiomid   ! Identifier of the file
375      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt    ! attribute name
376      INTEGER               , INTENT(  out), OPTIONAL ::   katt0d   ! read scalar integer
377      INTEGER, DIMENSION(:) , INTENT(  out), OPTIONAL ::   katt1d   ! read 1d array integer
378      REAL(wp)              , INTENT(  out), OPTIONAL ::   patt0d   ! read scalar  real
379      REAL(wp), DIMENSION(:), INTENT(  out), OPTIONAL ::   patt1d   ! read 1d array real
380      CHARACTER(len=*)      , INTENT(  out), OPTIONAL ::   cdatt0d  ! read character
381      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar    ! name of the variable
382      !
383      INTEGER                         ::   if90id   ! temporary integer
384      INTEGER                         ::   ivarid   ! NetCDF variable Id
385      LOGICAL                         ::   llok     ! temporary logical
386      CHARACTER(LEN=100)              ::   clinfo   ! info character
387      !---------------------------------------------------------------------
388      !
389      if90id = iom_file(kiomid)%nfid
390      IF( PRESENT(cdvar) ) THEN
391         ! check the variable exists in the file
392         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
393         IF( llok ) THEN
394            ! check the variable has the attribute required
395            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt) == nf90_noerr
396         ELSE
397            CALL ctl_warn('iom_nf90_getatt: no variable '//TRIM(cdvar)//' found')
398         ENDIF
399      ELSE
400         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
401         ivarid = NF90_GLOBAL
402      ENDIF
403      !
404      IF( llok) THEN
405         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt)
406         IF(PRESENT( katt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  katt0d), clinfo)
407         IF(PRESENT( katt1d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  katt1d), clinfo)
408         IF(PRESENT( patt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  patt0d), clinfo)
409         IF(PRESENT( patt1d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  patt1d), clinfo)
410         IF(PRESENT(cdatt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values = cdatt0d), clinfo)
411      ELSE
412         CALL ctl_warn('iom_nf90_getatt: no attribute '//TRIM(cdatt)//' found')
413         IF(PRESENT( katt0d))    katt0d    = -999
414         IF(PRESENT( katt1d))    katt1d(:) = -999
415         IF(PRESENT( patt0d))    patt0d    = -999._wp
416         IF(PRESENT( patt1d))    patt1d(:) = -999._wp
417         IF(PRESENT(cdatt0d))   cdatt0d    = '!'
418      ENDIF
419      !
420   END SUBROUTINE iom_nf90_getatt
421
422
423   SUBROUTINE iom_nf90_putatt( kiomid, cdatt, katt0d, katt1d, patt0d, patt1d, cdatt0d, cdvar)
424      !!-----------------------------------------------------------------------
425      !!                  ***  ROUTINE  iom_nf90_putatt  ***
426      !!
427      !! ** Purpose : write an attribute with NF90
428      !!              (either a global attribute (default) or a variable
429      !!               attribute if optional variable name is supplied (cdvar))
430      !!-----------------------------------------------------------------------
431      INTEGER               , INTENT(in   )           ::   kiomid   ! Identifier of the file
432      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt    ! attribute name
433      INTEGER               , INTENT(in   ), OPTIONAL ::   katt0d   ! read scalar integer
434      INTEGER, DIMENSION(:) , INTENT(in   ), OPTIONAL ::   katt1d   ! read 1d array integer
435      REAL(wp)              , INTENT(in   ), OPTIONAL ::   patt0d   ! read scalar  real
436      REAL(wp), DIMENSION(:), INTENT(in   ), OPTIONAL ::   patt1d   ! read 1d array real
437      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdatt0d  ! read character
438      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar    ! name of the variable
439      !
440      INTEGER                         ::   if90id   ! temporary integer
441      INTEGER                         ::   ivarid   ! NetCDF variable Id
442      INTEGER                         ::   isize    ! Attribute size
443      INTEGER                         ::   itype    ! Attribute type
444      LOGICAL                         ::   llok     ! temporary logical
445      LOGICAL                         ::   llatt     ! temporary logical
446      LOGICAL                         ::   lldata   ! temporary logical
447      CHARACTER(LEN=100)              ::   clinfo   ! info character
448      !---------------------------------------------------------------------
449      !
450      if90id = iom_file(kiomid)%nfid
451      IF( PRESENT(cdvar) ) THEN
452         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! is the variable in the file?
453         IF( .NOT. llok ) THEN
454            CALL ctl_warn('iom_nf90_putatt: no variable '//TRIM(cdvar)//' found'   &
455               &        , '                 no attribute '//cdatt//' written' )
456            RETURN
457         ENDIF
458      ELSE
459         ivarid = NF90_GLOBAL
460      ENDIF
461      llatt = NF90_Inquire_attribute(if90id, ivarid, cdatt, len = isize, xtype = itype ) == nf90_noerr
462      !
463      ! trick: irec used to know if the file is in define mode or not
464      lldata = iom_file(kiomid)%irec /= -1   ! default: go back in define mode if in data mode
465      IF( lldata .AND. llatt ) THEN          ! attribute already there. Do we really need to go back in define mode?
466         ! do we have the appropriate type?
467         IF(PRESENT( katt0d) .OR. PRESENT( katt1d))   llok = itype == NF90_INT
468         IF(PRESENT( patt0d) .OR. PRESENT( patt1d))   llok = itype == NF90_DOUBLE
469         IF(PRESENT(cdatt0d)                      )   llok = itype == NF90_CHAR
470         ! and do we have the appropriate size?
471         IF(PRESENT( katt0d))   llok = llok .AND. isize == 1
472         IF(PRESENT( katt1d))   llok = llok .AND. isize == SIZE(katt1d)
473         IF(PRESENT( patt0d))   llok = llok .AND. isize == 1
474         IF(PRESENT( patt1d))   llok = llok .AND. isize == SIZE(patt1d)
475         IF(PRESENT(cdatt0d))   llok = llok .AND. isize == LEN_TRIM(cdatt0d)
476         !
477         lldata = .NOT. llok
478      ENDIF
479      !
480      clinfo = 'iom_nf90_putatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt)
481      IF(lldata)   CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ! leave data mode to define mode
482      !
483      IF(PRESENT( katt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       katt0d) , clinfo)
484      IF(PRESENT( katt1d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       katt1d) , clinfo)
485      IF(PRESENT( patt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       patt0d) , clinfo)
486      IF(PRESENT( patt1d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       patt1d) , clinfo)
487      IF(PRESENT(cdatt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values = trim(cdatt0d)), clinfo)
488      !
489      IF(lldata)   CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ! leave define mode to data mode
490      !
491   END SUBROUTINE iom_nf90_putatt
492
493
494   SUBROUTINE iom_nf90_rp0123d( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
495         &                                  pv_r0d, pv_r1d, pv_r2d, pv_r3d )
496      !!--------------------------------------------------------------------
497      !!                   ***  SUBROUTINE  iom_nf90_rstput  ***
498      !!
499      !! ** Purpose : read the time axis cdvar in the file
500      !!--------------------------------------------------------------------
501      INTEGER                     , INTENT(in)           ::   kt       ! ocean time-step
502      INTEGER                     , INTENT(in)           ::   kwrite   ! writing time-step
503      INTEGER                     , INTENT(in)           ::   kiomid   ! Identifier of the file
504      CHARACTER(len=*)            , INTENT(in)           ::   cdvar    ! variable name
505      INTEGER                     , INTENT(in)           ::   kvid     ! variable id
506      INTEGER                     , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
507      REAL(wp)                    , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
508      REAL(wp), DIMENSION(      :), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
509      REAL(wp), DIMENSION(:, :   ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
510      REAL(wp), DIMENSION(:, :, :), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
511      !
512      INTEGER               :: idims                ! number of dimension
513      INTEGER               :: idvar                ! variable id
514      INTEGER               :: jd                   ! dimension loop counter   
515      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes   
516      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size 
517      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
518      CHARACTER(LEN=256)    :: clinfo               ! info character
519      CHARACTER(LEN= 12), DIMENSION(5) :: cltmp     ! temporary character
520      INTEGER               :: if90id               ! nf90 file identifier
521      INTEGER               :: idmy                 ! dummy variable
522      INTEGER               :: itype                ! variable type
523      INTEGER, DIMENSION(4) :: ichunksz             ! NetCDF4 chunk sizes. Will be computed using
524      !                                             ! nn_nchunks_[i,j,k,t] namelist parameters
525      INTEGER               :: ichunkalg, ishuffle, ideflate, ideflate_level
526      !                                             ! NetCDF4 internally fixed parameters
527      LOGICAL               :: lchunk               ! logical switch to activate chunking and compression
528      !                                             ! when appropriate (currently chunking is applied to 4d fields only)
529      INTEGER               :: idlv                 ! local variable
530      INTEGER               :: idim3                ! id of the third dimension
531      !
532      INTEGER ::   nldi_save, nlei_save    !:patch before we remove periodicity and close boundaries in output files
533      INTEGER ::   nldj_save, nlej_save    !:
534      !---------------------------------------------------------------------
535      !
536      clinfo = '          iom_nf90_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
537      if90id = iom_file(kiomid)%nfid
538      !
539      ! use patch to force the writing off periodicity and close boundaries
540      ! without this, issue in some model decomposition
541      ! seb: patch before we remove periodicity and close boundaries in output files
542      nldi_save = nldi   ;   nlei_save = nlei
543      nldj_save = nldj   ;   nlej_save = nlej
544      IF( nimpp           ==      1 ) nldi = 1
545      IF( nimpp + jpi - 1 == jpiglo ) nlei = jpi
546      IF( njmpp           ==      1 ) nldj = 1
547      IF( njmpp + jpj - 1 == jpjglo ) nlej = jpj
548      !
549      ! define dimension variables if it is not already done
550      ! ==========================
551      IF( iom_file(kiomid)%nvars == 0 ) THEN
552         ! are we in define mode?
553         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
554            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
555         ENDIF
556         ! define the dimension variables if it is not already done
557         ! Warning: we must use the same character length in an array constructor (at least for gcc compiler)
558         cltmp = (/ 'nav_lon     ', 'nav_lat     ', 'nav_lev     ', 'time_counter', 'numcat      ' /)   
559         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(1)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(1) ), clinfo)
560         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(2)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(2) ), clinfo)
561         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(3)), NF90_FLOAT , (/ 3    /), iom_file(kiomid)%nvid(3) ), clinfo)
562         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(4)), NF90_DOUBLE, (/ 4    /), iom_file(kiomid)%nvid(4) ), clinfo)
563         ! update informations structure related the dimension variable we just added...
564         iom_file(kiomid)%nvars       = 4
565         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
566         iom_file(kiomid)%cn_var(1:4) = cltmp(1:4)
567         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /)
568         IF( NF90_INQ_DIMID( if90id, 'numcat', idmy ) == nf90_noerr ) THEN   ! add a 5th variable corresponding to the 5th dimension
569            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(5)), NF90_FLOAT , (/ 5 /), iom_file(kiomid)%nvid(5) ), clinfo)
570            iom_file(kiomid)%nvars     = 5
571            iom_file(kiomid)%luld(5)   = .FALSE.
572            iom_file(kiomid)%cn_var(5) = cltmp(5)
573            iom_file(kiomid)%ndims(5)  = 1
574         ENDIF
575         ! trick: defined to 0 to say that dimension variables are defined but not yet written
576         iom_file(kiomid)%dimsz(1, 1)  = 0   
577         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
578      ENDIF
579      ! define the data if it is not already done
580      ! ===============
581      IF( kvid <= 0 ) THEN
582         !
583         ! NetCDF4 chunking and compression fixed settings
584         ichunkalg = 0
585         ishuffle = 1
586         ideflate = 1
587         ideflate_level = 1
588         !
589         idvar = iom_file(kiomid)%nvars + 1
590         ! are we in define mode?
591         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
592            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
593         ENDIF
594         ! variable definition
595         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
596         ELSEIF( PRESENT(pv_r1d) ) THEN
597            IF( SIZE(pv_r1d,1) == jpk ) THEN   ;   idim3 = 3
598            ELSE                               ;   idim3 = 5
599            ENDIF
600                                              idims = 2   ;   idimid(1:idims) = (/idim3,4/)
601         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2  ,4/)
602         ELSEIF( PRESENT(pv_r3d) ) THEN
603            IF( SIZE(pv_r3d,3) == jpk ) THEN   ;   idim3 = 3
604            ELSE                               ;   idim3 = 5
605            ENDIF
606                                              idims = 4   ;   idimid(1:idims) = (/1,2,idim3,4/)
607         ENDIF
608         IF( PRESENT(ktype) ) THEN   ! variable external type
609            SELECT CASE (ktype)
610            CASE (jp_r8)   ;   itype = NF90_DOUBLE
611            CASE (jp_r4)   ;   itype = NF90_FLOAT
612            CASE (jp_i4)   ;   itype = NF90_INT
613            CASE (jp_i2)   ;   itype = NF90_SHORT
614            CASE (jp_i1)   ;   itype = NF90_BYTE
615            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
616            END SELECT
617         ELSE
618            itype = NF90_DOUBLE
619         ENDIF
620         IF( PRESENT(pv_r0d) ) THEN
621            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype,                    &
622               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
623         ELSE
624            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, idimid(1:idims),   &
625               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
626         ENDIF
627         lchunk = .false.
628         IF( snc4set%luse .AND. idims == 4 )   lchunk = .true.
629         ! update informations structure related the new variable we want to add...
630         iom_file(kiomid)%nvars         = idvar
631         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
632         iom_file(kiomid)%scf(idvar)    = 1.
633         iom_file(kiomid)%ofs(idvar)    = 0.
634         iom_file(kiomid)%ndims(idvar)  = idims
635         IF( .NOT. PRESENT(pv_r0d) ) THEN   ;   iom_file(kiomid)%luld(idvar) = .TRUE.
636         ELSE                               ;   iom_file(kiomid)%luld(idvar) = .FALSE.
637         ENDIF
638         DO jd = 1, idims
639            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, idimid(jd), len = iom_file(kiomid)%dimsz(jd,idvar) ), clinfo)
640            IF ( lchunk ) ichunksz(jd) = iom_file(kiomid)%dimsz(jd,idvar)
641         END DO
642         IF ( lchunk ) THEN
643            ! Calculate chunk sizes by partitioning each dimension as requested in namnc4 namelist
644            ! Disallow very small chunk sizes and prevent chunk sizes larger than each individual dimension
645            ichunksz(1) = MIN( ichunksz(1),MAX( (ichunksz(1)-1)/snc4set%ni + 1 ,16 ) ) ! Suggested default nc4set%ni=4
646            ichunksz(2) = MIN( ichunksz(2),MAX( (ichunksz(2)-1)/snc4set%nj + 1 ,16 ) ) ! Suggested default nc4set%nj=2
647            ichunksz(3) = MIN( ichunksz(3),MAX( (ichunksz(3)-1)/snc4set%nk + 1 , 1 ) ) ! Suggested default nc4set%nk=6
648            ichunksz(4) = 1                                                            ! Do not allow chunks to span the
649            !                                                                          ! unlimited dimension
650            CALL iom_nf90_check(SET_NF90_DEF_VAR_CHUNKING(if90id, idvar, ichunkalg, ichunksz), clinfo)
651            CALL iom_nf90_check(SET_NF90_DEF_VAR_DEFLATE(if90id, idvar, ishuffle, ideflate, ideflate_level), clinfo)
652            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' chunked ok. Chunks sizes: ', ichunksz
653         ENDIF
654         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
655      ELSE
656         idvar = kvid
657      ENDIF
658      !
659      ! time step kwrite : write the variable
660      IF( kt == kwrite ) THEN
661         ! are we in write mode?
662         IF( iom_file(kiomid)%irec == -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
663            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = 0
664         ENDIF
665         ! on what kind of domain must the data be written?
666         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
667            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
668            IF(     idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN
669               ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
670            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN
671               ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
672            ELSEIF( idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN
673               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
674            ELSE
675               CALL ctl_stop( 'iom_nf90_rp0123d: should have been an impossible case...' )
676            ENDIF
677
678            ! write dimension variables if it is not already done
679            ! =============
680            ! trick: is defined to 0 => dimension variable are defined but not yet written
681            IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN
682               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'nav_lon'     , idmy )         , clinfo )
683               CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, glamt(ix1:ix2, iy1:iy2) ), clinfo )
684               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'nav_lat'     , idmy )         , clinfo )
685               CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, gphit(ix1:ix2, iy1:iy2) ), clinfo )
686               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'nav_lev'     , idmy ), clinfo )
687               CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, gdept_1d       ), clinfo )
688               IF( NF90_INQ_VARID( if90id, 'numcat', idmy ) == nf90_noerr ) THEN
689                  CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, (/ (idlv, idlv = 1,iom_file(kiomid)%nlev) /)), clinfo )
690               ENDIF
691               ! +++ WRONG VALUE: to be improved but not really useful...
692               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'time_counter', idmy ), clinfo )
693               CALL iom_nf90_check( NF90_PUT_VAR( if90id, idmy, kt                      ), clinfo )   
694               ! update the values of the variables dimensions size
695               CALL iom_nf90_check( NF90_INQUIRE_DIMENSION( if90id, 1, len = iom_file(kiomid)%dimsz(1,1) ), clinfo )
696               CALL iom_nf90_check( NF90_INQUIRE_DIMENSION( if90id, 2, len = iom_file(kiomid)%dimsz(2,1) ), clinfo )
697               iom_file(kiomid)%dimsz(1:2, 2) = iom_file(kiomid)%dimsz(1:2, 1)
698               CALL iom_nf90_check( NF90_INQUIRE_DIMENSION( if90id, 3, len = iom_file(kiomid)%dimsz(1,3) ), clinfo )
699               iom_file(kiomid)%dimsz(1  , 4) = 1   ! unlimited dimension
700               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
701            ENDIF
702         ENDIF
703
704         ! write the data
705         ! =============
706         IF(     PRESENT(pv_r0d) ) THEN
707            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r0d                    ), clinfo )
708         ELSEIF( PRESENT(pv_r1d) ) THEN
709            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r1d(:)                 ), clinfo )
710         ELSEIF( PRESENT(pv_r2d) ) THEN
711            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r2d(ix1:ix2,iy1:iy2)   ), clinfo )
712         ELSEIF( PRESENT(pv_r3d) ) THEN
713            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r3d(ix1:ix2,iy1:iy2,:) ), clinfo )
714         ENDIF
715         ! add 1 to the size of the temporal dimension (not really useful...)
716         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
717               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
718         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
719      ENDIF
720      !
721      nldi = nldi_save   ;   nlei = nlei_save
722      nldj = nldj_save   ;   nlej = nlej_save
723      !     
724   END SUBROUTINE iom_nf90_rp0123d
725
726
727   SUBROUTINE iom_nf90_check( kstatus, cdinfo )
728      !!--------------------------------------------------------------------
729      !!                   ***  SUBROUTINE iom_nf90_check  ***
730      !!
731      !! ** Purpose :   check nf90 errors
732      !!--------------------------------------------------------------------
733      INTEGER,          INTENT(in) :: kstatus
734      CHARACTER(LEN=*), INTENT(in) :: cdinfo
735      !---------------------------------------------------------------------
736      IF(kstatus /= nf90_noerr)   CALL ctl_stop( 'iom_nf90_check : '//TRIM(nf90_strerror(kstatus)), TRIM(cdinfo) )
737   END SUBROUTINE iom_nf90_check
738
739   !!======================================================================
740END MODULE iom_nf90
Note: See TracBrowser for help on using the repository browser.