source: obsdata/trunk/ourplugins/cr_radiosondage_tvd.pl @ 298

#!/usr/bin/perl -c

# $Id: cr_radiosondage_tvd.pl thetis $

# aa_nnnnn.ret  -->  tvdaammjj.hhmmxx
#
# règle de renommage du fichier :
# ***************************** 
#       - ouvrir en lecture le fichier issu de la décompression qui s'appelle aa_nnnnn.ret 
#       - lire les 9 premières lignes
#       - lire la 10ième ligne qui commence en principe par la lettre a (minuscule)
#       - faire un test pour vérifier que la première est bien un a pour continuer
#       (boucle de test sur a pour pouvoir faire la suite)
#       - récupérer de cette ligne les éléments suivants : 16, 17,18,19,20.
#       (ils sont à chaque fois séparés par un blanc)
#       16 correspond aux minutes mm
#       17 correspond à l'heure   hh
#       18 correspond au jour     jj
#       19 correspond au mois     mm
#       20 correspond à l'année   aa
#       Pour composer le nom définitif, il faut ABSOLUMENT que aa, mm, jj, hh, mm soient
#       sur 2 positions donc il faut penser à complémenter avec un 0 (zéro devant) si ce qui est lu 
#       dans la ligne est sur une position (cf exemple).
#       Le nom définitif commence SYSTEMATIQUEMENT par tvd et s'écrit comme suit :
#       tvdaammjj.hhmmxx .
#
# exemple :
# *******
# réception des fichiers DDU du 30/08/06, après décompression, 
# obtention de la liste des radiosondages suivants : 
# 06_16406.ret
# 06_16407.ret 
# 06_16408.ret
# 06_16409.ret
# 06_16410.ret
# 06_16411.ret
# 06_16412.ret
# 06_16413.ret
# Considérons le fichier 06_16406.ret dont voici les 10 premières lignes :
# 1 V 10.1
# 2 A 8/6/16413 1 5 N
# 3 d 9990 9990 999
# 4 n
# 5 b C:\RS\RAW\P6082823.RAW
# 6 m 10.0  3
# 7 c
# 8 s 3  3
# 9 t   356
#10 a 9746 -221 85 140 45 -6665 14000 3 0 40 1 1 1 1 22 23 28  8  6 15700 89642
#
#les éléments 16, 17,18,19,20 sont 22 23 28  8  6 soient :
# 22 pour les minutes,
# 23 pour les heures,
# 28 pour le jour,
# 8 pour le mois (il faudra complémenter à 0), donc 08,
# 6 pour l'année (il faudra complémenter à 0), donc 06.
# Le nom du fichier sera donc : tvd060828.2322xx

use strict;

sub {
    my ($rda, $plugintype, $datafile, $datatype) = @_;

    $datafile =~ /\d\d_\d{4}\.ret$/i or return;

    my $archive = $rda->archive() or do {
        $rda->logging(4,
            'Can get archive'
        );
        return;
    };

    my $filename = $archive->extract($datafile) or do {
        $rda->logging(4,
            "Can't get temporary file: %s",
            $archive->error || "",
        );
        return(0);
    };

    my $resopen = open(my $handle, "<", $filename);

    unlink($filename);

    if (!$resopen) {
        $rda->logging(4,
            "Can't open temp file %s",
            $filename,
        );
        return(0);
    }


    # ripping 10 lines
    # <$handle> foreach (1..9); seems useless to read first 10 lines no ?
    # just search line begining by 'a' ?
    while (my $line = <$handle>) {
        $line =~ /^a / or next;
        chomp($line);
        my @val = split(/\s+/, $line);
        my %to_ret = ();
        my $idx = 15; # 16 but start at 0
        foreach (qw(minute heure jour mois annee)) {
            $to_ret{$_} = $val[$idx];
            $idx++;
        }
        return(1, %to_ret);
    }

    $rda->logging(0, "EOF of %s reached w/o having found date/time line", $datafile );
    close($handle);

    # not found at EOF
    return(0);
}