source: trunk/soft/ObsData/bin/obsdata @ 211

#!/usr/bin/perl

# $Id$

=head1 NAME

obsdata - Find, sort and dispatch data files

=head1 VERSION

CVS: $Revision$

=cut

use strict;
use warnings;
use ObsData;
use Getopt::Long;
use Pod::Usage;

my $verbose = 2;

GetOptions(
    'c|config=s' => \my $configfile,
    'check' => \my $check_only,
    'dry-run' => \my $dryrun,
    'l|logfile=s' => \my $log,
    'debug' => sub { $verbose = 0 },
    'v|verbose' => sub { $verbose-- },
    'h|help' => sub { pod2usage(-exitval => 0) },
    'i' => \my $interactif,
    'only-new' => \my $onlynew,
    'only-old' => \my $onlyold,
) or pod2usage();

=head1 SYNOPSIS

    obsdata -c config_file [[-l logfile] [-d] [-v|--debug]] [--check]
    obsdata [-h|-help]

=head1 OPTIONS

=over 4

=item -c|--config config-file

Use this configuration file

=item --check

Only check config file and exit

=item -l|--logfile logfile

Write all messages into this file

=item -v|--verbose

Increase verbosity (this does not affect log output)

=item --dry-run

Does everything except write on disk, log are filled anyway

=item --debug

Increase verbosity to debug level (does same things than -v -v -v)

=item -h|--help

Print short help message

=back

=cut

sub sub_interactive {
    my ($oa, $oe) = @_;
    for ($oe->id) {
        /^do_archive$/ and do {
            if ($onlyold && !$oe->test_result('archive_exists')) {
                return 0;
            }
            if($onlynew && $oe->test_result('archive_exists')) {
                return 0
            }
        };
        /^overwrite$/ && !$oe->test_result('dest_exists') and return 1;
    }
    print $oe->message ."\n";
    foreach ($oe->list_test) {
        printf("\t%s\n", $oe->test_message($_));
    }
    print "Processing ? Y/n: ";
    my $res = <STDIN>;
    chomp($res);
    return($res =~ /^[Yy]$/ ? 1 : 0);
}

my $obsdata = ObsData->new(
    $configfile,
    logfile => $log,
    verbose => 0,
    dry_run => $dryrun,
    logcallback => sub {
        return if($_[0] < $verbose);
        printf("%-9s %s\n", sprintf("[%s]", ObsData::loglevel($_[0])), $_[1]);
    },
    interactive_callback => $interactif ? \&sub_interactive : undef,
) or do {
    warn "Can't create obsdata object\n";
    pod2usage()
};

$obsdata->load or die "Can load osbdata";
my $checkres = $obsdata->checkconfig or die "Error while checking configuration";
exit(0) if ($check_only);

my @obs = $obsdata->list_obs;
my @datatype = ();

foreach my $o (@obs) {
    my %datadir = $obsdata->list_obsdatadir($o);
    foreach my $d (keys %datadir) {
        if(@datatype && !grep { $_ eq $d } @datatype) {
            next;
        }
        my $dir = $obsdata->get_obs_data_handle($o, $d) or next;
        $dir->process;
    }
}

my $s = $obsdata->generated_reported();



=head1 AUTHOR

Olivier Thauvin <olivier.thauvin@aerov.jussieu.fr>

=cut