source: trunk/procs/macros/make_ratio.pro @ 163

;+
;
; compute ratio between 2 or 4 variables [ a/b or (a-b)/(c-d) ]
;
; @version
; $Id$
;
;-
FUNCTION make_ratio,  file_name,  ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1,  TIME_2 =  time_2, ALL_DATA = all_data, ZMTYP = zmtyp

@common
@com_eg

; Extracts the variables between the commas.
; Pay attention : the order is important (a,b,c,d)

  div =  0.0

  tab_var = strsplit(macro_base_fld, ',', /EXTRACT)
  IF ( debug_w ) THEN print, 'size(tab_var) : ', size(tab_var)

  IF ( (size(tab_var))[1] NE 2 AND (size(tab_var))[1] NE 4 ) THEN BEGIN
    print, 'Number of variables in the macro should be 2 or 4'
  ENDIF

  IF ( (size(tab_var))[1] EQ 4 ) THEN BEGIN
    a = strtrim(tab_var(0), 2)
    b = strtrim(tab_var(1), 2)
    c = strtrim(tab_var(2), 2)
    d = strtrim(tab_var(3), 2)

    print, 'a : ', a
    print, 'b : ', b
    print, 'c : ', c
    print, 'd : ', d

    var_a =  nc_read(file_name, a,  ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1,  TIME_2 =  time_2, ALL_DATA = all_data)
    var_b =  nc_read(file_name, b,  ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1,  TIME_2 =  time_2, ALL_DATA = all_data)
    var_c =  nc_read(file_name, c,  ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1,  TIME_2 =  time_2, ALL_DATA = all_data)
    var_d =  nc_read(file_name, d,  ncdf_db, BOXZOOM = boxzoom, TIME_1 = time_1,  TIME_2 =  time_2, ALL_DATA = all_data)

    div = var_a.data
    ;;div[*, *] = valmask
    div[*, *] = -1000.0
    diff =  var_c.data - var_d.data

    idx =  WHERE( diff NE 0.0 )
    IF( idx[0] EQ -1 ) THEN STOP,  'STOP. Division cannot be computed'

    div(idx) = ( var_a.data(idx) - var_b.data(idx) )/( diff(idx) )
    legend = ' : ( '+a+' - '+b+' ) / ( '+c+' - '+d+' )'

   ENDIF

   IF ( (size(tab_var))[1] EQ 2 ) THEN BEGIN

    a = strtrim(tab_var(0), 2)
    b = strtrim(tab_var(1), 2)

    print, 'a : ', a
    print, 'b : ', b

    var_a =  nc_read(file_name, a,  ncdf_db, TIME_1 = time_1,  TIME_2 =  time_2)
    var_b =  nc_read(file_name, b,  ncdf_db, TIME_1 = time_1,  TIME_2 =  time_2)

    div = var_a.data
    div[*, *] = valmask

    idx =  WHERE( var_b.data NE 0.0 )
    IF( idx[0] EQ -1 ) THEN STOP,  'STOP. Division cannot be computed'

    div(idx) = ( var_a.data(idx) )/( var_b.data(idx)  )
    legend = ' : '+a+' / '+b

   ENDIF

   varname =  'ratio'
   varunit =  ''

   field = {name: '', data: div, legend: '', units: '', origin: '', dim: 0,  direc:''}   
   field.origin = var_a.origin
   field.dim = var_a.dim
   field.legend =  legend
   field.direc = var_a.direc   

   return, field

END