source: trunk/src/join_dmean_asc.pro @ 5

;+
;
; ==================
; join_dmean_asc.pro
; ==================
;
; .. function:: join_dmean_asc(data_dmean,data_asc)
;
;    Join information from mean (++details) and asc (++detail) structures
;
;    If station is not found in data_asc structure, latitude and longitude are set
;    to NaN.
;
;    :param data_dmean: structure ++details
;    :type data_dmean: structure
;    :raise data_dmean: required
;
;    :param data_asc: structure ++details
;    :type data_asc: structure
;    :raise data_asc: required
;
;    :returns: data structure +todo+ details or -1 if error
;    :rtype: structure +todo+ details
;
; :examples:
;
; Realistic example with POMME files::
;
;    IDL> data_asc=file_asc_to_mem()
;    IDL> data_prn=file_prn_to_mem()
;    IDL> data_dmean=dmean_mld(data_prn)
;    IDL> data_insitu=join_dmean_asc(data_dmean,data_asc)
;
; impression de controle ::
;
;    IDL> help, data_insitu, /structure
;    IDL> print, data_insitu[0]
;    IDL> print, data_insitu.lat
;    IDL> print, data_insitu.lon
;
; :uses:
;
;
; :func:`report`
;
; :see also:
;
; :func:`file_prn_to_mem`
; :func:`file_asc_to_mem`
; :func:`dmean_mld`
;
; :restrictions:
;
; :todo:
;
; test arguments
;
; missing values
;
; usage of report
;
; init returned structure to NaN vs 0L or 0.0
;
; check doy in prn files vs computed julianday
; now (20101124) differences due to either bad calculation here or bad doy calculion in .prn file or difference choice between begin, end, middle time.
;
; :history:
;
; - fplod 20101129T133140Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * correction for NaN
;   * suppression print controle
;
; - fplod 20101129T091703Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * input data_dmean instead of data_prn
;
; - fplod 20101126T153732Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * input = structures no more files
;
; - fplod 20101123T154451Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * creation
;
; :version:
;
; $Id$
;
;-
FUNCTION join_dmean_asc, data_dmean, data_asc
;
compile_opt idl2, strictarrsubs
;
; Return to caller if errors
ON_ERROR, 2
;
usage = 'result=join_dmean_asc(data_asc,data_dmean)'
;
nparam = N_PARAMS()
IF (nparam LT 2) THEN BEGIN
   ras = report(['Incorrect number of arguments.' $
         + '!C' $
         + 'Usage : ' + usage])
   return, -1
ENDIF
;
; initialize returned structure
resultstruct = { doy : 0L $
             , lat: 0.0 $
             , lon: 0.0 $
             , mean_zhom001: 0.0 $
             , mean_zhom002 : 0.0 $
             , mean_zhom005 : 0.0 $
             , mean_zhom010: 0.0 $
             , mean_zhomelch : 0.0 $
             , std_zhom001: 0.0 $
             , std_zhom002 : 0.0 $
             , std_zhom005 : 0.0 $
             , std_zhom010: 0.0 $
             , std_zhomelch : 0.0 $
             }
;
ndays = n_elements(data_dmean)
result = replicate(resultstruct, ndays)
;
; fill returned structure
FOR iday=0L, ndays -1 DO BEGIN
   result[iday].doy=data_dmean[iday].doy
   result[iday].mean_zhom001=data_dmean[iday].mean_zhom001
   result[iday].mean_zhom002=data_dmean[iday].mean_zhom002
   result[iday].mean_zhom005=data_dmean[iday].mean_zhom005
   result[iday].mean_zhom010=data_dmean[iday].mean_zhom010
   result[iday].mean_zhomelch=data_dmean[iday].mean_zhomelch
   result[iday].std_zhom001=data_dmean[iday].std_zhom001
   result[iday].std_zhom002=data_dmean[iday].std_zhom002
   result[iday].std_zhom005=data_dmean[iday].std_zhom005
   result[iday].std_zhom010=data_dmean[iday].std_zhom010
   result[iday].std_zhomelch=data_dmean[iday].std_zhomelch
   indice_asc=WHERE(data_asc.station EQ data_dmean[iday].first_station,count)
   IF (count EQ 0) THEN BEGIN
      print, 'no station ',  data_dmean[iday].first_station,' in data_asc.station'
      result[iday].lat = !VALUES.F_NAN
      result[iday].lon = !VALUES.F_NAN
   ENDIF ELSE BEGIN
      ;print, 'indice de la first_station', data_dmean[iday].first_station,' dans data_asc = ',indice_asc
      result[iday].lat = data_asc[indice_asc[0]].lat
      result[iday].lon = data_asc[indice_asc[0]].lon
   ENDELSE
ENDFOR
;
return, result
;
END