Version 25 (modified by gm, 10 years ago) (diff)

Last edited Timestamp?


Author : Gurvan Madec, Yevgeny Aksenov, Matthieu Leclair

ticket : #665

Branch : DEV_r1837_mass_heat_salt_fluxes


useful commands

* check out of NEMO directory:
svn co svn+ssh://gm@forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/DEV_r1837_mass_heat_salt_fluxes/NEMO

* commit :
svn ci  -m  "ticket:#665  blah_blah"    list_of_file

Description

Revisit the formulation of the fluxes between ocean, ice and atmosphere : an exchange of water (mass exchange) is now explicitly associated with an exchange of heat and salt content. This modification simplifies the implementation of a fully embedded sea-ice.

This update is the NOCS.4 task (Revisit of mass and salt fluxes) due by 2nd July 2010

The main modifications concern OPA, LIM2 and LIM3. They are:

(0) stylistic modification

style changes only have been put in revision 1855.

Nevertheless we have return back to the original revision 1850 from which we start from the trunk. The style changes we be re-added at the end of the development, after the testing phase.

The following is thus done directly from the trunk.

(1) heat content of Freezing/Melting? ice

In LIM2 only, the computation of the heat content of F/M ice is added (this is already done in LIM3 which is based on internal enrgy conservation, like CICE). The changes exactly mirror the changes introduced at NOCS in NEMO v3.0 when implementing first the sea-ice embedment. The basic idea is to reference at rt0 all the mass exchanges between ice and ocean.

NB: since emps becomes the salt flux, it is generally zero except with the salt exchange at the ocean-ice interface and when a SSS restoring in salinity is used (not when a equivalent freshwater flux formulation is used for the SSS restoring). Therefore emps done not appear anymore in all the sbc routine,. It is only set to zero in sbc_init, set to the ice-ocean salt flux in limsbc(_2), and modified in sbcssr if SSS retoring is used.

LIM2 : the modules involved in the change are : (see also the revision 1858)

  • ice_2.F90 : add arrays to describe the heat content associated with both snow and ice mass changes and also change the name of the mass changes. Thus the following lines :
       REAL(wp), PUBLIC, DIMENSION(jpi,jpj) ::   rdqsnif       !: Variation of snow mass 
       REAL(wp), PUBLIC, DIMENSION(jpi,jpj) ::   rdqicif       !: Variation of ice  mass 
    
    becomes
       REAL(wp), PUBLIC, DIMENSION(jpi,jpj) ::   rdm_snw       !: Variation of snow mass over 1 time step           [Kg/m2]
       REAL(wp), PUBLIC, DIMENSION(jpi,jpj) ::   rdq_snw       !: heat content associated to rdm_snw                [J/m2]
       REAL(wp), PUBLIC, DIMENSION(jpi,jpj) ::   rdq_ice       !: Variation of ice  mass over 1 time step           [Kg/m2]
       REAL(wp), PUBLIC, DIMENSION(jpi,jpj) ::   rdq_ice       !: heat content associated to rdm_snw                [J/m2]
    
  • thd_ice_2.F90 : associated 1D array names (rdsnif_1d, rdmicif_1d) have been changed into (rdm_snw_1d, rdm_ice_1d) and (rdq_snw_1d, rdq_ice_1d) have been added.
  • limthd_2.F90 : introduce the new variable names, and pass the new variables (rdq_snw, rdq_ice) to the lim_thd_zdf and lim_thd_lac routines

Note 1: we suppress the change of sst_m from Celcius to Kelvin and vice versa by adding a " + rt0 " at the 2 places it is used.

Note 2: zfontn has been suppressed as the heat associated with the melting of solid precipitation is now added to qns in sbc modules (=⇒> TO BE DONE in SBC)

  • limthd_lac_2.F90 : introduce the new variable name (rdm_ice), and add the update of rdq_ice : the last DO loop of lim_thd_lac routine is transformed as follows :
          DO ji = kideb , kiut
             dvlbq_1d  (ji) = ( 1. - frld_1d(ji) ) * h_ice_1d(ji) - ( 1. - zfrl_old(ji) ) * zhice_old(ji)
             rdmicif_1d(ji) = rdmicif_1d(ji) + rhoic * dvlbq_1d(ji)
          END DO
    
    becomes
          DO ji = kideb , kiut
             dvlbq_1d  (ji) = ( 1. - frld_1d(ji) ) * h_ice_1d(ji) - ( 1. - zfrl_old(ji) ) * zhice_old(ji)
             rdm_ice_1d(ji) = rdm_ice_1d(ji) + rhoic * dvlbq_1d(ji)
             rdq_ice_1d(ji) = rdq_ice_1d(ji) + rcpic * dvlbq_1d(ji) * ( tfu_1d(ji) - rt0 )      ! heat content relative to rt0
          END DO
    
  • limthd_zdf_2.F90 : introduce the new variable names (rdm_snw, rdm_ice), and and add the computation/update of rdq_snw, rdq_ice :

§ " 9.1. Surface ablation and update of snow thickness and qstbif_1d ", the lines

          !--volume of snow lost after surface melting and the associated mass
          dvsbq_1d(ji) =  ( 1.0 - frld_1d(ji) ) * ( h_snow_1d(ji) - zhsnw_old(ji) - zsprecip(ji) )
          dvsbq_1d(ji) =  MIN( zzero , dvsbq_1d(ji) )
          rdmsnif_1d(ji) =  rhosn * dvsbq_1d(ji)

becomes

          !--volume of snow lost after surface melting and the associated mass
          dvsbq_1d(ji) =  ( 1.0 - frld_1d(ji) ) * ( h_snow_1d(ji) - zhsnw_old(ji) - zsprecip(ji) )
          dvsbq_1d(ji) =  MIN( zzero , dvsbq_1d(ji) )
          ztmp = rhosn * dvsbq_1d(ji)
          rdm_snw_1d(ji) =  ztmp
          !--heat content of the water provided to the ocean (referenced to rt0)
          rdq_snw_1d(ji) =  cpic * ztmp * ( rt0_snow - rt0 )

§ " 9.4. Case of total ablation (ice is gone but snow may be left) ", the lines :

          !---updating new ice thickness and computing the newly formed ice mass
          zhicnew   =  zihgnew * zhicnew
          rdmicif_1d(ji) =  rdmicif_1d(ji) + ( 1.0 - frld_1d(ji) ) * ( zhicnew - h_ice_1d(ji) ) * rhoic
          !---updating new snow thickness and computing the newly formed snow mass
          zhsnfi   = zhsn + zdhsnm
          h_snow_1d(ji) = MAX( zzero , zhsnfi )
          rdmsnif_1d(ji) =  rdmsnif_1d(ji) + ( 1.0 - frld_1d(ji) ) * ( h_snow_1d(ji) - zhsn ) * rhosn

becomes

          !---updating new ice thickness and computing the newly formed ice mass
          zhicnew   =  zihgnew * zhicnew
          ztmp    =  ( 1.0 - frld_1d(ji) ) * ( zhicnew - h_ice_1d(ji) ) * rhoic
          rdm_ice_1d(ji) =  rdm_ice_1d(ji) + ztmp
          !---heat content of the water provided to the ocean (referenced to rt0)
          ! use of rt0_ice is OK for melting ice, in case of freezing tfu_1d should be used. This is done in 9.5 section (see below)
          rdq_ice_1d(ji) =  cpic * ztmp * ( rt0_ice - rt0 )
          !---updating new snow thickness and computing the newly formed snow mass
          zhsnfi   = zhsn + zdhsnm
          h_snow_1d(ji) = MAX( zzero , zhsnfi )
          ztmp = ( 1.0 - frld_1d(ji) ) * ( h_snow_1d(ji) - zhsn ) * rhosn
          rdm_snw_1d(ji) = rdm_snw_1d(ji) + ztmp
          !---updating the heat content of the water provided to the ocean (referenced to rt0)
          rdq_snw_1d(ji) = rdq_snw_1d(ji) + cpic * ztmp * ( rt0_snow - rt0 )

§ " 9.5. Update internal temperature and ice thickness. ", the following lines have been added at the end :

          ! update the ice heat content given to the ocean in freezing case (part from rt0_ice to tfu_1d)
         ztmp = ( 1. - zidhb ) * rhoic * dvbbq_1d(ji)
         rdqicif_1d(ji) = rdqicif_1d(ji) + cpic * ztmp * ( tfu_1d(ji) - rt0_ice )

§ " 10. Surface accretion. ", the lines :

          !---  volume change of ice and snow (used for ocean-ice freshwater flux computation)
          rdmicif_1d(ji) = rdmicif_1d(ji) + ( 1.0 - frld_1d(ji) )   * ( zhicnew - h_ice_1d (ji) ) * rhoic
          rdmsnif_1d(ji) = rdmsnif_1d(ji) + ( 1.0 - frld_1d(ji) )   * ( zhsnnew - h_snow_1d(ji) ) * rhosn

becomes

          !---  volume change of ice and snow (used for ocean-ice freshwater flux computation)
          ztmp = ( 1.0 - frld_1d(ji) ) * ( zhicnew - h_ice_1d (ji) ) * rhoic
          rdm_ice_1d(ji) = rdm_ice_1d(ji) + ztmp
          rdq_ice_1d(ji) = rdq_ice_1d(ji) + cpic * ztmp * ( tfu_1d(ji) - rt0 )
!!gm BUG ??   snow ==>  only needed for nn_ice_embd == 0  (standard levitating sea-ice)
          ztmp = ( 1.0 - frld_1d(ji) )   * ( zhsnnew - h_snow_1d(ji) ) * rhosn
         rdm_snw_1d(ji) = rdm_snw_1d(ji) + ztmp
         rdq_snw_1d(ji) = rdq_snw_1d(ji) + cpic * ztmp * ( rt0_snow - rt0 )

and, at last, § " 11. Lateral ablation (Changes in sea/ice fraction) ", the lines :

          !--variation of ice volume and ice mass 
          dvlbq_1d(ji)   = zihic * ( zfrl_old(ji) - frld_1d(ji) ) * h_ice_1d(ji)
          rdmicif_1d(ji) = rdmicif_1d(ji) + dvlbq_1d(ji) * rhoic
          !--variation of snow volume and snow mass 
          zdvsnvol    = zihsn * ( zfrl_old(ji) - frld_1d(ji) ) * h_snow_1d(ji)
          rdmsnif_1d(ji) = rdmsnif_1d(ji) + zdvsnvol * rhosn

becomes

          !--variation of ice volume and ice mass 
          dvlbq_1d(ji)   = zihic * ( zfrl_old(ji) - frld_1d(ji) ) * h_ice_1d(ji)
          ztmp = dvlbq_1d(ji) * rhoic
          rdm_ice_1d(ji) = rdm_ice_1d(ji) + ztmp
!!gm
!!gm   This should be split in two parts:
!!gm         1-  heat required to bring sea-ice at tfu  : this part should be added to the heat flux taken from the ocean
!!gm                 cpic * ztmp * 0.5 * ( tbif_1d(ji,2) + tbif_1d(ji,3) - 2.* rt0_ice )
!!gm         2-  heat content of lateral ablation referenced to rt0 : this part only put in rdq_ice_1d
!!gm                 cpic * ztmp * ( rt0_ice - rt0 )
!!gm   Currently we put all the heat in rdq_ice_1d
          rdq_ice_1d(ji) = rdq_ice_1d(ji) + cpic * ztmp * 0.5 * ( tbif_1d(ji,2) + tbif_1d(ji,3) - 2.* rt0 )
          !
          !--variation of snow volume and snow mass 
          zdvsnvol = zihsn * ( zfrl_old(ji) - frld_1d(ji) ) * h_snow_1d(ji)
          ztmp     = zdvsnvol * rhosn
          rdm_snw_1d(ji) = rdm_snw_1d(ji) + ztmp
!!gm
!!gm   This should be split in two parts:
!!gm         1-  heat required to bring snow at tfu  : this part should be added to the heat flux taken from the ocean
!!gm                 cpic * ztmp * ( tbif_1d(ji,1) - rt0_snow )
!!gm         2-  heat content of lateral ablation referenced to rt0 : this part only put in rdqicif_1d
!!gm                 cpic * ztmp * ( rt0_snow - rt0 )
!!gm   Currently we put all the heat in rdqicif_1d
          rdq_snw_1d(ji) = rdq_snw_1d(ji) + cpic * ztmp * ( tbif_1d(ji,1) - rt0 )
  • phycst.F90 : style changes + :
     - update of name:    rau0r   ==>>  r1_rau0      ;      ro0cpr = r1_rau0_rcp
    
     - new variable:    xlsn = lfus * rhosn    (for lim3, already defined in lim2)  
                        lfus = xlsn / rhosn    (for lim2, already defined in lim3)
    

z1_rau0 implies changes in dynzdf_exp.F90 ; dynzdf_imp.F90 and eosbn2.F90

r1_rau0_rcp implies changes in trabbc.F90 ; traqsr.F90 and eosbn2.F90

CAUTION : there is a need to homogenize the definition of constant for sea-ice at least between LIM-2 and LIM-3. This must be coordonated with CICE variables

(2) LIM-3 specific changes see revision XXXX

In LIM3 case, the problem is somewhat different. Indeed, LIM3 is written in an energy conserving way (Bitz & Lipscomb 1999). Therefore the heat exchanged ith both atmosphere and ocean is the internal energy (i.e. the heat flux through the interface + the heat content of the mass flux referenced to rt0). There is no need to introduce rdq_ice and rdq_snw fields.

Five key elements have been changed :

1- Addition of internal energy of snowfall over the ice. Reason: Tatm is used inside lim3 to compute the internal energy of snowfall. In coupled mode this will not be possible. Therefore, and in better agreement with SBC philosophy, we introduce qen_snw provided by sbcblk_c.. or sbccpl.

  • sbc_ice.F90 : add the internal energie of snow in both LIM2 and LIM3 cases (even if in lim3 it will not be used) :
       REAL(wp), PUBLIC, DIMENSION(jpi,jpj) ::   qen_snw     !: internal energy of snowfall (heat content - Latent)   [W/m2]
    

idem in thd_ice ( version _1d)

  • sbcice_lim.F90, sbcblk_core.F90 and sbcblk_clio.F90 : add qen_snw to the call argument of blk_ice_c…, and add its computation (p_qen_s) in the 2 bulk formulae module:
          p_qen_s(:,:) = sf(jp_snow)%fnow(:,:) * ( cpic * ( sf(jp_tair)%fnow(:,:) - rtt - lfus )
    

  • sbccpl.F90 : add the computation of qen_snw

CAUTION : BUG correction snow CP is cpic not rcp…. correction made.

  • limthd.F90, limthd_ent.F90 and limthd_dh : pass qen_snw from 2D to 1D in limthd, replace the use of tatm by the use of qen_snw in limthd_dh :
    !!gm          p_qen_s(:,:) = sf(jp_snow)%fnow(:,:) * ( cpic * ( sf(jp_tair)%fnow(:,:) - rtt ) - lfus )
             zqprec          = - p_qen_s(:,:) * rhosn / MAX( sprecip_1d(ji), 1.e-20 )
    !!gm instead of :
    !         zqprec          =  rhosn * ( cpic * ( rtt - tatm_ice_1d(ji) ) + lfus )   ! energy of fallen snow
    !!gm
    
    and in limthd_ent :
    !!gm          p_qen_s(:,:) = sf(jp_snow)%fnow(:,:) * ( cpic * ( sf(jp_tair)%fnow(:,:) - rtt ) - lfus )
    !!gm  so      rhosn * ( cpic * ( tatm - rtt ) - lfus )  = - p_qen_s(:,:) * rhosn / MAX( sprecip_1d(ji), 1.e-20 )
    !!gm therefore:          
             qm0(ji,1)   = - (  ( 1. - snswi(ji) ) * p_qen_s(:,:) / MAX( sprecip_1d(ji), 1.e-20 ) 
                &          -           snswi(ji)   * (  cpic * ( t_s_b(ji,1) - rtt ) - lfus  )     ) * rhosn * zthick0(ji,1)
    !!gm instead of :
    !         qm0(ji,1)   =  rhosn * ( cpic * ( rtt - ( 1. - snswi(ji) ) * tatm_ice_1d(ji)         &
    !            &                                         - snswi(ji)   * t_s_b(ji,1)     ) + lfus  ) * zthick0(ji,1)
    !!gm
    
    as a consequence, the declaration of tatm in key_lim3 case is suppressed from sbc_ice, and its initialisation from both sbcblk_core and clio.

NB: in clio bulk, we replace the 2D ztatm array by a local scalar ztair

QUESTION =⇒ Martin Sublimation in coupled mode !!!! ou comment??? mettre qen_snw à la valeur du bilan sublim - snow ???? est-ce que ça marche ou limitation ??

Coupled mode check the value of cpic used in the atmosphere as well as rcp !!! :-)

2- Change in the snowfall partition between leads and ice. Reason: in LIM3 part of the snow that fall over ice is transported by the wind and kept in lead area. The parameterisation in coded deeply in LIM3 routine, whereas in coupled mode we need to have the information in sbccpl. Furthermore, with the partitioning at sbc level, LIM2 can also benefite from it.

Introduce betas in the SBC, no more in LIM-3 alone.

reason: (1) make it also avalable in LIM-2 and ice-IF cases

(2) make it availablein coupled mode (sbccpl.F90 will have to use it)

  • sbc_oce.F90,sbcmod.F90 : in namelist namsbc, add the following variable:
       REAL(wp), PUBLIC ::   rn_psnw     = 1.e0      !: coef. of lead/ice partition of snowfall (>0 and <=1)
    
    add the lecture of the new variable and its print in sbcmod.F90.

namelist =⇒ DON'T FORGET TO add the new variable in the ref namelists !!!

3- Modify the salt flux computation from an equivalent freshwater flux to a salt flux

4- update the ice-ocean interface to salt flux

5- Add the coupled case in the interface ice-atmos and atmos-ocean

The following routines are involved in the modifications:

  • ice.F90 : As for LIM-2, the mass flux array names change from rdmsnif and rdmicif to more readable rdm_snw and rdm_ice ; NO heat content arrays needed.
  • thd_ice.F90 : associated 1D array names (rdsnif_1d, rdmicif_1d) have been changed into (rdm_snw_1d, rdm_ice_1d).
  • limthd.F90 : introduce the new variable names, and pass the new variables (rdq_snw, rdq_ice) to the lim_thd_zdf and lim_thd_lac routines

BUG correction : In LIM-3 a betas exponent has been introduced when computing the solid precipitation over the sea ice. Part of the snow that falls over sea-ice is put in the lead areas by the wind. Nevertheless, the latent heat flux due to snow melting is computed with sprecip *(1-at_i) whereas the actual solid precipitation over lead area is sprecip*(1-at_ibetas). If betas /=1, some latent heat is missing (see the ticket open on that purpose #670).

BUG correction : limthd : use fse3t_m instead of fse3t

=⇒> ONGOING work

(3) Non-solar flux including the heat content of mass exchanges (see revision 1859)

the definition of qns is modified as follows: the non solar part of the surface heat flux takes now also into account the heat content changes due to the change in volume associated with evaporation, precipitation, ice freezing and ice melting. This heat content is evaluated using the temperature (expressed in Celcius) of the mass of water exchanged between the different media (ocean, atmosphere and ice).

Note that the latent heat flux associated to the meltin of solid precipitation is now taken into account directly in qns in sbc… routines, instead of been added in limthd(_2) (cf. step (1))

  • ocean-atmosphere mass exchanges :

# liquid precipitation are assumed to be at the air temperature expressed in Celcius)

# solid precipitation are assumed to be at least below the the melting temperature of snow (rtt_snow) : min( Tair , rtt_snow )

# evaporation are at the SST. Note that sst_m is used. This is thus different from the former implicit value assumed for both precip and evap (use of tn in trasbc.F90)

We therefore need to add the air temperature to the sea-ice, change the definition of emps (now a salt flux), and add the heat content of the mass flux (emp) to the non-solar heat flux. The associated modified modules are : sbcmod.F90 ; sb

  • sbcmod.F90 : initialize emps to zero. The following lines have been added
          emps(:,:) = 0.e0                             ! the salt flux will be computed (i.e. will be non-zero) only if 
          !                                            ! sea-ice is present, or lk_vvl=F, or surface salt restoring is used.
    
  • sbcblk_core.F90 : add in qns the latent flux of solid precipitation + heat content of precip. and evap. In blk_oce_core routine, the following lines
    !CDIR COLLAPSE
          qns(:,:) = zqlw(:,:) - zqsb(:,:) - zqla(:,:)      ! Downward Non Solar flux
    !CDIR COLLAPSE
          emp (:,:) = zevap(:,:) - sf(jp_prec)%fnow(:,:) * rn_pfac * tmask(:,:,1)
    
    becomes
    !CDIR COLLAPSE
          qns(:,:) = zqlw(:,:) - zqsb(:,:) - zqla(:,:)      &                    ! Downward Non Solar flux
             &     - sf(jp_snow)%fnow(:,:) * lfus                                ! including melting of solid precip
    !CDIR COLLAPSE
          emp (:,:) = (  zevap(:,:)                         &                    ! mass flux (evap. - precip.)
             &         - sf(jp_prec)%fnow(:,:) * rn_pfac  ) * tmask(:,:,1)
    !CDIR COLLAPSE
          qns(:,:) = qns(:,:)                                                &   ! heat content due to mass flux (T in Celcius)
             &     - zevap(:,:) * pst(ji,jj) * rcp                           &      ! evaporation at SST
             &     + ( sf(jp_prec)%fnow(:,:) - sf(jp_snow)%fnow(:,:) )       &      ! liquid precip at Tair
             &     * ( sf(jp_tair)%fnow(:,:) - rt0 ) * rcp                   &   
             &     + sf(jp_snow)%fnow(:,:)                                   &      ! solid  precip at min(Tair,Tsnow)
             &     * ( MIN( sf(jp_tair)%fnow(:,:), rt0_snow ) - rt0 ) * cpic 
    
  • sbcblk_clio.F90 : add in qns the latent flux of solid precipitation (only if sea-ice present, otherwise the solid precipitation are not computed) + heat content of precip. and evap. In blk_oce_clio routine, the following lines
    !CDIR COLLAPSE
    !CDIR NOVERRCHK
          DO jj = 1, jpj
    !CDIR NOVERRCHK
             DO ji = 1, jpi
                qns (ji,jj) = zqlw(ji,jj) - zqsb(ji,jj) - zqla(ji,jj)      ! Downward Non Solar flux
                emp (ji,jj) = zqla(ji,jj) / cevap - sf(jp_prec)%fnow(ji,jj) / rday * tmask(ji,jj,1)
             END DO
          END DO
          emps(:,:) = emp(:,:)
    
    becomes
          zcevap = rcp /  cevap    ! convert zqla ==> evap (Kg/m2/s) ==> m/s ==> W/m2
          zcprec = rcp /  rday     ! convert prec ( mm/day ==> m/s)  ==> W/m2
    
    !CDIR COLLAPSE
          qns(:,:) = zqlw(:,:) - zqsb(:,:) - zqla(:,:)                    ! Downward Non Solar flux
    !CDIR COLLAPSE
          emp(:,:) = zqla(:,:) / cevap                                &   ! freshwater flux
             &     - sf(jp_prec)%fnow(:,:) / rday * tmask(:,:,1)
          !                                                               ! add heat content of mass exhanges
    !CDIR COLLAPSE
          qns(:,:) = qns(:,:)                                                 &
             &     - zqla(:,:)             * pst(:,:)              * zcevap   &   ! evaporation at SST in Celcius
             &     + sf(jp_prec)%fnow(:,:) * sf(jp_tair)%fnow(:,:) * zcprec       ! precipitation at Tair in Celcius
          ! NB: if sea-ice model, the snow precip are computed and the associated heat is added to qns (see blk_ice_clio)
    
    and in blk_ice_clio, add the following lines:
          ! ----------------------------------------------------------------------------- !
          !    Correct the OCEAN non solar flux with the existence of solid precipitation !
          ! ---------------=====--------------------------------------------------------- !
    !CDIR COLLAPSE
          qns(:,:) = qns(:,:)                                           &   ! update the non-solar heat flux with:
             &     - p_spr(:,:) * lfus                                                  &   ! melting solid precip
             &     + p_spr(:,:) * MIN( sf(jp_tair)%fnow(:,:), rt0_snow - rt0 ) * cpic   &   ! solid P at least below melting
             &     - p_spr(:,:) * sf(jp_tair)%fnow(:,:)                        * rcp        ! remove solid precip
    
  • sbccpl.F90 : the latent flux of solid precipitation is already taken into account. The heat content of the mass flux [precip. - evap (-runoff) (-calving)] should be added but only over open ocean (the modification does not concern the surface ice fluxes). It is not a simple story. To be perfectly conservative between atmos. and ocean, the atmosphere should provide the heat content associated with the mass flux. This is not done with the current atmospheric component used. Therefore an approximation should be done:

# evaporation : Since the atmosphere has seen the mean SST over the last coupling time interval. This previous SST is the one that should be used to compute the heat content of evaporation. It is not available but can be added to sbcssm module and in its restart. For the moment, we simply use the sst_m field.

# precipitation : as in former forced runs, the temperature of precipitation is assumed to be at the SST: we use sst_m field.

# runoff & calving : use sst_m as we have no better information

In sbc_cpl_rcv routine (ocean-atmos. only), move the emp part before the qns part and add the following lines

         zcoef = xlsn / rhosn                                    ! qns update over free ocean with:
         qns(:,:) = qns(:,:) - frcv(:,:,jpr_snow) * zcoef             ! remove the latent heat flux of melting solid precipitation 
            &                - emp(:,:) * sst_m(:,:) * rcp            ! remove the heat content of mass flux (assumed to be at SST)

In sbc_cpl_ice_flx routine (ocean-atmos-ice), the following lines

      IF( lk_diaar5 )   zcptn(:,:) = rcp * tn(:,:,1)
      ...
      zcoef = xlsn / rhosn
      ztmp(:,:) = p_frld(:,:,1) * zsnow(:,:) * zcoef
      pqns_tot(:,:) = pqns_tot(:,:) - ztmp(:,:)

becomes

      zcptn(:,:) = rcp * sst_m(:,:)
      ...
      zcoef = xlsn / rhosn                                        ! qns_tot update over free ocean with:
      ztmp(:,:) = p_frld(:,:,1) * zsnow(:,:) * zcoef
      pqns_tot(:,:) = pqns_tot(:,:)                       &
         &          - ztmp(:,:)                           &            ! remove the latent heat flux of solid precipitation melting
         &          - (  pemp_tot(:,:)                    &            ! remove the heat content of mass flux (assumed to be at SST)
         &             - pemp_ice(:,:) * p_frld(:,:,1)  ) * zcptn(:,:) 
  • sbcana.F90 ; sbcflx.F90 ; sbcfwb.F90 ; sbcrnf.F90 : add in qns the heat content of the mass flux taken at SST. immediate changes
  • sbcssr : add a change in qns if the SSS restoring is converted into an emp ; update emps as a salt flux is SSS restoring is just a salinity restoring term

(4) Update ocean forcing and ice forcing

see revision 1859 except for LIM-3 (limsbc.F90) updated in revision XXXX

Modification of trasbc and limsbc(_2) modules in order to take into account the above changes (heat content of water exchanges (LIM2) and explicit salt flux (LIM2 & 3) and coupled interface for LIM3)

  • ocean-atmosphere mass exchanges : In the un-approximated case (lk_vvl=T) the ocean receives at its surface (1) a salt flux associate with Freezing and Melting of sea-ice, and (2) a heat flux which includes the budget of the heat content of all mass exchanged with the atmosphere and sea-ice. In the linear free surface case (lk_vvl=F), the model volume of the ocean is assumed to be constant, therefore an extra term appears in both T and S forcing term, the concentration/dilution term : the volume (associated to mass flux) removed or add to the ocean is replaced by a same volume of ocean water at Tn and Sn, so that the model ocean volume remains constant.

trasbc.F90 T and S forcing terms becomes symmetric. The following lines :

      DO jj = 2, jpj
         DO ji = fs_2, fs_jpim1   ! vector opt.
#if ! defined key_zco
            zse3t = 1. / fse3t(ji,jj,1)
#endif
            IF( lk_vvl) THEN
               zta = ro0cpr * qns(ji,jj) * zse3t &                   ! temperature : heat flux
                &    - emp(ji,jj) * zsrau * tn(ji,jj,1)  * zse3t     ! & cooling/heating effet of EMP flux
               zsa = 0.e0                                            ! No salinity concent./dilut. effect
            ELSE
               zta = ro0cpr * qns(ji,jj) * zse3t     ! temperature : heat flux
               zsa = emps(ji,jj) * zsrau * sn(ji,jj,1)   * zse3t     ! salinity :  concent./dilut. effect
            ENDIF
            ta(ji,jj,1) = ta(ji,jj,1) + zta                          ! add the trend to the general tracer trend
            sa(ji,jj,1) = sa(ji,jj,1) + zsa
         END DO
      END DO

becomes

      IF( lk_vvl ) THEN          ! Variable Volume Layers case   ===>> heat content of mass flux in qns
         DO jj = 2, jpj
            DO ji = fs_2, fs_jpim1   ! vector opt.
               z1_e3t_rau0 = 1./ ( fse3t(ji,jj,1) * rau0 )
               ta(ji,jj,1) = ta(ji,jj,1) + z1_e3t_rau0 * qns (ji,jj)  * r1_rcp             ! non solar heat flux
               sa(ji,jj,1) = sa(ji,jj,1) + z1_e3t_rau0 * emps(ji,jj)                       ! salt flux (freezing/melting)
            END DO
         END DO
         !
      ELSE                       ! Constant Volume layers case   ===>> Concentration dillution effect
         DO jj = 2, jpj
            DO ji = fs_2, fs_jpim1   ! vector opt.
               z1_e3t_rau0 = 1./ ( fse3t(ji,jj,1) * rau0 )
               ta(ji,jj,1) = ta(ji,jj,1) + z1_e3t_rau0 * (  qns (ji,jj) * r1_rcp       &   ! non solar heat flux
                  &                                       + emp (ji,jj) * tn(ji,jj,1)  )   ! concent./dilut. effect
               sa(ji,jj,1) = sa(ji,jj,1) + z1_e3t_rau0 * (  emps(ji,jj)                &   ! salt flux (freezing/melting)
                  &                                       + emp (ji,jj) * sn(ji,jj,1)  )   ! concent./dilut. effect
            END DO
         END DO
      ENDIF
  • ocean-ice mass exchanges :

Ice-IF : sbcice_if.F90 : no changes except style as there is no mass flux exchanges in ice-if case.

LIM-2 : limsbc_2.F90 :

.... lot of things....

becomes

            !
            ! - computation the solar flux at ocean surface
#if defined key_coupled 
            zqsr = qsr_tot(ji,jj) + ( fstric(ji,jj) - qsr_ice(ji,jj,1) ) * ( 1.0 - pfrld(ji,jj) )
#else
            zqsr = pfrld(ji,jj) * qsr(ji,jj)  + ( 1.  - pfrld(ji,jj) ) * fstric(ji,jj)
#endif            
            !
            ! - computation the non solar heat flux at ocean surface
            zqns    =  - ( 1. - thcm(ji,jj) ) * zqsr   &   ! part of the solar energy used in leads
               &       + iflt    * ( fscmbq(ji,jj) + ffltbif(ji,jj) )                                &
               &       + ifral   * ( ial * qcmif(ji,jj) + (1 - ial) * qldif(ji,jj) ) * r1_rdt_ice    &
               &       + ifrdv   * (       qfvbq(ji,jj) +             qdtcn(ji,jj) ) * r1_rdt_ice

            ! - store residual heat flux (put in the ocean at the next time-step)
            fsbbq(ji,jj) = ( 1.0 - ( ifvt + iflt ) ) * fscmbq(ji,jj)   ! ???
            !
            ! - heat content of mass exchanged between ocean and sea-ice
            zqhc = ( rdq_snw(ji,jj) + rdq_ice(ji,jj) ) * r1_rdt_ice    ! heat flux due to sown & ice heat content exchanges
            !            
            qsr(ji,jj) = zqsr                                          ! solar heat flux 
            qns(ji,jj) = zqns - fdtcn(ji,jj) + zqhc                    ! non solar heat flux
  
            !                          !------------------------------------------!
            !                          !      mass flux at the ocean surface      !
            !                          !------------------------------------------!
            !
            ! mass flux at the ocean-atmosphere interface (open ocean fraction = leads area)
#if defined key_coupled
            !                                                       ! coupled mode: 
            zemp = + emp_tot(ji,jj)                              &       ! net mass flux over the grid cell (ice+ocean area)
               &   - emp_ice(ji,jj) * ( 1. - pfrld(ji,jj) )              ! minus the mass flux intercepted by sea-ice
#else
            !                                                       ! forced  mode: 
            zemp = + emp(ji,jj)     *         frld(ji,jj)      &         ! mass flux over open ocean fraction 
               &   - tprecip(ji,jj) * ( 1. -  frld(ji,jj) )    &         ! liquid precip. over ice reaches directly the ocean
               &   + sprecip(ji,jj) * ( 1. - pfrld(ji,jj) )    &         ! snow is intercepted by sea-ice (previous frld)
#endif            
            !
            ! mass flux at the ocean/ice interface (sea ice fraction)
            zemp_snw = rdm_snw(ji,jj) * r1_rdt_ice                  ! snow melting = pure water that enters the ocean
            zfmm     = rdm_ice(ji,jj) * r1_rdt_ice                  ! Freezing minus Melting (F-M)

            ! salt flux at the ice/ocean interface (sea ice fraction) [PSU*kg/m2/s]
            zfsalt = - sice_r(ji,jj) * zfmm                         ! F-M salt exchange
            zcd    =   soce_r(ji,jj) * zfmm                         ! concentration/dilution term due to F-M
            !
            ! salt flux only       : add concentration dilution term in salt flux  and no  F-M term in volume flux
            ! salt and mass fluxes : non concentartion dilution term in salt flux  and add F-M term in volume flux
            emps(ji,jj) = zfsalt +                  zswitch  * zcd   ! salt flux (+ C/D if no ice/ocean mass exchange)
            emp (ji,jj) = zemp   + zemp_snw + ( 1.- zswitch) * zfmm  ! mass flux (- F/M mass flux if no ice/ocean mass exchange)
            !

LIM-3 : limsbc.F90 : see revision XXX.

Add soce_r and sice_r as in LIM-2 case

In routine lim_sbc_flx the computation of the heat, salt and mass fluxes has been completely revisited. In particular, the coupled case should be now OK, except for the albedo computation which has to be checked.

The heat flux is now computed as follows: ==⇒>>> CAUTION heat content still not added !

            !
            !==  solar heat flux at ocean surface  ==!   (N.B. use of frld before it changes due to the thermodynanics)
#if defined key_coupled 
            zqsr =                           qsr_tot(ji,jj)                   &   ! total over a cell
               & - ( 1. - pfrld(ji,jj) ) * ( qsr_ice(ji,jj,1) - fstric(ji,jj) )   ! minus the fraction intercepted by ice
#else
            zqsr =        pfrld(ji,jj)   * qsr(ji,jj)                         &   ! fraction over open ocean
               & + ( 1. - pfrld(ji,jj) ) * fstric(ji,jj)                          ! plus the faction passing through the ice
#endif

            fscmbq(ji,jj) = ( 1.0 - pfrld(ji,jj) ) * fstric(ji,jj)           !!gm ???  to be checked
            
            !
            !==  non solar heat flux at ocean surface  ==!
            zqns = - zqsr                                                                     &   ! remove the solar part
               &   + iflt  * ( fscmbq(ji,jj) )                                                &   ! total abl -> fscmbq is given to the ocean
               &   + ifral * ( ial * qcmif(ji,jj) + (1 - ial) * qldif(ji,jj) ) * r1_rdt_ice   &
               &   + ifrdv * (       qfvbq(ji,jj) +             qdtcn(ji,jj) ) * r1_rdt_ice   &
               &   + fhmec(ji,jj)                                                             &   ! snow melt in ridging
               &   + fheat_rpo(ji,jj)                                                         &   ! porous ridged ice formation
               &   + fheat_res(ji,jj)                                                             ! residual heat flux (correction of ice thickness)
            ! fscmbq  Part of the solar radiation transmitted through the ice and going to the ocean computed in limthd_zdf.F90
            ! ffltbif Total heat content of the ice (brine pockets+ice) / delta_t
            ! qcmif   Energy needed to bring the ocean surface layer until its freezing (ok)
            ! qldif   heat balance of the lead (or of the open ocean)
            ! qfvbq   i think this is wrong!  ---> Array used to store energy in case of total lateral ablation
            ! qfvbq latent heat uptake/release after accretion/ablation
            ! qdtcn Energy from the turbulent oceanic heat flux heat flux coming in the lead

            IF( num_sal == 2 )   zqns = zqns + fhbri(ji,jj)   ! brine drainage 

            ! bottom radiative component is sent to the computation of the oceanic heat flux
            !==  store residual heat flux  == ! (put in the ocean at the next time-step)
            fsbbq(ji,jj) = ( 1.0 - ( ifvt + iflt ) ) * fscmbq(ji,jj)     

            !==  heat fluxes at the ocean interface  ==!
            qsr(ji,jj) = zqsr                                       ! solar heat flux 
            qns(ji,jj) = zqns - fdtcn(ji,jj)                        ! non solar heat flux
            !                           ! fdtcn : turbulent oceanic heat flux
!lim2
!            ! - heat content of mass exchanged between ocean and sea-ice
!            zqhc = ( rdq_snw(ji,jj) + rdq_ice(ji,jj) ) * r1_rdt_ice    ! heat flux due to snow & ice heat content exchanges
!            !            
!            qsr(ji,jj) = zqsr                                          ! solar heat flux 
!            qns(ji,jj) = zqns - fdtcn(ji,jj) + zqhc                    ! non solar heat flux
! 
!lim2 

The mass and salt fluxes are now computed as follows:

            !==  mass flux at the ocean-atmosphere interface  ==!   (open ocean fraction = leads area)
#if defined key_coupled
            !                                                         ! coupled mode: 
            zemp =   emp_tot(ji,jj)                                 &    ! net mass flux over the grid cell (ice+ocean area)
               &   - emp_ice(ji,jj) * ( 1. - pfrld(ji,jj) )              ! minus the mass flux intercepted by sea-ice
#else
            !                                                         ! forced  mode: 
            zemp =   emp(ji,jj)     * ( 1.0 - at_i(ji,jj)        )  &    ! mass flux over open ocean fraction 
               &   - tprecip(ji,jj) *         at_i(ji,jj)           &    ! add liquid precip. over ice reaches directly the ocean
               &   + sprecip(ji,jj) * ( 1. - pfrld(ji,jj)**betas )  &    ! remove snow is intercepted by sea-ice (previous frld)
#endif            
            !
            !==  mass flux at the ocean/ice-snow interface  ==!   (sea ice fraction)
            zemp_snw =   rdm_snw(ji,jj) * r1_rdt_ice                &    ! snow melting = pure water that enters the ocean
               &       - fmmec  (ji,jj)                                  ! snow falling when ridging
               !
            zemp_ice = + rdm_ice(ji,jj) * r1_rdt_ice                     ! Freezing minus Melting (F-M)
            !
            !==  salt flux at the ice/ocean interface  ==!   (sea ice fraction) [PSU*kg/m2/s]
            zfsalt =   fsalt_res(ji,jj)            &   ! Residual salt flux due to correction of ice thickness
               &     + fseqv    (ji,jj)            &   ! Equivalent salt flux due to ice growth/melt
               &     + fsbri    (ji,jj) * zinda    &   ! brine drainage 
               &     + fsalt_rpo(ji,jj)                ! porous ridged ice formation
               !
            zcd    =   soce_r(ji,jj)    * zemp_ice     ! concentration/dilution term due to F-M
            !
            !==  total salt and mass fluxes at the ocean interface  ==!
            ! zswitch=1, salt flux only       : add concentration dilution term in salt flux  and no  F-M term in volume flux
            !        =0, salt and mass fluxes : no  concentration dilution term in salt flux  and add F-M term in volume flux
            emps(ji,jj) = zfsalt +                  zswitch  * zcd       ! salt flux (+ C/D if no ice/ocean mass exchange)
            emp (ji,jj) = zemp   + zemp_snw + ( 1.- zswitch) * zemp_ice  ! mass flux (- F/M mass flux if no ice/ocean mass exchange)
            !            
            fsbri(ji,jj) =  zinda * fsbri(ji,jj)       !  correcting brine and salt fluxes (diag.)
            !

(4) change emp and emps names

The emps field is suppress by introducing fsalt, the salt flux at the ocean surface (only non zero below sea-ice)

A symmetric name is chosen for the emp : fmass. Indeed emp is a mass flux expressed in Kg/m2/s. its name emp is miss leading: emp does not only represent the Evaporation minus Precipitation budget, as it also include the freezing or melting of sea-ice, and also sometime the runoff. Therefore using fmass appears more meaningful.

in case of linear free surface (no key_vvl defined), the salt flux take into account the concentration/dilution term

(5) update other parts of the system : C1D_SRC ; NST_SRC ; OFF_SRC ; TOP_SRC …

CAUTION : limsbc_2 : Baltic sea ice salinity changed from 2 PSU to 0.5 PSU !!!! change in limsbc.F90 to be done. Furthermore, only the orca2 case has been coded. All other orca configurations are missing. This should be introduce by a lat/lon definition of the baltic area.

N.B.

  • LIM-3 needs the air temperature … This is related to the heat content change when Melting the fallen snow. Think how to take this in a different way, so that in coupled mode it works !
  • introduce (as was done for sea-ice embedment) the air temperature as an argument of both blk_ice_core and blk_ice_clio routines
  • Philosophical change: in near future it appears that the use of key_vvl should be replaced by key_linssh. In other words, the defaut option of NEMO will be a non-linear free surface (and thus variable volume for the model levels). This has to be discussed prior to its implementation.
  • In the same idea : the embedded sea-ice should become the defaut case, with in option the 2 levitating cases. A test should then force a levitating sea-ice if key_linssh defined
  • Idea for LIM-3 optimisation : instead of 2D ⇒ 1D transformation, is it possible to introduce a 3D (including ice categories) ⇒ 1D transformation. Gain: longer vector so clear in vector computer, less obvious on scalar one, except that the limthd… will become 1 gigantic done loop ⇒ better also for scalar.

CAUTION

  • in coupled mode, the atmosphere and the ocean must share the same latent heat flux of solid precipitation
  • in coupled mode, the atmosphere should provide not only the mass flux [e-p(-runoff)(-calvin)] but also the heat content associated with this mass flux computed with a temperature in Celcius.

Testing

Testing could consider (where appropriate) other configurations in addition to NVTK].

NVTK Tested'''YES/NO'''
Other model configurations'''YES/NO'''
Processor configurations tested[ Enter processor configs tested here ]
If adding new functionality please confirm that the
New code doesn't change results when it is switched off
and ''works'' when switched on
'''YES/NO/NA'''

(Answering UNSURE is likely to generate further questions from reviewers.)

'Please add further summary details here'

  • Processor configurations tested
  • etc——

Bit Comparability

Does this change preserve answers in your tested standard configurations (to the last bit) ?'''YES/NO '''
Does this change bit compare across various processor configurations. (1xM, Nx1 and MxN are recommended)'''YES/NO'''
Is this change expected to preserve answers in all possible model configurations?'''YES/NO'''
Is this change expected to preserve all diagnostics?
,,''Preserving answers in model runs does not necessarily imply preserved diagnostics. ''
'''YES/NO'''

If you answered '''NO''' to any of the above, please provide further details:

  • Which routine(s) are causing the difference?
  • Why the changes are not protected by a logical switch or new section-version
  • What is needed to achieve regression with the previous model release (e.g. a regression branch, hand-edits etc). If this is not possible, explain why not.
  • What do you expect to see occur in the test harness jobs?
  • Which diagnostics have you altered and why have they changed?Please add details here……..

System Changes

Does your change alter namelists?'''YES/NO '''
Does your change require a change in compiler options?'''YES/NO '''

If any of these apply, please document the changes required here…….


Resources

''Please ''summarize'' any changes in runtime or memory use caused by this change……''


IPR issues

Has the code been wholly (100%) produced by NEMO developers staff working exclusively on NEMO?'''YES/ NO '''

If No:

  • Identify the collaboration agreement details
  • Ensure the code routine header is in accordance with the agreement, (Copyright/Redistribution? etc).Add further details here if required……….