source: trunk/biblioentry_xml.xsl @ 45

<?xml version="1.0" encoding="iso-8859-1"?>

<!--
module :
traitement d'une référence bibliographique (biblioentry)

update :
$Id$
fplod 2007-06-20T17:18:02Z aedon.locean-ipsl.upmc.fr (Darwin)
<bibliomisc role="id"> replaced by <biblioid class="doi">
fplod 2007-05-16T14:01:44Z aedon.locean-ipsl.upmc.fr (Darwin)
correction in order to write doi only once
fplod 2007-05-16T10:27:34Z aedon.locean-ipsl.upmc.fr (Darwin)
remove biblioentry/date and publisher
add  biblioentry/biblioset/biliomisc
fplod 2007-05-15T07:37:46Z aedon.locean-ipsl.upmc.fr (Darwin)
factorisation de biblioentry
fplod 2007-05-14T15:48:04Z aedon.locean-ipsl.upmc.fr (Darwin)
correction to add biblioentry/date (replace biblioentry/biblioset/pubdate) 
when "in press"
fplod 2007-05-04T07:59:34Z aedon.locean-ipsl.upmc.fr (Darwin)
factorisation de bibnemomaf01_xml.xsl, bibnemomaf02_xml.xsl,bibnemomaf04_xml.xsl
-->

<xsl:stylesheet
 id="id" version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:include href="correction_db.xsl"/>

<xsl:template name="one_biblioentry">
 <xsl:param name="visu_modif"/>
 <xsl:param name="my_biblioentry"/>
 <xsl:element name="listitem">
  <xsl:element name="para">
    <xsl:apply-templates select="$my_biblioentry/authorgroup"/>
    <xsl:text>, </xsl:text>
    <xsl:if test="$my_biblioentry/descendant::pubdate">
     <xsl:apply-templates select="$my_biblioentry/descendant::pubdate"/>
    </xsl:if>
    <xsl:if test="$my_biblioentry/descendant::date">
     <xsl:apply-templates select="$my_biblioentry/descendant::date"/>
    </xsl:if>
    <xsl:text> : </xsl:text>
    <xsl:apply-templates select="$my_biblioentry/title"/>
    <xsl:text>, </xsl:text>
    <xsl:choose>
     <xsl:when test="$my_biblioentry/descendant::biblioset">
      <xsl:apply-templates select="$my_biblioentry/descendant::biblioset/child::title"/>
      <xsl:if test="$my_biblioentry/descendant::volumenum">
       <xsl:text>, </xsl:text>
       <xsl:apply-templates select="$my_biblioentry/descendant::volumenum"/>
       <xsl:if test="$my_biblioentry/descendant::issuenum">
        <xsl:text>, </xsl:text>
        <xsl:apply-templates select="$my_biblioentry/descendant::issuenum"/>
       </xsl:if>
      </xsl:if>
      <xsl:if test="$my_biblioentry/descendant::pagenums">
       <xsl:text>, </xsl:text>
       <xsl:apply-templates select="$my_biblioentry/descendant::pagenums"/>
      </xsl:if>
      <xsl:if test="$my_biblioentry/descendant::biblioset/child::bibliomisc">
       <xsl:apply-templates select="$my_biblioentry/descendant::biblioset/child::bibliomisc"/>
      </xsl:if>
     </xsl:when>
     <xsl:otherwise>
      <xsl:apply-templates select="$my_biblioentry/publishername"/>
     </xsl:otherwise>
    </xsl:choose>
    <xsl:apply-templates select="$my_biblioentry/biblioid"/>
    <xsl:apply-templates select="$my_biblioentry/bibliomisc"/>
  </xsl:element>
  <xsl:if test="$visu_modif= 'modif'">
   <xsl:call-template name="correction">
    <xsl:with-param name="id" select="$my_biblioentry/@id"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:element>
</xsl:template>

<xsl:template match="authorgroup">
 <xsl:apply-templates select="author"/>
 <xsl:apply-templates select="corpauthor"/>
</xsl:template>

<xsl:template match="author">
<!--
1er auteur Nom, prénom les autres Prenom Nom
une virgule entre les auteurs sauf entre les deux derniers
-->
  <xsl:if test="personname/surname = ''">
   <xsl:message>
eee : empty surname for <xsl:value-of select="ancestor::biblioentry/@id"/>
   </xsl:message>
  </xsl:if>
  <xsl:if test="personname/firstname= ''">
   <xsl:message>
eee : empty firstname for <xsl:value-of select="ancestor::biblioentry/@id"/>
   </xsl:message>
  </xsl:if>
  <xsl:if test="personname/firstname= '.'">
   <xsl:message>
eee : firstname = '.' for <xsl:value-of select="ancestor::biblioentry/@id"/>
   </xsl:message>
  </xsl:if>
  <xsl:choose>
   <xsl:when test="position()=1">
    <xsl:value-of select="personname/surname"/><xsl:text>, </xsl:text>
    <xsl:value-of select="personname/firstname"/>
   </xsl:when>
   <xsl:otherwise>
    <xsl:value-of select="personname/firstname"/><xsl:text> </xsl:text>
    <xsl:value-of select="personname/surname"/>
   </xsl:otherwise>
  </xsl:choose>

<!--
une virgule entre les auteurs sauf entre les deux derniers
-->
  <xsl:choose>
   <xsl:when test="count(following-sibling::*)  &gt; 1"> <!-- plusieurs suivants -->
    <xsl:text>, </xsl:text>
   </xsl:when>
   <xsl:when test="count(following-sibling::*)  = 1">
    <xsl:text> and </xsl:text> <!-- un suivant -->
   </xsl:when>
  </xsl:choose>
</xsl:template>

<xsl:template match="corpauthor">
<!--
une virgule entre les auteurs sauf entre les deux derniers
-->
  <xsl:choose>
   <xsl:when test="count(following-sibling::*)  &gt; 1"> <!-- plusieurs suivants -->
    <xsl:text>, </xsl:text>
   </xsl:when>
   <xsl:when test="count(following-sibling::*)  = 1">
    <xsl:text> and </xsl:text> <!-- un suivant -->
   </xsl:when>
  </xsl:choose>
  <xsl:value-of select="."/>
</xsl:template>
<xsl:template match="biblioentry/title">
  <xsl:value-of select="."/>
</xsl:template>

<xsl:template match="biblioset[@relation='journal']/title">
  <xsl:value-of select="."/>
</xsl:template>
<xsl:template match="publishername">
 <xsl:message terminate="no">
   eee : publishername 
   <xsl:value-of select="."/> exists in node
   <xsl:value-of select="ancestor::biblioentry/@id"/>
   eee : try to put information in biblioset
 </xsl:message>
</xsl:template>
<xsl:template match="biblioset[@relation='journal']/pubdate">
  <xsl:value-of select="."/>
</xsl:template>
<xsl:template match="date">
 <xsl:message terminate="no">
   eee : date 
   <xsl:value-of select="."/> exists in node
   <xsl:value-of select="ancestor::biblioentry/@id"/>
   eee : try to put information in biblioset
 </xsl:message>
</xsl:template>

<xsl:template match="biblioset[@relation='journal']/volumenum">
  <xsl:value-of select="."/>
</xsl:template>

<xsl:template match="biblioset[@relation='journal']/issuenum">
  <xsl:value-of select="."/>
</xsl:template>

<xsl:template match="biblioset[@relation='journal']/pagesnum">
  <xsl:value-of select="."/>
</xsl:template>

<xsl:template match="biblioid">
<xsl:choose>
<xsl:when test="@class='doi'">
 <xsl:choose>
  <xsl:when test=". = '???'">
   <xsl:message> iii : no doi found for 
    <xsl:value-of select="ancestor::biblioentry/@id"/>
   </xsl:message>
  </xsl:when>
 <xsl:otherwise>
  <!-- transformer 10.1029/2003GL018906 en un lien sur http://dx.doi.org/10.1029/2003GL018906 par exemple
  -->
  <xsl:text>, </xsl:text>
  <xsl:element name="ulink">
   <xsl:attribute name="url">
    <xsl:text>http://dx.doi.org/</xsl:text>
    <xsl:value-of select="."/>
   </xsl:attribute>
   doi:<xsl:value-of select="."/>
  </xsl:element>
 </xsl:otherwise>
 </xsl:choose>
</xsl:when>
<xsl:otherwise>
 <xsl:message>
eee : unknown biblioid purpose for <xsl:value-of select="ancestor::biblioentry/@id"/>
eee : <xsl:value-of select="."/>
 </xsl:message>
</xsl:otherwise>
</xsl:choose>
</xsl:template>

<xsl:template match="bibliomisc">
<xsl:choose>
<xsl:when test="contains(.,'In Press')">
 <xsl:text>, </xsl:text>
 <xsl:value-of select="."/>
</xsl:when>
<xsl:when test="contains(.,'In press')">
 <xsl:text>, </xsl:text>
 <xsl:value-of select="."/>
</xsl:when>
<xsl:when test="contains(.,'in press')">
 <xsl:text>, </xsl:text>
 <xsl:value-of select="."/>
</xsl:when>
<xsl:when test="contains(.,'in revision')">
 <xsl:text>, </xsl:text>
 <xsl:value-of select="."/>
</xsl:when>
<xsl:otherwise>
 <xsl:message>
eee : unknown bibliomisc purpose for <xsl:value-of select="ancestor::biblioentry/@id"/>
eee : <xsl:value-of select="."/>
 </xsl:message>
</xsl:otherwise>
</xsl:choose>
</xsl:template>

</xsl:stylesheet>