source: trunk/years_ploticus.xsl @ 57

<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet 
version="1.0" 
xmlns:d="http://docbook.org/ns/docbook"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<!--
module :
production d'un fichier de commande ploticus avec données incorporées pour
le graphe publications/année

warning : ploticus did not accept years on 4 digit (yyyy). Only two are available, so this tool should be used if the range of years is more than
[1950,2049] or so ...

see also years_gnuplot.xsl  (but no histogram, only linepoints)

++ voir une solution svg http://www.chez.com/xml/exemples/xslt/barchart/

update :
$Id$
fplod 2008-04-29T15:28:53Z aedon.locean-ipsl.upmc.fr (Darwin)
chgt for dbk5 in
/usr/home/fplod/src/superbib_ws/years_ploticus.xsl sur aedon.locean-ipsl.upmc.fr
inspired by /sw/share/ploticus2/pltestsuite/bars3.htm
creation
-->

<xsl:output method="text"/>

<xsl:include href="biblioentry_xml.xsl"/>

<xsl:key name="key_years" match="///d:pubdate" use="."/>

<xsl:template match="d:bibliography">
#
#  $ ploticus -o years.png png years.ploticus
#
# source :
# years.ploticus
#
# update :
# <xsl:value-of select="$makedate"/>
#
#proc getdata
data:
<!-- loop on years -->
<xsl:for-each select="///d:pubdate[generate-id(.) = generate-id(key('key_years', .)[1])]">
 <xsl:sort order="ascending" data-type="number" select="."/>
 <xsl:call-template name="one_year">
  <xsl:with-param name="year" select="."/>
 </xsl:call-template>
</xsl:for-each>

#proc areadef
  title: Nb of publications by year date : <xsl:value-of select="$makedate"/>
  titledetails: align=center
  xaxis.label: Year
  xscaletype: date yy
  xaxis.stubs: inc 2 year
  xaxis.stubformat: yyyy
  xautorange: datafield=1
  yaxis.label: Nb of publications
  yautorange: datafield=2
  yaxis.stubs: inc
  yaxis.location: min-0.25

#proc bars
  lenfield: 2
  locfield: 1
  color: red
  barwidth: 0.25
  outline: no

</xsl:template>

<xsl:template name="one_year">
 <xsl:param name="year"/>
 <xsl:choose>
  <xsl:when test="$year &lt; 2000">
   <xsl:value-of select="($year - 1900)"/>
  </xsl:when>
  <xsl:otherwise>
   <xsl:value-of select="($year - 2000)"/>
  </xsl:otherwise>
 </xsl:choose>

 <xsl:text> </xsl:text>
 <xsl:value-of select="count(/descendant::d:biblioentry[child::d:biblioset[child::d:pubdate=$year]]) "/>
 <xsl:text>&#xA;</xsl:text>
</xsl:template>

</xsl:stylesheet>