source: trunk/biblioentry_xml.xsl @ 64

<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet
version="1.0"
xmlns:d="http://docbook.org/ns/docbook"
xmlns:xl="http://www.w3.org/1999/xlink"
xmlns:html="http://www.w3.org/1999/xhtml"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<!--
module :
traitement d'une référence bibliographique (biblioentry)

update :
$Id$
fplod 2008-05-07T09:06:53Z aedon.locean-ipsl.upmc.fr (Darwin)
improvements for conference
fplod 2008-05-06T09:35:00Z aedon.locean-ipsl.upmc.fr (Darwin)
add category choices
fplod 2008-04-29T15:41:56Z aedon.locean-ipsl.upmc.fr (Darwin)
chgt for dbk5 in 
fplod 2008-04-29T09:10:31Z aedon.locean-ipsl.upmc.fr (Darwin)
chgt for dbk5 out
fplod 2007-06-20T17:18:02Z aedon.locean-ipsl.upmc.fr (Darwin)
<bibliomisc role="id"> replaced by <biblioid class="doi">
fplod 2007-05-16T14:01:44Z aedon.locean-ipsl.upmc.fr (Darwin)
correction in order to write doi only once
fplod 2007-05-16T10:27:34Z aedon.locean-ipsl.upmc.fr (Darwin)
remove biblioentry/date and publisher
add biblioentry/biblioset/bibliomisc
fplod 2007-05-15T07:37:46Z aedon.locean-ipsl.upmc.fr (Darwin)
factorisation de biblioentry
fplod 2007-05-14T15:48:04Z aedon.locean-ipsl.upmc.fr (Darwin)
correction to add biblioentry/date (replace biblioentry/biblioset/pubdate) 
when "in press"
fplod 2007-05-04T07:59:34Z aedon.locean-ipsl.upmc.fr (Darwin)
factorisation de bibnemomaf01_xml.xsl, bibnemomaf02_xml.xsl,bibnemomaf04_xml.xsl
-->

<xsl:include href="correction_db.xsl"/>
<xsl:include href="category_form.xsl"/>
<xsl:include href="message_lang.xsl"/>

<xsl:template name="one_biblioentry">
 <xsl:param name="visu_modif"/>
 <xsl:param name="my_biblioentry"/>
 <xsl:element name="listitem">
  <xsl:element name="para">
    <xsl:apply-templates select="$my_biblioentry/d:authorgroup"/>
    <xsl:text>, </xsl:text>
    <xsl:if test="$my_biblioentry/descendant::d:pubdate">
     <xsl:apply-templates select="$my_biblioentry/descendant::d:pubdate"/>
    </xsl:if>
    <xsl:if test="$my_biblioentry/descendant::d:date">
     <xsl:apply-templates select="$my_biblioentry/descendant::d:date"/>
    </xsl:if>
    <xsl:text> : </xsl:text>
    <xsl:apply-templates select="$my_biblioentry/d:title"/>
    <xsl:text>, </xsl:text>
    <xsl:choose>
     <xsl:when test="$my_biblioentry/descendant::d:biblioset[@relation='journal']">
      <xsl:apply-templates select="$my_biblioentry/descendant::d:biblioset/child::d:title"/>
      <xsl:if test="$my_biblioentry/descendant::d:publishername">
       <xsl:text>, </xsl:text>
       <xsl:apply-templates select="$my_biblioentry/descendant::d:publishername"/>
      </xsl:if>
      <xsl:if test="$my_biblioentry/descendant::d:publisher/d:address">
       <xsl:text>, </xsl:text>
       <xsl:apply-templates select="$my_biblioentry/descendant::d:publisher/d:address"/>
      </xsl:if>
      <xsl:if test="$my_biblioentry/descendant::d:volumenum">
       <xsl:text>, </xsl:text>
       <xsl:apply-templates select="$my_biblioentry/descendant::d:volumenum"/>
       <xsl:if test="$my_biblioentry/descendant::d:issuenum">
        <xsl:text>, </xsl:text>
        <xsl:apply-templates select="$my_biblioentry/descendant::d:issuenum"/>
       </xsl:if>
      </xsl:if>
      <xsl:if test="$my_biblioentry/descendant::d:pagenums">
       <xsl:text>, </xsl:text>
       <xsl:apply-templates select="$my_biblioentry/descendant::d:pagenums"/>
      </xsl:if>
      <xsl:if test="$my_biblioentry/descendant::d:biblioset/child::d:bibliomisc">
       <xsl:apply-templates select="$my_biblioentry/descendant::d:biblioset/child::d:bibliomisc"/>
      </xsl:if>
     </xsl:when>
     <xsl:when test="$my_biblioentry/descendant::d:biblioset[@relation='conference']">
      <xsl:apply-templates select="$my_biblioentry/descendant::d:biblioset/descendant::d:conftitle"/>
      <xsl:if test="$my_biblioentry/descendant::d:biblioset/descendant::d:confnum">
       <xsl:apply-templates select="$my_biblioentry/descendant::d:biblioset/descendant::d:confnum"/>
      </xsl:if>
      <xsl:text>, </xsl:text>
      <xsl:apply-templates select="$my_biblioentry/descendant::d:biblioset/descendant::d:confdates"/>
      <xsl:text>, </xsl:text>
      <xsl:apply-templates select="$my_biblioentry/descendant::d:biblioset/descendant::d:address"/>
      <xsl:text>, </xsl:text>
      <xsl:apply-templates select="$my_biblioentry/descendant::d:biblioset/descendant::d:publishername"/>
      <xsl:if test="$my_biblioentry/descendant::d:pagenums">
       <xsl:text>, </xsl:text>
       <xsl:apply-templates select="$my_biblioentry/descendant::d:pagenums"/>
      </xsl:if>
     </xsl:when>
     <xsl:otherwise>
      <xsl:message terminate="no">
eee : unknown biblioset relation for <xsl:value-of select="ancestor::d:biblioentry/@xml:id"/>
eee : <xsl:value-of select="$my_biblioentry/descendant::d:biblioset/@relation"/>
      </xsl:message>
      <xsl:apply-templates select="$my_biblioentry/descendant::d:publishername"/>
     </xsl:otherwise>
    </xsl:choose>
    <xsl:apply-templates select="$my_biblioentry/d:biblioid"/>
  </xsl:element>
  <xsl:if test="$visu_modif= 'modif'">
   <xsl:call-template name="correction">
    <xsl:with-param name="id" select="$my_biblioentry/@xml:id"/>
   </xsl:call-template>
  </xsl:if>
  <xsl:if test="$visu_modif= 'category'">
   <xsl:call-template name="category">
    <xsl:with-param name="id" select="$my_biblioentry/@xml:id"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:element>
</xsl:template>

<xsl:template match="d:authorgroup">
 <xsl:apply-templates select="d:author"/>
 <xsl:apply-templates select="d:corpauthor"/>
</xsl:template>

<xsl:template match="d:author">
<!--
1er auteur Nom, prénom les autres Prenom Nom
une virgule entre les auteurs sauf entre les deux derniers
-->
  <xsl:if test="d:personname/d:surname = ''">
   <xsl:message>
eee : empty surname for <xsl:value-of select="ancestor::d:biblioentry/@xml:id"/>
   </xsl:message>
  </xsl:if>
  <xsl:if test="d:personname/d:firstname= ''">
   <xsl:message>
eee : empty firstname for <xsl:value-of select="ancestor::d:biblioentry/@xml:id"/>
   </xsl:message>
  </xsl:if>
  <xsl:if test="d:personname/d:firstname= '.'">
   <xsl:message>
eee : firstname = '.' for <xsl:value-of select="ancestor::d:biblioentry/@xml:id"/>
   </xsl:message>
  </xsl:if>
  <xsl:choose>
   <xsl:when test="position()=1">
    <xsl:value-of select="d:personname/d:surname"/><xsl:text>, </xsl:text>
    <xsl:value-of select="d:personname/d:firstname"/>
   </xsl:when>
   <xsl:otherwise>
    <xsl:value-of select="d:personname/d:firstname"/><xsl:text> </xsl:text>
    <xsl:value-of select="d:personname/d:surname"/>
   </xsl:otherwise>
  </xsl:choose>

<!--
une virgule entre les auteurs sauf entre les deux derniers
-->
  <xsl:choose>
   <xsl:when test="count(following-sibling::*)  &gt; 1"> <!-- plusieurs suivants -->
    <xsl:text>, </xsl:text>
   </xsl:when>
   <xsl:when test="count(following-sibling::*)  = 1">
    <!-- un suivant -->
    <xsl:call-template name="and">
     <xsl:with-param name="language" select="/d:bibliography/@xml:lang"/>
    </xsl:call-template>
   </xsl:when>
  </xsl:choose>
</xsl:template>

<xsl:template match="d:corpauthor">
<!--
une virgule entre les auteurs sauf entre les deux derniers
-->
  <xsl:choose>
   <xsl:when test="count(following-sibling::*)  &gt; 1"> <!-- plusieurs suivants -->
    <xsl:text>, </xsl:text>
   </xsl:when>
   <xsl:when test="count(following-sibling::*)  = 1">
    <xsl:text> and </xsl:text> <!-- un suivant -->
   </xsl:when>
  </xsl:choose>
  <xsl:value-of select="normalize-space(.)"/>
</xsl:template>
<xsl:template match="d:biblioentry/d:title">
  <xsl:value-of select="normalize-space(.)"/>
</xsl:template>

<xsl:template match="d:biblioset[@relation='journal']/d:title">
  <xsl:value-of select="normalize-space(.)"/>
</xsl:template>

<xsl:template match="d:publishername">
  <xsl:value-of select="normalize-space(.)"/>
</xsl:template>

<xsl:template match="d:biblioset[@relation='journal']/d:pubdate">
  <xsl:value-of select="normalize-space(.)"/>
</xsl:template>
<xsl:template match="d:biblioset[@relation='conference']/d:pubdate">
  <xsl:value-of select="normalize-space(.)"/>
</xsl:template>
<xsl:template match="d:date">
 <xsl:message terminate="no">
   eee : date 
   <xsl:value-of select="normalize-space(.)"/> exists in node
   <xsl:value-of select="ancestor::d:biblioentry/@xml:id"/>
   eee : try to put information in biblioset
 </xsl:message>
</xsl:template>

<xsl:template match="d:biblioset[@relation='journal']/d:volumenum">
  <xsl:value-of select="normalize-space(.)"/>
</xsl:template>

<xsl:template match="d:biblioset[@relation='journal']/d:issuenum">
  <xsl:value-of select="normalize-space(.)"/>
</xsl:template>

<xsl:template match="d:biblioset[@relation='journal']/d:pagesnum">
  <xsl:value-of select="normalize-space(.)"/>
</xsl:template>

<xsl:template match="d:biblioset[@relation='conference']/d:publisher/d:publishername">
  <xsl:value-of select="normalize-space(.)"/>
</xsl:template>
<xsl:template match="d:conftitle">
  <xsl:value-of select="normalize-space(.)"/>
</xsl:template>
<xsl:template match="d:confdates">
  <xsl:value-of select="normalize-space(.)"/>
</xsl:template>
<xsl:template match="d:confnum">
  <xsl:value-of select="normalize-space(.)"/>
</xsl:template>
<xsl:template match="d:address">
  <xsl:value-of select="normalize-space(.)"/>
</xsl:template>

<xsl:template match="d:biblioid">
<xsl:choose>
<xsl:when test="@class='doi'">
 <xsl:choose>
  <xsl:when test=". = '???'">
   <xsl:message> iii : no doi found for 
    <xsl:value-of select="ancestor::d:biblioentry/@xml:id"/>
   </xsl:message>
  </xsl:when>
 <xsl:otherwise>
  <!-- transformer 10.1029/2003GL018906 en un lien sur http://dx.doi.org/10.1029/2003GL018906 par exemple
  -->
  <xsl:text>, </xsl:text>
  <xsl:element name="link">
   <xsl:attribute name="xl:href">
    <xsl:text>http://dx.doi.org/</xsl:text>
    <xsl:value-of select="normalize-space(.)"/>
   </xsl:attribute>
   <xsl:text>doi:</xsl:text><xsl:value-of select="normalize-space(.)"/>
  </xsl:element>
 </xsl:otherwise>
 </xsl:choose>
</xsl:when>
<xsl:when test="@class='isbn'">
 <xsl:text>, ISBN : </xsl:text><xsl:value-of select="normalize-space(.)"/>
</xsl:when>
<xsl:when test="@class='other'">
 <xsl:text>, </xsl:text><xsl:value-of select="@otherclass"/><xsl:text> : </xsl:text><xsl:value-of select="normalize-space(.)"/>
</xsl:when>
<xsl:otherwise>
 <xsl:message terminate="no">
eee : unknown biblioid class for <xsl:value-of select="ancestor::d:biblioentry/@xml:id"/>
eee : <xsl:value-of select="normalize-space(.)"/>
 </xsl:message>
</xsl:otherwise>
</xsl:choose>
</xsl:template>

<xsl:template match="d:bibliomisc">
<xsl:choose>
<xsl:when test="contains(.,'In Press')">
 <xsl:text>, </xsl:text>
 <xsl:value-of select="normalize-space(.)"/>
</xsl:when>
<xsl:when test="contains(.,'In press')">
 <xsl:text>, </xsl:text>
 <xsl:value-of select="normalize-space(.)"/>
</xsl:when>
<xsl:when test="contains(.,'in press')">
 <xsl:text>, </xsl:text>
 <xsl:value-of select="normalize-space(.)"/>
</xsl:when>
<xsl:when test="contains(.,'in revision')">
 <xsl:text>, </xsl:text>
 <xsl:value-of select="normalize-space(.)"/>
</xsl:when>
<xsl:when test="contains(.,'submitted')">
 <xsl:text>, </xsl:text>
 <xsl:value-of select="normalize-space(.)"/>
</xsl:when>
<xsl:otherwise>
 <xsl:message>
eee : unknown bibliomisc purpose for <xsl:value-of select="ancestor::d:biblioentry/@xml:id"/>
eee : <xsl:value-of select="normalize-space(.)"/>
 </xsl:message>
</xsl:otherwise>
</xsl:choose>
</xsl:template>

</xsl:stylesheet>