;*****************************************************
;*****************************************************
PRO cw_specifie_set_value, id, value
   if size(value, /type) NE 8 then return
   widget_control, widget_info(id,find_by_uname='min'), set_value = strtrim(value.min, 2)
   widget_control, widget_info(id,find_by_uname='max'), set_value = strtrim(value.max, 2)
   widget_control, widget_info(id,find_by_uname='int'), set_value = strtrim(value.inter, 2)
   widget_control, widget_info(id,find_by_uname='palnum'), set_value = strtrim(value.lct, 2)
   autres = extractstru(value, ['min', 'max', 'inter', 'lct', 'nothing', 'xindex', 'yindex'])
   if size(autres, /type) EQ 8 then BEGIN 
      autresid = widget_info(id,find_by_uname='autres')
      widget_control, widget_info(id,find_by_uname='autres'), get_value = autresautres
      autresautres = autresautres[0]
      if strtrim(autresautres, 2) NE '' then begin
         nothing = execute('autresautres = get_extra('+autresautres+')')
         autres = mixstru(autres, autresautres)
      endif
      autres = strkeywd(autres)
      widget_control, widget_info(id,find_by_uname='autres'), set_value = autres
   endif
   return
end
;*****************************************************
;*****************************************************
FUNCTION cw_specifie_get_value, id
   widget_control, widget_info(id,find_by_uname='min'), get_value = min
   min = float(min[0])
   widget_control, widget_info(id,find_by_uname='max'), get_value = max
   max = float(max[0])
   widget_control, widget_info(id,find_by_uname='int'), get_value = int
   int = float(int[0])
   widget_control, widget_info(id,find_by_uname='palnum'), get_value = palnum
   palnum = long(palnum[0])
   widget_control, widget_info(id,find_by_uname='autres'), get_value = autres
   autres = autres[0]
;
   exextra = {min:min, max:max, inter:int, lct:palnum}
   if strtrim(autres, 2) NE '' then $
    rien = execute('exextra = get_extra('+autres+', _extra = exextra)')
   return, exextra
end
;*****************************************************
;*****************************************************
FUNCTION cw_specifie_event, event
;------------------------------------------------------------
; on recuper les ID des differents widgets 
;------------------------------------------------------------
;------------------------------------------------------------
   widget_control, event.id, get_uvalue = uval
   widget_control, event.top, get_uvalue = top_uvalue
   smallin = extractatt(top_uvalue, 'smallin')
   numdessinin = smallin[2]-1
   smallout = extractatt(top_uvalue, 'smallout')
   numdessinout = smallout[2]-1
;------------------------------------------------------------
   case uval of
      'default':BEGIN 
;---------------
; on trouve le nom de la variable:
;---------------
         champid = widget_info(event.top, find_by_uname = 'champ')
         currentfile = extractatt(top_uvalue, 'currentfile')
         listvar = (*(extractatt(top_uvalue, 'fileparameters'))[currentfile]).listvar
         varname = listvar[widget_info(champid, /droplist_select)]
;---------------
         exextra = definedefaultextra(varname)
         widget_control, widget_info(event.handler,find_by_uname='min'), set_value = strtrim(exextra.min, 1)
         widget_control, widget_info(event.handler,find_by_uname='max'), set_value = strtrim(exextra.max, 1)
         widget_control, widget_info(event.handler,find_by_uname='int'), set_value = strtrim(exextra.inter, 1)
         widget_control, widget_info(event.handler,find_by_uname='palnum'), set_value = strtrim(exextra.lct, 1)
         widget_control, widget_info(event.handler,find_by_uname='autres'), set_value = ''
      END
      'palcol':BEGIN 
         ind = fix(strmid(event.value, 0, strpos(event.value, '-')))
         widget_control, widget_info(event.handler,find_by_uname='palnum'), set_value = strtrim(ind, 1)
      END
      'ok':
      ELSE:
   endcase
   return,{ID:event.handler, TOP:event.top, HANDLER:0L, OK:uval EQ 'ok'}
end
;*****************************************************
;*****************************************************
FUNCTION cw_specifie, parent, ROW = row, COLUMN = column, UVALUE = uvalue, UNAME = uname, FRAME = frame, FORXXX = forxxx, _extra = ex
; cheking exclusive keywords
   column = keyword_set(column)*(1-keyword_set(row))
   row = keyword_set(row)*(1-keyword_set(column)) +(keyword_set(row) EQ column) 
;------------------------------------------------
   if NOT keyword_set(uvalue) then uvalue = ''
   if NOT keyword_set(uname) then uname = ''
   base = widget_base(parent, ROW = row, COLUMN = column  $
                      , EVENT_FUNC = 'cw_specifie_event' $
                      , FUNC_GET_VALUE='cw_specifie_get_value' $
                      , PRO_SET_VALUE='cw_specifie_set_value' $
                      , UVALUE = uvalue, UNAME = uname, _extra = ex)   
; base1 pour specifier le min, le max et l''intervalle
   base1 = widget_base(base, /row, /frame)
   rien = widget_label(base1, value = 'Min')
   rien = widget_text(base1, value = '', /editable, xsize = 5, uname = 'min', uvalue = 'min')
   rien = widget_label(base1, value = 'Max')
   rien = widget_text(base1, value = '', /editable, xsize = 5, uname = 'max', uvalue = 'max')
   rien = widget_label(base1, value = 'Int')
   rien = widget_text(base1, value = '', /editable, xsize = 5, uname = 'int', uvalue = 'int')
; base2 por specifier la palette de couleur (soit par numero soit ds
; un menu deroulant)
   if keyword_set(FORXXX) then base2 = widget_base(base, /row, /frame) ELSE base2 = base1
   rien = widget_label(base2, value = 'Pal Numb')
   if keyword_set(forxxx) then colvalue = '' ELSE colvalue = '39'
   rien = widget_text(base2, value = colvalue, /editable, xsize = 3, uname = 'palnum', uvalue = 'palnum')
   lct,  get_name = nomcouleur
   nbrligne = 30
   nbrlist = n_elements(nomcouleur)/nbrligne
   nomcouleur = strtrim(sindgen(n_elements(nomcouleur)), 1)+'- '+nomcouleur
   nomcouleur = '0\'+nomcouleur
   nomcouleur = ['1\color palette', nomcouleur]
   if nbrlist GT 1 then for i = 1,nbrlist do $
    nomcouleur = [nomcouleur[0:nbrligne*i-1+i], '1\ ', nomcouleur[nbrligne*i+i:n_elements(nomcouleur)-1]]
   rien = cw_pdmenu(base2,nomcouleur, /RETURN_NAME , uvalue = 'palcol', uname = 'palcol')

; baseavantfin pour passer tous les mots cles possibles...
; widget text contennant les autres mots cles passe ds top_uvalue.exextra
; en reste-t-il? si oui, il faut les mettres sous forme de string

   baseavantfin = widget_base(base, /row, /frame)
   rien = widget_label(baseavantfin, value = 'Keywords')
   rien = widget_text(baseavantfin, value = '  ', /editable, uname = 'autres', uvalue = 'autres', scr_xsize = 400)
   if keyword_set(forxxx)  then begin
; basefin pour en finir, 2 boutons: Default/OK
      basefin = widget_base(base, /row, /frame, /align_center)
      rien = widget_button(basefin,value='Default', uvalue = 'default')
      rien = widget_button(basefin,value='OK', uvalue = 'ok')
; on intialise les widget_text:
      cw_specifie_set_value, base, definedefaultextra('rien_du_tout')
   endif

;------------------------------------------------
   return, base
end