source: trunk/bibnemomaf01_xml.xsl @ 16

<?xml version="1.0" encoding="iso-8859-1"?>

<!--
module :
sortir les références bibliographiques par pseudo-année

source :
/usr/home/fplod/incas/bibnemo/src/bibnemomaf/bibnemomaf01_xml.xsl sur aedon.locean-ipsl.upmc.fr

update :
$Id$
++ plein de trucs
fplod 2007-06-08T08:36:48Z aedon.locean-ipsl.upmc.fr (Darwin)
add total nb of publications in one cell. quite interesting usage of
XPATH to determine mininum and maximum value of a element !
fplod 2007-05-21T14:06:53Z aedon.locean-ipsl.upmc.fr (Darwin)
ajout de plot nbpub/years
fplod 2007-05-04T08:02:29Z aedon.locean-ipsl.upmc.fr (Darwin)
externalisation de biblioentry
passage de itemizedlist à sect1 pour homogénéisation sur présentation par auteur(et parce que je préfère)
fplod 2007-04-02T08:53:30Z aedon.locean-ipsl.upmc.fr (Darwin)
journal dans biblioset
fplod 2007-03-30T12:38:34Z aedon.locean-ipsl.upmc.fr (Darwin)
creation
-->

<xsl:stylesheet
 id="id" version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output
 method="xml"
 indent="yes"
 encoding="ISO-8859-1"
 omit-xml-declaration="no"
 doctype-public="-//OASIS//DTD DocBook XML V4.5//EN"
 doctype-system="http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd"/>

<xsl:include href="biblioentry_xml.xsl"/>

<xsl:variable name="list_years" select="///pubdate[not( self::node() = following::pubdate )]"/>

<xsl:template name="years">
<!--
creation of an informatable of nb years
each entry of the table is a link #year_xxxx
-->
<xsl:element name="informaltable">
 <xsl:attribute name="id">years</xsl:attribute>
 <xsl:attribute name="summary">years of publications</xsl:attribute>
 <xsl:element name="tgroup">
  <xsl:variable name="nb_cols" select="count($list_years)"/>
  <xsl:attribute name="cols"><xsl:value-of select="$nb_cols"/></xsl:attribute>
  <xsl:attribute name="align">center</xsl:attribute>
  <xsl:attribute name="colsep">1</xsl:attribute>
  <xsl:attribute name="rowsep">1</xsl:attribute>
  <xsl:for-each select="///pubdate[not( self::node() = following::pubdate )]">
   <xsl:sort order="descending" data-type="number" select="."/>
   <xsl:element name="colspec">
    <xsl:attribute name="colname">year_<xsl:value-of select="."/></xsl:attribute>
   </xsl:element>
  </xsl:for-each>
  <xsl:element name="tbody">
   <xsl:element name="row">
    <xsl:for-each select="///pubdate[not( self::node() = following::pubdate )]">
     <xsl:sort order="descending" data-type="number" select="."/>
     <xsl:element name="entry">
      <xsl:attribute name="colname"><xsl:text>year_</xsl:text><xsl:value-of select="."/></xsl:attribute>
      <xsl:element name="ulink">
       <xsl:attribute name="url"><xsl:text>#year_</xsl:text><xsl:value-of select="."/></xsl:attribute>
       <xsl:value-of select="."/>
      </xsl:element>
     </xsl:element>
    </xsl:for-each>
   </xsl:element>
   <xsl:element name="row">
    <xsl:for-each select="///pubdate[not( self::node() = following::pubdate )]">
     <xsl:sort order="descending" data-type="number" select="."/>
     <xsl:element name="entry">
      <xsl:attribute name="colname"><xsl:text>year_</xsl:text><xsl:value-of select="."/></xsl:attribute>
      <xsl:element name="emphasis">
       <xsl:attribute name="role">bold</xsl:attribute>
<xsl:variable name="nb_current">
 <xsl:variable name="current_year"><xsl:value-of select="."/></xsl:variable>
 <xsl:value-of select="count(/descendant::biblioentry[child::biblioset[child::pubdate=$current_year]])"/>
</xsl:variable>
       <xsl:value-of select="$nb_current"/>
      </xsl:element>
     </xsl:element>
    </xsl:for-each>
   </xsl:element>
   <xsl:variable name="year_min">
    <xsl:value-of select="///pubdate[not(. &gt; ///pubdate)]"/>
   </xsl:variable>
   <xsl:variable name="year_max">
    <xsl:value-of select="///pubdate[not(. &lt; ///pubdate)]"/>
   </xsl:variable>
   <xsl:element name="row">
    <xsl:element name="entry">
     <xsl:attribute name="namest"><xsl:value-of select="concat('year_',$year_max)"/></xsl:attribute>
      <xsl:attribute name="nameend"><xsl:value-of select="concat('year_',$year_min)"/></xsl:attribute>
     <xsl:element name="emphasis">
      <xsl:attribute name="role">bold</xsl:attribute>
       <xsl:value-of select="count(/descendant::biblioentry)"/>
     </xsl:element>
    </xsl:element>
   </xsl:element>
  </xsl:element>
 </xsl:element>
</xsl:element>
</xsl:template>

<xsl:template match="bibliography">

<article lang="en">
<title>NEMO - Publications - Papers by years</title>
<articleinfo>
<authorgroup>
<author><personname><firstname>Sébastien</firstname> <surname>Masson</surname></personname></author>
<author><personname><firstname>Françoise</firstname> <surname>Pinsard</surname></personname></author>
<!--++-->
</authorgroup>
<keywordset>
<keyword>NEMO</keyword>
</keywordset>
<!-- ++ date -->
</articleinfo>
<highlights id="top">
<para>
This page intents to provide an exhaustive list of the papers that have used 
NEMO or OPA and/or results from them. 
Obvioulsy many papers are missing. 
If you find omissions or mistakes please ask some modification via 
<xsl:element name="ulink">
 <xsl:attribute name="url">
  <xsl:value-of select="'./bibnemomain.php'"/>
 </xsl:attribute>
 <xsl:text>Nemo Survey main page</xsl:text>
</xsl:element>.
</para>
</highlights>
<para>
You can also see <quote>NEMO - Publications - Papers</quote> sorted by 
<xsl:text>authors</xsl:text>
authors in
<xsl:element name="ulink">
 <xsl:attribute name="url">
  <xsl:value-of select="'./bibnemomaf02.html'"/>
 </xsl:attribute>
 <xsl:text>one big document </xsl:text>
</xsl:element>
<xsl:text> or in </xsl:text>
<xsl:element name="ulink">
 <xsl:attribute name="url">
  <xsl:value-of select="'../many/bibnemomaf03/index.html'"/>
 </xsl:attribute>
 <xsl:text>several </xsl:text>
</xsl:element> <xsl:text> (one by author)</xsl:text>.
</para>

<para>
Last update of the bibliography databank : <xsl:value-of select="bibliographyinfo/date"/>
</para>

<xsl:call-template name="years"/>

<figure id="fig_pubbyyears"><title>Nb of publications by years</title>
<mediaobject> 
<imageobject> 
<imagedata fileref="../../images/years.png" format="PNG"/>
</imageobject>
<textobject><phrase>[years.png]</phrase></textobject>
</mediaobject>
</figure>

<sect1 id="intro">
<title>Introduction</title>
<para>
This document provide bibliography sorted by year.
</para>
</sect1>

   <!-- loop on years -->
   <xsl:for-each select="$list_years">
    <xsl:sort order="descending" data-type="number" select="."/>
    <xsl:call-template name="one_year">
     <xsl:with-param name="year" select="."/>
    </xsl:call-template>
   </xsl:for-each>
</article>
</xsl:template>

<xsl:template match="bibliographyinfo/date"/>
<xsl:template match="bibliography/title"/>

<xsl:template name="one_year">
<xsl:param name="year"/>
<!--
 <xsl:message>call template avec <xsl:value-of select="$year"/></xsl:message>
 <xsl:message>noeud courant <xsl:value-of select="name(.)"/></xsl:message>
-->
 <xsl:message>
year_<xsl:value-of select="$year"/> : <xsl:value-of select="count(/descendant::biblioentry[child::biblioset[child::pubdate=$year]]) + count(/descendant::biblioentry[child::date=$year])"/> 
</xsl:message>
 <xsl:element name="sect1">
  <xsl:attribute name="id"><xsl:value-of select="concat('year_',$year)"/></xsl:attribute>
  <xsl:element name="title">
   <xsl:value-of select="$year"/>
   <xsl:element name="ulink">
   <xsl:attribute name="url"><xsl:text>#top</xsl:text></xsl:attribute>
   <xsl:element name="inlinemediaobject">
     <xsl:element name="imageobject">
      <xsl:element name="imagedata">
       <xsl:attribute name="fileref">../../images/globalicondl11x10_up.gif</xsl:attribute>
      </xsl:element>
     </xsl:element>
     <xsl:element name="textobject">
      <xsl:element name="phrase">
       <xsl:text>top</xsl:text>
      </xsl:element>
     </xsl:element>
    </xsl:element>
   </xsl:element>
  </xsl:element>
  <orderedlist>
   <xsl:for-each select="/descendant::biblioentry[child::biblioset[child::pubdate=$year]]|/descendant::biblioentry[child::date=$year]">
    <xsl:sort order="ascending" data-type="text" select="./authorgroup/author/personname/surname"/>
    <xsl:sort order="ascending" data-type="text" select="./authorgroup/author/personname/firstname"/>
    <xsl:call-template name="one_biblioentry">
     <xsl:with-param name="visu_modif" select="'visu'"/>
     <xsl:with-param name="my_biblioentry" select="."/>
    </xsl:call-template>
   </xsl:for-each>
  </orderedlist>
 </xsl:element>
</xsl:template>

</xsl:stylesheet>