source: trunk/src/file_asc_p2l2_to_mem.pro @ 2

;+
;
; ========================
; file_asc_p2l2_to_mem.pro
; ========================
;
; .. function:: file_asc_p2l2_to_mem(filename)
;
;    Read long station information files and store data in a structure
;
;    :param filename: filename to be read
;    :type filename: string
;    :raise filename: required
;
;    :returns: data structure +todo+ details or -1 if error
;    :rtype: structure +todo+ details
;
; notes
; decalage 
; xx
;
; :examples:
;
; ::
;
;    IDL> filename='/usr/work/incas/fplod/pomme_d/sta.P2L2.asc'
;    IDL> result=file_asc_p2l2_to_mem(filename)
;
; impression de contrôle : 1re station, toutes les stations::
;
;    IDL> help, result,/structure
;    IDL> print, result[0].station
;    IDL> print, result.station
;
; :uses:
;
; :func:`report`
;
; :restrictions:
;
; :todo:
;
; format fixe
;
; test existence of filename
;
; usage of ${POMME_ID}
;
; :history:
;
; - fplod 20101123T122132Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * creation using "Reading Into a Structure" of
;     http://www.dfanning.com/tips/ascii_column_data.html
;
;
; :version:
;
; $Id$
;
;-
FUNCTION file_asc_p2l2_to_mem, filename
;
compile_opt idl2, strictarrsubs
;
; Return to caller if errors
ON_ERROR, 2
;
usage = 'result=file_asc_p2l2_to_mem(filename)'
;
nparam = N_PARAMS()
IF (nparam LT 1) THEN BEGIN
   ras = report(['Incorrect number of arguments.' $
         + '!C' $
         + 'Usage : ' + usage])
   return, -1
ENDIF
;
arg_type = size(filename,/type)
IF (arg_type NE 7) THEN BEGIN
   ras = report(['Incorrect arg type filename' $
         + '!C' $
         + 'Usage : ' + usage])
   return, -1
ENDIF
;
arg_dim =  size(filename,/n_elements)
IF (arg_dim LT 1) THEN BEGIN
   ras = report(['Incorrect arg dimension filename' $
         + '!C' $
         + 'Usage : ' + usage])
  return, -1
ENDIF
;
; initialize header
header = STRARR(1)
;
resultstruct = { station: 0L $
                , sonde: 0L $
                , zmax: 0L $
                , an: 0L $
                , mm: 0L $
                , jj: 0L $
                , hh_begin: 0L $
                , mm_begin: 0L $
                , deg_lat_begin : 0L $
                , mm_lat_begin: 0.0 $
                , deg_lon_begin: 0L $
                , mm_lon_begin: 0.0 $
                , hh_end: 0L $
                , mm_end: 0L $
                , deg_lat_end: 0L $
                , mm_lat_end: 0.0 $
                , deg_lon_end: 0L $
                , mm_lon_end: 0.0 $
                }
;
nrows = file_lines(filename) - N_ELEMENTS(header)
result = Replicate(resultstruct, nrows)
;
; open file
OPENR, lun, filename, /GET_LUN
;++ hanlde error
;
; read header
READF, lun, header
;
; read data lines
READF, lun, result
;
; close file
FREE_LUN, lun
;
return, result
;
END