source: trunk/soft/ObsData/ObsData/Event.pm @ 167

# $Id$

use strict;
use warnings;

package ObsData::Event;

=head1 NAME

ObsData::Event - A simple class to manage message between backend
and main software.

=head1 SYNOPSIS

    my $callback = sub {
        my ($events) = @_;
        print $events->message . "\n";
    }

    my $oe = ObsData::Event->new('id', 'what should I do');

    $callback($oe);

=head1 METHODS

=head2 new($id $message)

Create a new ObsData::Event object to handle $message with $id

=cut

sub new {
    my ($class, $id, $message) = @_;
    
    if(!($id && $message)) {
        return undef;
    }
    
    bless(
        {
            id => $id,
            message => $message,
            test => {},
            test_order => [],
        },
        $class
    );
}

=head2 id

Return the id of the object

=cut

sub id {
    my ($self) = @_;
    return($self->{id});
}

=head2 message

Return the message handle by the object

=cut

sub message {
    my ($self) = @_;
    return($self->{message});
}

=head2 add_test($test_id, $message, $result)

Add a new test into the object.

=cut

sub add_test {
    my ($self, $test_id, $message, $result) = @_;
    if (!exists($self->{test}{$test_id})) {
        push(@{$self->{test_order}}, $test_id);
    }
    $self->{test}{$test_id}{message} ||= $message;
    $self->{test}{$test_id}{result} = $result;
}

=head2 list_test

List test currently stored into the object. Return the list of test id.

=cut

sub list_test {
    my ($self) = @_;
    return(@{$self->{test_order}});
}

=head2 test_message($test_id)

Return the message associated to a test.

=cut

sub test_message {
    my ($self, $test_id) = @_;
    return($self->{test}{$test_id}{message});
}

=head2 test_result($test_id)

Return the result associated to a test

=cut

sub test_result {
    my ($self, $test_id) = @_;
    return($self->{test}{$test_id}{result});
}

1;

__END__

=head1 AUTHOR

Olivier Thauvin <olivier.thauvin@aerov.jussieu.fr>

=cut