!!----------------------------------------------------------------------
   !!                   ***  tau_forced_daily.h90  ***
   !!----------------------------------------------------------------------

   !!----------------------------------------------------------------------
   !!   tau     :   update the surface stress - daily fields in NetCDF file
   !!----------------------------------------------------------------------
   !! * local modules variables
   INTEGER ::   &
      numtau,         &  ! logical unit for the i-component of the wind data
      numtav,         &  ! logical unit for the j-component of the wind data
      ntau1, ntau2 ,  &  ! index of the first and second record used
      ndaytau            ! new day for ers/ncep tau forcing

   CHARACTER (len=34) ::   &      !!! * monthly climatology/interanual fields
      cl_taux ,  & ! generic name of the i-component monthly NetCDF file
      cl_tauy      ! generic name of the j-component monthly NetCDF file
   !!----------------------------------------------------------------------
   !!   OPA 9.0 , LOCEAN-IPSL (2005) 
   !! $Header$ 
   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt 
   !!----------------------------------------------------------------------

CONTAINS

   SUBROUTINE tau( kt )
      !!---------------------------------------------------------------------
      !!                    ***  ROUTINE tau  ***
      !!     
      !! ** Purpose :   provide to the ocean the stress at each time step
      !!
      !! ** Method  :   Read the daily surface stress components in NetCDF 
      !!      file. They are given in the (i,j) referential 
      !!        The i-component is given at U-point (INTERP package)
      !!        The j-component is given at V-point (INTERP package)
      !!
      !!    CAUTION: never mask the surface stress field !
      !!
      !! ** Action  :   update at each time-step the two components of the 
      !!      surface stress in both (i,j) and geographical referencial
      !!
      !! History :
      !!   4.0  !  91-03  (G. Madec)  Original code
      !!   6.0  !  92-07  (M. Imbard)
      !!   8.1  !  00-08  (D. Ludicone) adapted to ERS-NCEP
      !!   8.5  !  02-11  (G. Madec)  F90: Free form and module
      !!        !  03-07  (C. Ethe, G. Madec)  daily generic forcing
      !!----------------------------------------------------------------------
      !! * Modules used
      USE ioipsl       ! NetCDF library

      !! * Arguments
      INTEGER, INTENT( in  ) ::   kt   ! ocean time step

      !! * Local declarations
      INTEGER, PARAMETER ::   jpday = 365
      INTEGER ::   &
         itime,   &
         iday, idy,   &
         ipi, ipj, ipk
      INTEGER  , DIMENSION(jpday)  ::   istep
      REAL(wp) , DIMENSION(jpi,jpj)::  &
         zlon  , & 
         zlat
      REAL(wp) , DIMENSION(jpk)::  &
         zlev
      REAL(wp) ::   zsecond, zdate0
      !!---------------------------------------------------------------------
      cl_taux = 'taux.nc'
      cl_tauy = 'tauy.nc'

      ! -------------- !
      ! Initialization !
      ! -------------- !

      itime = jpday
      ipi   = jpiglo
      ipj   = jpjglo
      ipk   = jpk
      idy   = 365
      IF ( nleapy == 1 ) idy = 366 


      ! -------------------- !
      ! First call kt=nit000 !
      ! -------------------- !

      IF( kt == nit000 ) THEN
         IF(lwp) THEN
            WRITE(numout,*) ' '
            WRITE(numout,*) ' tau    : DAILY wind stress in NetCDF files'
            WRITE(numout,*) ' ~~~~~~~'
         ENDIF
         ! title, dimensions and tests
#if defined key_AGRIF
      if ( .NOT. Agrif_Root() ) then
         cl_taux = TRIM(Agrif_CFixed())//'_'//TRIM(cl_taux)
      endif
#endif
         
         CALL flinopen( cl_taux, mig(1), nlci, mjg(1), nlcj,   &   ! taux on U-grid
                        .FALSE., ipi   , ipj, ipk   ,        &
                        zlon , zlat  , zlev   , itime,       &
                        istep, zdate0, zsecond, numtau )
         
         IF( itime /= jpday .AND. itime /= jpday+1 ) THEN
            IF(lwp) WRITE(numout,cform_err)
            IF(lwp) WRITE(numout,*) '   problem with time coordinates in file ', cl_taux
            IF(lwp) WRITE(numout,*) '   itime = ', itime,' jpday = ',jpday
            nstop = nstop + 1
         ENDIF
         IF( ipi /= jpidta .OR. ipj /= jpjdta  ) THEN
            IF(lwp) WRITE(numout,cform_err)
            IF(lwp) WRITE(numout,*) '   problem with size read in file ', cl_taux
            IF(lwp) WRITE(numout,*) '   ipi = ',ipi,' jpidta = ',jpidta
            IF(lwp) WRITE(numout,*) '   ipj = ',ipj,' jpjdta = ',jpjdta
            nstop = nstop + 1
         ENDIF
#if defined key_AGRIF
      if ( .NOT. Agrif_Root() ) then
         cl_tauy = TRIM(Agrif_CFixed())//'_'//TRIM(cl_tauy)
      endif
#endif

         CALL flinopen( cl_tauy, mig(1), nlci, mjg(1), nlcj,   &   ! tauy on V-grid
                        .FALSE., ipi   , ipj, ipk   ,        &
                        zlon , zlat  , zlev   , itime,       &
                        istep, zdate0, zsecond, numtav )
         
         IF( itime /= jpday .AND. itime /= jpday+1 ) THEN
            IF(lwp) WRITE(numout,cform_err)
            IF(lwp) WRITE(numout,*) '   problem with time coordinates in file ', cl_tauy
            IF(lwp) WRITE(numout,*) '   itime = ', itime,' jpday = ',jpday
            nstop = nstop + 1
         ENDIF
         IF( ipi /= jpidta .OR. ipj /= jpjdta ) THEN
            IF(lwp) WRITE(numout,cform_err)
            IF(lwp) WRITE(numout,*) '   problem with size read in file ', cl_tauy
            IF(lwp) WRITE(numout,*) '   ipi = ',ipi,' jpidta = ',jpidta
            IF(lwp) WRITE(numout,*) '   ipj = ',ipj,' jpjdta = ',jpjdta
            nstop = nstop + 1
         ENDIF
      ENDIF

      ! ----------------- !
      ! Read daily file   !
      ! ----------------- !

      IF ( ndaytau /= nday ) THEN
            
         ndaytau = nday
         iday  = nday_year
            
         ! Read daily wind stress data
         CALL flinget( numtau,'taux',                 &   ! taux: i-component at U-pt
                       jpidta,jpjdta,1,jpday,iday,    &
                       iday,mig(1),nlci,mjg(1),nlcj,taux(1:nlci,1:nlcj) )
         CALL flinget( numtav,'tauy',                 &   ! tauy: j-component at V-pt
                       jpidta,jpjdta,1,jpday,iday,    &
                       iday,mig(1),nlci,mjg(1),nlcj,tauy(1:nlci,1:nlcj) )
            
         IF (lwp .AND. nitend-nit000 <= 100 ) THEN
            WRITE(numout,*)
            WRITE(numout,*) ' read daily wind stress ok'
            WRITE(numout,*)
            WRITE(numout,*) ' day: ', ndastp , '  taux: 1 multiply by ', 1.
            CALL prihre( taux, jpi, jpj, 1, jpi, 20, 1, jpj, 10, 1., numout )
            WRITE(numout,*)
            WRITE(numout,*) ' day: ', ndastp , '  tauy: 1 multiply by ', 1.
            CALL prihre( tauy, jpi, jpj, 1, jpi, 20, 1, jpj, 10, 1., numout )
            WRITE(numout,*) ' ' 
         ENDIF
            
         CALL FLUSH(numout)
      ENDIF
         
      ! Save components in geographical ref on U grid
      tauxg(:,:) = taux(:,:)
      tauyg(:,:) = tauy(:,:)
         
      ! ------------------- !
      ! Last call kt=nitend !
      ! ------------------- !

      ! Closing of the 2 files
      IF( kt == nitend ) THEN
          CALL flinclo( numtau )
          CALL flinclo( numtav )
      ENDIF
         
   END SUBROUTINE tau