source: trunk/procs/meshes/mesh_orca.pro @ 3

PRO mesh_orca, I_INDEX = i_index, DELTA_I = delta_i, J_INDEX = j_index, DELTA_J = delta_j, K_INDEX = k_index, DELTA_K = delta_k, ZONAL =  zonal, NO_SHIFT = no_shift, WHOLE_ARRAYS = whole_arrays, H_CONFIG = h_config, V_CONFIG = V_config

@common
@com_eg
;

   IF NOT keyword_set(H_CONFIG) THEN h_config = 'ORCA_R2'
   IF NOT keyword_set(V_CONFIG) THEN v_config = 'L30'
   print, '    Init ORCA mesh horizontal config '+h_config
   print, '                     vertical config '+v_config


;----------------------------------------------------------
; bornes de la grille
;----------------------------------------------------------

   CASE h_config OF
      'ORCA_R2': begin
         IF keyword_set(WHOLE_ARRAYS) THEN BEGIN
            ixminmesh  =0 & ixmaxmesh  =181
            iyminmesh  =0 & iymaxmesh  =148
         ENDIF ELSE BEGIN   
            ixminmesh  =2 & ixmaxmesh  =181
            iyminmesh  =0 & iymaxmesh  =147
         ENDELSE  
      END 
      'ORCA_R4':  begin
         IF keyword_set(WHOLE_ARRAYS) THEN BEGIN
            ixminmesh  =0 & ixmaxmesh  =91
            iyminmesh  =0 & iymaxmesh  =75
         ENDIF ELSE BEGIN   
            ixminmesh  =2 & ixmaxmesh  =91
            iyminmesh  =0 & iymaxmesh  =75
         ENDELSE  
      END 
   ENDCASE 

   CASE v_config OF
      'L300': BEGIN & izminmesh  =0 & izmaxmesh  =300 & END 
      'L30': BEGIN & izminmesh  =0 & izmaxmesh  =30 & END 
   ENDCASE 
;
; init shift and periodicity


   IF keyword_set(NO_SHIFT) THEN key_shift = 0

   no_lon_shift = 0

   key_periodique = 1

; reduce grid in latitude ?

   IF keyword_set(J_INDEX) THEN BEGIN

      IF NOT keyword_set(DELTA_J) THEN delta_j = 1
      delta_j = delta_j - 1

      iyminmesh = j_index
      iymaxmesh = j_index+delta_j

      print, '      set ORCA grid to j_index in ', j_index, j_index+delta_j
      iymindta = iyminmesh
   ENDIF

; reduce grid in longitude ?

   IF keyword_set(I_INDEX) THEN BEGIN

      no_lon_shift = no_lon_shift + 1

      IF NOT keyword_set(DELTA_I) THEN delta_i = 1
      delta_i = delta_i - 1

      ixminmesh  = i_index
      ixmaxmesh  = i_index+delta_i

      print, '      set ORCA grid to i_index in ', i_index, i_index+delta_i

      ixmindta = ixminmesh
      key_periodique = 0
      key_offset = [0, 0, 0]
      diaznl_idx = 0
      key_shift = 0
   ENDIF

; reduce grid in depth ?

   IF keyword_set(K_INDEX) THEN BEGIN

      IF NOT keyword_set(DELTA_K) THEN delta_k = 1
      delta_k = delta_k - 1

      izminmesh  = k_index-1
      izmaxmesh  = k_index-1+delta_k

      izmindta = izminmesh

      print, '      set ORCA grid to k_index in ', k_index-1, k_index-1+delta_k

   ENDIF
;
;------------------------------------------------------
; lecture de la grille
;------------------------------------------------------

   key_yreverse = 0

   CASE h_config OF
      'ORCA_R2': BEGIN
         CASE v_config of
            'L30': BEGIN 
               CASE orca_mask_version OF
                  'V1': mesmsk = 'meshmask.orca.2d.nc'
                  'V2': mesmsk = 'meshmask_ORCA_R2.nc'
                  'V3': mesmsk = 'meshmask_ORCA_R2_V2.nc'
               ENDCASE
               IF whole_arrays EQ 0 THEN BEGIN 
                   cmd_grid = 'ncdf_meshread, sm_file, GLAMBOUNDARY = glamboundary_box, onearth = onearth'
               ENDIF ELSE BEGIN 
                   cmd_grid = 'ncdf_meshread, sm_file, GLAMBOUNDARY = glamboundary_box'
               ENDELSE 
            END 
            'L300': BEGIN
               mesmsk = 'meshmask.orca.2d.L300.nc'
               cmd_grid = 'ncdf_meshread, sm_file, GLAMBOUNDARY = glamboundary_box'
            END 
         ENDCASE 
      END 
      'ORCA_R4': BEGIN
         mesmsk = 'meshmask_orca4.nc'
         cmd_grid = 'ncdf_meshread, sm_file, GLAMBOUNDARY = glamboundary_box' 
      END 
   ENDCASE
   
   print, '                         mask config '+orca_mask_version
   IF keyword_set(WHOLE_ARRAYS) THEN print, '                         [whole array]'          
        
   sm_file = hom_idl+'grids/'+mesmsk
   res = find(sm_file)

   IF res NE 'NOT FOUND' THEN BEGIN
       res_grid =  execute(cmd_grid)
   ENDIF ELSE BEGIN
       stop, 'No meshmask file found for ORCA mesh config'
   ENDELSE

; reduce grid to zonal mean

   IF keyword_set(ZONAL) THEN BEGIN

      no_lon_shift = no_lon_shift + 1

      jpi = 1
      ixminmesh  = 0
      ixmaxmesh  = 0

      print, '   set ORCA grid to zonal mean '

      diaznl_idx = 0

      glamt = glamt[diaznl_idx, *]
      glamu = glamu[diaznl_idx, *]
      glamv = glamv[diaznl_idx, *]
      glamf = glamf[diaznl_idx, *]
      gphit = gphit[diaznl_idx, *]
      gphiu = gphiu[diaznl_idx, *]
      gphiv = gphiv[diaznl_idx, *]
      gphif = gphif[diaznl_idx, *]

      e1t = e1t[diaznl_idx, *]
      e2t = e2t[diaznl_idx, *]
      e1u = e1u[diaznl_idx, *]
      e2u = e2u[diaznl_idx, *]
      e1v = e1v[diaznl_idx, *]
      e2v = e2v[diaznl_idx, *]

; read offset

      key_offset = [0, 0, 0]

      key_shift = 0

   ENDIF


   IF no_lon_shift EQ 0 THEN BEGIN
      CASE h_config OF
         'ORCA_R2': BEGIN
; read offset
            
            key_offset = [2, 0, 0]
;
; indice i pour grille j moyenne zonale
;
            diaznl_idx = 50-1
            
         END 
         'ORCA_R4': BEGIN 
; read offset

            key_offset = [2, 0, 0]
;
; indice i pour grille j moyenne zonale
;
            diaznl_idx = 25-1
            
         END 
      ENDCASE 
   ENDIF

   IF keyword_set(NO_SHIFT) THEN key_offset = [0, 0, 0]

   print, '     key_shift =', key_shift

   print, '    End of ORCA mesh config '

END