source: trunk/src/interp_erai_msl_1989_2009.pro @ 153

;+
;
; .. _interp_erai_msl_1989_2009.pro:
;
; =============================
; interp_erai_msl_1989_2009.pro
; =============================
;
; DESCRIPTION
; ===========
;
; Interpolation of msl from ERA-I grid to OAFLUX grid
;
; :file:`${PROJECT_ID}/20c3m_erai_msl_TROP_1989_2009.nc`
; containing
; msl from ERA-I
; has been produced by
; :ref:`compute_erai_daily_region_2d.sh`.
;
; :file:`${PROJECT_ID}/mask_oaflux_30N30S.nc`
; containing
; OAFLUX grid
; has been produced by
; :func:`oaflux_mask_30n30s`.
;
; Interpolated msl
; is written in
; :file:`${PROJECT_OD}/erai_msl_19890101_20091231_oafluxgrid.nc`
; if this file not already exists.
;
; This output file
; :file:`${PROJECT_OD}/erai_msl_19890101_20091231_oafluxgrid.nc`
; must be processed after by
; :ref:`d2m_to_q2m_erai.pro`.
;
; .. only:: man
;
;    Figure is visible on PDF and HTML documents only.
;
; .. only:: html or latex
;
;     .. graphviz::
;
;        digraph interp_erai_msl_1989_2009 {
;
;           file_in [shape=ellipse,fontname=Courier,label="${PROJECT_ID}/20c3m_erai_msl_TROP_1989_2009.nc"];
;           mask [shape=ellipse,fontname=Courier,label="${PROJECT_ID}/mask_oaflux_30N30S.nc"];
;           file_out [shape=ellipse,fontname=Courier,label="${PROJECT_OD}/erai_msl_19890101_20091231_oafluxgrid.nc"];
;
;           interp_erai_msl_1989_2009 [shape=box,
;           fontname=Courier,
;           color=blue,
;           URL="http://forge.ipsl.jussieu.fr/tropflux/browser/trunk/src/interp_erai_msl_1989_2009.pro",
;           label="${PROJECT}/src/interp_erai_msl_1989_2009.pro"];
;
;           {file_in mask} -> {interp_erai_msl_1989_2009} -> {file_out}
;
;        }
;
; SEE ALSO
; ========
;
; :ref:`interpolate_data`
;
; :ref:`project_profile.sh`
;
; :func:`report <saxo:report>`
; :func:`isadirectory <saxo:isadirectory>`
; :func:`isafile <saxo:isafile>`
; :func:`initncdf <saxo:initncdf>`
; :func:`read_ncdf <saxo:read_ncdf>`
; :func:`domdef <saxo:domdef>`
; :func:`call_interp2d <saxo:call_interp2d>`
; :func:`ncdf_quickwrite <saxo:ncdf_quickwrite>`
;
; :ref:`d2m_to_q2m_erai.pro`
;
; EXAMPLES
; ========
;
; ::
;
;  IDL> .compile file_interp
;  IDL> interp_erai_msl_1989_2009
;
; TODO
; ====
;
; use real output of :ref:`compute_erai_daily_region_2d.sh`.
;
; msl_attr={units:'milibars' .. millibar at least, hPa will be probably
; more SI
;
; why 19880101,20100930 as dates
;
; first step time 14245.5 (days since 1950-01-01 00:00:00) : correct ?
;
; KNOWN ISSUES
; ============
;
; test of existence of fullfilename_msk not very efficient because
; MUST_EXIST keyword of :func:`isafile <saxo:isafile>` not yet implemented
;
; EVOLUTIONS
; ==========
;
; $Id: interp_erai_msl_1989_2009.pro 88 2011-08-19 15:40:14Z pinsard $
;
; $URL$
;
; - pinsard 2011-08-23T09:09:16Z loholt1.ipsl.polytechnique.fr (Linux)
;
;   * retry on loholt1 with idl8 and idl6
;
; - fplod 20110811T113646Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * check for units in original file before conversion
;
; - fplod 20110809T145539Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * remove v1 from pro name and file
;   * header
;   * usage of ${PROJECT_ID} and ${PROJECT_OD}
;   * remove return statement
;   * add test on IO files
;   * add OUTMASK_IND and SET_OUTMSKVAL to call_interp2d call
;
; - pbk 2008
;
;   * creation
;
;-
pro interp_erai_msl_1989_2009
;
@cm_4cal
@cm_4data
@cm_4mesh
@cm_4data
@cm_project
;
; check for input directory
;
; test if ${PROJECT_ID} defined
CASE project_id_env OF
    ''  :  BEGIN
     msg = 'eee : ${PROJECT_ID} is not defined'
     ras = report(msg)
     STOP
           END
 ELSE: BEGIN
     msg = 'iii : ${PROJECT_ID} is ' + project_id_env
     ras = report(msg)
       END
ENDCASE
;
iodirin = isadirectory(project_id_env)
;
; existence and protection of ${PROJECT_ID}
IF (FILE_TEST(iodirin, /DIRECTORY, /EXECUTABLE, /READ) EQ 0) THEN BEGIN
   msg = 'eee : the directory' + iodirin  + ' is not accessible.'
   ras = report(msg)
   STOP
ENDIF
;
; build mask filename
filename_msk='mask_oaflux_30N30S.nc'
;
; check if this file exists
msg='iii : looking for ' + filename_msk
ras = report(msg)
fullfilename_msk = isafile(iodirin + filename_msk, NEW=0, /MUST_EXIST)
IF fullfilename_msk[0] EQ '' THEN BEGIN
   msg = 'eee : the file ' + fullfilename_msk + ' was not found.'
   ras = report(msg)
   STOP
ENDIF
;
; build data filename
filename='20c3m_erai_msl_TROP_1989_2009.nc'
;
; check if this file exists
msg='iii : looking for ' + filename
ras = report(msg)
fullfilename = isafile(iodirin + filename, NEW=0, /MUST_EXIST)
IF fullfilename[0] EQ '' THEN BEGIN
   msg = 'eee : the file ' + fullfilename + ' was not found.'
   ras = report(msg)
   STOP
ENDIF
;
; test if ${PROJECT_OD} defined
CASE project_od_env OF
  '' : BEGIN
         msg = 'eee : ${PROJECT_OD} is not defined'
         ras = report(msg)
       STOP
       END
  ELSE: BEGIN
          msg = 'iii : ${PROJECT_OD} is ' + project_od_env
          ras = report(msg)
        END
 ENDCASE
;
; check if output data will be possible
iodirout = isadirectory(project_od_env)
;
; existence and protection
IF (FILE_TEST(iodirout, /DIRECTORY, /WRITE) EQ 0) THEN BEGIN
    msg = 'eee : the directory' + iodirout  + ' was not found.'
    ras = report(msg)
    STOP
ENDIF
;
; build output filename
filename_out = 'erai_msl_19890101_20091231_oafluxgrid.nc'
fullfilename_out = iodirout + filename_out
; in order to avoid unexpected overwritten
IF (FILE_TEST(fullfilename_out) EQ 1) THEN BEGIN
   msg = 'eee : the file ' + fullfilename_out  + ' already exists.'
   ras = report(msg)
   STOP
ENDIF
;
initncdf, fullfilename
domdef
latin=reform(gphit(0,*))
lonin=reform(glamt(*,0))
print, 'lat grid ',min(latin),max(latin),latin(1)-latin(0)
print, 'lon grid ',min(lonin),max(lonin),lonin(1)-lonin(0)
mslin=read_ncdf("msl",19880101,20100930,file=fullfilename,/nostr)
;
timein=time
jptin=jpt
tab=mslin(*,*,0)
mskin=glamt*0.+1.
;
initncdf, fullfilename_msk
domdef
latout=reform(gphit(0,*))
lonout=reform(glamt(*,0))
print, 'lat grid ',min(latout),max(latout),latout(1)-latout(0)
print, 'lon grid ',min(lonout),max(lonout),lonout(1)-lonout(0)
mskout=read_ncdf("msk", file=fullfilename_msk,/nostr)
;
; conversion to hPa
ncdf_getatt, fullfilename, 'msl', units=units
CASE units OF
    'Pascal': BEGIN
        mslin=mslin/100
    END
    ELSE: BEGIN
        msg = 'eee : ' + units + ' unknown'
        ras = report(msg)
        STOP
    END
ENDCASE
;
help, mslin,lonin,latin,mskin,lonout,latout,mskout
;
mslout=fltarr(jpi,jpj,jptin)
for jt=0,jptin-1 do begin
  ; ++ print, 'Interpolation jt=',jt,' / ',jptin-1
  tab=reform(mslin(*,*,jt))
  mslout(*,*,jt)=call_interp2d(tab,lonin,latin,mskin $
      , lonout,latout,method='bilinear' $
      , OUTMASK_IND=mskout, SET_OUTMSKVAL=mskout)
  mslout(*,*,jt)=mslout(*,*,jt)*mskout+(1.-mskout)*1.e20
endfor
;
initncdf, fullfilename_msk
time=timegen(jptin, start=julday(1,1,1989,0), units='days')
cda0=string(jul2date(time(0)),format='(i8.8)')
cda1=string(jul2date(time(jpt-1)),format='(i8.8)')
timein=time-julday(1,1,1950,00,00)
;
lat=latout
lon=lonout
ncfile='!' + fullfilename_out
lon_attr={units:'degrees_east',long_name:'Longitude'}
lat_attr={units:'degrees_north',long_name:'Latitude'}
time_attr={units:'days since 1950-01-01 00:00:00',long_name:'Time axis',time_origin:'1950-JAN-01 00:00:00'}
globattr={source:'Data are from ECMWF ERA-Interim reanalysis', timerange:cda0+' - '+cda1}
msl_attr={units:'milibars',missing_value:1e20,long_name:'Mean Sea leval pressure',short_name:'msl',axis:'TYX'}
;
ncfields = 'msl[longitude,latitude,time]=mslout:msl_attr; ' $
                      + 'longitude[]=lon:lon_attr; ' $
                      + 'latitude[]=lat:lat_attr; ' $
                      + 'time[*time]=timein:time_attr ' $
                      + ' @ globattr'
;
@ncdf_quickwrite
;
end