source: trunk/procs/macros/make_energetics.pro @ 203

Last change on this file since 203 was 203, checked in by pinsard, 14 years ago

remove trailing blanks
  • Property svn:keywords set to Id
File size: 16.8 KB
Line 
1;+
2;
3; make energetics computations
4;
5; @param FILE_NAME {in}{required}{type=string}
6;
7; @param NCDF_DB {in}{required}{type=string}
8; <location>:<path> or just <path>
9;
10; @keyword BOXZOOM
11;
12; @keyword TIME_1
13;
14; @keyword TIME_2
15;
16; @keyword ALL_DATA
17;
18; @keyword ZMTYP
19;
20; @returns
21; structure
22; -1 in case of error
23
24; @uses
25; <pro>common</pro>
26; <propost_it>com_eg</propost_it>
27;
28; @history
29; - fplod 20100119T094252Z aedon.locean-ipsl.upmc.fr (Darwin)
30;
31;   * check parameters
32;
33; @version
34; $Id$
35;
36;-
37FUNCTION make_energetics, file_name, ncdf_db $
38         , BOXZOOM=boxzoom $
39         , TIME_1=time_1 $
40         , TIME_2=time_2 $
41         , ALL_DATA=all_data $
42         , ZMTYP=zmtyp
43;
44  compile_opt idl2, strictarrsubs
45;
46@common
47@com_eg
48;
49   IF debug_w THEN BEGIN
50    info = report('enter ...')
51    print, 'cmd_wrk.grid =', cmd_wrk.grid
52   ENDIF
53;
54 usage='result=make_energetics(file_name, ncdf_db ' $
55         + ', BOXZOOM=boxzoom ' $
56         + ', TIME_1=time_1 ' $
57         + ', TIME_2=time_2 ' $
58         + ', ALL_DATA=all_data ' $
59         + ', ZMTYP=zmtyp)'
60
61 nparam = N_PARAMS()
62 IF (nparam LT 2) THEN BEGIN
63    ras = report(['Incorrect number of arguments.' $
64          + '!C' $
65          + 'Usage : ' + usage])
66    return, -1
67 ENDIF
68
69 arg_type = size(file_name,/type)
70 IF (arg_type NE 7) THEN BEGIN
71   ras = report(['Incorrect arg type file_name' $
72          + '!C' $
73          + 'Usage : ' + usage])
74   return, -1
75 ENDIF
76
77 arg_type = size(ncdf_db,/type)
78 IF (arg_type NE 7) THEN BEGIN
79   ras = report(['Incorrect arg type ncdf_db' $
80          + '!C' $
81          + 'Usage : ' + usage])
82   return, -1
83 ENDIF
84
85CASE cmd_wrk.grid OF
86   'T': source_model = 'opa'
87   'T#': source_model = 'opa#'
88   'T05': source_model = 'opa'
89   'T05#': source_model = 'opa#'
90   ELSE: source_model = 'ipcc'
91ENDCASE
92
93;; full vertical domain
94;; imposes vert_type = '0' in plt_def
95vert_switch = 0
96IF debug_w THEN BEGIN
97   print, 'base_file_name:', base_file_name
98   print, 'file_name:', file_name
99ENDIF
100;
101; Read T, S, U, V, W, taux, tauy
102;
103   print, '    Data size to read (M)= ', nxt*nyt*jpt*(5*nzt + 2)*1.e-6
104
105CASE source_model OF
106   'opa': BEGIN
107      tn = nc_read(file_name,'votemper', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
108      sn = nc_read(file_name,'vosaline', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
109      IF data_domain EQ 'pacific' THEN BEGIN
110         file_namu = strmid(file_name, 0, strlen(file_name)-8)+'U_pac.nc'
111         file_namv = strmid(file_name, 0, strlen(file_name)-8)+'V_pac.nc'
112         file_namw = strmid(file_name, 0, strlen(file_name)-8)+'W_pac.nc'
113      ENDIF ELSE BEGIN
114         file_namu = strmid(file_name, 0, strlen(file_name)-4)+'U.nc'
115         file_namv = strmid(file_name, 0, strlen(file_name)-4)+'V.nc'
116         file_namw = strmid(file_name, 0, strlen(file_name)-4)+'W.nc'
117      ENDELSE
118      un = nc_read(file_namu,'vozocrtx', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
119      vn = nc_read(file_namv,'vomecrty', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
120      wn = nc_read(file_namw,'vovecrtz', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
121      tauxn = nc_read(file_namu,'sozotaux', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
122      tauyn = nc_read(file_namv,'sometauy', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
123      var_temp = 'votemper'
124      file_temp = file_name
125   END
126   'opa#': BEGIN
127      tn = nc_read(file_name,'votemper', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
128      IF data_domain EQ 'pacific' THEN BEGIN
129         file_nams = strmid(file_name, 0, strlen(file_name)-17)+'T_pac_vosaline.nc'
130         file_namu = strmid(file_name, 0, strlen(file_name)-17)+'U_pac_vozocrtx.nc'
131         file_namv = strmid(file_name, 0, strlen(file_name)-17)+'V_pac_vomecrty.nc'
132         file_namw = strmid(file_name, 0, strlen(file_name)-17)+'W_pac_vovecrtz.nc'
133         file_namsu = strmid(file_name, 0, strlen(file_name)-17)+'U_pac_sozotaux.nc'
134         file_namsv = strmid(file_name, 0, strlen(file_name)-17)+'V_pac_sometauy.nc'
135      ENDIF ELSE BEGIN
136         file_nams = strmid(file_name, 0, strlen(file_name)-13)+'T_vosaline.nc'
137         file_namu = strmid(file_name, 0, strlen(file_name)-13)+'U_vozocrtx.nc'
138         file_namv = strmid(file_name, 0, strlen(file_name)-13)+'V_vomecrty.nc'
139         file_namw = strmid(file_name, 0, strlen(file_name)-13)+'W_vovecrtz.nc'
140         file_namsu = strmid(file_name, 0, strlen(file_name)-13)+'U_sozotaux.nc'
141         file_namsv = strmid(file_name, 0, strlen(file_name)-13)+'V_sometauy.nc'
142      ENDELSE
143      sn = nc_read(file_nams,'vosaline', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
144      un = nc_read(file_namu,'vozocrtx', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
145      vn = nc_read(file_namv,'vomecrty', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
146      wn = nc_read(file_namw,'vovecrtz', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
147      tauxn = nc_read(file_namsu,'sozotaux', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
148      tauyn = nc_read(file_namsv,'sometauy', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
149      var_temp = 'votemper'
150      file_temp = file_name
151      source_model = 'opa'
152   END
153   'ipcc': BEGIN
154      base_file_name_grd = base_file_name+base_suffix
155      tn = nc_read(base_file_name_grd+'_thetao.nc','thetao', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
156      sn = nc_read(base_file_name_grd+'_so.nc','so', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
157      un = nc_read(base_file_name_grd+'_uo.nc','uo', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
158      vn = nc_read(base_file_name_grd+'_vo.nc','vo', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
159      wn = nc_read(base_file_name_grd+'_wo.nc','wo', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
160      tauxn = nc_read(base_file_name_grd+'_tauu.nc','tauu', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
161      tauyn = nc_read(base_file_name_grd+'_tauv.nc','tauv', ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1, TIME_2 = time_2)
162      var_temp = 'thetao'
163      file_temp = base_file_name_grd+'_thetao.nc'
164   END
165ENDCASE
166
167t_unit = tn.units
168
169; assign and free memory
170
171   t = tn.data & tn = 0
172   s = sn.data & sn = 0
173   u = un.data & un = 0
174   v = vn.data & vn = 0
175   w = wn.data & wn = 0
176   tx = tauxn.data & tauxn = 0
177   ty = tauyn.data & tauyn = 0
178
179   rg = 9.81
180
181   print, '     read ok'
182
183; rearrange data depending on source
184
185CASE source_model OF
186   'opa': BEGIN
187      ; build mask
188      IF valmask EQ 0. THEN BEGIN
189         tmaskr = abs(s) gt 1.e-6
190         valmask = 1.e20
191         idxw = where (tmaskr EQ 0)
192         IF idxw[0] NE -1 THEN w[idxw] = valmask
193         idxt = where (tmaskr EQ 0)
194         IF idxt[0] NE -1 THEN t [idxt] = 0.
195         IF idxt[0] NE -1 THEN s [idxt] = 0.
196         tmaskr = 0 ; free memory
197      ENDIF ELSE BEGIN
198         idxt = where (t EQ valmask)
199         IF idxt[0] NE -1 THEN t [idxt] = 0.
200         IF idxt[0] NE -1 THEN s [idxt] = 0.
201      ENDELSE
202
203      ; transform W fields onto T grid
204      maskw = w LT valmask/10.
205      w_T = 0.5*( w*maskw + shift(w, 0, 0, -1, 0)*shift(maskw, 0, 0, -1, 0) )
206      w_T[*, *, (size(w))[3]-1, *] = w_T[*, *, (size(w))[3]-2, *]
207      w = 0
208      maskw = 0  ; free memory
209
210   END
211   'ipcc': BEGIN
212      idx_t = where (t GT valmask/10)
213      ; special case CCCMA
214      IF strpos(cmd_wrk.exp, 'CCCMA') NE -1 THEN BEGIN
215         ; transform W fields onto T grid
216         maskw = w LT valmask/10.
217         w_T = 0.5*( w*maskw + shift(w, 0, 0, -1, 0)*shift(maskw, 0, 0, -1, 0) )
218         w_T[*, *, (size(w))[3]-1, *] = w_T[*, *, (size(w))[3]-2, *]
219         w = 0
220         w_T[idx_t] = valmask
221         maskw = 0 ; free memory
222      ENDIF ELSE w_T = w
223
224      idx_2d = where (u[*, *, 0, 0] GT valmask/10.)
225      IF idx_2d[0] NE -1 THEN tx[idx_2d] = valmask
226      idx_2d = where (v[*, *, 0, 0] GT valmask/10.)
227      IF idx_2d[0] NE -1 THEN ty[idx_2d] = valmask
228      idx = where (t LT valmask/10.)
229      IF t_unit NE "C" THEN BEGIN
230         IF idx[0] NE -1 THEN t[idx] = t[idx]-273.15
231      ENDIF
232      idx1 = n_elements(idx_t)
233      idx_w = where (w_T GT valmask/10)
234      idx2 = n_elements(idx_w)
235      IF idx1 NE idx2 THEN BEGIN
236         print, ' *** WARNING wo and thetao do not have same masks !', idx1, idx2, min(idx_t -idx_w), max(idx_t- idx_w)
237         print, ' *** Setting wo to zero on all masked points'
238         w_T[idx_w] = 0.
239      ENDIF ELSE print, '       check these are 0 (W,T): ', min(idx_t -idx_w), max(idx_t- idx_w)
240      w = 0 & idx = 0 & idx_t = 0 & idx_w = 0 ; free memory
241      idxt=where(t GT valmask/10.)
242      idxs=where(s GT valmask/10.)
243      IF source_model EQ 'ipcc' THEN print, '       check these are 0 (T,S): ', min(idxt -idxs), max(idxt-idxs)
244      IF idxt[0] NE -1 THEN t[idxt]=0.
245      IF idxs[0] NE -1 THEN s[idxs]=0.
246      idxs = 0                  ; free memory
247
248   END
249ENDCASE
250
251
252; compute potential density rho
253
254   print, '     compute rho...'
255
256
257   sr=sqrt(abs(s))
258   r1=((((6.536332E-9*t-1.120083E-6)*t+1.001685E-4)*t $
259        -9.095290E-3)*t+6.793952E-2)*t+999.842594
260   r2=(((5.3875E-9*t-8.2467E-7)*t+7.6438E-5)*t-4.0899E-3)*t+8.24493E-1
261   r3=(-1.6546E-6*t+1.0227E-4)*t-5.72466E-3
262   rhop = ( ( 4.8314E-4*s + r3*sr +r2)*s +r1)
263   print, '      rhop min/max', min(rhop), max(rhop)
264   IF idxt[0] NE -1 THEN rhop[idxt] = valmask
265   sr = 0 & r1 = 0 &  r2 = 0 &  r3 = 0 & t = 0 & s = 0 ; free memory
266
267; compute mean profiles on T grid
268
269   vargrid = 'T'
270   IF valmask NE 0 THEN BEGIN
271      rho_s = grossemoyenne(rhop, 'xyt', boite = zbox, NAN = valmask)
272   ENDIF ELSE rho_s = grossemoyenne(rhop, 'xyt', boite = zbox)
273
274   rho_s4d = replicate(1, nxt*nyt)#rho_s
275   rho_s4d = reform(rho_s4d[*]#replicate(1, jpt), nxt, nyt, nzt, jpt, /overwrite)
276
277
278; compute mean stability = d(rho_s)/dz (on W grid)
279
280   rho_diff = (rho_s-shift(rho_s,-1))/shift(e3w, -1)
281   rho_diff = shift(temporary(rho_diff), 1)
282   rho_diff[0] = 0.
283
284; transform onto T grid
285
286   rho_diff_T = 0.5*(rho_diff+shift(rho_diff, -1))
287   rho_diff_T[(size(rho_diff))[1]-1] = rho_diff[(size(rho_diff))[1]-2]
288
289   stab_inv = ABS(1./rho_diff_T)
290
291   rho_diff_T = 0 ; free memory
292
293; remove first 2 levels (MXL too unstable)
294
295   stab_inv[0:1] = 0.
296
297; test: remove only top level
298
299;   stab_inv[0:0] = 0.
300
301; compute [(rho-rho_s)**2]/stability
302
303   stab_inv = replicate(1, nxt*nyt)#stab_inv
304   stab_inv = reform(stab_inv[*]#replicate(1, jpt), nxt, nyt, nzt, jpt, /overwrite)
305
306   int_val2 = ((rhop-rho_s4d)^2)*stab_inv
307   IF idxt[0] NE -1 THEN int_val2[idxt] = 0.
308
309   print, '     compute APE...'
310
311   ape = 0.5*rg*grossemoyenne(int_val2, 'xyz', /integration)
312
313   int_val2 = 0 ; free memory
314
315   ape_wr = ape
316   ape = ape*1.e-18
317;
318; compute buoyancy forcing bfx = int[(rho-rho_s).w]dxdydz
319;
320   print, '     compute BF...'
321
322   int_val = (rhop-rho_s4d)*(w_T)
323   IF idxt[0] NE -1 THEN int_val[idxt] = 0.
324
325; remove first 2 levels (MXL too unstable)
326   int_val[*, *, 0:1, *] = 0.
327
328   bfx = rg*grossemoyenne(int_val, 'xyz', /integration)
329
330   int_val = 0 ; free memory
331
332   bfx_wr = bfx
333   bfx_b = bfx
334   bfx = bfx*1.e-11
335
336; compute wind work = int(tau.um)dx.dy where um=u(over 30 m)
337
338   print, '     compute WW...'
339
340   umean=grossemoyenne(u,'z',boite=[0,30])
341   vmean=grossemoyenne(v,'z',boite=[0,30])
342;   umean=grossemoyenne(u,'z',boite=[0,10])
343;   vmean=grossemoyenne(v,'z',boite=[0,10])
344
345   idx = where(tx GT valmask/10.)
346   idy = where(ty GT valmask/10.)
347   idxu = where(umean GT valmask/10.)
348   idyv = where(vmean GT valmask/10.)
349
350   IF idx[0] NE -1 THEN tx[idx] = 0.
351   IF idy[0] NE -1 THEN ty[idy] = 0.
352   IF idxu[0] NE -1 THEN umean[idxu] = 0.
353   IF idyv[0] NE -1 THEN vmean[idyv] = 0.
354
355   dot_prodx = tx*umean
356   dot_prody = ty*vmean
357
358   wwx = grossemoyenne(dot_prodx, 'xy', /integration)
359   wwy = grossemoyenne(dot_prody, 'xy', /integration)
360   ww = wwx + wwy
361
362   ww_wr = ww
363   ww_b = ww
364   ww = ww*1.e-11
365   wwx = wwx*1.e-11
366   wwy = wwy*1.e-11
367
368; compute forcing efficiency: stddev(B)/stddev(W)
369
370   bfx_1mm = trends(bfx_b, 412, 't')
371   bfx_sc = mean_sc
372   ww_1mm = trends(ww_b, 412, 't')
373   ww_sc = mean_sc
374   efficiency = sqrt((moment(bfx_1mm))[1])/sqrt((moment(ww_1mm))[1])
375   efficiency_sc = sqrt((moment(bfx_sc[0:11]))[1])/sqrt((moment(ww_sc[0:11]))[1])
376
377; plotting stuff
378
379   ps = 0
380
381   red = [0, 255,   0,   0, 0, 255]
382   green = [0,   0, 255,   0, 0,   0]
383   blue = [0,   0,   0, 255, 0, 255]
384   red = [0, red, red, red, red, red, red, red ]
385   green = [0, green, green, green, green, green, green, green]
386   blue = [0, blue, blue, blue, blue, blue, blue, blue ]
387   tvlct, red, green, blue
388
389   IF cmd_wrk.out EQ 'ps' THEN ps = 1
390
391   IF ps EQ 1 THEN openps
392
393   pltt, ape, 't', petit = [2, 4, 1], landscape = 1, /rempli, /BASICMARGES, title = 'APE (full) '+cmd_wrk.exp, window=3
394   pltt, ww, 't', petit = [2, 4, 2], min = -2, max = 5, /noerase, /rempli, /BASICMARGES, title = 'Wind work (full) '+cmd_wrk.exp, window=3
395   pltt, bfx, 't', petit = [2, 4, 8], min = -2, max = 5, color = 4, /noerase, /rempli, /BASICMARGES, title = 'B (full)', window=3
396
397   ape_1mm = trends(ape, 412, 't')
398   pltt, ape_1mm, 't', petit = [2, 4, 3], /noerase, /rempli, /BASICMARGES, title = 'APE (inter)', window=3
399   jpt_b = jpt
400   jpt = 24
401   pltt, mean_sc[0:23], 't', petit = [2, 4, 5], /noerase, /rempli, /BASICMARGES, title = 'APE (seasonal cycle x 2)', window=3
402
403   jpt = jpt_b
404
405   ww_1mm = trends(ww, 412, 't')
406   tmp = mean_sc
407   wwx_1mm = trends(wwx, 412, 't')
408
409   pltt, ww_1mm, 't', petit = [2, 4, 4], color = 2, /noerase, /rempli, /BASICMARGES, title = 'Interannual W (red) B (blue) [efficiency = '+string(strcompress(efficiency))+']', window=3
410   pltt, bfx_1mm*1.e-11, 't', petit = [2, 4, 4], /ov1d, color = 4, thick = 2, /noerase, /rempli, /BASICMARGES, window=3
411
412   jpt_b = jpt
413   jpt = 24
414   pltt, tmp[0:23], 't', petit = [2, 4, 6], min = -1, max = 3.5, /noerase, /rempli, /BASICMARGES, title = 'Seasonal Cycle x 2 (W total: black, B: blue, Wx/y: red/green)', window=3
415   pltt, mean_sc[0:23], 't', petit = [2, 4, 6], /ov1d, color = 2, thick = 2, /noerase, /rempli, /BASICMARGES, window=3
416   wwy_1mm = trends(wwy, 412, 't')
417   pltt, mean_sc[0:23], 't', petit = [2, 4, 6], /ov1d, color = 3, thick = 2, /noerase, /rempli, /BASICMARGES, window=3
418   pltt, bfx_sc[0:23]*1.e-11, 't', petit = [2, 4, 6], /ov1d, color = 4, thick = 1, /noerase, /rempli, /BASICMARGES
419   jpt = jpt_b
420
421; compute and plot sst in nino 3
422
423   maxdepth = 10
424   IF gdept[0] GT maxdepth THEN maxdepth = gdept[0]
425
426   ;domdef, [210., 280., -5., 5., 0., maxdepth]
427   bte = [210., 280., -5., 5., 0., maxdepth]
428   tn = nc_read(file_temp,var_temp, ncdf_db, BOXZOOM = bte, TIME_1 = time_1, TIME_2 = time_2)
429   st = tn.data
430   sst = grossemoyenne(st, 'xyz')
431   sst_wr = sst
432   sst = trends(sst, 412, 't')
433
434   pltt, sst, 't', petit = [2, 4, 7], /noerase, /rempli, /BASICMARGES, title = 'Nino3 SSTA'
435
436   correlation = C_CORRELATE(ape, sst, [0])
437
438   IF ps EQ 1 THEN BEGIN
439      closeps
440      printps
441   ENDIF
442
443; write to ascii file
444
445   get_lun, nuldat
446   filename = cmd_wrk.exp+'_'+cmd_wrk.date1+'_'+cmd_wrk.spec+'_'+cmd_wrk.plt+'_sst.asc'
447   openw, nuldat, asciidir+filename
448   print, '     -> writing nino 3 sst data to ', asciidir+filename & print, ' '
449   printf, nuldat, sst_wr, format = '(f8.3)'
450   free_lun, nuldat & close, nuldat
451
452   get_lun, nuldat
453   filename = cmd_wrk.exp+'_'+cmd_wrk.date1+'_'+cmd_wrk.spec+'_'+cmd_wrk.plt+'_ape.asc'
454   openw, nuldat, asciidir+filename
455   print, '     -> writing ape data to ', asciidir+filename & print, ' '
456   printf, nuldat, ape_wr, format = '(g10.4)'
457   free_lun, nuldat & close, nuldat
458
459   get_lun, nuldat
460   filename = cmd_wrk.exp+'_'+cmd_wrk.date1+'_'+cmd_wrk.spec+'_'+cmd_wrk.plt+'_ww.asc'
461   openw, nuldat, asciidir+filename
462   print, '     -> writing ww data to ', asciidir+filename & print, ' '
463   print, '         min/max of ww, ww_1mm = ', min(ww), max(ww), min(ww_1mm), max(ww_1mm)
464   printf, nuldat, ww_wr, format = '(g10.4)'
465   free_lun, nuldat & close, nuldat
466
467   get_lun, nuldat
468   filename = cmd_wrk.exp+'_'+cmd_wrk.date1+'_'+cmd_wrk.spec+'_'+cmd_wrk.plt+'_bf.asc'
469   openw, nuldat, asciidir+filename
470   print, '     -> writing bf data to ', asciidir+filename & print, ' '
471   print, '         min/max of bfx, bfx_1mm= ', min(bfx), max(bfx), min(bfx_1mm), max(bfx_1mm)
472   printf, nuldat, bfx_wr, format = '(g10.4)'
473   free_lun, nuldat & close, nuldat
474
475; check that d(APE)/dt ~ ww
476
477   dapedt = (ape-shift(ape, 1))/(86400.*30.)
478;   pltt, dapedt-(ww*1.e11),'t',petit=[1,2,1],/rempli,/portrait
479;   pltt, dapedt/(ww*1.e11),'t',petit=[1,2,2],/rempli,/portrait,/noerase
480   print, ' d(APE)/dt / wind work correlation', C_CORRELATE(dapedt, ww, [0])
481   print, ' APE/nino3 sst correlation=', correlation
482   print, ' B/W efficiency (interannual) = ', efficiency
483   print, ' B/W efficiency (SC) = ', efficiency_sc
484
485   field = {name: '', data: rhop, legend: '', units: '', origin: '', direc: '', dim: 0}
486
487   field.origin = tn.origin
488   field.dim = tn.dim - 1
489
490   field.direc = 'xyzt'
491
492   return, field
493END
Note: See TracBrowser for help on using the repository browser.