source: trunk/src/interp_erai_sst_1989_2009.pro @ 67

;+
;
; .. _interp_erai_sst_1989_2009.pro:
;
; =============================
; interp_erai_sst_1989_2009.pro
; =============================
;
; DESCRIPTION
; ===========
;
; Interpolation of sst from ERA-I grid to OAFLUX grid
;
; :file:`${PROJECT_ID}/20c3m_erai_sstk_TROP_1989_2009.nc` containing sst from ERA-I have been produced
; by :ref:`compute_erai_daily_region_2d.sh`.
;
; :file:`${PROJECT_ID}/mask_oaflux_30N30S.nc` containing OAFLUX grid have been p roduced by :ref:`oaflux_mask_30N30S.pro`.
;
; Interpolated sst is written in
; :file:`${PROJECT_OD}/erai_sst_19890101_20091231_oafluxgrid.nc` if this file not already exists.
;
; This output file :file:`${PROJECT_OD}/erai_sst_19890101_20091231_oafluxgrid.nc` must be processed after by :ref:`sst_correction_ncdf.pro`.
;
;
;     .. graphviz::
;
;        digraph interp_erai_sst_1989_2009 {
;           graph [
;           rankdir="LR",
;           ]
;           file_in [shape=ellipse,fontname=Courier,label="${PROJECT_ID}/20c3m_erai_sstk_TROP_1989_2009.nc"];
;
;           mask [shape=ellipse,fontname=Courier,label="${PROJECT_ID}/mask_oaflux_30N30S.nc"];
;
;           ncfile [shape=ellipse,fontname=Courier,label="${PROJECT_OD}/erai_sst_19890101_20091231_oafluxgrid.nc"];
;
;           interp_erai_sst_1989_2009 [shape=box,
;           fontname=Courier,
;           color=blue,
;           URL="http://forge.ipsl.jussieu.fr/tropflux/browser/trunk/src/interp_erai_sst_1989_2009.pro",
;           label="${PROJECT}/src/interp_erai_sst_1989_2009.pro"];
;
;           {file_in mask} -> {interp_erai_sst_1989_2009} -> {ncfile}
;          }
;
; SEE ALSO
; ========
;
; :ref:`project_profile.sh`
;
; :func:`report <saxo:report>`
; :func:`isadirectory <saxo:isadirectory>`
; :func:`isafile <saxo:isafile>`
; :func:`initncdf <saxo:initncdf>`
; :func:`read_ncdf <saxo:read_ncdf>`
; :func:`domdef <saxo:domdef>`
; :func:`call_interp2d <saxo:call_interp2d>`
; :func:`ncdf_quickwrite <saxo:ncdf_quickwrite>`
;
; :ref:`sst_correction_ncdf.pro`
;
; EXAMPLES
; ========
;
; ::
;
;  IDL> .compile file_interp
;  IDL> interp_erai_sst_1989_2009
;
; TODO
; ====
;
; make it work : pb on loholt1::
;
;   Variable is undefined: OUTMASK_IND.
;
; coding rules
;
; use real output of :ref:`compute_erai_daily_region_2d.sh`.
;
; KNOWN ISSUES
; ============
;
; test of existence of fullfilename_msk not very efficient because
; MUST_EXIST keyword of :func:`isafile <saxo:isafile>` not yet implemented
;
; EVOLUTIONS
; ==========
;
; $Id$
;
; $URL$
;
; - pinsard 2011-07-04T15:45:35Z loholt1.ipsl.polytechnique.fr (Linux)
;
;   * usage of ${PROJECT_ID} and $PROJECT_OD
;
; - fplod 20101217T140745Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * remove hard coded directory for mask_oaflux_30N30S.nc
;
; - fplod 20101215T100932Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * add graph in header
;
; - fplod 20101214T093615Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * minimal header
;
; - pbk 2008
;
;   * creation
;
;-
pro interp_erai_sst_1989_2009
;
@cm_4cal
@cm_4data
@cm_4mesh
@cm_4data
@cm_project
;
; check for input directory
;
; test if ${PROJECT_ID} defined
CASE project_id_env OF
    ''  :  BEGIN
     msg = 'eee : ${PROJECT_ID} is not defined'
     ras = report(msg)
     STOP
           END
 ELSE: BEGIN
     msg = 'iii : ${PROJECT_ID} is ' + project_id_env
     ras = report(msg)
       END
ENDCASE
;
iodirin = isadirectory(project_id_env)
;
; existence and protection of ${PROJECT_ID}
IF (FILE_TEST(iodirin, /DIRECTORY, /EXECUTABLE, /READ) EQ 0) THEN BEGIN
   msg = 'eee : the directory' + iodirin  + ' is not accessible.'
   ras = report(msg)
   STOP
ENDIF
;
; build mask filename
filename_msk='mask_oaflux_30N30S.nc'
;
; check if this file exists
fullfilename_msk = isafile(iodirin + filename_msk, NEW=0, /MUST_EXIST)
IF fullfilename_msk[0] EQ '' THEN BEGIN
   msg = 'eee : the file ' + fullfilename_msk + ' was not found.'
   ras = report(msg)
   STOP
ENDIF
;
; build data filename
filename='20c3m_erai_sstk_TROP_1989_2009.nc'
;
; check if this file exists
fullfilename = isafile(iodirin + filename, NEW=0, /MUST_EXIST)
IF fullfilename_msk[0] EQ '' THEN BEGIN
   msg = 'eee : the file ' + fullfilename_msk + ' was not found.'
   ras = report(msg)
   STOP
ENDIF
;
; test if ${PROJECT_OD} defined
CASE project_od_env OF
  '' : BEGIN
         msg = 'eee : ${PROJECT_OD} is not defined'
         ras = report(msg)
       STOP
       END
  ELSE: BEGIN
          msg = 'iii : ${PROJECT_OD} is ' + project_od_env
          ras = report(msg)
        END
 ENDCASE
;
; check if output data will be possible
iodirout = isadirectory(project_od_env)
;
; existence and protection
IF (FILE_TEST(iodirout, /DIRECTORY, /WRITE) EQ 0) THEN BEGIN
    msg = 'eee : the directory' + iodirout  + ' was not found.'
    ras = report(msg)
    STOP
ENDIF
;
; build output filename
filename_out = 'erai_sst_19890101_20091231_oafluxgrid.nc'
fullfilename_out = iodirout + filename_out
; in order to avoid unexpected overwritten
IF (FILE_TEST(fullfilename_out) EQ 1) THEN BEGIN
   msg = 'eee : the file ' + fullfilename_out  + ' already exists.'
   ras = report(msg)
   STOP
ENDIF
;
initncdf, fullfilename
domdef
latin=reform(gphit(0,*)) & lonin=reform(glamt(*,0))
print, 'lat grid ',min(latin),max(latin),latin(1)-latin(0)
print, 'lon grid ',min(lonin),max(lonin),lonin(1)-lonin(0)
sstkin=read_ncdf("sstk",19871201,20100930,file=fullfilename,/nostr)

timein=time & jptin=jpt
tab=sstkin(*,*,0)
mskin=glamt*0.+1. & ind=where((tab eq 1.e9) or finite(tab,/nan)) & mskin(ind)=0.
;mskin=glamt*0.+1.

initncdf, fullfilename_msk
domdef
latout=reform(gphit(0,*)) & lonout=reform(glamt(*,0))
print, 'lat grid ',min(latout),max(latout),latout(1)-latout(0)
print, 'lon grid ',min(lonout),max(lonout),lonout(1)-lonout(0)
mskout=read_ncdf("msk", file=fullfilename_msk,/nostr)
;stop
help, sstkin,lonin,latin,mskin,lonout,latout,mskout

si=size(sstkin)
sstkout=fltarr(jpi,jpj,jptin)
for jt=0,jptin-1 do begin
  print, 'Interpolation jt=',jt,' / ',jptin-1
  tab=reform(sstkin(*,*,jt))
  sstkout(*,*,jt)=call_interp2d(tab,lonin,latin,mskin,lonout,latout,method='bilinear')
  sstkout(*,*,jt)=sstkout(*,*,jt)*mskout+(1.-mskout)*1.e20
endfor


timein=timein & jptin=jpt

initncdf, fullfilename_msk
time=timegen(7670, units='days', start=julday(1,1,1989)) & jpt=n_elements(time)
tt=time
cda0=string(jul2date(time(0)),format='(i8.8)')
cda1=string(jul2date(time(jpt-1)),format='(i8.8)')
timein=timein-julday(1,1,1950,00,00)

lat=latout
lon=lonout
ncfile='!' + fullfilename_out
lon_attr={units:'degrees_east',long_name:'Longitude'}
lat_attr={units:'degrees_north',long_name:'Latitude'}
time_attr={units:'days since 1950-01-01 00:00:00',long_name:'Time axis',time_origin:' 1950-JAN-01 00:00:00'}
sstk_attr={units:'degK',missing_value:1e20,long_name:'Sea Surface Temperature',short_name:'sst',axis:'TYX'}
globattr={source:'Data are from ECMWF ERA-Interim reanalysis', timerange:cda0+' - '+cda1}


ncfields = 'sst[longitude,latitude,time]=sstkout:sstk_attr; ' $
                      + 'longitude[]=lon:lon_attr; ' $
                      + 'latitude[]=lat:lat_attr; ' $
                      + 'time[*time]=timein:time_attr ' $
                      + ' @ globattr'

@ncdf_quickwrite


end