<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet
version="1.0"
xmlns:d="http://docbook.org/ns/docbook"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<!--rst

.. _year_gnuplot.xsl:

================
year_gnuplot.xsl
================

DESCRIPTION
===========

production d'un fichier de commande gnuplot avec données incorporées pour
le graphe publications/année

TODO
====

understand message "avoid all points y value undefined"
when this line is process::

  set xrange [<xsl:value-of select="$yyyy_min"/>:<xsl:value-of select="$yyyy_max"/>]

EVOLUTIONS
==========

$Id$

$URL$

- fplod 20120228

  * rewrite ReST header
  * remove svg stuff
  * add min and max year computation thanks to
    http://www.dpawson.co.uk/xsl/sect2/N5121.html#d6617e433 max(), min() and avg() functions
    but not used because of gnuplot issue

- fplod 2008-04-30T06:50:45Z aedon.locean-ipsl.upmc.fr (Darwin)

  * chgt for dbk5 in

- fplod 2007-05-21T12:52:07Z aedon.locean-ipsl.upmc.fr (Darwin)

  * creation
    d'après /Users/pinsard/ES/src/estimation/src/estimation_graph1_gnuplot.xsl

-->

<xsl:output
 method="text"
 encoding="ISO-8859-1"
 indent="yes"/>

<xsl:include href="biblioentry_xml.xsl"/>

<xsl:variable name="list_years" select="///d:pubdate[not( self::node() = following::d:pubdate )]"/>

<xsl:variable name="yyyy_max">
     <xsl:for-each select="$list_years">
       <xsl:sort data-type="number" order="descending"/>
       <xsl:if test="position()=1">
	  <xsl:value-of select="."/>
       </xsl:if>
     </xsl:for-each>
</xsl:variable>

<xsl:variable name="yyyy_min">
     <xsl:for-each select="$list_years">
       <xsl:sort data-type="number" order="ascending"/>
       <xsl:if test="position()=1">
	  <xsl:value-of select="."/>
       </xsl:if>
     </xsl:for-each>
</xsl:variable>

<xsl:template match="d:bibliography">
#+
# .. _years_gnuplot.gnu:
#
# DESCRIPTION
# ===========
#
# EXAMPLES
# ========
#
# :: 
#
#  $ gnuplot years_gnuplot.gnu
#
# EVOLUTIONS
# ===========
#
# - <xsl:value-of select="$makedate"/>
#
#   * created by :ref:`years_gnuplot.xsl`
#
#-
reset
#
# codage iso pour les diacritiques
set encoding iso_8859_1
#
set size 1.0, 1.0
set origin 0.0, 0.0
#
# pas de légendes
set nokey
#
# definition of axes
set xlabel "Year"
set xdata time
set timefmt "%Y"
set format x "%Y"
#set xrange [<xsl:value-of select="$yyyy_min"/>:<xsl:value-of select="$yyyy_max"/>] # commented to understand message "avoid all points y value undefined"
set xrange [*:*]
set yrange [*:*]
set ylabel "Nb of publications"
# titre sur le graphique
set title "nb of publications by year date : <xsl:value-of select="$makedate"/>"
#
set term png
set output "<xsl:value-of select="$path"/>/years.png"

plot '-' using 1:2 with lines
   <!-- loop on years -->
   <xsl:for-each select="$list_years">
    <xsl:sort order="ascending" data-type="number" select="."/>
    <xsl:call-template name="one_year">
     <xsl:with-param name="year" select="."/>
    </xsl:call-template>
   </xsl:for-each>
   <xsl:text>e</xsl:text>
   <xsl:text>&#xA;</xsl:text>
</xsl:template>

<xsl:template name="one_yearcount">
<xsl:param name="year"/>
<xsl:value-of select="count(/descendant::d:biblioentry[child::d:biblioset[child::d:pubdate=$year]]) "/>
<xsl:text> </xsl:text>
</xsl:template>

<xsl:template name="one_year">
<xsl:param name="year"/>
<xsl:value-of select="$year"/>
<xsl:text> </xsl:text>
<xsl:value-of select="count(/descendant::d:biblioentry[child::d:biblioset[child::d:pubdate=$year]]) "/>
<xsl:text>&#xA;</xsl:text>
</xsl:template>

</xsl:stylesheet>